*NAME-                                                                * 00400013
*   IECKEOBC     QTAM END-OF-BLOCK AND LINE CORRECTION                * 00800013
*                                                                     * 01200013
*STATUS-  CHANGE LEVEL 001                                OS QTAM II  * 01600013
*                                                                     * 02000013
*FUNCTION-                                                            * 02400013
*        IF THE MESSAGE WAS CANCELLED OR AN ERROR MESSAGE WAS SENT,   * 02800013
*   RETURN IS TO THE NEXT LPS INSTRUCTION.                            * 03200013
*        IF THERE WAS A DATA CHECK, THE RETRY COUNTER IS INCREMENTED  * 03600013
*   BY ONE.  IF THE RETRY COUNT IS THREE, RETURN IS TO THE NEXT LPS   * 04000013
*   INSTRUCTION.  OTHERWISE, THE ROUTINE BRANCHES TO THE RECALL       * 04400013
*   ROUTINE OF IGG019NG TO OBTAIN THE HEADER.  IF THE LINE IS SENDING,* 04800013
*   THE CODE FOR WRITE CONTINUE IS SET IN THE LCBCECB FIELD (LCB + 4) * 05200013
*   OF THE LCB, AND RETURN IS TO LPSTART TO RETRY THE OPERATION.  IF  * 05600013
*   THE LINE IS NOT SENDING, ACTION IS TAKEN TO RETRY RECEIVING THE   * 06000013
*   MESSAGE.  IF THERE IS AN EOB IN THE HEADER SEGMENT, THE MESSAGE   * 06400013
*   IS CANCELLED AND A NEW FIRST BUFFER IS SET UP.  IF THERE IS NO    * 06800013
*   EOB PRESENT IN ANY BUFFER POSITION OTHER THAN THE LAST            * 07200013
*   POSITION, THE CANCEL BIT OF MSTATUS IS SET TO A ONE (HEADER       * 07600013
*   PREFIX + 12 IS OR'ED WITH A X'80').  THE LAST SEQUENCE NUMBER IN  * 08000013
*   THE TERMINAL TABLE IS STORED IN TSEQUIN (TERMINAL TABLE ENTRY +   * 08400013
*   4) FIELD, UNLESS THE NUMBER IS ZERO.  LINKAGE IS MADE TO THE      * 08800013
*   RECALL ROUTINE TO OBTAIN THE HEADER.  THE SCAN POINTER IS UPDATED * 09200013
*   TO CONTAIN MESSAGE SIZE AND THE LCBTRST FIELD OF THE LCB (LCB+82) * 09600013
*   IS UPDATED TO CONTAIN THE ADDRESS OF THE EOB CHARACTER RELATIVE   * 10000013
*   TO THE ADDRESS OF THE LAST CORRECTLY TRANSMITTED SEGMENT OF THE   * 10400013
*   CURRENT MESSAGE.  AN END OF ADDRESS CHARACTER IS SET UP, AND THE  * 10800013
*   HEADER IS FILLED WITH IDLE CHARACTERS IN THE SPACE RESERVED FOR   * 11200013
*   TIME, DATE, OR SEQUENCE NUMBER.  THE DISTRIBUTION LIST AND        * 11600013
*   MULTIPLE ROUTE INDICATORS AT LCBDLPTR (LCB + 46) AND LCBMPLRT     * 12000013
*   (LCB + 32) RESPECTIVELY ARE SET TO ZERO, AND THE ERROR HALF WORD  * 12400013
*   AT LCBERRST (LCB +40) IS SET TO ZERO.  FOR ALL RECEIVING          * 12800013
*   MESSAGES, THE END OF MESSAGE IS SET IN THE MSTATUS FIELD OF THE   * 13200013
*   PREFIX (PREFIX +12 IS OR'ED WITH A X'02') AND THE RETRY OPERAND   * 13600013
*   IS SET AT LCBCECB (LCB + 4 IS REPLACED BY A X'07') AND THE        * 14000013
*   BUFFER SIZE IS STORED IN MSEGSZE (PREFIX + 8).  THE LCBCLCCW AT   * 14400013
*   LCB + 36 IS SET TO REUSE THE BUFFER AND RETURN IS TO THE ACTIVATE * 14800013
*   ROUTINE.  (WRITE INITIAL IS SET FOR 1030 AND 1060 TERMINALS       * 15200013
*   INSTEAD OF WRITE CONTINUE).                                       * 15600013
*        IF THERE WAS NO DATA CHECK AND EITHER END OF TRANSMISSION,   * 16000013
*   UNIT EXCEPTION, OR UNIT CHECK HAS BEEN ENCOUNTERED OR THE RESIDUAL* 16400013
*   COUNT OF THE CSW IS ZERO, THEN RETURN IS TO THE NEXT LPS          * 16800013
*   INSTRUCTION.  IF NONE OF THESE CONDITIONS OCCURRED, THE END OF    * 17200013
*   BLOCK BIT IN THE PREFIX IS SET (MSTATUS AT PREFIX + 12 IS OR'ED   * 17600013
*   WITH A X'20') SINCE IT IS INDICATED THAT THE MESSAGE WAS          * 18000013
*   TRANSMITTED CORRECTLY.  THE SCAN POINTER IS UPDATED TO CONTAIN    * 18400013
*   THE MESSAGE SIZE AND IS STORED IN THE MSPTR FIELD OF THE PREFIX   * 18800013
*   AT PREFIX + 25.  THE RETRY COUNTER IS SET TO ZERO IN THE LCBERRST * 19200013
*   FIELD OF THE LCB.  THE LCBTRST HALF WORD IS UPDATED BY STORING    * 19600013
*   THE MESSAGE SEGMENT SIZE IN THIS FIELD.  IF THE TRANSMISSION WAS  * 20000013
*   A WRITE OPERATION AND THE NEXT CHARACTER TO BE WRITTEN IS AN END  * 20400013
*   OF TRANSMISSION, RETURN IS TO THE NEXT LPS INSTRUCTION.  OTHERWISE* 20800013
*   AN END OF BLOCK INDICATION IS SET IN THE LCBCECB FIELD OF THE LCB.* 21200013
*   FOR BOTH OPERATIONS THE BUFFER IS SET UP TO BE REUSED AND THE     * 21600013
*   ROUTINE BRANCHES TO THE ACTIVATE ROUTINE, AND RETURN IS FROM THE  * 22000013
*   ACTIVATE ROUTINE.                                                 * 22400013
*                                                                     * 22800013
*ENTRY POINTS-                                                        * 23200013
*   IECKEOBC - EXPANSION OF THE EOBLC MACRO GENERATES A BALR TO THIS  * 23600013
*              POINT USING REGISTER 15 AS THE BRANCH ADDRESS REGISTER * 24000013
*              AND REGISTER 14 AS THE RETURN REGISTER.                * 24400013
*                                                                     * 24800013
*INPUT-                                                               * 25200013
*   REGISTER  3- CONTAINS THE ADDRESS OF THE DCB ASSOCIATED WITH THE  * 25600013
*              TRANSMISSION.                                          * 26000013
*   REGISTER  4- ADDRESS OF THE LCB.                                  * 26400013
*   REGISTER  5- POINTER TO BYTE BEFORE CURRENT CHAR IN SEGMENT.      * 26800013
*   REGISTER  6- BUFFER ADDRESS.                                      * 27200013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 27600013
*   REGISTER  8- TERMINAL TABLE SOURCE ENTRY.                         * 28000013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT.                     * 28400013
*   REGISTER 14- RETURN ADDRESS    .                                  * 28800013
*   REGISTER 15- ENTRY POINT.                                         * 29200013
*                                                                     * 29600013
*OUTPUT-                                                              * 30000013
*   REGISTER  5- CONTAINS MESSAGE SEGMENT SIZE.                       * 30400013
*   REGISTER 11- CONTAINS ADDRESS OF LAST CHARACTER IN MESSAGE.       * 30800013
*                                                                     * 31200013
*EXTERNAL ROUTINES-                                                   * 31600013
*   IECKACT - ACTIVATE ROUTINE OF IGG019NG TO REACTIVATE THE BUFFERS. * 32000013
*   IECKRC - RECALL ROUTINE OF IGG019NG TO OBTAIN THE HEADER.         * 32400013
*                                                                     * 32800013
*EXITS-                                                               * 33200013
*   NORMAL- EXIT IS TO NEXT LPS INSTRUCTION IF EITHER THE MESSAGE     * 33600013
*              WAS CANCELLED OR AN ERROR MESSAGE WAS SENT, OR IF      * 34000013
*              A DATA CHECK HAS NOT OCCURRED AND EITHER END OF        * 34400013
*              TRANSMISSION, UNIT CHECK, OR UNIT EXCEPTION IS         * 34800013
*              INDICATED.                                             * 35200013
*   ERROR- RETURN IS TO LPSTART TO RETRY THE OPERATION IF A           * 35600013
*              TRANSMISSION ERROR OCCURRED.  IF THE ERROR HAS         * 36000013
*              OCCURRED THREE TIMES, THEN RETURN IS TO THE NEXT LPS   * 36400013
*              INSTRUCTION.                                           * 36800013
*                                                                     * 37200013
*TABLES/WORK AREAS-                                                   * 37600013
*   BYTE - A ONE-BYTE WORK AREA USED TO SAVE THE MODEL AND ADAPTER    * 38000013
*              TYPE FOR TESTING FOR 1030 OR 1060 TERMINALS.           * 38400013
*                                                                     * 38800013
*ATTRIBUTES-                                                          * 39200013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 39600013
*                                                                     * 40000013
*NOTES-                                                               * 40400013
*   REGISTER  3- SECOND LEVEL RETURN REGISTER FROM RECALL ROUTINE.    * 40800013
*   REGISTER  9- WORK REGISTER AND BRANCH ADDRESS REGISTER TO ACTIVATE* 41200013
*              ROUTINE.                                               * 41600013
*   REGISTER 12- WORK REGISTER USED TO SET UP EOA CHARACTER.          * 42000013
*                                                                     * 42400013
*********************************************************************** 42800013
IECKEOBC START                                                          43200013
*3160468000,716000                                                 00PS 43300015
*3160532000                                                        2202 43400015
*3410666000                                                        8308 43500017
*1200556000,648800-651200                                         23161 43530018
*1200728000                                                        00PS 43560018
* 532100-532200,715000,870000                                     M3156 43580018
* 715000                                                          M3174 43590018
* 724600-727000                                                  A37721 43595020
DREG1    EQU   1                                                        43600013
RREG2    EQU   3                                                        44000013
LCBREG   EQU   4                                                        44400013
SPREG    EQU   5                                                        44800013
MSREG    EQU   6                                                        45200013
LGREG    EQU   7                                                        45600013
TCREG    EQU   8                                                        46000013
WREG1    EQU   9                                                        46400013
IREG     EQU   2                                                   00PS 46800015
EOSREG   EQU   11                                                       47200013
WREG2    EQU   12                                                       47600013
RREG1    EQU   14                                                       48000013
SREG     EQU   15                                                       48400013
UCBDEV   EQU   16                                                       48800013
DEBUCB   EQU   32                                                       49200013
         USING  *,SREG                                                  49600013
         USING IECKPREF,MSREG                                           50000013
         USING IECKLCB0,LCBREG                                          50400013
         USING IHADCB,IREG                                              50800013
         USING IECKTERM,TCREG                                           51200013
         TM    MSTATUS,64          TEST IF CANCELLED OR ERROR MSG SENT  51600013
         BO    CLEAR               IF SO RETURN                         52000013
         L     IREG,LCBDCBPT      ADDRESS OF THE DCB                    52400013
         L     IREG,DCBDEBAD      ADDRESS OF THE DEB                    52800013
         L     IREG,DEBUCB(IREG)  ADDRESS OF A UCB FOR THIS LINE GROUP  53200013
         TM    LCBCSW+4,1          TEST FOR EOT RECEIVED          M3156 53210018
         BO    CLEAR               IF YES, RETURN TO LPS          M3156 53220018
         TM    LCBECBPT,X'7F'      TEST CONDITION CODE FOR ERROR   2202 53250015
*                                        X'7F' NORMAL COMPLETION   2202 53300015
*                                      X'FF' NORMAL COMPLETION,SIO 2202 53350015
*                                        X'41' PERMANENT ERROR     2202 53400015
*                                        X'F1' PERMANENT ERROR,SIO 2202 53450015
         BO    XXX                 BRANCH IF EITHER NORMAL COMP.   2202 53500015
         TM    LCBERRST+1,X'03'    HAVE WE FAILED THREE TIMES           53600013
         BO    CKEND                    CHECK FOR END OF MESSAGE        54000013
         BNZ   RETRNSMT                                                 54400013
XXX      TM    LCBCSW+4,X'03'          TEST FOR EOT OR OTHER ERRORS2202 54800015
         BNZ   CLEAR               IF YES,RETURN TO LPS                 55200013
TSTZERO  OC    LCBCSW+6(2),LCBCSW+6    IS RESIDUAL COUNT ZERO     21858 55600018
         BE    CLEAR               IF YES,RETURN TO LPS                 56000013
         OI    MSTATUS,X'20'       SET EOB BIT IN PREFIX                56400013
         TM    MSTATUS,1           IS THIS A TEXT SEGMENT               56800013
         BC    7,PRTEXT            IF YES CONTINUE - OTHERWISE          57200013
         LA    WREG1,HDSTRT-1          GET START OF MESSAGE HEADER      57600013
         SR    SPREG,WREG1             ADJUST SCAN POINTER TO MSG SIZE  58000013
         STC   SPREG,MSPTR             AND RESTORE IN HEADER PREFIX     58400013
PRTEXT   MVC   LCBCECB+1(3),LCBCSEG  STORE ADDR OF EOB CHAR             58800013
         LH    WREG1,MSEGSZE       GET SIZE OF PARTIAL BUFFER           59200013
         STH   WREG1,LCBTRST     SAVE IT FOR TRANSLATE AND ERROR        59600013
         AH    WREG1,LCBCSW+6      ADDBACK REMAINDER OF BUFFER          60000013
         MVI   LCBCECB,3           SET READ CONTINUE OP FOR BTAM        60400013
         TM    LCBSTATE,X'04'      TEST FOR WRITE OPERATION             60800013
         BC    8,PREBTAM           IF NOT,BR TO SET UP REST OF DECB     61200013
         BAL   DREG1,TEST3060     GO TEST FOR 1030 OR 1060              61600013
         B     CLEAR              RETURN TO LPS IS 1030 OR 1060         62000013
         MVI   LCBCECB,4          SET WRITE CONTINUE OP FOR BTAM        62400013
         B     PREBTAM             GO SET UP REST OF DECB               62800013
RETRNSMT TM    LCBSENSE,X'41'          TIME OUT OR I R                  63200013
         BNZ   CLEAR                   TREAT AS END OF MESSSAGE         63600013
         TM    LCBERCCW+2,1           TEST PREVIOUS PERM ERR FLAG       64000013
         BO    *+8                     ON, DO NOT RESET ERRORS          64400013
         NI    LCBERRST+1,X'3F'        RESET TRANSMISSION ERRORS        64800013
         OI    MSTATUS,X'80'       SET CANCEL FLAG SO DESTINATION-23161 64880018
*                                 DASD WILL NOT PLACE MESSAGE IN  23161 64960018
*                                 QBACK CHAIN. CANCEL FLAG WILL BE23161 65040018
*                                 TURNED OFF BY DESTINATION-DASD. 23161 65120018
         L     WREG1,0(0,13)       GET ADDR OF NUCLEUS ENTRY TABLE      65200013
         BAL   RREG2,240(0,WREG1)  BRANCH TO RECALL SUBR                65600013
         TM    LCBSTATE,4          IS LINE SENDING                      66000013
         BC    8,RECV              IF NO, GO TO RECEIVE ROUTINE         66400013
         OI    MSTATUS,X'20'       SET EOB BIT IN PREFIX           8308 66600017
         MVI   LCBCECB,4           SET WRITE CONTINUE OP FOR BTAM       66800013
         BAL   DREG1,TEST3060     GO TEST FOR 1030 OR 1060              67200013
         MVI   LCBCECB,2          SET WRITE INITIAL OP FOR BTAM         67600013
         BCR   15,LGREG            RETURN TO LPS                        68000013
TEST3060 MVC   BYTE(1),UCBDEV+3(IREG) ADAPTER TYPE TO WORK AREA         68400013
         MVN   BYTE(1),UCBDEV(IREG) MODEL TO WORK BYTE                  68800013
         CLI   BYTE,X'12'         TEST FOR 1030                         69200013
         BCR   8,DREG1            BRANCH IF 1030                        69600013
         CLI   BYTE,X'21'         TEST FOR 1060                         70000013
         BCR   8,DREG1            BRANCH IF 1060                        70400013
         BC    15,4(DREG1)        RETURN NOT 1030 OR 1060               70800013
BYTE     DC    X'00'                                                    71200013
RECV     DS    0H                                                 M3174 71500018
         TM    MSTATUS,32          TEST FOR FIRST EOB IN MESSAGE   00PS 71800015
         BC    7,GOOD              BRANCH IF EOB NOT LAST IN BUFFER     72000013
         OI    MSTATUS,128         IF FIRST CANCEL AND RETURN TO DISK   72400013
         L     WREG1,LCBDESTQ-1    GET DESTINATION QCB ADDRESS   A37721 72460020
         USING QBLOCK,WREG1                                      A37721 72520020
         LH    WREG2,QSIZE         GET COUNT OF MESSAGES IN Q    A37721 72580020
         BCTR  WREG2,0             DECREMENT BY ONE              A37721 72640020
         STH   WREG2,QSIZE         AND RESTORE                   A37721 72700020
         LH    WREG1,MSNUMIN       GET LAST SEQIN NUMBER           00PS 72800018
         LTR   WREG1,WREG1         IS SEQUENCE EQUAL ZERO               73200013
         BE    *+8                 IF YES BRANCH                        73600013
         STH   WREG1,TSEQUIN       OTHERWISE LOAD TSEQUIN               74000013
         L     WREG1,0(0,13)       GET ADDR OF NUCLEUS ENTRY TABLE      74400013
         BAL   RREG2,240(0,WREG1)  BRANCH TO RECALL SUBR                74800013
         LH    WREG1,8(LGREG)      RESET SCAN POINTER                   75200013
         STC   WREG1,MSPTR                                              75600013
         TM    UCBDEV+3(IREG),X'70' TEST FOR 2260                       76000013
         BC    8,ENT260            BRANCH IF 2260                       76400013
         LA    WREG2,HDSTRT-7-IECKPREF(WREG1)  CHARACTER AFTER EOA      76800013
         STH   WREG2,LCBTRST       FOR ACTIVATE AND TRANSLATE           77200013
         LTR   WREG1,WREG1             SPACE FOR TIME AND DATE          77600013
         BC    8,ENT260                BRANCH IF NO                     78000013
         LA    WREG1,1(0,WREG1)    BUMP WREG1                           78400013
         LA    WREG2,C'#'          SETUP EOA CHARACTER                  78800013
         STC   WREG2,HDSTRT-1(WREG1)   AND FILL                         79200013
         LA    WREG2,X'17'             WITH IDLE CHARS                  79600013
         BCT   WREG1,*-8           DECREMENT AND RETURN TO FILL         80000013
ENT260   SR    WREG1,WREG1                                              80400013
         STH   WREG1,LCBDLPTR      CLEAR DISTRIBUTION LIST AND          80800013
         MVI   LCBMPLRT,0          MULTIPLE ROUTE INDICATORS            81200013
         NI    LCBERRST,1          RESET HEADER ERROR FLAGS             81600013
GOOD     L     WREG2,=V(IECKBFSZ)   GET ADDR OF BFR SIZE ENTRY          82000013
         OI    MSTATUS,2           TURN ON  END OF MESSAGE              82400013
         MVI   LCBCECB,7           SET RETRY OP FOR ACTIVATE            82800013
         LH    WREG1,0(0,WREG2)    GET SIZE OF BUFFER                   83200013
PREBTAM  STH   WREG1,MSEGSZE       AND STORE                            83600013
         LA    EOSREG,MSEGSZE-1(WREG1) GET ADDR OF LAST CHAR IN BUFFER  84000013
         LA    WREG1,LCBCLPCI-9    RESET ACTIVATE TO REUSE BUFFER       84400013
         ST    WREG1,LCBCLCCW                                           84800013
         L     WREG1,0(0,13)       GET ADDR OF NUCLEUS ENTRY TABLE      85200013
         B     236(0,WREG1)        BRANCH TO ACTIVATE SUBROUTINE        85600013
CKEND    NI    LCBERRST+1,X'FC'         ZERO RETRY COUNTER              86000013
         OI    LCBERCCW+2,1            SET PREVIOUS ERROR FLAG          86400013
         B     TSTZERO             TEST RESIDUAL COUNT            M3156 87000018
CLEAR    NI    LCBERRST+1,X'FC'        ZERO RETRY COUNTER               87600013
         NI    LCBERCCW+2,X'FE'        CLEAR PREVIOUS ERROR FLAG        88000013
         BR    RREG1                    RETURN TO LPS                   88400013
         EJECT                                                          88800013
         PREFIXD                                                        89200013
         EJECT                                                          89600013
         LCBD  QTAM=3                                                   90000013
         EJECT                                                          90400013
         TERMTBLD                                                       90800013
         EJECT                                                          90900020
         QCBD                                                           91000020
         EJECT                                                          91200013
         DCBD  DSORG=CX                                                 91600013
         END                                                            92000013
