         TITLE 'IECKDLQT  QTAM DISTRIBUTION-LIST'                       00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-                                                                * 01600013
*   IECKDLQT   QTAM DISTRIBUTION-LIST                                 * 02000013
*                                                                     * 02400013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 02800013
*                                                                     * 03200013
*FUNCTION-                                                            * 03600013
*        IECKDLQT WILL PUT A MESSAGE ON THE QUEUE FOR A PARTICULAR    * 04000013
*   DISTRIBUTION LIST WHEN THAT LIST NAME IS SPECIFIED AS THE         * 04400013
*   DESTINATION.  THE ROUTINE WILL ALSO ROUTE THE MESSAGE TO THE      * 04800013
*   DESTINATIONS SPECIFIED IN THE DISTRIBUTION LIST.                  * 05200013
*        THE DESTINATION KEY IS OBTAINED FROM THE MESSAGE HEADER AND  * 05600013
*   STORED IN THE LCBDLPTR (LCB + 46) FIELD OF THE LCB.  THIS KEY IS  * 06000013
*   THE OFFSET OF THE DISTRIBUTION LIST ENTRY FROM THE BEGINNING OF   * 06400013
*   THE TERMINAL TABLE.  THE ADDRESS OF THE TERMINAL TABLE IS ADDED   * 06800013
*   TO THIS OFFSET TO GIVE THE ADDRESS OF THE LIST ENTRY.  THE        * 07200013
*   DESTINATION ENTRIES ARE KEPT IN THE DISTRIBUTION LIST ENTRY AS    * 07600013
*   OFFSETS OF THAT TERMINAL TABLE ENTRY FROM THE BEGINNING OF THE    * 08000013
*   TABLE.  THE OFFSET OF THE FIRST ENTRY IS OBTAINED AND INDEXED     * 08400013
*   TO THE BEGINNING OF TABLE ADDRESS TO YIELD THE ADDRESS IN THE     * 08800013
*   TERMINAL TABLE CORRESPONDING TO THE FIRST ENTRY IN THE            * 09200013
*   DISTRIBUTION LIST.  THE QCB FOR THAT ENTRY IS MOVED TO LCBDESTQ   * 09600013
*   (LCB + 29).                                                       * 10000013
*        IF THIS IS THE FIRST TIME THROUGH THIS ROUTINE EVER, THEN    * 10400013
*   CONTROL IS PASSED TO THE ENDINSRT ROUTINE IN IGG019NG.  ENDINSERT * 10800013
*   WILL PUT THIS ROUTINE ON A QUEUE FOR ROUTINES TO BE EXECUTED BY   * 11200013
*   CLEANUP.  THE BRANCH TO ENDINSRT FROM IECKDLQT IS MODIFIED SO     * 11600013
*   THAT HEREAFTER THIS BRANCH WILL BE TO THE PRIORITY ROUTINE.       * 12000013
*   THE MESSAGE IS POSTED TO THE DISTRIBUTION LIST QUEUE.             * 12400013
*        AT CLEANUP TIME FOR THIS MESSAGE, CONTROL WILL PASS TO       * 12800013
*   THE ENTRY POINT DLRET.  THIS BEGINS THE SECOND                    * 13200013
*   FUNCTION OF THIS ROUTINE: DISTRIBUTING THE MESSAGE TO THE         * 13600013
*   DESIRED QUEUES FOR SUBSEQUENT TRANSMISSION.                       * 14000013
*        THE ROUTINE WILL OBTAIN THE OFFSETS FROM THE DISTRIBUTION    * 14400013
*   LIST, ADD THE ADDRESS OF THE TERM TABLE AND GET THE QCB FROM THE  * 14800013
*   TABLE ENTRY.  THE MESSAGE HEADER IS RECALLED USING THE RECALL     * 15200013
*   ROUTINE, AND THE DESTINATION CODE IS PLACED IN THE TTDKEY         * 15600013
*   (TERMINAL TABLE ADDRESS + 26) FIELD OF THE HEADER PREFIX.         * 16000013
*   CONTROL IS PASSED TO THE BUFFER CLEANUP ROUTINE TO POST THE       * 16400013
*   MESSAGE TO THE PROPER DESTINATION QUEUE.                          * 16800013
*        WHEN CLEANUP HAS COMPLETED ITS FUNCTION, CONTROL IS AGAIN    * 17200013
*   PASSED TO THE DLRET ENTRY IN THIS ROUTINE.  THE POINTER TO        * 17600013
*   OFFSETS IN THE DISTRIBUTION LIST IS UPDATED.  THIS CYCLE IS       * 18000013
*   REPEATED UNTIL ALL THE ENTRIES IN THE LIST HAVE BEEN HANDLED.     * 18400013
*   CONTROL PASSES TO THE POINT IN THE CLEANUP ROUTINE WHICH WILL     * 18800013
*   HANDLE FINAL CLEANUP AT THIS TIME.                                * 19200013
*                                                                     * 19600013
*ENTRY POINTS-                                                        * 20000013
*   THERE ARE TWO UNLABELED ENTRY POINTS. THE FIRST IS AT IECKDLQT+14.* 20400013
*        ENTRY HERE IS FROM IECKQQ01 WHEN THE DESTINATION CODE FOR A  * 20800013
*        MESSAGE IS A DISTRIBUTION LIST.                              * 21200013
*        THE SECOND IS ENTERED FROM THE CLEANUP ROUTINE AFTER THE     * 21600013
*        MESSAGE HAS BEEN PUT ON THE DESTINATION QUEUE, AND THE LCB   * 22000013
*        FOR THIS DESTINATION CODE HAS COME TO THE TOP OF THE         * 22400013
*        READY QUEUE.                                                 * 22800013
*                                                                     * 23200013
*INPUT-                                                               * 23600013
*   REGISTER 1- ADDRESS OF THE ECB FOR THE BUFER.                     * 24000013
*                                                                     * 24400013
*OUTPUT-                                                              * 24800013
*   NONE.                                                             * 25200013
*                                                                     * 25600013
*EXTERNAL ROUTINES-                                                   * 26000013
*   ENDINSRT (IN MODULE IGG019NG).                                    * 26400013
*   PRIORITY (IN MODULE IECKQQQ1).                                    * 26800013
*   RECALL  (IECKRC IN MODULE IGG019NG).                              * 27200013
*                                                                     * 27600013
*EXITS-                                                               * 28000013
*   NORMAL - CONTROL PASSES TO THE CLEANUP ROUTINE (IECKPR) TO POST   * 28400013
*        MESSAGE TO DISTRIBUTION LIST QUEUE.  EXIT IS TO AN UNLABLED  * 28800013
*        POINT IN CLEANUP WHEN ALL DESTINATIONS HAVE BEEN PROCESSED.  * 29200013
*                                                                     * 29600013
*TABLES/WORK AREAS-                                                   * 30000013
*   NONE.                                                             * 30400013
*                                                                     * 30800013
*ATTRIBUTES-                                                          * 31200013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 31600013
*                                                                     * 32000013
*   NOTES-                                                            * 32400013
*   REGISTER  0- THE OFFSET OF THE DESIRED DESTINATION ENTRY FROM     * 32800013
*        THE BEGINNING OF THE TERMINAL TABLE.                         * 33200013
*   REGISTER  4- BASE FOR THIS LCB.                                   * 33600013
*   REGISTER  8- DESTINATION KEY FOR DISTRIBUTION LIST.               * 34000013
*   REGISTER  9- BASE FOR THIS ROUTINE.                               * 34400013
*   REGISTER 12- BASE FOR CONTROL PROGRAM.                            * 34800013
*                                                                     * 35200013
*********************************************************************** 35600013
IECKDLQT START                                                          36000013
*2010686000                                                        6930 36200016
QWAIT    EQU   65                                                       36400013
DREG0    EQU   0                                                        36800013
FREG     EQU   1                                                        37200013
TREG     EQU   2                                                        37600013
Y        EQU   3                                                        38000013
LCBREG   EQU   4                                                        38400013
X        EQU   6                                                        38800013
MSREG    EQU   6                                                        39200013
TCREG    EQU   8                                                        39600013
QREG     EQU   9                                                        40000013
TCBREG   EQU   10                                                       40400013
BREG     EQU   12                                                       40800013
*            IN THIS ROUTINE, REGISTER 13 HAS A POINTER TO IGG019NG     41200013
         SPACE                                                          41600013
         USING IECKLCB0,LCBREG                                          42000013
         USING IECKPREF,FREG                                            42400013
         USING IECKDLQT,9                                               42800013
         USING CTLPROG+2,BREG                                           43200013
