*********************************************************************** 00500013
*                                                                     * 01000013
*NAME-                                                                * 01500013
*   IECKERMG     QTAM ERROR MESSAGE (ERRMSG)                          * 02000013
*                                                                     * 02500013
*STATUS-  CHANGE LEVEL= 19         JANUARY 1971                       * 03000021
*                                                                     * 03500013
*FUNCTION-                                                            * 04000013
*        IECKERMG CAUSES AN ERROR MESSAGE SPECIFIED BY THE CALLING    * 04500013
*   ROUTINE TO BE SENT TO A DESIGNATED TERMINAL IF ANY OF THE ERROR   * 05000013
*   CONDITIONS SPECIFIED IN THE ERROR MASK IN THE ERRMSG MACRO        * 05500013
*   EXPANSION IS INDICATED IN THE ERROR HALFWORD (LCBERRST AT LCB+43),* 06000013
*   OR IF THE ERROR MASK IS ZERO.                                     * 06500013
*        IF NONE OF THE ERROR CONDITIONS SPECIFIED BY A NON-ZERO      * 07000013
*   ERROR MASK ARE INDICATED IN THE ERROR HALFWORD OF THE LCB, THEN   * 07500013
*   CONTROL IS RETURNED TO THE NEXT LPS INSTRUCTION.                  * 08000013
*        IF THE MESSAGE IS TO BE RETRANSMITTED TO 2740 MOD 2 (INDI-   * 08100021
*   CATED BY X'FF' IN LCBCPA + 29), RETURN IS MADE TO THE LPS TO      * 08200021
*   AVOID DUPLICATE ERROR MESSAGES.                                   * 08300021
*        IF AT LEAST ONE OF THE ERROR CONDITIONS SPECIFIED HAS        * 08500013
*   OCCURRED, THE RECALL ROUTINE OF MODULE IGG019NG IS ENTERED TO     * 09000013
*   OBTAIN THE HEADER.  THE SEQUENCE OUT NUMBER, MSNUMOUT IS ZEROED   * 09300021
*   FOR RETRIEVE.  THEN A TEST IS MADE FOR THE OPTION OF              * 09600021
*   INCLUDING THE MESSAGE HEADER IN THE ERROR MESSAGE (A PERIOD AS    * 10000013
*   THE FIRST CHARACTER OF THE ERROR MESSAGE INDICATES INCLUSION OF   * 10500013
*   THE HEADER).  IF THE HEADER IS NOT TO BE INCLUDED, THE SCAN       * 11000013
*   POINTER IS POSITIONED PAST THE CHARACTERS IN THE HEADER FOR THE   * 11500013
*   TIME AND DATE STAMP AND THE ERROR MESSAGE OVERLAYS THE REMAINDER  * 12000013
*   OF THE HEADER, AND THE NUMBER OF CHARACTERS SKIPPED IS PLACED IN  * 12500013
*   THE MSPTR FIELD OF THE HEADER PREFIX (AT PREFIX + 25). IF THE     * 13000013
*   HEADER IS TO BE INCLUDED, THE ERROR MESSAGE IS PLACED IN THE      * 13500013
*   BUFFER FOLLOWING THE HEADER IF THERE IS SUFFICIENT SPACE.  IF NO  * 13700021
*   EOB IS PRESENT AND IF INCOMPLETE HEADER BIT (X'04') HAS BEEN SET  * 13900021
*   IN THE ERROR HALFWORD, THE SCAN POINTER IS DECREMENTED BY ONE TO  * 14100021
*   OVERLAY THE EOT.                                                  * 14300021
*   LENGTH OF THE ERROR MESSAGE EXCEEDS THE SPACE IN THE BUFFER, THE  * 14500013
*   ERROR TEXT IS TRUNCATED FROM THE RIGHT.                           * 15000013
*        THE MESSAGE SIZE IS PLACED IN THE MSGSIZE HALFWORD AT HEADER * 15500013
*   PREFIX + 8, AND A X'46' IS PLACED IN THE MSTATUS BYTE AT HEADER   * 16000021
*   PREFIX + 12 TO INDICATE A SINGLE SEGMENT MESSAGE.                 * 16500013
*        IF THERE HAS BEEN A SEQUENCE NUMBER ERROR, THE LAST VALID    * 16600021
*   SEQUENCE-IN NUMBER IS OBTAINED FROM THE TERMINAL TABLE.  THE ERROR* 16700021
*   TEXT IS SCANNED FOR A $.  IF A $ IS FOUND, THE SEQUENCE-IN NUMBER * 16800021
*   IS INSERTED, IN DECIMAL FORM, IN THE ERROR TEXT.  UPON ENCOUNTER- * 16900021
*   ING A SECOND $, THE SPECIFIED SEQUENCE NUMBER, OBTAINED FROM THE  * 17000021
*   LCBBRKCT FIELD IN THE LCB, IS INSERTED INTO THE TEXT.             * 17100021
*        FOR ALL MESSAGES MSNUMIN IN THE PREFIX IS ZEROED FOR         * 17200021
*   RETRIEVE.  EXIT IS MADE TO THE LOOK-UP ROUTINE, WHICH RETURNS TO  * 17300021
*   THE NEXT LPS INSTRUCTION BY BRANCHING VIA REGISTER 14 AROUND THE  * 17500013
*   MACRO GENERATED CONSTANTS.                                        * 18000013
*                                                                     * 18500013
*ENTRY POINTS-                                                        * 19000013
*   IECKERMG - CONTROL IS GIVEN HERE VIA A BALR USING REGISTER 15 AS  * 19500013
*              THE BRANCH ADDRESS REGISTER AND REGISTER 14 AS THE     * 20000013
*              RETURN REGISTER AS A PART OF THE ERRMSG MACRO          * 20500013
*              EXPANSION.                                             * 21000013
*                                                                     * 21500013
*INPUT-                                                               * 22000013
*   REGISTER  0- CONTAINS THE SIZE OF THE ERROR MESSAGE               * 22500013
*   REGISTER  1- CONTAINS THE ADDRESS OF THE ERROR MESSAGE            * 23000013
*   REGISTER  2- CONTAINS THE ADDRESS OF THE DESTINATION NAME.        * 23500013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 24000013
*   REGISTER  5- POINTER TO BYTE BEFORE CURRENT CHAR IN SEGMENT       * 24500013
*   REGISTER  6- BUFFER ADDRESS                                       * 25000013
*   REGISTER 14- RETURN ADDRESS                                       * 25500013
*              REGISTER 14 ALSO POINTS TO A MACRO GENERATED PARAMETER * 26000013
*              CONSISTING OF THE HALFWORD ERROR MASK SPECIFIED BY THE * 26500013
*              CALLING ROUTINE.                                       * 27000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 27500013
*                                                                     * 28000013
*OUTPUT-                                                              * 28500013
*   THE ERROR MESSAGE TEXT WILL BE MOVED TO THE PROPER PLACE IN THE   * 29000013
*              HEADER OF BUFFER (AS EXPLAINED ABOVE).                 * 29500013
*                                                                     * 30000013
*EXTERNAL ROUTINES-                                                   * 30500013
*   IECKRC - RECALL ROUTINE OF IGG019NG TO OBTAIN ACCESS TO THE       * 31000013
*              HEADER.                                                * 31500013
*   IECKLKUP - LOOKUP ROUTINE TO SCAN THE TERMINAL TABLE FOR THE      * 32000013
*              DESTINATION NAME.                                      * 32500013
*                                                                     * 33000013
*EXITS-                                                               * 33500013
*   NORMAL- IF NONE OF THE ERRORS SPECIFIED BY THE ERROR MASK ARE     * 34000013
*              INDICATED IN THE ERROR HALFWORD (LCBERRST AT LCB+40),  * 34500013
*              RETURN IS TO THE NEXT LPS INSTRUCTION.  IF THE ERROR   * 35000013
*              MASK IS ZERO OR IF AT LEAST ONE OF THE ERRORS SPECIFIED* 35500013
*              IS INDICATED, RETURN IS TO IECKLKUP WHICH IN TURN      * 36000013
*              RETURNS TO THE NEXT LPS INSTRUCTION.                   * 36500013
*   ERROR- NONE.                                                      * 37000013
*                                                                     * 37500013
*TABLES/WORK AREAS-                                                   * 38000013
*   NONE.                                                             * 38500013
*                                                                     * 39000013
*ATTRIBUTES-                                                          * 39500013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 40000013
*                                                                     * 40500013
*NOTES-                                                               * 41000013
*   REGISTER  3- SECOND LEVEL LINKAGE TO RECALL SUBROUTINE.           * 41500013
*   REGISTER  9- WORK REGISTER.  USED TO HOLD THE CALLING ROUTINE'S   * 42000013
*              ERROR MASK.                                            * 42500013
*   REGISTER 10- WORK REGISTER.  HOLDS THE ADDRESS OF THE START OF THE* 43000013
*              ERROR TEXT IN THE BUFFER AND, ON RETURN TO IECKLKUP,   * 43500013
*              THE ADDRESS OF THE START OF THE PREFIX-1.              * 44000013
*   REGISTER 15- BASE REGISTER FOR THIS ROUTINE                       * 44500013
*                                                                     * 45000013
*********************************************************************** 45500013
         TITLE 'IECKERMG  QTAM ERROR MESSAGE (ERRMSG)'                  46000013
