         TITLE 'IECKITCP  QTAM INTERCEPT (INTERCPT)'                    00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*NAME-                                                                * 02400013
*   IECKITCP     QTAM INTERCEPT (INTERCPT)                            * 03000013
*                                                                     * 03600013
*STATUS-  CHANGE LEVEL= 18         JANUARY 1971                       * 04200021
*                                                                     * 04800013
*FUNCTION-                                                            * 05400013
*        IECKITCP CAUSES SUPPRESSION OF ALL MESSAGE TRANSMISSION TO   * 06000013
*   A TERMINAL IF ANY OF THE ERROR CONDITIONS SPECIFIED IN THE        * 06600013
*   ERROR MASK (A HALF WORD POINTED TO BY REGISTER 14) IS INDICATED IN* 07200013
*   THE ERROR HALF WORD OF THE LCB (LCBERRST AT LCB+40), OR WHEN THE  * 07800013
*   ERROR MASK IS ZERO.                                               * 08400013
*        IF THE ERROR MASK IS NOT ZERO AND NONE OF THE ERROR          * 09600013
*   CONDITIONS ARE INDICATED, THEN RETURN IS TO THE NEXT LPS          * 10200013
*   INSTRUCTION BY BRANCHING ON THE CONTENTS OF REGISTER 14 + 2 AROUND* 10800013
*   THE ERROR MASK.                                                   * 11400013
*        IF AT LEAST ONE OF THE ERROR CONDITIONS SPECIFIED IN THE MASK* 12000013
*   IS INDICATED IN LCBERRST OR IF THE ERROR MASK IS ZERO, THEN       * 12600013
*   LINKAGE IS MADE TO THE RECALL ROUTINE (IECKRC) OF IGG019NG TO     * 13200013
*   OBTAIN THE HEADER.  QSIZE OF THE QCB IS INCREASED BY ONE SINCE THE* 13600021
*   MESSAGE WAS NOT SENT. THE PRIORITY BIT IN MSTATUS (HEADER PREFIX  * 14000021
*   + 12) IS SET TO A ONE (MSTATUS IS OR'ED WITH A X'04') SO THAT A   * 14400013
*   NEW SEQUENCE NUMBER WILL NOT BE ASSIGNED.  THE SERVICED BIT OF    * 15000013
*   MSTATUS IS SET TO A ZERO (MSTATUS IS AND'ED WITH A X'EF'). THE    * 15600013
*   SEND BIT OF THE ENTRY IN THE TERMINAL TABLE (TSTATUS AT ENTRY + 8)* 16200013
*   IS SET TO A ZERO (TSTATUS IS AND'ED WITH A X'FD') TO INDICATE     * 16800013
*   THAT MESSAGES ON THE QUEUE FOR THE DESTINATION WERE WITHHELD FROM * 17400013
*   TRANSMISSION.                                                     * 18000013
*        THE INTERCEPT BIT (BIT 5, REPRESENTED BY A X'04') IS TESTED. * 18600013
*   IF IT IS ON (ONE), AND THE HEADER ADDRESS IS NOT LESS THAN THE    * 19200013
*   INTERCEPT FIELD, RETURN IS TO THE NEXT LPS INSTRUCTION SINCE IT   * 19800013
*   IS INDICATED THAT A PREVIOUS MESSAGE IS IN THE INTERCEPT FIELD.   * 20400013
*   OTHERWISE, THE QUEUE ADDRESS IS MOVED FROM TQCBADDR AT TERMINAL   * 21000013
*   TABLE ENTRY + 1 TO LCBDESTQ AT LCB + 29, THE HEADER ADDRESS IS    * 21600013
*   PLACED IN THE INTERCEPT FIELD IN THE USER AREA OF THE TERMINAL    * 22200013
*   TABLE ENTRY, AND THE INTERCEPT BIT IN THE TERMINAL TABLE ENTRY    * 22800013
*   IS SET TO A ONE (TSTATUS IN OR'ED WITH A X'04').  THEN THE OFFSET * 23400013
*   TO THE INTERCEPT FIELD IN THE TERMINAL TABLE IS PLACED IN THE     * 24000013
*   FIRST BYTE OF THE SCAN ROUTINE ADDRESS AT LPSTART FOR LATER USE   * 24600013
*   BY THE RELEASE MESSAGE ROUTINE (RELEASM MACRO), AND RETURN IS TO  * 25200013
*   THE NEXT LPS INSTRUCTION                                          * 25800013
*        IF THIS MESSAGE IS TO BE RETRANSMITTED TO A 2740 MOD 2,      * 25870021
*   INDICATED BY X'FF' IN LCB, AN AUTOMATIC RELEASEM IS DONE.  QFAC   * 25940021
*   IS SET TO LCBCHDR TO CAUSE MESSAGES TO BE RETRANSMITTED UNLESS    * 26010021
*   A PRIORTY MESSAGE WAS INTERCEPTED (INDICATED IF THE HEADER ADDR.  * 26080021
*   IS GREATER THAN QFAC IN QUEUE).   THE INTERCEPT BIT IS TURN OFF   * 26150021
*   AND THE SEND BIT IS TURNED ON IN THE TSTATUS FIELD OF THE TERMINAL* 26220021
*   TABLE ENTRY.  RETURN IS MADE TO THE NEXT LPS INSTRUCTION.         * 26290021
*                                                                     * 26400013
*ENTRY POINTS-                                                        * 27000013
*   IECKITCP - THE EXPANSION OF THE INTERCPT MACRO GENERATES A BALR   * 27600013
*              TO THIS POINT USING REGISTER 15 AS THE BRANCH ADDRESS  * 28200013
*                                                                     * 28800013
*INPUT-                                                               * 29400013
*   REGISTER  1- POINTER TO THE INTERCEPT FIELD IN THE USER'S PORTION * 30000013
*              OF THE TERMINAL TABLE ENTRY.                           * 30600013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 31200013
*   REGISTER  6- BUFFER ADDRESS                                       * 31800013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 32400013
*   REGISTER  8- TERMINAL TABLE SOURCE ENTRY                          * 33000013
*   REGISTER 14- RETURN ADDRESS                                       * 33600013
*              REGISTER 14 ALSO POINTS TO A PARAMETER LIST CONSISTING * 34200013
*              OF THE HALF WORD ERROR MASK GENERATED BY THE           * 34800013
*              INTERCPT MACRO.                                        * 35400013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 36000013
*                                                                     * 36600013
*OUTPUT-                                                              * 37200013
*   IF NONE OF THE ERRORS DESIGNATED BY THE ERROR MASK HAVE OCCURRED, * 37800013
*              THERE IS NO OUTPUT.                                    * 38400013
*   OTHERWISE, THE FOLLOWING ACTIONS ARE TAKEN:                       * 39000013
*              1) THE PRIORITY BIT AT MSTATUS IS SET TO A ONE.        * 39600013
*              2) THE SERVICED BIT AT MSTATUS IS SET TO A ZERO.       * 40200013
*              3) THE SEND BIT AT TSTATUS IS SET TO A ZERO.           * 40800013
*              4) THE INTERCEPT BIT AT TSTATUS IS SET TO A ONE IF IT  * 41400013
*                 IS NOT ALREADY A ONE.                               * 42000013
*   IF THE INTERCEPT BIT IS ALREADY A ONE AND THE HEADER ADDRESS IS   * 42600013
*              NOT LESS THAN THE INTERCEPT FIELD, THERE IS NO FURTHER * 43200013
*              OUTPUT.  OTHERWISE THE OFFSET FROM THE START OF THE    * 43800013
*              TERMINAL TABLE ENTRY TO THE INTERCEPT FIELD IS PLACED  * 44400013
*              IN THE FIRST BYTE OF THE ADDRESS OF THE SCAN ROUTINE   * 45000013
*              AT LPSTART (POINTED TO BY REGISTER 7).                 * 45600013
*                                                                     * 46200013
*EXTERNAL ROUTINES-                                                   * 46800013
*   IECKRC - RECALL ROUTINE OF IGG019NG IS ENTERED TO OBTAIN THE      * 47400013
*              HEADER.                                                * 48000013
*                                                                     * 48600013
*EXITS-                                                               * 49200013
*   NORMAL- EXIT IS TO THE NEXT LPS INSTRUCTION BY BRANCHING ON THE   * 49800013
*              CONTENTS OF REGISTER 14 +2 AROUND THE MACRO GENERATED  * 50400013
*              CONSTANT.                                              * 51000013
*   ERROR- NONE.                                                      * 51600013
*                                                                     * 52200013
*TABLES/WORK AREAS-                                                   * 52800013
*   NONE.                                                             * 53400013
*                                                                     * 54000013
*ATTRIBUTES-                                                          * 54600013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 55200013
*                                                                     * 55800013
*NOTES-                                                               * 56400013
*   REGISTER  3- SECOND LEVEL RETURN REGISTER FORM RECALL ROUTINE.    * 57000013
*   REGISTER  9- BRANCH ADDRESS REGISTER OT RECALL ROUTINE.           * 57600013
*                                                                     * 58200013
*********************************************************************** 58800013
IECKITCP START                                                          59400013
*1171727000-730000                                                 5480 59700016
*1200598000,840400-845600                                          000D 59800018
*A042000,136000-140000,258700-2629000                            S21016 59850021
WREG0    EQU   0                                                   000D 59900018
DREG1    EQU   1                                                        60000013
RREG2    EQU   3                                                        60600013
LCBREG   EQU   4                                                        61200013
MSREG    EQU   6                                                        61800013
LGREG    EQU   7                                                        62400013
TCREG    EQU   8                                                        63000013
WREG1    EQU   9                                                        63600013
RREG1    EQU   14                                                       64200013
SREG     EQU   15                                                       64800013
         USING *,SREG                                                   65400013
         USING IECKTERM,TCREG                                           66000013
         USING IECKPREF,MSREG                                           66600013
         USING IECKLCB0,LCBREG                                          67200013
         LH    WREG1,0(0,RREG1)    LOAD ERROR HALF WORD                 67800013
         SLA   WREG1,16            ERROR MASK TO HI ORDER PART OF REG   68400013
         BC    8,ERRACT2           IF MASK IS ZERO,DO ERR ACTION UNCND  69000013
         N     WREG1,LCBERRST      TEST FOR DESIGNATED ERRORS           69600013
         BC    8,2(0,RREG1)        IF NO ERRORS,RETURN                  70200013
