         TITLE 'IECKMODE  QTAM MESSAGE MODE (MODE)'                     01000013
*********************************************************************** 02000013
*                                                                     * 03000013
*NAME-                                                                * 04000013
*                                                                     * 05000013
*   IECKMODE     QTAM MESSAGE MODE (MODE)                             * 06000013
*                                                                     * 07000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 08000013
*                                                                     * 09000013
*FUNCTION-                                                            * 10000013
*        THIS ROUTINE IS ENTERED WHEN A SPECIFIC CHARACTER IS         * 11000013
*   SPECIFIED AS THE SECOND OPERAND OF THE MODE MACRO.  THE SCAN      * 12000013
*   ROUTINE IS USED TO LOCATE THE NEXT FIELD IN THE MESSAGE HEADER.   * 13000013
*   IF THIS CHARACTER IS IDENTICAL TO THE CONTROL CHARACTER SPECIFIED * 14000013
*   IN THE MACRO STATEMENT, THEN THE SPECIFIED ROUTINE IS EXECUTED.   * 15000013
*        IF THE CHARACTERS DO NOT MATCH, THE SCAN POINTER IS RESTORED,* 16000013
*   AND CONTROL RETURNS TO THE NEXT LPS INSTRUCTION.                  * 17000013
*                                                                     * 18000013
*ENTRY POINTS-                                                        * 19000013
*   IECKMODE - CONTROL IS PASSED TO THIS POINT WHEN A SPECIFIC        * 20000013
*        CHARACTER IS GIVEN AS THE OPERAND OF THE MODE MACRO          * 21000013
*        STATEMENT.  REGISTER 15 WILL CONTAIN THE BRANCH ADDRESS, AND * 22000013
*        REGISTER 14 WILL CONTAIN THE RETURN ADDRESS.                 * 23000013
*                                                                     * 24000013
*INPUT-                                                               * 25000013
*   REGISTER  1- PARAMETER REGISTER CONTAINING THE ADDRESS OF THE     * 26000013
*        ROUTINE NAMED AS THE FIRST OPERAND OF THE MACRO.             * 27000013
*   REGISTER 14- RETURN ADDRESS                                       * 28000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 29000013
*                                                                     * 30000013
*OUTPUT-                                                              * 31000013
*   NONE.                                                             * 32000013
*                                                                     * 33000013
*EXTERNAL ROUTINES-                                                   * 34000013
*   IECKSCAN - TO LOCATE THE START OF THE NEXT FIELD IN THE MESSAGE   * 35000013
*        HEADER.                                                      * 36000013
*                                                                     * 37000013
*EXITS-                                                               * 38000013
*   NORMAL- IF CHARACTERS ARE IDENTICAL, A BRANCH TO THE SPECIFIED    * 39000013
*        ROUTINE IS EXECUTED.  BRANCH IS ON REGISTER 1.               * 40000013
*        IF CHARACTERS DO NOT AGREE, SCAN POINTER IS REPOSITIONED TO  * 41000013
*        ITS PLACE BEFORE THIS TEST.  CONTROL PASSES TO NEXT LPS      * 42000013
*        INSTRUCTION BY BRANCHING ON REGISTER 14.                     * 43000013
*   ERROR- NONE.                                                      * 44000013
*                                                                     * 45000013
*TABLES/WORK AREAS-                                                   * 46000013
*   NONE.                                                             * 47000013
*                                                                     * 48000013
*ATTRIBUTES-                                                          * 49000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 50000013
*                                                                     * 51000013
*NOTES-                                                               * 52000013
*   REGISTER  0- WORK REGISTER TO SAVE SCAN POINTER.                  * 53000013
*   REGISTER  2- OUTPUT FROM SCAN ROUTINE.  WILL CONTAIN ADDRESS OF   * 54000013
*        START OF NEW FIELD.                                          * 55000013
*   REGISTER  3- RETURN ADDRESS FOR BRANCH TO SCAN.                   * 56000013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 57000013
*                                                                     * 58000013
*********************************************************************** 59000013
IECKMODE START                                                          60000013
DREG0    EQU   0                                                        61000013
DREG1    EQU   1                                                        62000013
KREG     EQU   2                                                        63000013
RREG2    EQU   3                                                        64000013
SPREG    EQU   5                                                        65000013
LGREG    EQU   7                                                        66000013
RREG1    EQU   14                                                       67000013
SREG     EQU   15                                                       68000013
         LR    DREG0,SPREG         SAVE SCAN POINTER                    69000013
         L     SREG,4(0,LGREG)     GET ADDRESS OF SCAN SUBROUTINE       70000013
         BALR  RREG2,SREG          LINK TO SCAN SUBROUTINE              71000013
         CLC   2(1,RREG1),0(KREG)  WAS MODE CHARACTER FOUND             72000013
         BCR   8,DREG1             IF YES GO TO DESIGNATED SUBROUTINE   73000013
         LR    SPREG,DREG0         ELSE RESTORE THE SCAN POINTER        74000013
         B     4(0,RREG1)          AND RETURN                           75000013
         END                                                            76000013