IECKERMG START                                                          46500013
*3410612000                                                       20394 46600017
*3410666000-67000                                                 19064 46700017
*90351820000                                                      19064 46800017
*1200572000-578000                                                 000D 46900018
* 832000                                                         A27523 46950019
* 665500                                                         A29189 46970019
*A030000,081000-083000,093000-096000,137000-143000,160000,       S21016 46980021
*A166000-173000                                                  S21016 46990021
DREG0    EQU   0                                                        47000013
DREG1    EQU   1                                                        47500013
RREG2    EQU   3                                                        48000013
LCBREG   EQU   4                                                        48500013
SPREG    EQU   5                                                        49000013
MSREG    EQU   6                                                        49500013
TCREG    EQU   8                                                        50000013
WREG1    EQU   9                                                        50500013
WREG2    EQU   10                                                       51000013
IREG  EQU  12                                                           51500013
RREG1    EQU   14                                                       52000013
SREG     EQU   15                                                       52500013
         USING *,SREG                                                   53000013
         USING IECKPREF,MSREG                                           53500013
         USING IECKTERM,TCREG                                           54000013
         USING IECKLCB0,LCBREG                                          54500013
         LH    WREG1,0(0,RREG1)    LOAD ERROR HALF WORD                 55000013
         SLA   WREG1,16            ERROR MASK TO HI ORDER PART OF REG   55500013
         BC    8,ERRACT3           IF MASK IS ZERO, DO ERROR ACTION     56000013
         N     WREG1,LCBERRST      TEST FOR DESIGNATED ERRORS           56500013
         BC    8,2(0,RREG1)        IF NO ERRORS,RETURN                  57000013
