         TITLE 'IECKCVRS  QTAM CONVERSATIONAL MODE (MODE)'              00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-                                                                * 01600013
*   IECKCVRS     QTAM CONVERSATIONAL MODE                             * 02000013
*                                                                     * 02400013
*STATUS-  CHANGE LEVEL= 20         JANUARY 1971                       * 02800021
*                                                                     * 03200013
*FUNCTION-                                                            * 03600013
*        THE CONVERSE BIT IS SET IN THE LCBSTATE FIELD OF THE LCB     * 04000013
*   (LCBSTATE AT LCB + 0 IS OR'ED WITH A X'20').  IF THIS IS THE      * 04400013
*   FIRST TIME THE MACRO IS USED IN THE LPS, THEN THE ROUTINE BRANCHES* 04800013
*   AND LINKS TO ENDINSRT (END INSERT ROUTINE OF IGG019NG).  IF THE   * 05200013
*   IECKCVRS ROUTINE HAS BEEN ENTERED BEFORE, RETURN IS TO THE NEXT   * 05600013
*   LPS INSTRUCTION.                                                  * 06000013
*        THE ENDINSRT ROUTINE PLACES THE ADDRESS OF A SPECIAL ENTRY   * 06400013
*   POINT OF THE CONVERSE ROUTINE (WHICH THE CLEANUP ROUTINE WILL     * 06800013
*   PROCESS FOR IECKCVRS) INTO A CHAIN OF ADDRESSES ACCORDING TO THE  * 07200013
*   PRIORITY SPECIFIED IN THE CODE.  ENDINSRT REPLACES THE SECOND     * 07600013
*   OPERAND OF THE BAL INSTRUCTION OF ENDINSRT WITH THE ADDRESS OF    * 08000013
*   THE NEXT LPS INSTRUCTION, WHICH CAUSES A BRANCH TO THE NEXT LPS   * 08400013
*   INSTRUCTION INSTEAD OF TO ENDINSRT ON SUBSEQUENT PASSES THROUGH   * 08800013
*   IECKCVRS.  ENDINSRT RETURNS VIA THE RETURN REGISTER (3) MINUS     * 09200013
*   FOUR, WHICH RETURNS TO THE SAME BAL INSTRUCTION AFTER IT HAS BEEN * 09600013
*   CHANGED.  THE CODE FOLLOWING THIS BAL INSTRUCTION IS ENTERED FROM * 10000013
*   THE CLEANUP ROUTINE BY A BRANCH TO THE NEXT ROUTINE IN THE ADDRESS* 10400013
*   CHAIN MENTIONED ABOVE.                                            * 10800013
*        IF CONVERSATIONAL MODE HAS NOT BEEN INDICATED, THERE IS AN   * 11200013
*   ERROR MESSAGE TO BE PROCESSED, OR A POLLING OR ADDRESSING ERROR   * 11600013
*   HAS OCCURRED, THEN RETURN IS TO THE NEXT ROUTINE IN THE CHAIN.    * 12000013
*   THE CONVERSATIONAL MODE MUST BE FOR PROCESSING; THEREFORE, IF THE * 12400013
*   QUEUE IS NOT A PROCESSING QUEUE, RETURN IS TO THE NEXT ROUTINE    * 12800013
*   IN THE CHAIN.  IF THE LINE IS RECEIVING, THEN THE ROUTINE BRANCHES* 13200013
*   TO THE LPS CONTROL ROUTINE TO WAIT FOR COMPLETION OF PROCESSING   * 13600013
*   THE INCOMING MESSAGE.  IF A CLOSEDOWN IS IN PROGRESS, RETURN IS   * 13800021
*   MADE TO CLEANUP.  IF THE LINE IS SENDING, THE LINE IS TURNED      * 14000021
*   AROUND TO RECEIVE BY SETTING THE HIGHEST PRIORITY, THE CONVERSE   * 14400013
*   AND RECEIVE BITS AT LCBSTATE (A X'28' IS PLACED IN LCB + 40), AND * 14800013
*   A READ OPERATION CODE AT LCBCEBC (LCB + 4).  IF THE END OF THE    * 15200013
*   POLLING LIST HAS BEEN REACHED, THE START OF THE POLLING LIST IS   * 15600013
*   STORED IN THE LCBPOLPT FIELD AT LCB + 85.  THE FUNCTIONS USUALLY  * 15700021
*   DONE BY BRB RING ROUTINE OF CLEARING LCBERRST AND LCBDLPTR AND    * 15800021
*   REMOVING THE INVALID ADDRESS FROM LCBSTART ARE DONE BY CONVERSE   * 15900021
*   TO TURN THE LINE AROUND AND RESTART POLLING. THE LCBCLCCW FIELD AT* 16000021
*   LCB + 36 IS RESET WITH THE BRB ADDRESS FOR INITIALIZATION OF THE  * 16400013
*   ACTIVATE LINE ROUTINE.  THE ROUTINE THEN ISSUES A POST (SVC 67)   * 16800013
*   TO INSERT BRB INTO THE READY QUEUE.  THE ROUTINE BRANCHES TO THE  * 17200013
*   LPS CONTROL ROUTINE TO WAIT FOR THE MESSAGE TO BE RECEIVED.  THE  * 17600013
*   LPS CONTROL ROUTINE THEN RETURNS TO THE CODE IN THE CONVERSE      * 18000013
*   ROUTINE.  THE SERVICE BIT IS SET IN THE PREFIX OF THE MESSAGE     * 18400013
*   (MSTATUS AT PREFIX + 12 IS OR'ED WITH A X'10') AND THE CONVERSE   * 18800013
*   BIT IS CLEARED IN THE LCBSTATE FIELD OF THE LCB.                  * 19200013
*        IF THE SOURCE TERMINAL WAS NOT IDENTIFIED, THEN RETURN IS TO * 19600013
*   THE START OF THE CLEANUP ROUTINE.  THE CHAIN, POINTED TO BY THE   * 20000013
*   QCB FOR A SOURCE TERMINAL, IS SEARCHED FOR A DEB TO SEE IF THE    * 20400013
*   PROCESS QUEUE CONTAINS A REPLY.  IF THE CHAIN HAS BEEN SEARCHED   * 20800013
*   COMPLETELY, RETURN IS TO THE START OF THE CLEANUP ROUTINE.  IF    * 21200013
*   THERE IS A REPLY, LCBENDOP IS SET TO POINT TO THE LCB IN THE DEB  * 21400021
*   SO DISK END WILL NOT READ AHEAD,AND THE                           * 21600021
*   WRITE OPERATION CODE IS SET IN THE LCBCECB FIELD OF THE LCB.  THE * 22000013
*   ROUTINE POSTS THE ORIGINAL MESSAGE TO THE EMPTY BUFFER QUEUE.     * 22400013
*   THE LCB IS RESTORED WITH THE DISK ADDRESS OF THE REPLY.  THE      * 22800013
*   RELATIVE ADDRESS OF THE EOB IS SET IN THE LCBTRST FIELD OF THE    * 23200013
*   LCB AT LCB + 82.  THE ROUTINE THEN DOES A POST TO THE DISK I/O    * 23600013
*   QUEUE AND BRANCHES TO THE LPS CONTROL ROUTINE TO WAIT FOR THE     * 24000013
*   MESSAGE TO BE RECIVED.                                            * 24400013
*                                                                     * 24800013
*ENTRY POINTS-                                                        * 25200013
*   IECKCVRS - EXPANSION OF THE MODE MACRO WITH CONVERSE AS THE FIRST * 25600013
*              OPERAND AND NO CHARACTER SPECIFIED AS THE SECOND       * 26000013
*              OPERAND GENERATES A BALR TO THIS POINT USING REGISTER  * 26400013
*              1 AS THE BRANCH ADDRESS REGISTER AND REGISTER 14 AS    * 26800013
*              THE RETURN REGISTER.  IF THERE IS A CHARACTER SPECIFIED* 27200013
*              IN THE SECOND OPERAND, THEN THE ADDRESS OF THE CONVERSE* 27600013
*              ROUTINE IS PLACED IN THE PARAMETER REGISTER 1, AND THE * 28000013
*              ROUTINE IS ENTERED BY A BRANCH FROM THE MESSAGE MODE   * 28400013
*              ROUTINE.                                               * 28800013
*                                                                     * 29200013
*INPUT-                                                               * 29600013
*   REGISTER  1- ADDRESS OF THIS ROUTINE WHEN ENTERED FORM MODE MACRO * 30000013
*              EXPANSION.                                             * 30400013
*   REGISTER  4- ADDRESS OF THE LCB.                                  * 30800013
*   REGISTER  6- BUFFER ADDRESS.                                      * 31200013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 31600013
*   REGISTER  8- TERMINAL TABLE SOURCE ENTRY.                         * 32000013
*   REGISTER 14- RETURN ADDRESS.                                      * 32400013
*   REGISTER 15- ADDRESS OF A SECTION OF THIS ROUTINE WHEN ENTERED    * 32800013
*              FROM CLEANUP ROUTINE.                                  * 33200013
*                                                                     * 33600013
*OUTPUT-                                                              * 34000013
*   THE BRB IS INSERTED TO THE READY QUEUE AND POSTED TO THE DISK     * 34400013
*              I/O DEVICE.                                            * 34800013
*                                                                     * 35200013
*EXTERNAL ROUTINES-                                                   * 35600013
*   ENDINSRT - END INSERT ROUTINE IN MODULE IGG019NG TO SET UP THE    * 36000013
*              ADDRESS CHAIN FOR THE CLEANUP ROUTINE.                 * 36400013
*   LPS CONTROL PROGRAM - STARTUP MODULE IN IGG019NG TO WAIT FOR THE  * 36800013
*              MESSAGE TO BE RECEIVED.                                * 37200013
*   QPOST - SVC 67 (MODULE IGG067 IN MODULE IECKQQ01) INSERT THE BRB  * 37600013
*              INTO THE READY QUEUE AND POST TO THE DISK I/O QUEUE.   * 38000013
*                                                                     * 38400013
*EXITS-                                                               * 38800013
*   NORMAL- RETURN FROM FIRST TIME THROUGH IS TO THE NEXT LPS         * 39200013
*              INSTRUCTION.  ON SUCCEEDING ENTRIES FROM CLEANUP,      * 39600013
*              RETURN IS TO STARTUP MODULE IN IGG019NG.               * 40000013
*   ERROR-NONE.                                                       * 40400013
*                                                                     * 40800013
*TABLES/WORK AREAS-                                                   * 41200013
*   NONE.                                                             * 41600013
*                                                                     * 42000013
*ATTRIBUTES-                                                          * 42400013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 42800013
*                                                                     * 43200013
*NOTES-                                                               * 43600013
*   REGISTER  1- BASE REGISTER FOR FIRST SECTION OF THIS ROUTINE WHEN * 44000013
*              ENTERED FROM MACRO EXPANSION.  USED AS A WORK REGISTER * 44400013
*              WHEN ENTERED FROM CLEANUP.                             * 44800013
*   REGISTER  2- WORK REGISTER.                                       * 45200013
*   REGISTER  3- SECOND LEVEL RETURN REGISTER FROM END INSERT AND WORK* 45600013
*              REGISTER.                                              * 46000013
*   REGISTER  9- BASE REGISTER FOR THE QCB DESECT (QCBD MACRO         * 46400013
*              EXPANSION).                                            * 46800013
*   REGISTER 15- BASE REGISTER WHEN THIS ROUTINE IS ENTERED FROM      * 47200013
*              CLEANUP.                                               * 47600013
*                                                                     * 48000013
*********************************************************************** 48400013
IECKCVRS START                                                          48800013
*0300724000                                                        00PS 49000017
* 721000-724000,785000-790000,876800-879200                      A29201 49100019
* 672000,722000                                                  A31036 49150020
*A028000,138000-140000,157000-160000,214000-216000               S21016 49170021
QWAIT    EQU   65                                                       49200013
QPOST    EQU   67                                                       49600013
DREG1    EQU   1                                                        50000013
FREG     EQU   1                                                        50400013
TREG     EQU   2                                                        50800013
Y        EQU   3                                                        51200013
LCBREG   EQU   4                                                        51600013
X        EQU   6                                                        52000013
LGREG    EQU   7                                                        52400013
TCREG    EQU   8                                                        52800013
QREG     EQU   9                                                        53200013
TCBREG   EQU   10                                                       53600013
BREG     EQU   12                                                       54000013
RREG1    EQU   14                                                       54400013
         USING IECKLCB0,LCBREG                                          54800013
         USING *,DREG1                                                  55200013
         OI    LCBSTATE,X'20'      SET CONVERSE BIT IN LCB              55600013
         CNOP  0,4                                                      56000013
         L     3,0(13)                 ADDRESS OF LPS SECTION OF NG     56400013
         BAL   3,300(0,3)              TO ROUTINE ENDINSRT IN NG.       56800013
*                                  THIS IS A FIRST TIME SWITCH WITH THE 57200013
*                                  BRANCH ADDRESS BEING CHANGED IN      57600013
*                                  ENDINSRT CAUSING THE INSTRUCTION     58000013
*                                  TO BECOME AS FOLLOWS:                58400013
*                                      BAL   3,4(0,14)                  58800013
*                                  THE ADDRESS IS OVERLAID WITH LAST    59200013
*                                  TWO BYTES OF THE FOLLOWING CONSTANT  59600013
         USING IECKPREF,FREG                                            60000013
         USING QBLOCK,QREG                                              60400013
         USING *,15                                                     60800013
         DC    X'4000E004'     USED IN IGG019NG TO MODIFY ABOVE BRANCH  61200013
*                                  AND OVERLAID BY ENDINSRT TO BECOME   61600013
*                                  THE ADDRESS OF THE NEXT ROUTINE IN   62000013
*                                  THE QUEUE FOR THE CLEANUP ROUTINE.   62400013
*                                                                       62800013
*                              THIS IS THE CLEANUP ROUTINE ENTRY POINT  63200013
         TM    LCBSTATE,X'A0'  IS THIS CONVERSATIONAL MODE AND IS THE   63600013
*                                  ORIGINAL MESSAGE THRU PROCESSING     64000013
         BCR   14,14           NOT CONVERSATIONAL MODE OR ERROR         64400013
*                                   MESSAGE MUST BE PROCESSED - RETURN  64800013
*                                   TO THE CLEANUP ROUTINE              65200013
         TM    LCBERRST+1,8    IS THERE A POLLING OR ADDRESSING ERROR   65600013
         BCR   1,14            RETURN IF ERROR TO CLEANUP               66000013
         L     FREG,LCBDESTQ-1 LOAD REG WITH MESSAGE DESTINATION ADDRES 66400013
         CLI   4(FREG),1       IS THIS A PROCESS OR DESTINATION QUEUE   66800013
         BCR   7,14            NOT PROCESS QUEUE - RETURN               67200013
         LR    1,14                SAVE RETURN ADDRESS           A31036 67400020
         L     14,0(0,13)      GET ADDRESS OF LPS QUEUE                 67600013
         TM    LCBSTATE,X'08'  IS LINE RECEIVING                        68000013
         BZ    RECV            IF NOT: BRANCH TO TURN LINE TO RECEIVE   68400013
         LA    3,CVRET         SET RETURN AFTER MESSAGE IS PROCESSED    68800013
         STM   14,3,LCBCPA     SAVE RETURN REGS IN CHANNEL PROGRAM AREA 69200013
         TM    LCBSTATE,X'10'  HAS MESASAGE BEEN PROCESSED              69600013
         BNZ   232(0,14)       BRANCH TO STARTUP IF NOT PROCESSED YET   70000013
*                                   FOR COMPLETION OF PROCESSING FOR    70400013
*                                   INCOMING MESSAGE - REENTER AT CVRET 70800013
         MVI   LCBSTATE,X'E6'      SET SEND AND                         71200013
         B     RESUMEX         BRANCH TO TEST FOR REPLY IN QUEUE        71600013
*  LINE IS NOT RECEIVING - FOLLOWING TURNS THE LINE AROUND TO RECEIVE   72000013
RECV     TM    288(RREG1),X'0F'    IS CLOSEDOWN IN PROGRESS      A29201 72100019
         BCR   14,1                BRANCH YES TO CLEANUP TO      A31036 72200020
*                                    AVOID RE-POLL               A29201 72300019
         MVI   LCBSTATE,8          SET RECEIVE IN LCBSTATE       A29201 72400019
         MVI   LCBCECB,1       SET READ INITIAL OP FOR BTAM IN DECB     72800013
         L     QREG,LCBPOLPT-1 GET ADDRESS OF POLLING CHARACTERS        73200013
         OC    0(2,QREG),0(QREG)  IS THIS THE END OF THE POLLING LIST   73600013
         BNZ   RESUMEX               NO - USEABLE POLLING CHARACTERS    74000013
*  THE FOLLOWING FINDS THE START OF THE POLLING LIST                    74400013
         L     QREG,LCBUCBX    GET UCB INDEX FROM THE LCB               74800013
         SRL   QREG,24         ALIGN INDEX                              75200013
         SLL   QREG,2                                                   75600013
         A     QREG,LCBDCBPT   ADD DCB POINTER TO INDEX                 76000013
         L     QREG,DCBCPOLL-IHADCB(0,QREG)  INCREMENT BY DCB SIZE      76400013
         LA    QREG,2(0,QREG)  FINAL ADJUSTMENT                         76800013
         ST    QREG,LCBPOLPT-1 RESTORE LCB POLL POINTER                 77200013
RESUMEX  L     FREG,LCBCLPCI-1 GET ADDR OF CURRENT BUFFER REQUEST BLOCK 77600013
         MVI   FPRI,X'EC'      SET UP HIGHEST PRIORITY                  78000013
         LA    TREG,12(0,14)   GET ADDR OF ACTIVE BUFFER REQUEST QUEUE  78400013
RESUME   SR    QREG,QREG           CLEAR REGISTER                A29201 78500019
         STH   QREG,LCBERRST       CLEAR ERROR HALF WORD         A29201 78600019
         STH   QREG,LCBDLPTR       CLEAR DISTRIBUTION LIST POINTER29201 78700019
         NI    LCBSTART+2,X'FC'    REMOVE INVALID ADDRESS FROM   A29201 78800019
*                                    CHANNEL PROGRAM CHECK       A29201 78900019
         LA    Y,LCBCLPCI-9        INITIALIZE FOR ACTIVATE       A29201 79000019
         ST    Y,LCBCLCCW      RESET THE BRB ADDRESS IN LCB             79200013
         SVC   QPOST           INSERTS BRB INTO READY QUEUE             79600013
*                                  AND POSTS TO THE DISK I/O QUEUE      80000013
         B     232(0,14)       WAIT FOR MESSAGE TO BE RECEIVED          80400013
*  THE FOLLOWING LOOKS FOR A REPLY IN THE PROCESS QUEUE                 80800013
CVRET    OI    MSTATUS-FBLOCK(X),X'10' SET SERVICED BIT IN PREFIX       81200013
         NC    LCBTTIND,LCBTTIND   HAS SOURCE TERMINAL BEEN IDENTIFIED  81600013
         BZ    244(0,14)  SOURCE NOT IDENTIFIED - GO TO CLEANUP ROUTINE 82000013
         L     QREG,0(0,TCREG) SET UP QCB FOR SOURCE TERMINAL           82400013
         SR    FREG,FREG           CLEAR A TESTING REGISTER             82800013
LOOK     L     QREG,QSORCE-1   GET ADDRESS OF FIRST LCB ON CHAIN        83200013
         BCTR  QREG,0          CLEAR LOW ORDER BIT WHICH                83600013
*                                 IS USED AS A SWITCH                   84000013
         CLI   QDUMMY,0        ARE WE BACK TO QCB AGAIN                 84400013
         BE    ANYPROC         YES - GO TEST FOR ANY REPLY FOUND        84800013
         CLI   8(QREG),X'12'   IS THIS AN LCB IN CHAIN                  85200013
         BE    LOOK            BRANCH IF YES - LOOKING FOR A DEB IN     85600013
*                                  QUEUE TO IDENTIFY A PROCESS QUEUE    86000013
         LR    FREG,QREG           SAVE LCB ADDRESS                     86400013
         B     LOOK                SCAN FOR LAST LCB                    86800013
ANYPROC  LTR   FREG,FREG           WAS THERE A REPLY IN THE QUEUE       87200013
         BZ    244(14)             BRANCH IF NO TO CLEANUP              87600013
         IC    TREG,LCBSTATE       SAVE LCBSTATE                 A29201 87680019
         ST    FREG,LCBENDOP-1     POINT LCB TO DUMMY LCB IN     A29201 87760019
*                                    PROCESS QUEUE DEB           A29201 87840019
         STC   TREG,LCBSTATE       RESTORE LCBSTATE              A29201 87920019
         LR    QREG,FREG           ELSE ACCESS LAST PROCESS LCB CHAINED 88000013
         MVI   LCBCECB,2           SET WRITE INITIAL OP FOR BTAM        88400013
         LR    FREG,X          GET BUFFER ADDRESS IN FREG               88800013
         LA    TREG,24(0,14)   GET ADDRESS OF THE EMPTY BUFFER QUEUE    89200013
         SVC   QPOST           POST ORIGINAL MESSAGE TO EMPTY BUFFER Q  89600013
         L     FREG,LCBCLPCI-1 GET THE BRB ADDRESS                      90000013
         MVC   LCBRCADD,QNASEG RESTORE LCB WITH DISK ADDRESS OF REPLY   90400013
         MVC   LCBCHDR,QNASEG                                           90800013
         MVC   LCBCSEG,QNASEG                                           91200013
         MVC   MSLCB,QNASEG                                             91600013
         MVI   MSTATUS,9       SET TO INDICATE DISK ADDRESS IN MSLCB    92000013
         MVI   FPRI,X'E0'      RESTORE TO LOWEST PRIORITY               92400013
         LA    TREG,HDSTRT-MSEGSZE GET RELATIVE ADDR OF EOB CHARACTER   92800013
         STH   TREG,LCBTRST    STORE IN LCB                             93200013
         LA    TREG,36(0,14)   GET THE ADDRESS OF THE DISK I/O QUEUE    93600013
         B     RESUME          GO WAIT FOR REPLY FROM DISK              94000013
         EJECT                                                          94400013
         PREFIXD                                                        94800013
         EJECT                                                          95200013
         QCBD                                                           95600013
         EJECT                                                          96000013
         LCBD  QTAM=3                                                   96400013
         EJECT                                                          96800013
         DCBD  DSORG=(QX)                                               97200013
         END                                                            97600013
