         TITLE 'IECKDCBL - QTAM LOCATE DCB ROUTINE'                     00800013
*********************************************************************** 01600013
*                                                                     * 02400013
*NAME-                                                                * 03200013
*   IECKDCBL   QTAM LOCATE DCB                                        * 04000013
*                                                                     * 04800013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 05600013
*                                                                     * 06400013
*FUNCTION-                                                            * 07200013
*        IECKDCBL LOCATES THE DCB FOR A SPECIFIED TERMINAL.           * 08000013
*        THIS ROUTINE IS USED AS A SECOND LEVEL ROUTINE BY STOPLN,    * 08800013
*   STARTLN, COPYP, AND CHNGP TO LOCATE THE DESIRED DCB.              * 09600013
*        THE ADDRESS OF THE TERMINAL TABLE IS RETRIEVED FROM THE      * 10400013
*   COMMUNICATIONS VECTOR TABLE.  THE TABLE IS SCANNED FOR THE        * 11200013
*   PROPER DESTINATION CODE.  IF THE DESTINATION CODE IS NOT FOUND,   * 12000013
*   A RETURN CODE OF X'20' IS RETURNED TO THE CALLING ROUTINE.        * 12800013
*        IF THE TERMINAL TABLE ENTRY IS FOUND, THE ADDRESS OF THE     * 13600013
*   QCB FOR THAT DESTINATION IS OBTAINED AND A TEST IS MADE TO        * 14400013
*   DETERMINE THE TYPE OF TABLE ENTRY.  IF IT IS A LIST OR PROCESS    * 15200013
*   ENTRY, AN ERROR CODE OF X'20' IS RETURNED TO THE CALLING          * 16000013
*   ROUTINE.                                                          * 16800013
*        IF THAT ENTRY WAS NOT A LIST OR PROCESS ENTRY, THE ADDRESS   * 17600013
*   OF THE DCB IS RETRIEVED FROM THE QCB AND PLACED IN REGISTER 0.    * 18400013
*   THE RELATIVE LINE NUMBER IS INSERTED INTO THE HIGH ORDER BYTE     * 19200013
*   OF THAT REGISTER.  A NORMAL RETURN CODE OF X'00' IS SET IN        * 20000013
*   REGISTER 15, AND CONTROL RETURNS TO THE CALLING ROUTINE.          * 20800013
*                                                                     * 21600013
*ENTRY POINTS-                                                        * 22400013
*   IECKDCBL - EXPANSION OF THE STOPLN, STARTLN, COPYP, OR CHNGP      * 23200013
*        MACRO INSTRUCTION GENERATES A BALR TO THIS POINT, USING      * 24000013
*        REGISTER 15 AS THE ENTRY POINT REGISTER AND REGISTER 14 AS   * 24800013
*        THE RETURN REGISTER.                                         * 25600013
*                                                                     * 26400013
*INPUT-                                                               * 27200013
*   REGISTER  1- ADDRESS OF THE TERMINAL NAME TO BE FOUND.            * 28000013
*   REGISTER 14- RETURN ADDRESS.                                      * 28800013
*   REGISTER 15- ENTRY POINT ADDRESS.                                 * 29600013
*                                                                     * 30400013
*OUTPUT-                                                              * 31200013
*   REGISTER  6- IF THE PROPER ENTRY IS FOUND, AND IT IS NOT A LIST   * 32000013
*        OR PROCESS TERMINAL, THEN THIS REGISTER WILL HAVE THE        * 32800013
*        RELATIVE LINE NUMBER IN THE HIGH ORDER BYTE, AND THE         * 33600013
*        ADDRESS OF THE DCB IN THE LOW ORDER THREE BYTES.             * 34400013
*   REGISTER 15- THE CONDITION CODE WILL BE RETURNED HERE:            * 35200013
*        X'00'- NO ERRORS                                             * 36000013
*        X'20'- TERMINAL TABLE ENTRY NOT FOUND, OR                    * 36800013
*               ENTRY IS LIST OR PROCESS ENTRY.                       * 37600013
*                                                                     * 38400013
*EXTERNAL ROUTINES-                                                   * 39200013
*   NONE.                                                             * 40000013
*                                                                     * 40800013
*EXITS-                                                               * 41600013
*   NORMAL- RETURN IS ACCOMPLISHED BY ISSUING A RETURN MACRO. RETURN  * 42400013
*        CODE IS X'00'.                                               * 43200013
*   ERROR - SAME AS ABOVE, BUT WITH ERROR CODE OF X'20'.              * 44000013
*                                                                     * 44800013
*TABLES/WORK AREAS-                                                   * 45600013
*   NONE.                                                             * 46400013
*                                                                     * 47200013
*ATTRIBUTES-                                                          * 48000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 48800013
*                                                                     * 49600013
*NOTES-                                                               * 50400013
*   REGISTER  4- WORK REGISTER. ADDRESS OF THE TERMINAL TABLE.        * 51200013
*   REGISTER  5- WORK REGISTER. MAXIMUM SIZE OF ANY TERMID ENTRY.     * 52000013
*   REGISTER  6- WORK REGISTER. LENGTH OF TERMINAL TABLE ENTRY.       * 52800013
*   REGISTER  8- WORK REGISTER. ADDRESS OF END OF TABLE.              * 53600013
*   REGISTER  9- WORK REGISTER. ERROR FLAG.                           * 54400013
*                                                                     * 55200013
*********************************************************************** 56000013
IECKDCBL START                                                          56800013
R1       EQU   1                                                        57600013
TERM     EQU   4                                                        58400013
LEN      EQU   5                                                        59200013
WK       EQU   6                                                        60000013
WK1      EQU   7                                                        60800013
LAST     EQU   8                                                        61600013
FLAG     EQU   9                                                        62400013
SREG     EQU   15                                                       63200013
*                                                                       64000013
CVTTRMTB EQU   156                                                      64800013
INVALID  EQU   32                                                       65600013
         EJECT                                                          66400013
         USING *,SREG                                                   67200013
         SAVE  (4,12)                                                   68000013
         L     TERM,16                 LOAD ADDRESS OF THE CVT          68800013
         L     TERM,CVTTRMTB(TERM)     NOW CONTAINS TERM TABLE ADDRESS  69600013
         SR    FLAG,FLAG               SET RETURN CODE TO ZERO          70400013
         SR    LEN,LEN                                                  71200013
         IC    LEN,4(TERM)             MAX. SIZE OF TERM NAME           72000013