ERRACT3  CLI   LCBCPA+29,X'FF'     IS THIS MESSAGE TO BE           000D 57200018
*                                   RETRANSMITTED TO 2740 M2       000D 57400018
         BE    2(0,RREG1)          RETURN IF YES                   000D 57600018
         MVC   LCBCECB+1(3),LCBCHDR MAKE HEADER ADDRESS AVAILABLE  000D 57800018
         OR    DREG0,WREG1             SAVE ERROR INDICATOR             58000013
         L     WREG1,0(0,13)       GET ADDRESS OF THE LPS QUEUE         58500013
         OI    LCBSTATE,16        SET INIT. MODE FOR RECALL             59000013
         BAL   RREG2,240(0,WREG1)  BRANCH TO RECALL SUBROUTINE          59500013
         ST    DREG0,FIELD             SET UP ERROR INDICATOR           60000013
         SLL   DREG0,16                RESTORE REGISTER WITH COUNT      60500013
         SRL   DREG0,16                  OF ERROR MESSAGE CHARCTERS     61000013
         XC    MSNUMOUT,MSNUMOUT   CLEAR SEQUENCE OUT NUMBER      20394 61200017
         CLI   0(DREG1),C'.'       HEADER TO BE INCLUDED WITH MESSAGE   61500013
         BC    8,ADDHDR            BRANCH IF YES                        62000013
         LA    SPREG,HDSTRT-2      IF THE HEADER IS NOT INCLUDED, RESET 62500013
*                                    SCANPOINTER TO START OF THE HEADER 63000013
         LA    SPREG,1(0,SPREG)    SKIPPING OVER 'DF' CHARACTERS WHICH  63500013
         CLI   1(SPREG),X'17'       ARE IN THE HEADER FOR TIME AND      64000013
         BE    *-8                   DATE STAMP                         64500013
         LA    WREG2,HDSTRT-1     SET POINTER FOR SUB                   65000013
         SR    SPREG,WREG2        NUMBER OF IDLE CHARACTERS             65500013
         STC   SPREG,MSPTR        SET MSPTR EQUAL NUMBER OF IDLES       66000013
         AR    SPREG,WREG2        RESET SPREG                           66500013
         B     A                  CONTINUE PROCESSING            A29189 66550019
ADDHDR   TM    MSTATUS,X'20'   IS EOB PRESENT                     19064 66600017
         BO    A                  YES                             19064 66700017
         TM    LCBERRST,4          IS INCOMPLETE HEADER SET      19064  66800017
         BZ    A                  NO, OK                          19064 66900017
         BCTR  SPREG,0            OVERLAY EOT                     19064 67000017