* DISTRIBUTION-LIST SUBTASK                                             43600013
*      STCB--PRE-ASSEMBLED IN MODULE IECKDLQT, LOCATED AT IECKDLQT+8.   44000013
*      PROGRAM ENTRY--ENTERS THE MODULE AT IECKDLQT + 14.               44400013
* DISTRIBUTION LIST QUEUE                                               44800013
*      QCB--PRE-ASSEMBLED IN THE MODULE (IECKDLQT) INTRODUCED           45200013
*      BY THE APPEARANCE OF THE LIST MACRO-INSTR IN THE PROB PROG.      45600013
*      ELEMENT CHAIN--LIMITED TO THE DUMMY LAST ELEMENT                 46000013
*      LABELED IECKSTOP.  NO ELEMENT CHAIN IS DEVELOPED.                46400013
*      ELEMENTS RELATED TO A DISTRIBUTION LIST ARE                      46800013
*      IMMEDIATELY TRANSFERRED TO THE DESTINATION-DASD                  47200013
*      QUEUE FOR THE FIRST TERMINAL IN THE DISTRIBUTION LIST.           47600013
*      STCB--LIMITED TO THE STCB FOR THE DISTRIBUTION-LIST SUBTASK.     48000013
         DC    2A(0)                                                    48400013
         DC    AL1(2)                                                   48800013
         DC    AL3(IECKDLQT+8)                                          49200013
         DC    AL1(255)                                                 49600013
         L     LCBREG,MSLCB-1      GET ADDRESS OF LCB FROM PREFIX       50000013
         LH    TCREG,TTDKEY        GET DESTINATION KEY FROM PREFIX      50400013
         LA    15,DLRET            ESTABLISH NEW BASE SO THAT REGISTER  50800013
