         TITLE 'IECKEOAD  QTAM END-OF-ADDRESS  (EOA)'                   00700013
*********************************************************************** 01400013
*                                                                     * 02100013
*NAME-                                                                * 02800013
*   IECKEOAD   QTAM  END-OF-ADDRESS (EOA)                             * 03500013
*                                                                     * 04200013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04900013
*                                                                     * 05600013
*FUNCTION-                                                            * 06300013
*        IECKEOAD CAUSES MULTIPLE ROUTING OF AN INCOMING MESSAGE      * 07000013
*   WHEN ONE OR MORE DESTINATIONS ARE SPECIFIED IN THE HEADER.        * 07700013
*        THE ROUTINE IS ENTERED AFTER MSGTYPE HAS FOUND THE NEXT      * 08400013
*   FIELD IN THE HEADER NOT TO BE THE EOA CHARACTER.  THE ROUTINE     * 09100013
*   GETS THE OFFSET OF THIS DESTINATION AND STORES IT AT              * 09800013
*   LCBMPLRT (LCB+32).  IF THIS IS THE FIRST TIME THROUGH THIS        * 10500013
*   ROUTINE, CONTROL IS PASSED TO ENDINSRT.  ENDINSRT PLACES THE      * 11200013
*   ADDRESS OF THE SECOND SECTION OF THE EOA ROUTINE INTO A CHAIN     * 11900013
*   OF ADDRESSES OF ROUTINES TO BE ENTERED BY CLEANUP IN ITS HANDLING * 12600013
*   OF INCOMING AND OUTGOING MESSAGES.  PRIOR TO RETURNING TO EOA,    * 13300013
*   ENDINSRT OVERLAYS THE SECOND OPERAND OF THE BAL INSTRUCTION IN THE* 14000013
*   EOA ROUTINE WITH THE ADDRESS OF THE SKIP CHARACTER SET ROUTINE.   * 14700013
*   ENDINSRT THEN RETURNS TO THAT BAL INSTRUCTION, WHICH BRANCHES TO  * 15400013
*   SKIP CHARACTER SET.  SKIP CHARACTER SET BY-PASSES ANY             * 16100013
*   INTERVENING DESTINATION CODES AND RETURNS TO THE NEXT INSTRUCTION * 16800013
*   IN THE EOA MACRO EXPANSION.                                       * 17500013
*        THE NEXT MACRO INSTRUCTION MAKES A TEST TO SEE IF A          * 18200013
*   DUPLICATE MESSAGE HEADER IS BEING HANDLED. IF THE HEADER IS NOT   * 18900013
*   A DUPLICATE, NORMAL LPS HEADER PROCESSING CONTINUES.  IF IT IS A  * 19600013
*   DUPLICATE HEADER, A BRANCH IS MADE TO ENDRCV MACRO EXPANSION SINCE* 20300013
*   LPS HEADER PROCESSING HAS ALREADY BEEN PERFORMED FOR THIS HEADER. * 21000013
*        AFTER THE CLEANUP ROUTINE HAS COMPLETED THE ROUTING OF A     * 21700013
*   MESSAGE TO THE APPROPRIATE DASD DESTINATION OR PROCESS QUEUE, A   * 22400013
*   TEST IS MADE TO SEE IF MULTIPLE ROUTING IS IN PROGRESS.  IF IT IS * 23100013
*   NOT, RETURN IS TO THE CLEANUP ROUTINE.  IF MULTIPLE ROUTING IS IN * 23800013
*   PROGRESS, LINKAGE IS MADE TO THE RECALL ROUTINE TO OBTAIN A       * 24500013
*   DUPLICATE COPY OF THE HEADER.  THE SCAN POINTER IS RESET TO POINT * 25200013
*   TO THE NEXT DESTINATION CODE IN THE HEADER BY USING ITS OFFSET    * 25900013
*   PREVIOUSLY COMPUTED.  EXIT IS TO THE ROUTE ROUTINE TO HANDLE THIS * 26600013
*   DESTINATION CODE.  THIS CONTINUES UNTIL THERE ARE NO MORE         * 27300013
*   DESTINATIONS.                                                     * 28000013
*                                                                     * 28700013
*ENTRY POINTS-                                                        * 29400013
*   IECKEOAD - CONTROL IS PASSED HERE WHEN MSGTYPE HAS GOTTEN THE     * 30100013
*        NEXT FIELD AND FOUND IT NOT TO BE THE EOA CHARACTER.         * 30800013
*   THERE IS AN UNLABELED ENTRY POINT WHICH BEGINS A SEPERATE         * 31500013
*        SECTION OF CODE EXECUTED ONLY WHEN ENTRY IS FROM THE         * 32200013
*        CLEANUP ROUTINE.                                             * 32900013
*                                                                     * 33600013
*INPUT-                                                               * 34300013
*   REGISTER  1- ENTRY POINT REGISTER.                                * 35000013
*   REGISTER 14- RETURN ADDRESS OF NEXT LPS INSTRUCTION.              * 35700013
*        REGISTER 14 ALSO SERVES AS A PARAMETER REGISTER, PASSING     * 36400013
*        THE FIELD SIZE AND EOA CHARACTER SPECIFIED IN THE MACRO.     * 37100013
*   REGISTER 15- ENTRY POINT ADDRESS.                                 * 37800013
*                                                                     * 38500013
*OUTPUT-                                                              * 39200013
*   NONE.                                                             * 39900013
*                                                                     * 40600013
*EXTERNAL ROUTINES-                                                   * 41300013
*   IECKSKPS.                                                         * 42000013
*   ENDINSRT (IN MODULE IGG019NG).                                    * 42700013
*   RECALL (IECKRC IN MODULE IGG019NG).                               * 43400013
*   IECKROUT.                                                         * 44100013
*                                                                     * 44800013
*EXITS-                                                               * 45500013
*   NORMAL- RETURN IS TO ROUTE UNTIL ALL MULTIPLE ROUTING CEASES,     * 46200013
*        THEN RETURN IS TO THE CLEANUP ROUTINE.                       * 46900013
*   ERROR - NONE.                                                     * 47600013
*                                                                     * 48300013
*TABLES/WORK AREAS-                                                   * 49000013
*   NONE.                                                             * 49700013
*                                                                     * 50400013
*ATTRIBUTES-                                                          * 51100013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 51800013
*                                                                     * 52500013
*NOTES-                                                               * 53200013
*   REGISTER  3- SECOND LEVEL RETURN ADDRESS FOR BRANCHES TO ENDINSRT * 53900013
*        OR SKIP.                                                     * 54600013
*   REGISTER  4- BASE FOR LCB.                                        * 55300013
*   REGISTER  5- WORK REGISTER.  PRESENT POSITION IN HEADER.          * 56000013
*   REGISTER  6- WORK REGISTER.  ADDRESS OF BEGINNING OF BUFFER.      * 56700013
*                                                                     * 57400013
*********************************************************************** 58100013
IECKEOAD START                                                          58800013
*2010850000                                                        6930 59100018
DREG1    EQU   1                                                        59500013
RREG2    EQU   3                                                        60200013
LCBREG   EQU   4                                                        60900013
SPREG    EQU   5                                                        61600013
MSREG    EQU   6                                                        62300013
WREG1    EQU   9                                                        63000013
RREG1    EQU   14                                                       63700013
SREG     EQU   15                                                       64400013
         USING *,DREG1                                                  65100013
         USING IECKLCB0,LCBREG                                          65800013
         USING IECKPREF,MSREG                                           66500013
         LA    WREG1,256-31(0,SPREG) THIS CODE GETS THE OFFSET, FROM    67200013
         SR    WREG1,MSREG               THE START OF THE HEADER, OF    67900013