ERRACT2  MVC   LCBCECB+1(3),LCBCHDR  MAKE HEADER ADDRESS AVAILABLE      70800013
         L     WREG1,0(0,13)       GET ADDRESS OF LPS QUEUE             71400013
         BAL   RREG2,240(WREG1)    BRANCH TO RECALL FOR HEADER          72000013
         MVC   LCBDESTQ(3),TQCBADDR  MOVE QUEUE ADDRESS TO LCB          72600013
         L     WREG1,TQCBADDR-1    ACCESS QCB ADDRESS              5480 72700016
         LH    RREG2,20(WREG1)     ACCESS QSIZE                    5480 72800016
         LA    RREG2,1(RREG2)      BUMP                            5480 72900016
         STH   RREG2,20(WREG1)     RESTORE QSIZE                   5480 73000016
         OI    MSTATUS,X'04'       TURN ON PRIORITY BIT SO THAT A NEW   73200013
*                                    SEQUENCE NUMBER IS NOT ASSIGNED    73800013
         NI    MSTATUS,X'EF'       TURN OFF SERVICED BIT                74400013
         NI    TSTATUS,X'FD'       TURN OFF THE SEND BIT                75000013
         TM    TSTATUS,X'04'       TEST THE INTERCEPT BIT               75600013
         BZ    SET                 BRANCH IF NOT ON (PREVIOUS MESSAGE   76200013
*                                    NOT IN INTERCEPT)                  76800013
         CLC   LCBCHDR(3),0(DREG1) ELSE IS RECALLED HEADER ADDRESS LESS 77400013