*                                          9 CAN BE USED                51200013
         USING DLRET,15                                                 51600013
         BAL   14,DLTEST           GO GET ADDRESS OF NEXT ENTRY IN LIST 52000013
         NOP   0             ENTRY POINT WHEN USER HAS SPECIFIED LIST   52400013
*                                  WITHOUT ENTRIES                      52800013
         STH   DREG0,TTDKEY        PUT OFFSET IN PREFIX                 53200013
         MVC   1(3,FREG),1(TCREG)  PUT QCB FOR DESTINATION INTO ECB     53600013
*                                        OF BUFFER                      54000013
         LA    9,80(0,13)          GET ADDRESS OF READY QUEUE           54400013
         SPACE                                                          54800013
         CNOP  0,4                                                      55200013
         L     3,0(13)                 ADDRESS OF LPS SECTION OF NG     55600013
         BAL   3,300(0,3)              TO ROUTINE ENDINSRT IN NG. THIS  56000013
*                                        BRANCH ADDRESS CHANGED IN THE  56400013
*                                        ENDINSRT ROUTINE OF IGG019NG   56800013
*                                        SO THAT THE BRANCH IS TO       57200013
*                                        PRIORITY AFTER FIRST TIME      57600013
DLRET    DC    X'C000'             THIS IS OVERLAID IN THE ENDINSRT     58000013
         DC    S(PRIORITY)               ROUTINE OF IGG019NG TO BE THE  58400013
