         TITLE 'IECKEOBK  QTAM END-OF-BLOCK (EOB)'                      00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*                                                                     * 02400013
*NAME-                                                                * 03000013
*   IECKEOBK     QTAM END-OF-BLOCK (EOB)                              * 03600013
*                                                                     * 04200013
*STATUS-  CHANGE LEVEL= 18         JANUARY 1971                       * 04800021
*                                                                     * 05400013
*FUNCTION-                                                            * 06000013
*        FOR A WTTA LINE GROUP, IF WRU SIGNAL RECEIVED (INDICATED BY  * 06200021
*    X'40' IN LCBINCAM), A READ CONTINUE IS SET UP.                   * 06400021
*        THIS ROUTINE IS NOT EXECUTED AND RETURN IS TO THE NEXT LPS   * 06600013
*   INSTRUCTION IF ANY OF THE FOLLOWING CONDITIONS ARE SATISFIED:     * 07200013
*        1) THE MESSAGE HAS BEEN CANCELLED.                           * 07800013
*        1) AN ERROR MESSAGE HAS BEEN SENT.                           * 08400013
*        3) THE MESSAGE HAS BEEN REROUTED.                            * 09000013
*        4) THE STATUS BYTE OF THE CSW INDICATES END OF TRANSMISSION. * 09600013
*        5) A UNIT EXCEPTION HAS OCCURRED. (NOT FOR 2260)             * 10200021
*        6) THE RESIDUAL COUNT IN THE CSW IS ZERO.                    * 10800013
*        IF NONE OF THE ABOVE HAVE OCCURRED, THE END OF BLOCK BIT IN  * 11400013
*   THE PREFIX IS SET (MSTATUS AT ADDRESS OF HEADER PREFIX + 8 IS     * 12000013
*   OR'ED WITH A X'20'), SINCE IT IS INDICATED THAT THIS MESSAGE WAS  * 12600013
*   TRANSMITTED CORRECTLY.  IF THE SEGEMENT IS NOT A TEXT SEGMENT,    * 13200013
*   THE SCAN POINTER IS ADJUSTED TO CONTAIN THE MESSAGE SIZE, WHICH   * 13800013
*   IS PLACED IN THE MSPTR BYTE AT HEADER PREFIX +25.                 * 14400013
*        THE LCBTRST HALF WORD AT LCB+82 IS UPDATED BY PLACING THE    * 15000013
*   SEGMENT SIZE, OBTAINED FROM MSGSIZE AT HEADER PREFIX + 8, IN THIS * 15600013
*   FIELD.                                                            * 16200013
*        IF THE TRANSMISSION WAS A WRITE OPERATION AND THE DEVICE IS A* 16800013
*   1030 OR A 1060, CONTROL IS RETURNED TO THE NEXT LPS INSTRUCTION.  * 17400013
*   OTHERWISE THE WRITE CONTINUE CODE OF X'04' IS SET AT LCBCEBC.  IF * 18000013
*   THE TRANSMISSION WAS A READ, THE OP CODE FOR A READ (X'03') IS    * 18600013
*   SET IN THE LCBCEBC FIELD OF THE LCB.  IN BOTH CASES, THE BUFFER   * 19200013
*   IS SET TO BE REUSED.  THE ROUTINE THEN BRANCHES TO THE ACTIVATE   * 19800013
*   ROUTINE OF IGG019NG AND CONTROL IS RETURNED TO THE CALLING ROUTINE* 20400013
*   FROM THERE.                                                       * 21000013
*                                                                     * 21600013
*ENTRY POINTS-                                                        * 22200013
*   IECKEOBK - EXPANSION OF THE EOB MACRO GENERATES A BALR TO THIS    * 22800013
*              POINT USING REGISTER 15 AS THE BRANCH ADDRESS REGISTER * 23400013
*              AND REGISTER 14 AS THE RETURN REGISTER.                * 24000013
*                                                                     * 24600013
*INPUT-                                                               * 25200013
*   REGISTER  3- POINTER TO THE DCB ASSOCIATED WITH THE TRANSMISSION  * 25800013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 26400013
*   REGISTER  5- POINTS TO THE LAST CHARACTER IN THE HEADER           * 27000013
*   REGISTER  6- BUFFER ADDRESS                                       * 27600013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 28200013
*   REGISTER 14- RETURN ADDRESS                                       * 28800013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 29400013
*                                                                     * 30000013
*OUTPUT-                                                              * 30600013
*   IF NONE OF THE 6 CONDITIONS MENTIONED ABOVE ARE SATISFIED, THE    * 31200013
*        MSTATUS FIELD OF THE PREFIX INDICATES END OF BLOCK.  ALSO,   * 31800013
*        IF THE OPERATION WAS A WRITE AND THE DEVICE IS NOT A 1030 OR * 32400013
*        1060, WRITE CONTINUE IS INDICATED IN THE LCB AT LCBCEBC BY A * 33000013
*        X'04'.  IF THE OPERATION WAS A READ, THE OP CODE FOR A READ  * 33600013
*        (X'03') IS SET IN THE LCBCEBC FIELD.  IN BOTH CASES REGISTER * 34200013
*        11 IS SET TO POINT TO THE LAST CHARACTER IN THE BUFFER.      * 34800013
*                                                                     * 35400013
*EXTERNAL ROUTINES-                                                   * 36000013
*   IECKACT - ACTIVATE MODULE IN IGG019NG TO SET UP THE BUFFER FOR    * 36600013
*              REUSE.                                                 * 37200013
*                                                                     * 37800013
*EXITS-                                                               * 38400013
*   NORMAL- IF ANY OF THE 6 CONDITIONS MENTIONED ABOVE ARE SATISFIED  * 39000013
*              OR IF THE TRANSMISSION WAS A WRITE OPERATION AND THE   * 39600013
*              DEVICE WAS A 1030 OR 1060, RETURN IS TO THE NEXT LPS   * 40200013
*              INSTRUCTION.                                           * 40800013
*           OTHERWISE, EXIT IS TO THE ACTIVATE ROUTINE, WHICH IN TURN * 41400013
*              EXITS TO THE NEXT LPS INSTRUCTION.                     * 42000013
*   ERROR- NONE.                                                      * 42600013
*                                                                     * 43200013
*TABLES/WORK AREAS-                                                   * 43800013
*   BYTE - A ONE-BYTE WORK AREA USED TO SAVE THE MODEL AND ADAPTER    * 44400013
*              TYPE FOR TESTING FOR 1030 OR 1060 TERMINALS.           * 45000013
*                                                                     * 45600013
*ATTRIBUTES-                                                          * 46200013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 46800013
*                                                                     * 47400013
*NOTES-                                                               * 48000013
*   REGISTER  9- WORK REGISTER.  USED FOR MANIPULATION OF DATA WITHIN * 48600013
*              THE ROUTINE AND AS THE BRANCH ADDRESS REGISTER TO THE  * 49200013
*              ACTIVATE ROUTINE.                                      * 49800013
*                                                                     * 50400013
*********************************************************************** 51000013
IECKEOBK START                                                          51600013
*2719606700-610900,666000                                          000C 51900017
*1200636000                                                       21858 52000018
* 618600-619200,623400,633000                                     M3164 52060018
* 619800-622800                                                   M3126 52120018
*A048000,062000-064000,102000                                    S21016 52160021
*A622900-623200,D623400                                          A50579 52180021
DREG1    EQU   1                                                        52200013
LCBREG   EQU   4                                                        52800013
SPREG    EQU   5                                                        53400013
MSREG    EQU   6                                                        54000013
WREG1    EQU   9                                                        54600013
EOSREG   EQU   11                                                       55200013
WREG2    EQU   12                                                       55800013
RREG1    EQU   14                                                       56400013
SREG     EQU   15                                                       57000013
UCBDEV   EQU   16                                                       57600013
DEBUCB   EQU   32                                                       58200013
         USING *,SREG                                                   58800013
         USING IECKPREF,MSREG                                           59400013
         USING IECKLCB0,LCBREG                                          60000013
         USING IHADCB,WREG1                                             60600013
         L     WREG1,LCBDCBPT          ADDRESS OF THE DCB          000C 60670017
         TM    DCBCPOLL,X'68'          IS IT A WTTA LINE GROUP     000C 60740017
         BNO   NOWTTA                  NO                          000C 60810017
         TM    LCBINCAM,X'40'          YES,IS WRU SIGNAL RECEIVED  000C 60880017
         BCR   8,RREG1                 NO,RETURN TO LPS            000C 60950017
         B     WTTA01                  YES,PERFORM A READ CONTINUE 000C 61020017
NOWTTA   EQU   *                                                   000C 61090017
         TM    MSTATUS,64          TEST IF CANCELLED OR ERROR MSG SENT  61200013
         BCR   1,RREG1             IF SO RETURN                         61800013
         TM    LCBCSW+4,1          TEST FOR EOT RECEIVED          M3164 61860018
         BCR   7,RREG1             IF YES, RETURN TO LPS          M3164 61920018
         L     WREG2,DCBDEBAD      ADDRESS OF THE DEB             M3126 61980018
         L     WREG2,DEBUCB(WREG2) ADDRESS OF A UCB FOR THIS      M3126 62040018
*                                    LINE GROUP                   M3126 62100018
         MVC   BYTE(1),UCBDEV+3(WREG2) ADAPTER TYPE TO WORK AREA  M3126 62160018
         MVN   BYTE(1),UCBDEV(WREG2)   MODEL TYPE TO WORK AREA    M3126 62220018
         CLI   BYTE,X'81'          IS THIS A 2260 DEVICE          M3126 62280018
         BNE   CKEOT       NO, CONTINUE                          A50579 62290021
         CLI   LCBCECB,X'03'     2260 READ CONTINUE?             A50579 62300021
         BNE   CKCOUNT           NO, CHECK RESIDUAL COUNT        A50579 62310021
CKEOT    EQU   *                                                 A50579 62320021
         TM    LCBCSW+4,X'03'      TEST FOR EOT OR OTHER ERRORS         62400013
         BCR   7,RREG1             IF YES,RETURN TO LPS                 63000013
CKCOUNT  EQU   *                                                  M3164 63300018
         OC    LCBCSW+6(2),LCBCSW+6    IS RESIDUAL COUNT ZERO     21858 63600018
         BCR   8,RREG1             IF YES,RETURN TO LPS                 64200013
*                                                                       64800013
*      EXIT IF 1030 OR 1060                                             65400013
*                                                                       66000013
WTTA01   EQU   *                                                   000C 66600017
         OI    MSTATUS,X'20'      SET EOB BIT IN THE PREFIX             68400013
         TM    MSTATUS,1           IS THIS A TEXT SEGMENT               69000013
         BC    7,PRTEXT            IF YES CONTINUE - OTHERWISE          69600013
         LA    WREG1,HDSTRT-1           GET START OF MESSAGE HEADER     70200013
         SR    SPREG,WREG1              ADJUST SCAN PTR TO MESSAGE SIZE 70800013
         STC   SPREG,MSPTR              AND RESTORE IN HEADER PREFIX    71400013
*  SPREG INITIALLY POINTED TO THE LAST CHARACTER IN THE HEADER          72000013
*  AT THIS POINT, MSEGSZE HAS BUFFER SIZE UP TO & INCLUDING             72600013
*        THE EOB CHARACTER MINUS 8 BYTES FOR ECB                        73200013
PRTEXT   LH    WREG1,MSEGSZE       VALUE OF MSEGSZE AFTER NXT TRANSMN   73800013
         STH   WREG1,LCBTRST       SAVE LIMIT OF AREA TRANS             74400013
         AH    WREG1,LCBCSW+6      WREG1 CONTAINS BUFFER SIZE MINUS 8   75000013
         MVI   LCBCECB,3           SET OP CODE FOR READ CONTINUE        75600013
         TM    LCBSTATE,X'04'      IS THIS A WRITE OP                   76200013
         BC    8,BTAMENT           IF YES, CHECK FOR EOT                76800013
         CLI   BYTE,X'12'         TEST FOR 1030                         78600013
         BCR   8,RREG1            RETURN IF 1030                        79200013
         CLI   BYTE,X'21'         TEST FOR 1060                         79800013
         BCR   8,RREG1            RETURN IF 1060                        80400013
CONTN    MVI   LCBCECB,4           SET OP CODE FOR WRITE CONTINUE       81000013
BTAMENT  STH   WREG1,MSEGSZE       STORE IT - VARIABLE SEGMENT SIZE     81600013
         LA    EOSREG,MSEGSZE-1(WREG1) GET ADDR OF LAST CHAR IN BUFFER  82200013
         LA    WREG1,LCBCLPCI-9    RESET ACTIVATE TO REUSE BUFFER       82800013
         ST    WREG1,LCBCLCCW                                           83400013
         L     WREG1,0(0,13)       GET ADDR OF NUCLEUS ENTRY TABLE      84000013
         B     236(0,WREG1)        BRANCH TO ACTIVATE SUBROUTINE        84600013
BYTE     DC    X'00'                                                    85200013
         EJECT                                                          85800013
         PREFIXD                                                        86400013
         EJECT                                                          87000013
         LCBD                                                           87600013
         EJECT                                                          88200013
         DCBD  DSORG=CX                                                 88800013
         END                                                            89400013