*                                        THE DESTINATION IN THE HEADER  68600013
*                                        BY SUBTRACTING THE PREFIX SIZE 69300013
*                                        AND BUFFER ADDRESS FROM THE    70000013
*                                        SCAN POINTER                   70700013
         STC   WREG1,LCBMPLRT      STORE THE OFFSET IN THE LCB          71400013
         L     SREG,=V(IECKSKPS)   GET ADDRESS OF SKIP TO CHARACTER SET 72100013
         CNOP  0,4                                                      72800013
         L     3,0(13)                 ADDRESS OF LPS SECTION OF NG     73500013
         BAL   3,300(0,3)              TO ROUTINE ENDINSRT IN NG.       74200013
*                                        INSTRUCTION IS OVERLAID IN THE 74900013
*                                        ENDINSRT ROUTINE TO BRANCH     75600013
*                                        TO THE SKIP ROUTINE AFTER THE  76300013
*                                        FIRST TIME                     77000013
         USING *,SREG                                                   77700013
         DC    X'8000F000'         THIS CONSTANT IS CHANGED BY ENDINSRT 78400013
*                                        TO REFLECT THE ADDRESS OF THE  79100013
*                                        NEXT ROUTINE TO BE HANDLED BY  79800013
*                                        THE BUFFER CLEANUP ROUTINE     80500013
         CLI   LCBMPLRT,0          HAS MULTIPLE ROUTING BEEN SPECIFIED  81200013
         BCR   8,14                BRANCH IF NO TO THE ROUTINE          81900013
*                                       SPECIFIED IN THE ABOVE CONSTANT 82600013
         MVC   LCBCECB+1(3),LCBCHDR SAVE HEADER FOR INSERTION IN QUEUE  83300013
*                                        OF NEXT DESTINATION            84000013
         BAL   RREG2,4(0,14)    GO TO SPECIAL ENTRY IN RECALL ROUTINE   84700013
         NI    MSTATUS,X'FB'                                       6930 85000018
         SR    SPREG,SPREG         CLEAR THE SCAN POINTER               85400013
         STH   SPREG,LCBERRST      CLEAR LCB ERROR INDICATOR            86100013
         STH   SPREG,LCBDLPTR      CLEAR DISTRIBUTION LIST POINTER      86800013
         IC    SPREG,LCBMPLRT      GET MULTIPLE ROUTE POINTER           87500013
         LA    SPREG,HDSTRT-1(SPREG) RESET SCAN POINTER TO OFFSET OF    88200013
*                                   NEXT DESTINATION FROM END OF PREFIX 88900013
         MVI   LCBMPLRT,0          CLEAR MULTIPLE ROUTE INDICATOR       89600013
         L     RREG1,LCBSTATE      RELOAD RETURN ADDRESS TO EOA MACRO   90300013
*                                        SAVED BY ROUTE ROUTINE         91000013
         L     SREG,=V(IECKROUT)   GET ADDRESS OF THE ROUTE ROUTINE     91700013
         BR    SREG                GO TO THE ROUTE ROUTINE              92400013
         EJECT                                                          93100013
         LCBD                                                           93800013
         EJECT                                                          94500013
         PREFIXD                                                        95200013
         END                                                            95900013