NONE     BCTR  LEN,0                   SUB ONE FOR COMPARE INSTRUCTION  72800013
         SR    WK,WK                   ZERO REGISTER                    73600013
         L     LAST,0(TERM)            ADDRESS OF LAST TERM ENTRY       74400013
         LA    TERM,8(TERM)            ADDRESS OF FIRST TERM ENTRY      75200013
NEXT     EX    LEN,COMPARE             COMPARE TERM NAMES               76000013
         BE    FOUND                   BRANCH IF TERM NAMES EQUAL       76800013
         IC    WK,0(TERM)              LENGTH OF THIS TERM ENTRY        77600013
         LA    TERM,0(TERM,WK)         ADDRESS OF NEXT ENTRY            78400013
         CR    TERM,LAST               PAST LAST ENTRY                  79200013
         BH    ERROR                   BRANCH YES- TERMNAME INVALID     80000013
         B     NEXT                    GO COMPARE NEXT ENTRY            80800013
FOUND    L     WK,0(TERM)              LOAD ADDRESS OF ASSOCIATED QCB   81600013
         CLI   8(WK),X'68'             TEST FOR TERMINAL TYPE ENTRY     82400013
         BNE   ERROR                   BRANCH LIST OR PROCESS ENTRY     83200013
         L     WK,16(WK)               DCB ADDRESS                      84000013
         LA    WK,0(WK)                CLEAR HIGH ORDER BYTE            84800013
         ALR   0,WK                    COMBINE RLN AND DCB ADDRESS      85600013
         B     RET                     EXIT                             86400013
ERROR    LA    FLAG,INVALID            SET ERROR RETURN CODE            87200013
RET      LR    15,FLAG                 RETURN CODE TO REGISTER 15       88000013
         RETURN (4,12)                                                  88800013
COMPARE  CLC   9(1,TERM),0(R1)         COMPARE TERMINAL NAMES           89600013
         END                                                            90400013
