         TITLE 'IECKDATE  QTAM DATESTAMP (DATESTMP)'                    01000013
*********************************************************************** 02000013
*                                                                     * 03000013
*NAME-                                                                * 04000013
*   IECKDATE     QTAM DATE STAMP (DATESTMP)                           * 05000013
*                                                                     * 06000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 07000013
*                                                                     * 08000013
*FUNCTION-                                                            * 09000013
*        LINKS TO EXPAND ROUTINE TO EXPAND HEADER BY FIVE BYTES TO    * 10000013
*   ALLOW FOR THE DATE INFORMATION.  CURRENT DATE IS OBTAINED         * 11000013
*   IN PACKED DECIMAL FORM.  ROUTINE UNPACKS THE DATA AND INSERTS     * 12000013
*   IT INTO THE MESSAGE HEADER IN THE FORMAT BYY.DDD , WHERE B=BLANK  * 13000013
*   YY=YEAR, AND DDD=DAY OF THE YEAR.                                 * 14000013
*                                                                     * 15000013
*ENTRY POINTS-                                                        * 16000013
*   IECKDATE - EXPANSION OF THE DATESTMP MACRO GENERATES A BALR TO    * 17000013
*        THIS POINT, USING REGISTER 15 AS THE ENTRY POINT REGISTER.   * 18000013
*                                                                     * 19000013
*INPUT-                                                               * 20000013
*   REGISTER 14- RETURN ADDRESS.                                      * 21000013
*        REGISTER 14 ALSO POINTS TO A HALFWORD PARAMETER, THE LENGTH  * 22000013
*        (IN BINARY) OF THE DATE FIELD TO BE INSERTED IN THE MESSAGE  * 23000013
*        HEADER.  THIS PARAMETER WILL BE USED BY THE EXPAND ROUTINE.  * 24000013
*   REGISTER 15- ENTRY POINT.                                         * 25000013
*                                                                     * 26000013
*OUTPUT-                                                              * 27000013
*   THE DATE WILL BE INSERTED IN THE MESSAGE HEADER.                  * 28000013
*                                                                     * 29000013
*EXTERNAL ROUTINES-                                                   * 30000013
*   IECKEXPD - TO PROVIDE SPACE IN THE HEADER FOR THE DATE.           * 31000013
*                                                                     * 32000013
*EXITS-                                                               * 33000013
*   NORMAL- RETURN TO THE NEXT LPS INSTRUCTION BY BRANCHING AROUND    * 34000013
*        MACRO GENERATED CONSTANT.  BRANCH IS ON REGISTER 3.          * 35000013
*   ERROR- NONE.                                                      * 36000013
*                                                                     * 37000013
*TABLES/WORK AREAS-                                                   * 38000013
*   DATEWORD- USED AS WORK AREA IN UNPACKING DATE INFORMATION.        * 39000013
*                                                                     * 40000013
*ATTRIBUTES-                                                          * 41000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 42000013
*                                                                     * 43000013
*NOTES-                                                               * 44000013
*   REGISTER  1- USED AS A WORK REGISTER.  WILL RECEIVE THE TIME AND  * 45000013
*        DATE INFORMATION FROM THE SUPERVISOR.                        * 46000013
*   REGISTER  2- USED AS A BASE REGISTER.                             * 47000013
*   REGISTER  3- RETURN ADDRESS TO NEXT LPS INSTRUCTION.              * 48000013
*   REGISTER 10- WILL CONTAIN ADDRESS OF FIRST BYTE IN EXPANDED FIELD * 49000013
*        WHEN CONTROL RETURNS FROM EXPAND.                            * 50000013
*                                                                     * 51000013
*********************************************************************** 52000013
IECKDATE START                                                          53000013
DREG0    EQU   0                                                        54000013
DATEREG  EQU   1                                                        55000013
TREG     EQU   2                                                        56000013
RREG2    EQU   3                                                        57000013
WREG2    EQU   10                                                       58000013
RREG1    EQU   14                                                       59000013
SREG     EQU   15                                                       60000013
         BALR  TREG,0                                                   61000013
         USING *,TREG                                                   62000013
         L     SREG,=V(IECKEXPD)   GET ADDRESS OF THE EXPAND ROUTINE    63000013
         BALR  RREG2,SREG          LINK TO EXPAND SUBROUTINE            64000013
         LR    RREG2,RREG1         SAVE RETURN REGISTER                 65000013
         TIME  DEC                 OBTAIN TIME AND DATE FROM SUPERVISOR 66000013
         SLL   DATEREG,8           SHIFT LEFT ONE BYTE                  67000013
         ST    DATEREG,TEMP        PREPARE FOR EXPANSION                68000013
         UNPK  DATEWORD+1(5),TEMP(3) CHANGE TO ZONED FORMAT             69000013
         OI    DATEWORD+5,X'F0'    ENSURE ZONES IN LOW ORDER            70000013
         MVC    DATEWORD(2),DATEWORD+1  EXPAND DATE ONE BYTE            71000013
         MVI   DATEWORD+2,X'4B'    AND INSERT PERIOD   YY.DDD           72000013
         MVC   1(6,WREG2),DATEWORD INSERT DATE INTO HEADER              73000013
         B     2(0,RREG2)          RETURN                               74000013
DATESZE  DC    X'0007'             LENGTH OF DATE FIELD                 75000013
DATEWORD DS    1D                                                       76000013
TEMP     DS    1F                                                       77000013
DATE     DC    X'0065096C'                                              78000013
         DS    0F                                                       79000013
         END                                                            80000013