*                                        ADDRESS OF THE NEXT ROUTINE    58800013
*                                        IN THE QUEUE                   59200013
         USING IECKPREF,MSREG                                           59600013
         LH    TCREG,LCBDLPTR      GET OFFSET TO DISTRIBUTION LIST      60000013
         LTR   TCREG,TCREG         IS THERE AN ENTRY                    60400013
         BCR   8,14                BRANCH IF NO                         60800013
         MVC   LCBCECB+1(3),LCBCHDR  SAVE HEADER FOR INSERTION IN QUEUE 61200013
*                                        OF NEXT DESTINATION            61600013
         LA    TCREG,2(0,TCREG)    BUMP TO NEXT ENTRY IN LIST           62000013
DLTEST   STH   TCREG,LCBDLPTR      STORE DESTINATION KEY IN POINTER     62400013
*                                        TO NEXT ENTRY IN DISTRIBUTION  62800013
*                                            LIST                       63200013
         A     TCREG,=V(TERMTBL)   GET ADDRESS OF LIST                  63600013
         LH    TCREG,18(0,TCREG)   GET OFFSET TO LIST ENTRY IN TABLE    64000013
         LTR   DREG0,TCREG         IS THERE AN ENTRY IN TERMTBL         64400013
         BCR   8,14                BRANCH IF NO                         64800013
         A     TCREG,=V(TERMTBL)   ELSE GET ADDRESS OF ENTRY            65200013
         MVC   LCBDESTQ,1(TCREG)   PUT QCB ADDRESS IN LCB               65600013
         BAL   3,4(0,14)           WHEN THIS ROUTINE IS ENTERED FROM    66000013
*                                        IGG019NG, THIS BRANCH GOES TO  66400013
*                                        A SPECIAL ENTRY IN THE RECALL  66800013
*                                        ROUTINE TO RETRIEVE THE HEADER 67200013
*                                        A SPECIAL ENTRY IS REQUIRED    67600013
*                                        SINCE NO BUFFER IS AVAILABLE   68000013
*                                        FOR A NORMAL ENTRY             68400013
         NI    MSTATUS,X'FB'                                       6930 68600016
         SPACE                                                          68800013
         STH   DREG0,TTDKEY        STORE DESTINATION IN PREFIX UPON     69200013
*                                        RETURN                         69600013
         NI    LCBSTATE,X'FD'      SET LCBSTATE                         70000013
         L     15,0(0,13)          GET ADDRESS OF THE LPS QUEUE         70400013
         BC    15,244(0,15)        GO TO BUFFER CLEANUP IN IGG019NG     70800013
         SPACE                                                          71200013
         EJECT                                                          71600013
         USING TBLOCK,Y                                                 72000013
         USING QBLOCK,QREG                                              72400013
         USING TCB,TCBREG                                               72800013
CTLPROG  DSECT                                                          73200013
QATTACH  EQU   X'48'                                                    73600013
QSAVE    EQU   X'4C'                                                    74000013
READY    EQU   X'50'                                                    74400013
IRBSAVE  EQU   X'54'                                                    74800013
WAITRB   EQU   X'58'                                                    75200013
DUMMY    EQU   X'60'                                                    75600013
NRET     EQU   X'76'                                                    76000013
         EJECT                                                          76400013
         CTLPROGD                                                       76800013
         EJECT                                                          77200013
         PREFIXD                                                        77600013
         EJECT                                                          78000013
         TCBD                                                           78400013
         EJECT                                                          78800013
         STCBD                                                          79200013
         EJECT                                                          79600013
         QCBD                                                           80000013
         EJECT                                                          80400013
         LCBD                                                           80800013
         END                                                            81200013