*                                    THAN INTERCEPT FIELD               78000013
         BNL   2(RREG1)            RETURN IF NO                         78600013
SET      MVC   0(3,DREG1),LCBCHDR  UPDATE INTERCEPT FIELD WITH HEADER   79200013
*                                    ADDRESS                            79800013
         OI    TSTATUS,X'04'       SET INTERCEPT BIT IN TERMTBL         80400013
         SR    DREG1,TCREG         GET OFFSET FROM START OF TERMTBL     81000013
*                                    ENTRY TO INTERCEPT FIELD IN        81600013
*                                    TERMTBL ENTRY                      82200013
         STC   DREG1,4(LGREG)      AND STORE IT IN 1ST BYTE OF ADDRESS  82800013
*                                    OF SCAN ROUTINE IN LPSTART.  LGREG 83400013
*                                    HAS ADDRESS OF START OF LPS.       84000013
         CLI   LCBCPA+29,X'FF'     IS THIS MESSAGE TO BE           000D 84040018
*                                   RETRANSMITTED TO 2740 M2       000D 84080018
         BNE   2(RREG1)            BRANCH IF NO, OTHERWISE DO      000D 84120018
*                                   RELEASEM FUNCTION NOW          000D 84160018
         CLC   1(3,WREG1),LCBCHDR  COMPARE MESSAGE HEADER ADDRESS  000D 84200018
*                                   IN LCB TO ADDRESS OF FIRST     000D 84240018
*                                   ELEMENT IN QUEUE               000D 84280018
         BNH   *+10                BRANCH IF HEADER ADDRESS IS     000D 84320018
*                                   GREATER THAN MESSAGE ADDRESS   000D 84360018
*                                   IN QUEUE (PRIORITY MESSAGES    000D 84400018
*                                   HAVE BEEN PLACED ON THE QUEUE) 000D 84440018
         MVC   1(3,WREG1),LCBCHDR  UPDATE QFAC WITH CURRENT RRN    000D 84480018
         XI    TSTATUS,6           TURN OFF INTERCEPT BIT AND      000D 84520018
*                                   TURN ON SEND BIT IN TSTATUS    000D 84560018
         B     2(RREG1)            AND RETURN                           84600013
         EJECT                                                          85200013
         TERMTBLD                                                       85800013
         EJECT                                                          86400013
         LCBD  QTAM=3                                                   87000018
         EJECT                                                          87600013
         PREFIXD                                                        88200013
         END                                                            88800013
