         TITLE 'IECKLKUP  QTAM LOOK-UP'                                 00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*NAME-                                                                * 02400013
*   IECKLKUP     QTAM LOOK-UP                                         * 03000013
*                                                                     * 03600013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04200013
*                                                                     * 04800013
*FUNCTION-                                                            * 05400013
*        IECKLKUP WILL SCAN THE TERMINAL TABLE IN SEARCH OF ONE       * 06000013
*   PARTICULAR DESTINATION NAME.  THE ADDRESS OF THE FIRST BYTE       * 06600013
*   IN THE TERMINAL TABLE IS LOADED INTO A WORK REGISTER.  THE MAXIMUM* 07200013
*   NUMBER OF CHARACTERS IN THE DESTINATION NAME OF ANY ENTRY IS      * 07800013
*   RETRIEVED FROM TERMTBL+4. THIS NUMBER OF CHARACTERS IS COMPARED   * 08400013
*   BETWEEN THE DESTINATION SPECIFIED IN THE HEADER AND THE TERMID    * 09000013
*   OF THIS ENTRY IN THE TERMINAL TABLE.                              * 09600013
*        IF THE COMPARANDS ARE EQUAL, THE ADDRESS OF THE QUEUE CONTROL* 10200013
*   BLOCK FOR THE DESTINATION QUEUE IS PLACED IN THE LCBDESTQ (LCB+29)* 10800013
*   FIELD OF THE LCB.  THE RELATIVE ADDRESS OF THE DESTINATION ENTRY  * 11400013
*   IS PLACED IN THE TTDKEY FIELD OF THE HEADER PREFIX.  CONTROL      * 12000013
*   RETURNS TO THE USER BY BRANCHING ON REGISTER 14 PAST THE MACRO    * 12600013
*   GENERATED CONSTANT.                                               * 13200013
*        IF THE COMPARANDS ARE NOT EQUAL, THE SIZE OF A TERMINAL TABLE* 13800013
*   ENTRY IS INDEXED TO THE WORK REGISTER.  THE SEARCH CONTINUES UNTIL* 14400013
*   THE END OF THE TABLE IS REACHED.                                  * 15000013
*        IF THE END OF THE TABLE IS REACHED BEFORE THE DESIRED ENTRY  * 15600013
*   IS FOUND, THE INVALID DESTINATION BIT IN THE ERROR HALFWORD IS    * 16200013
*   SET (LCBERRST AT LCB+40 IS OR'ED WITH A X'80'), AND THE ADDRESS   * 16800013
*   OF THE QCB FOR THE ERROR DESTINATION QUEUE IS PLACED IN THE       * 17400013
*   LCBDESTQ FIELD OF THE LCB.  THE TTDKEY FIELD OF THE HEADER PREFIX * 18000013
*   IS ZERO IF THE DESTINATION NAME IS NOT FOUND.  RETURN IS TO THE   * 18600013
*   CALLING ROUTINE BY BRANCHING ON REGISTER 14 AROUND THE MACRO      * 19200013
*   GENERATED CONSTANT.                                               * 19800013
*                                                                     * 20400013
*ENTRY POINTS-                                                        * 21000013
*   IECKDRCT - CONTROL IS PASSED HERE BY A BALR FROM THE GENERATED    * 21600013
*        CODE OF THE DIRECT MACRO.  REGISTER 15 IS THE BRANCH         * 22200013
*        ADDRESS REGISTER, AND REGISTER 14 IS THE RETURN ADDRESS      * 22800013
*        REGISTER.                                                    * 23400013
*   IECKLKUP - CONTROL IS PASSED HERE BY AN UNCONDITIONAL BRANCH      * 24000013
*        FROM THE ROUTE, ERROR MESSAGE, OR REROUTE ROUTINES.          * 24600013
*                                                                     * 25200013
*INPUT-                                                               * 25800013
*   REGISTER  2- POINTER TO COPY OF DESTINATION TERMINAL NAME FROM THE* 26400013
*        HEADER.                                                      * 27000013
*   REGISTER 14- RETURN ADDRESS                                       * 27600013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 28200013
*                                                                     * 28800013
*OUTPUT-                                                              * 29400013
*   REGISTER  1- IF DESTINATION NAME WAS FOUND, THIS REGISTER WILL    * 30000013
*        HOLD THE ADDRESS OF THAT TERMINAL TABLE ENTRY.  IF NAME WAS  * 30600013
*        NOT FOUND, THIS REGISTER WILL HAVE THE ADDRESS OF THE        * 31200013
*        ERROR DESTINATION QUEUE.                                     * 31800013
*   IF THE TERMINAL NAME WAS FOUND, THE ADDRESS OF THE QCB ASSOCIATED * 32400013
*        WITH THIS DESTINATION QUEUE WILL BE IN THE LCBDESTQ (LCB+29) * 33000013
*        FIELD OF THE LCB.  THE RELATIVE ADDRESS OF THE DESTINATION   * 33600013
*        ENTRY IS PLACED IN THE TTDKEY FIELD OF THE HEADER PREFIX.    * 34200013
*   IF THE TERMINAL NAME WAS NOT FOUND,THE ADDRESS OF THE QCB         * 34800013
*        ASSOCIATED WITH THE ERROR DESTINATION QUEUE IS PLACED IN     * 35400013
*        THE LCBDESTQ FIELD OF THE LCB.  THE INVALID DESTINATION BIT  * 36000013
*        IN THE ERROR HALFWORD IS TURNED ON (LCBERRST IS OR'ED WITH   * 36600013
*        A X'80').  THE TTDKEY FIELD OF THE HEADER PREFIX IS ZERO.    * 37200013
*                                                                     * 37800013
*EXTERNAL ROUTINES-                                                   * 38400013
*   NONE.                                                             * 39000013
*                                                                     * 39600013
*EXITS-                                                               * 40200013
*   NORMAL - RETURN TO THE USER BY A BRANCH ON REGISTER 14.           * 40800013
*        REGISTER 14 WILL HAVE BEEN UPDATED BY 2 TO AID IN            * 41400013
*        BRANCHING AROUND THE CONSTANT.                               * 42000013
*   ERROR- IF THE END OF THE TABLE IS REACHED BEFORE THE DESIRED ENTRY* 42600013
*        IS FOUND, THE INVALID DESTINATION BIT IN THE ERROR HALFWORD  * 43200013
*        IS SET (LCBERRST AT LCB+40 IS OR'ED WITH A X'80'), AND THE  *  43800013
*        ADDRESS OF THE QCB FOR THE ERROR DESTINATION QUEUE IS PLACED * 44400013
*        IN THE LCBDESTQ FIELD OF THE LCB.  THE TTDKEY FIELD OF THE   * 45000013
*        HEADER PREFIX IS ZERO IF THE DESTINATION NAME IS NOT FOUND.  * 45600013
*                                                                     * 46200013
*TABLES/WORK AREAS-                                                   * 46800013
*   NONE.                                                             * 47400013
*                                                                     * 48000013
*ATTRIBUTES-                                                          * 48600013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 49200013
*                                                                     * 49800013
*NOTES-                                                               * 50400013
*   REGISTER  1- WORK REGISTER.  USED TO KEEP TRACK OF TERMINAL TABLE * 51000013
*        ENTRY BEING EXAMINED AT ANY GIVEN TIME  WHILE THIS ROUTINE   * 51600013
*        HAS CONTROL.                                                 * 52200013
*   REGISTER  9- WORK REGISTER.  WILL HOLD THE MAXIMUM NUMBER OF      * 52800013
*        CHARACTERS IN A DESTINATION NAME.  WILL CONTROL THE          * 53400013
*        NUMBER OF CHARACTERS COMPARED.                               * 54000013
*   REGISTER 10- BASE REGISTER FOR IECKTERM.  USED TO REFERENCE       * 54600013
*        CONSECUTIVE TERMID'S IN THE TERMINAL TABLE.                  * 55200013
*   REGISTER 12- WORK REGISTER.  WILL HOLD THE SIZE OF THIS TERMINAL  * 55800013
*        TABLE ENTRY.                                                 * 56400013
*                                                                     * 57000013
*********************************************************************** 57600013
IECKLKUP START                                                          58200013
         ENTRY IECKDRCT                                                 58800013
DREG1    EQU   1                                                        59400013
KREG     EQU   2                                                        60000013
LCBREG   EQU   4                                                        60600013
MSREG    EQU   6                                                        61200013
WREG1    EQU   9                                                        61800013
TCREG    EQU   10                  SPECIAL ASSIGNMENT FOR THIS ROUTINE  62400013
IREG     EQU   12                                                       63000013
RREG1    EQU   14                                                       63600013
SREG     EQU   15                                                       64200013
         USING IECKLCB0,LCBREG                                          64800013
         USING IECKTERM,TCREG                                           65400013
         USING IECKPREF,MSREG                                           66000013
         LA    RREG1,2(0,RREG1)    BUMP RETURN REGISTER PAST CONSTANT   66600013
         BALR  SREG,0              SET UP BASE FOR THIS ROUTINE         67200013
         USING *,SREG                                                   67800013
IECKDRCT SR    WREG1,WREG1         CLEAR REGISTER                       68400013
         L     DREG1,=V(TERMTBL)   GET ADDRESS OF TERMINAL TABLE        69000013
         IC    WREG1,4(0,DREG1)    GET MAXIMUM SIZE OF TERMINAL NAME    69600013
         BCTR  WREG1,0             ADJUST COUNT FOR EXECUTE             70200013
         NI    LCBSTATE,X'FD'      TURN OFF EOB STATUS BIT              70800013
         SR    IREG,IREG           CLEAR INCREMENT REGISTER             71400013
         LA    TCREG,8(0,DREG1)    GET ADDRESS OF FIRST TERMINAL ENTRY  72000013
COMPAR1  AR    TCREG,IREG          INDEX NEXT ENTRY                     72600013
         EX    WREG1,DESTCK2      EXECUTE TEST FOR DESTINATION ENTRY    73200013
         BC    8,DESTOK2           BRANCH IF COMPARE EQUAL              73800013
         IC    IREG,TNTRYSZE       GET ENTRY SIZE                       74400013
         CL    TCREG,0(0,DREG1)    TEST FOR END OF TABLE                75000013
         BC    7,COMPAR1           IF NOT END OF TABLE LOOP BACK        75600013
         OI    LCBERRST,X'80'      SET DESTINATION ERROR BIT            76200013
         L     WREG1,0(0,13)       GET LPS QUEUE ADDRESS FROM IGG019NG  76800013
         LA    TCREG,212(0,WREG1) GET ADDRESS OF ERROR DESTINATION QUE  77400013
         LR    DREG1,TCREG         NEW BASE ESTABLISHED-MOVE IT TO RG 1 78000013
DESTOK2  MVC   LCBDESTQ(3),TQCBADDR  MOVE ERROR QUEUE OR DESTINATION    78600013
*                                      QUEUE QCB TO LCB                 79200013
         SR    TCREG,DREG1         GET RELATIVE ADDRESS OF DESTINATION  79800013
*                                    ENTRY                              80400013
         STH   TCREG,TTDKEY        STORE IN HEADER PREFIX               81000013
         BR    RREG1               RETURN                               81600013
         SPACE                                                          82200013
DESTCK2  CLC   TERMID(1),0(KREG)                                        82800013
         EJECT                                                          83400013
         LCBD                                                           84000013
         EJECT                                                          84600013
         TERMTBLD                                                       85200013
         EJECT                                                          85800013
         PREFIXD                                                        86400013
         END                                                            87000013