A        LA    WREG2,1(0,SPREG) GET START OF ERROR TEXT IN SEGMENT19064 67100017
         L     WREG1,=V(IECKBFSZ)  GET ADDRESS OF BUFFER SIZE           67500013
         LH    WREG1,0(WREG1)      GET SIZE OF BUFFER                   68000013
         LA    WREG1,8(WREG1,MSREG) GET END OF BUFFER + 1               68500013
         SR    WREG1,WREG2         GET SPACE REMAINING IN BUFFER        69000013
         BC    12,DESTIN           BRANCH IF HEADER EXCEEDS SEGMENT     69500013
         CR    WREG1,DREG0         IS ERROR TEXT LARGER THAN REMAINING  70000013
*                                    BUFFER                             70500013
         BC    12,TRUNC            BRANCH IF YES                        71000013
         LR    WREG1,DREG0         OTHERWISE USE SIZE OF TEXT           71500013
TRUNC    BCTR  WREG1,0             REDUCE COUNT BY ONE FOR EXECUTE      72000013
         STH   WREG1,COUNT             SAVE COUNT-1 OF ERROR TEXT       72500013
         EX    WREG1,MOVEMSG       CAUSE ERROR MESSAGE TO BE MOVED      73000013
*                                    TO BUFFER                          73500013
         AR    WREG1,WREG2         GET ADDRESS OF LAST CHARACTER OF     74000013
*                                    ERROR MESSAGE IN BUFFER            74500013
         LA    WREG2,MSEGSZE-1     GET ADDRESS OF START OF PREFIX-1     75000013
         SR    WREG1,WREG2         GET MESSAGE SIZE                     75500013
         STH   WREG1,MSEGSZE           AND STORE IT IN PREFIX           76000013
DESTIN   MVI   MSTATUS,X'46'           INDICATE RECALL,SINGLE-SEGMENT,  76500013
*                                        AND PRIORITY MESSAGE           77000013
         TM    FIELD,X'30'             IS THIS A SEQ. NO. ERROR         77500013
         BZ    DONE                      NO                             78000013
         LA    DREG0,1                 SET INCREMENT OF ONE FOR LOOP    78500013
         LH    DREG1,COUNT             COUNT-1 OF ERROR TEXT IN SETMENT 79000013
         LA    WREG1,1(0,SPREG)        SET PRT. TO START OF ERROR TEXT  79500013
         LA    DREG1,0(DREG1,WREG1)    SET PTR. TO LAST CHAR. OF TEXT   80000013
         LH    IREG,TSEQUIN            SET UP LAST VALID SEQIN NUMBER   80500013
         BAL   RREG2,LOOP              PROCESS SEQ. NO.                 81000013
         LA    WREG1,1(0,WREG1)        SET UP FOR NEXT SCAN IN SEGMENT  81500013
         LH    IREG,LCBBRKCT        SET UP INVALID SEQ # RCVD.     00PS 82000017
         BAL   RREG2,LOOP              PROCESS IT                       82500013
DONE     EQU   *                                                        83000013
         XC    MSNUMIN(2),MSNUMIN  ZERO INPUT SEQUENCE NO.       A27523 83200019
         L     SREG,=V(IECKLKUP)   GET ADDRESS OF LOOKUP ROUTINE        83500013
         BR    SREG                GO TO LOOKUP ROUTINE                 84000013
LOOP     CLI   0(WREG1),C'$'           SCAN ERROR TEXT FOR $            84500013
         BE    CONVERT                   BRANCH IF FOUND                85000013
         BXLE  WREG1,DREG0,LOOP        SET UP FOR NEXT CHAR.            85500013
         B     DONE                      EXIT IF NO $ FOUND             86000013
CONVERT  CVD   IREG,SEQWORD            CONVERT SEQ. NO. TO DECIMAL      86500013
         OI    SEQWORD+7,X'0F'         MASK OUT ZONE                    87000013
         UNPK  1(4,WREG1),SEQWORD      UNPACK FIELD INTO ERROR TEXT     87500013
         MVI   0(WREG1),X'40'          SET BLANK AT BEGINNING OF FIELD  88000013
         BR    RREG2                   RETURN                           88500013
MOVEMSG  MVC   0(1,WREG2),0(DREG1) MOVE ERROR MESSAGE TO BUFFER         89000013
SEQWORD  DS    1D                                                       89500013
FIELD    DS    1F                                                       90000013
COUNT    DS    1H                                                       90500013
         EJECT                                                          91000013
         PREFIXD                                                        91500013
         EJECT                                                          92000013
         LCBD  QTAM=3                                                   92500018
         EJECT                                                          93000013
         TERMTBLD                                                       93500013
         END                                                            94000013
