         TITLE 'IECKEXPD  QTAM EXPAND'                                  01000013
*********************************************************************** 02000013
*                                                                     * 03000013
*NAME-                                                                * 04000013
*   IECKEXPD     QTAM EXPAND                                          * 05000013
*                                                                     * 06000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 07000013
*                                                                     * 08000013
*FUNCTION-                                                            * 09000013
*        THE DATA IN THE MESSAGE HEADER IS SHIFTED LEFT STARTING      * 10000013
*   AT THE SCAN POINTER FOR THE NUMBER OF BYTES INDICATED BY THE      * 11000013
*   PARAMETER POINTED TO BY REGISTER 14.  THIS WILL PROVIDE THE ROOM  * 12000013
*   IN THE HEADER FOR A FIELD TO BE INSERTED BY SEQOUT, TIMESTMP,     * 13000013
*   OR DATESTMP.  THE FIELD TO BE INSERTED WILL TERMINATE IN THE      * 14000013
*   BYTE POINTED TO BY THE SCAN POINTER.  A BLANK WILL BE INSERTED IN * 15000013
*   THE LEFTMOST POSITION OF THE NEWLY CREATED FIELD.                 * 16000013
*                                                                     * 17000013
*ENTRY POINTS-                                                        * 18000013
*   IECKEXPD - THIS ROUTINE IS ENTERED BY A BALR GENERATED BY THE     * 19000013
*       SEQOUT, TIMESTMP, OR DATESTMP MACRO'S.                        * 20000013
*                                                                     * 21000013
*INPUT-                                                               * 22000013
*   REGISTER  3- RETURN ADDRESS.                                      * 23000013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 24000013
*   REGISTER  5- POINTER TO THE BYTE AT THE START OF THE NEXT FIELD.  * 25000013
*   REGISTER  6- BUFFER ADDRESS                                       * 26000013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 27000013
*   REGISTER 14- PARAMETER REGISTER.  POINTS TO A HALFWORD CONTAINING * 28000013
*       THE LENGTH OF THE FIELD TO BE INSERTED.  REGISTER IS ALSO TO  * 29000013
*       BE USED BY THE CALLING ROUTINE AS ITS RETURN REGISTER.        * 30000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 31000013
*                                                                     * 32000013
*OUTPUT-                                                              * 33000013
*   REGISTER  9- CONTAINS THE FIELD SIZE MINUS ONE.                   * 34000013
*   REGISTER 10- CONTAINS A POINTER TO BEGINNING OF THE NEW FIELD.    * 35000013
*                                                                     * 36000013
*EXTERNAL ROUTINES-                                                   * 37000013
*   NONE.                                                             * 38000013
*                                                                     * 39000013
*EXITS-                                                               * 40000013
*   NORMAL- RETURN TO CALLING ROUTINE BY BRANCHING ON REGISTER 3.     * 41000013
*   ERROR- IF THERE IS NO ROOM IN THE HEADER TO SHIFT, RETURN IS TO   * 42000013
*        THE NEXT INSTRUCTION IN THE LPS, WITH NO EXPANSION OF THE    * 43000013
*        HEADER.  (NO ERROR INDICATION IS GIVEN).                     * 44000013
*                                                                     * 45000013
*TABLES/WORK AREAS-                                                   * 46000013
*   NONE.                                                             * 47000013
*                                                                     * 48000013
*ATTRIBUTES-                                                          * 49000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 50000013
*                                                                     * 51000013
*NOTES-                                                               * 52000013
*   REGISTER 12- WORK REGISTER.                                       * 53000013
*                                                                     * 54000013
*********************************************************************** 55000013
IECKEXPD START                                                          56000013
RREG2    EQU   3                                                        57000013
LCBREG   EQU   4                                                        58000013
SPREG    EQU   5                                                        59000013
MSREG    EQU   6                                                        60000013
WREG1    EQU   9                                                        61000013
WREG2    EQU   10                                                       62000013
EOSREG   EQU   11                                                       63000013
IREG     EQU   12                                                       64000013
RREG1    EQU   14                                                       65000013
SREG     EQU   15                                                       66000013
         USING *,SREG                                                   67000013
         USING IECKLCB0,LCBREG                                          68000013
         USING IECKPREF,MSREG                                           69000013
         CLI   0(SPREG),X'40'      IS SCAN POINTER POINTING AT BLANK    70000013
         BC    7,NOBLNK            IF NOT DON'T BACK UP POINTER         71000013
         BCTR  SPREG,0             ELSE BACK UP POINTER                 72000013
NOBLNK   LA    WREG2,HDSTRT-1      LOAD START OF MESSAGE ADDRESS        73000013
         AH    WREG2,0(0,RREG1)    COMPUTE ADDRESS OF FIRST CHARACTER   74000013
*                                    TO SHIFT                           75000013
         LR    WREG1,SPREG         LOAD SCAN POINTER VALUE              76000013
         SR    WREG1,WREG2        COMPUTE NUMBER OF CHARACTERS TO SHIFT 77000013
         BC    4,2(0,RREG1)        RETURN TO USER IF NEGATIVE           78000013
         EX    WREG1,SHIFT         CAUSE CHARACTERS TO BE SHIFTED       79000013
         LH    WREG1,0(0,RREG1)    GET FIELD SIZE                       80000013
         BCTR  WREG1,0             DECREMENT BY ONE                     81000013
         LR    WREG2,SPREG         LOAD VALUE OF SCAN POINTER           82000013
         SR    WREG2,WREG1         GET ADDRESS OF START OF TIME FIELD   83000013
         MVI   0(WREG2),X'40'      INSERT LEFT DELIMITER (BLANK)        84000013
         SR    IREG,IREG           CLEAR REGISTER                       85000013
         IC    IREG,LCBMPLRT       GET POINTER TO DESTINATION CODE(EOA) 86000013
         SH    IREG,0(0,RREG1)     SHIFT POINTER LEFT,SIZE OF NEW FIELD 87000013
         BCR   4,RREG2             IF NEGATIVE, SKIP STORED SCAN        88000013
*                                    POINTER UPDATE                     89000013
         STC   IREG,LCBMPLRT       RESTORE SCAN POINTER IN LCB          90000013
         BR    RREG2               RETURN TO CALLING SUBROUTINE         91000013
         SPACE                                                          92000013
SHIFT    MVC   HDSTRT(1),1(WREG2)  SHIFT CHARACTERS TO EXPAND HEADER    93000013
         EJECT                                                          94000013
         LCBD                                                           95000013
         EJECT                                                          96000013
         PREFIXD                                                        97000013
         END                                                            98000013
