*********************************************************************** 00000221
*                                                                     * 00000421
* STATUS  CHANGE LEVEL 190   JANUARY 1971                             * 00000621
*                                                                     * 00000821
* FUNCTION- THE RETURN REGISTER (14) AND SCAN POINTER REGISTER (5) ARE* 00001021
*    SAVED IN THE SAVE AREA IN THIS ROUTINE.  THE ADDRESS OF THE SCAN * 00001221
*    ROUTINE IS OBTAINED FROM THE LPSTART MACRO EXPANSION. THE ROUTINE* 00001421
*    BRANCHES TO THE SCAN ROUTINE TO OBTAIN THE FIRST FIELD OF THE    * 00001621
*    MESSAGE.  THE CONTROL MESSAGE IDENTIFER IS MOVED FROM THE MACRO  * 00001821
*    EXPANSION INTO A WORKAREA.  IF THE CONTROL MESSAGE IDENTIFER DOES* 00002021
*    NOT COMPARE WITH THE FIELD OBTAINED BY SCAN ROUTINE, 'INCOMPLETE * 00002221
*    HEADER' (BIT 5) IS SET IN LCBERRST OF THE LCB.  THE SCAN POINTER * 00002421
*    IS RESTORED, AND RETURN IS MADE TO THE NEXT LPS INSTRUCTION.     * 00002621
*         IF THE COMPARE WAS GOOD, INDICATING AN OPERATOR CONTROL     * 00002821
*    MESSAGE,MSTATUS IS CHECKED FOR SINGLE SEGEMENT.  IF A SINGLE     * 00003021
*    SEGMENT MESSAGE, LINKAGE IS MADE TO THE SCAN ROUTINE TO OBTAIN   * 00003221
*    THE FUNCTION TO BE PERFORMED.  IF THE OPERATION TO BE PERFORMED  * 00003421
*    IS NOT VALID, OR THE MESSAGE IS NOT HEADER LAST SEGMENT, THE     * 00003621
*    MESSAGE IS RETRANSMITTED TO THE SOURCE TERMINAL.  THIS IS DONE BY* 00003821
*    MOVING THE SOURCE KEY 'TTSKEY' TO THE DESTINATION KEY 'TTDKEY' OF* 00004021
*    THE BUFFER, THE ADDRESS OF THE QCB FROM THE TERMINAL TABLE OF THE* 00004221
*    SOURCE IS MOVED TO LCBDESTQ, REGISTERS ARE RESTORED, AND RETURN  * 00004421
*    IS TO THE MACRO EXPANSION WHICH BRANCHES TO ENDRCV SECTION.      * 00004621
*         IF THE OPERATION TYPE IS FOUND, CONTROL IS PASSED TO THE    * 00004821
*    PARTICULAR ROUTINE.                                              * 00005021
*         RCOPYT - SUBROUTINE SUB1 IS USED TO OBTAIN THE TERMINAL     * 00005221
*    ADDRESS OF THE SPECIFIED ENTRY AND BUFFER SIZE.  ENTRY SIZE IS   * 00005421
*    LOWERED BY FOUR,SINCE THE SIZE AND QCB ADDRESS IS NOT COPIED, AND* 00005621
*    THEN THE SIZE IS DOUBLED FOR CONVERSION.  IF THE BUFFER SIZE IS  * 00005821
*    LESS THAN THE TERMINAL TABLE SIZE-4, THE BUFFER SIZE IS USED. THE* 00006021
*    UNPAK SUBROUTINE IS USED TO UNPACK AND TRANSLATE THE TERMINAL    * 00006221
*    ENTRY INTO THE BUFFER.  THE MESSAGE IS SENT BACK TO THE SOURCE.  * 00006421
*         RCOPYC- SUBROUTINE SUB1 IS USED TO OBTAIN THE TERMINAL TABLE* 00006621
*    ADDRESS OF THE SPECIFIED ENTRY AND BUFFER SIZE.  THE QCB ADDRESS * 00006821
*    IS OBTAINED FROM THE TERMINAL TABLE.  IF THE QCB IS NOT FOR A    * 00007021
*    DESTINATION (X'68'), THE MESSAGE IS RETURNED TO SOURCE TERMINAL. * 00007221
*    THE LCB IS CALCULATED FROM THE LCB ADDRESS IN THE DCB AND THE    * 00007421
*    RELATIVE LINE NUMBER(RLN) TIMES THE SIZE OF AN LCB. THE ADDRESS  * 00007621
*    OF THE ERROR COUNTERS IN THE LCB IS OBTAINED BY SUBTRACTING 16   * 00007821
*    FROM THE END OF THE LCB.  THE REGISTERS ARE SAVED BEFORE AN SVC  * 00008021
*    QPOST IS ISSUED TO POST COPYCLR QCB TO ITSELF TO GAIN CONTROL IN * 00008221
*    DISABLE MODE SO THAT THE COUNTERS MAY BE MANIPULATED.            * 00008421
*         WHEN THE COPYCLR SUBTASK GAINS CONTROL, THE REGISTERS BEFORE* 00008621
*    QPOST ARE RESTORED.  THE THRESHOLD VALUES ARE ADDED TO THE ACCUM-* 00008821
*    LATIVE COUNTERS FOR TRANSMISSIONS, DATA CHECKS, INTERVENTION     * 00009021
*    REQUIRED, AND TIME OUT.  IF THE BUFFER SIZE IS LESS THAN 32      * 00009221
*    (DOUBLE THE 16 BYTE AREA NEEDED FOR CONVERSION), THE BUFFER SIZE * 00009421
*    IS USED FOR MOVE.  LINKAGE IS MADE TO THE UNPAK SUBROUTINE TO    * 00009621
*    TRANSLATE AND MOVE THE ERROR COUNTERS INTO THE BUFFER.  THE      * 00009821
*    THRESHOLD COUNTERS IN THE LCB ARE ZEROED.  A BRANCH TO DISPATCH  * 00010021
*    IS TAKEN TO RETURN TO COPYC.  COPYC RETURNS TO THE MACRO EXPAN-  * 00010221
*    SION TO SEND MESSAGES TO SOURCE TERMINAL.                        * 00010421
*         RSWITCH- THIS ROUTINE CHANGES THE OPERATOR CONTROL FACILITY * 00010621
*    TO AN ALTERNATE SPECIFIED IN THE MACRO.  IF 'ALTERNATE TERMINAL' * 00010821
*    (X'01') IS NOT SET IN THE FLAGS, THE MESSAGE IS RETURNED TO THE  * 00011021
*    SOURCE TERMINAL.  THE OFFSETS TO THE ALTERNATE AND PRIMARY       * 00011221
*    TERMINALS IN THE MACRO PARAMETER LIST ARE SWITCHED VIA 3 EXCLU-  * 00011421
*    SIVE OR'S.  THE SERVICE BIT IN THE MESSAGE IS SET SO THAT THE    * 00011621
*    BUFFER WILL BE RETURNED TO THE AVAILABLE BUFFER QUEUE.  RETURN IS* 00011821
*    TO THE MACRO EXPANSION WHICH BRANCHES TO ENDRCV SECTION.         * 00012021
*         CHNGT- LINKAGE IS MADE TO THE SUB1 SUBROUTINE TO OBTAIN THE * 00012221
*    TERMINAL ADDRESS AND BUFFER SIZE. THE SCAN POINTER IS BUMPTED    * 00012421
*    PASSED ALL BLANKS. IF THE BUFFER IS ALL BLANKS, RETURN IS MADE TO* 00012621
*    THE NEXT LPS INSTRUCTION.  THE CHARACTERS TO BE PLACED IN THE    * 00012821
*    TERMINAL TABLE ARE TRANSLATED AND CHECKED FOR ENDING CHARACTER OF* 00013021
*    EOB OR EOT.  IF AN INVALID CHARACTER IS USED, A TEST IS MADE TO  * 00013221
*    SEE IF THERE IS ENOUGH SPACE FOR AN EOB OR EOT TO BE INSERTED    * 00013421
*    AFTER THE DATA; IF NOT, AN EOT IS INSERTED AFTER THE TERM NAME.  * 00013621
*    THE MESSAGE IS THEN RETURNED TO THE SOURCE TERMINAL.             * 00013821
*         IF THE DATA IS VALID, THE SIZE IS CHECKED.  IF THE SIZE IS  * 00014021
*    ZERO, THE SERVICE BIT IS SET IN MSTATUS FIELD OF THE BUFFER SO   * 00014221
*    THAT THE BUFFER IS RETURNED.  IF THERE IS AN ODD NUMBER OF CHAR- * 00014421
*    ACTERS, THE MESSAGE IS TREATED AS INVALID.  THE SIZE OF THE      * 00014621
*    TERMINAL TABLE ENTRY IS ACCESSED AND DECREASED BY 4 FOR SIZE AND * 00014821
*    QCB ADDRESS.  THE DATA TO BE INSERTED IS DIVIDED BY 2 AND COM-   * 00015021
*    PARED WITH THE ADJUSTED TERMINAL SIZE.  IF DATA IS TOO LARGE FOR * 00015221
*    TERMINAL ENTRY  THE MESSAGE IS TREATED AS INVALID.  FOR A VALID  * 00015421
*    MESSAGE, THE CHANGE QCB IS POSTED TO ITSELF TO GAIN CONTROL WHILE* 00015621
*    DISABLED.                                                        * 00015821
*         WHEN THE CHANGE1 SUBTASK GAINS CONTROL, IT ACCESSES THE QCB * 00016021
*    FROM THE TERMINAL TABLE ENTRY TO BE CHANGED.  IF THE QCB IS NOT A* 00016221
*    DESTINATION QCB, THE DCB HAS NOT BEEN OPENED, OR THE LINE IS NOT * 00016421
*    ACTIVE, THEN THE SEQUENCE NUMBER CAN BE CHANGED.  OTHERWISE, THE * 00016621
*    SEQUENCE NUMBER CANNOT BE CHANGED SO THE COUNT IS DECREASED BY 4.* 00016821
*    THE DATA IS PACKED INTO AN AREA AND MOVED INTO THE TERMINAL ENTRY* 00017021
*    16 BYTES AT A TIME.  EXIT IS MADE TO DISPATCH TO RETURN TO CHNGT.* 00017221
*    THE SERVICE BIT IS SET IN THE BUFFER SO THAT IT WILL BE RETURNED * 00017421
*    TO THE AVAILABLE BUFFER QUEUE.  RETURN IS MADE TO THE MACRO WHICH* 00017621
*    BRANCHES TO ENDRCV SECTION.                                      * 00017821
*         RINTRCPT- THE FLAGS IN THE MACRO EXPANSION ARE CHECKED FOR  * 00018021
*    INTERCEPT (X'02').  IF THE INTERCEPT FLAG HAS NOT BEEN SET, THE  * 00018221
*    INTERCPT MACRO HAS NOT BEEN SPECIFIED. SINCE OPCTL INTERCEPT USES* 00018421
*    THE INTERCPT MACRO FUNCTION, THE MESSAGE IS ROUTED TO THE SOURCE * 00018621
*    AS IN ERROR.  LINKAGE IS MADE TO THE SUB1 SUBROUTINE TO GET THE  * 00018821
*    TERMINAL ADDRESS. IF THE QCB IS NOT FOR A TERMINAL, THE MESSAGE  * 00019021
*    IS RETURNED TO THE SOURCE TERMINAL.  THE 'SEND' BIT IN TSTATUS OF* 00019221
*    THE TERMINAL ENTRY IS TURNED OFF TO CAUSE THE TERMINAL TO BE     * 00019421
*    INTERCEPTED WHEN THE NEXT MESSAGE IS SENT.  THE 'SERVICED' BIT IS* 00019621
*    SET IN MSTATUS OF THE BUFFER TO CAUSE THE BUFFER TO BE RETURNED  * 00019821
*    TO THE AVAILABLE BUFFER QUEUE.  RETURN IS MADE TO THE MACRO      * 00020021
*    EXPANSION WHICH BRANCHES TO ENDRCV.                              * 00020221
*         RRELEASM- THE FLAGS IN THE MACRO EXPANSION ARE CHECKED FOR  * 00020421
*    INTERCEPT. IF INTERCEPT HAS NOT BEEN SPECIFIED,RELEASEM CANNOT BE* 00020621
*    DONE SO THE MESSAGE IS RETURNED TO THE SOURCE TERMINAL.  LINKAGE * 00020821
*    IS MADE TO THE SUB1 SUBROUTINE TO OBTAIN THE TERMINAL ADDRESS.   * 00021021
*    THE QLINK FIELD OF THE DESTINATION QCB IS CHECKED FOR RESTART. IF* 00021221
*    NONZERO A RESTART IS IN PROGRESS, SO A RELEASEM CANNOT BE DONE.  * 00021421
*    THE MESSAGE IS RETURNED TO THE SOURCE TERMINAL. IF TSTATUS IN    * 00021621
*    THE TERMINAL TABLE INDICATES THAT THE ENTRY IS NOT INTERCEPTED,  * 00021821
*    THE 'SERVICED' BIT IS SET IN MSTATUS TO RETURN BUFFER TO AVAIL-  * 00022021
*    ABLE BUFFER QUEUE.  THE ADDRESS IN THE INTERCPT FIELD IS LESS    * 00022221
*    THAN OR EQUAL TO THE FIRST ELEMENT IN THE QUEUE (QFAC), THE      * 00022421
*    INTERCPT OPTION FIELD OF THE TERMINAL TABLE IS MOVED INTO QFAC AS* 00022621
*    THE FIRST MESSAGE TO BE SENT.  THE 'INTERCPT' BIT IS TURNED OFF  * 00022821
*    AND RELEASE PENDING BIT IS SET ON IN TSTATUS OF THE TERMINAL     * 00023021
*    TABLE ENTRY.  IF THE STCB IN THE QCB IS THE SEND SCHEDULER, A    * 00023221
*    PRIMER IS NOT NEEDED SO THE 'SERVICE' BIT IS SET IN MSTATUS OF   * 00023421
*    THE BUFFER IS RETURNED TO THE AVAILABLE BUFFER QUEUE.  OTHERWISE,* 00023621
*    A PRIMER ELEMENT IS POSTED TO THE QCB TO ACTIVATE THE SEND SCHED-* 00023821
*    LER. THE 'SERVICED' BIT IS SET IN MSTATUS TO RETURN THE BUFFER TO* 00024021
*    THE AVAILABLE BUFFER QUEUE.                                      * 00024221
*         RSTARTLN- LINKAGE IS MADE TO THE SUB1 SUBROUTINE TO GET THE * 00024421
*    TERMINAL ADDRESS.  LINKAGE IS MADE TO SUB2 SUBROUTINE TO OBTAIN  * 00024621
*    TERMINAL ADDRESS.  A STARTLN INDICATOR OF 2 IS SET IN SW1.  A    * 00024821
*    BRANCH IS TAKEN TO THE STOPLN ROUTINE TO USE COMMON CODE FOR     * 00025021
*    ERROR CHECKING.  THE MESSAGE IS RETURNED TO THE TERMINAL IF THE  * 00025221
*    TERMINAL ENTRY IS NOT FOR A DESTINATION ENTRY, THE BUFFER DOES   * 00025421
*    NOT CONTAIN 22 USEABLE BYTES,  THE DCB FOR THE LINE HAS NOT BEEN * 00025621
*    OPENED, OR THE LINE NUMBER IS GREATER THAN THE NUMBER OF DEB     * 00025821
*    EXTENTS.  IF LCBERCCW + 2 HAS THE 2 BIT ON, THE ROUTINE LOOPS    * 00026021
*    UNTIL THE PREVIOUS STARTLN OR STOPLN HAS COMPLETED.              * 00026221
*         TO START THE LINE, THE RECEIVE SCHEDULER IS RESTORED. IF THE* 00026421
*    RECEIVE SCHEDULER WAS NOT REMOVED BY STOPLN (LCBCPRI=X'80'), THE * 00026621
*    SCHEDULER IS RESTORED.  IF THE SCHEDULER HAD BEEN REMOVED, THE   * 00026821
*    FLAG IN LCBCPRI IS TURNED OFF, AND THE RECEIVE SCHEDULER IS LINK-* 00027021
*    ED INTO THE STCB CHAIN.  LCBCPA + 32 IS SET TO X'FF' TO INDICATE * 00027221
*    STARTLN.  INITIAL CCW'S ARE SET UP IN THE CHANNEL PROGRAM AREA.  * 00027421
*    THE PROPER SAD CCW IS SET FOR 2702'S, NOP FOR DIAL LINES, AND    * 00027621
*    TYPE III ADAPTERS AND ENABLE FOR NONDIAL LINES.  A FLAG IS SET IN* 00027821
*    LCBERCCW + 2 TO INDICATE SIO.  AN SVC 0 IS ISSUED TO START THE   * 00028021
*    LINE.  UPON RETURN, THE ROUTINE LOOPS BACK IF THERE ARE MORE     * 00028221
*    LINES TO START.  IF                                              * 00028421
*    STARTLN WAS SUCCESSFUL, THE 'SERVICE' BIT IS SET IN MSTATUS TO   * 00028621
*    RETURN BUFFER TO AVAILABLE BUFFER QUEUE.  RETURN IS MADE TO THE  * 00028821
*    MACRO WHICH BRANCHES TO ENDRCV SECTION.                          * 00029021
*         RINTREL- THE INTREL ROUTINE SETS AN INTREL SWITCH (SW1) TO  * 00029221
*    INDICATE INTREL, AND THEN EXECUTES THE SAME AS RSTOPLN.          * 00029421
*         RSTOPLN - LINKAGE IS MADE TO THE SUB1 SUBROUTINE TO OBTAIN  * 00029621
*    THE TERMINAL ADDRESS.  IF THE TERMINAL ENTRY IS NOT A DESTINATION* 00029821
*    ENTRY (A PROCESS OR DLIST ENTRY), THE MESSAGE IS RETURNED AND    * 00030021
*    THE FUNCTION IS NOT PERFORMED.  THE SCAN POINTER IS BUMPED PAST  * 00030221
*    ALL BLANKS.  IF THE BUFFER DOES NOT CONTAIN 22 USEABLE           * 00030421
*    BYTES, THE FUNCTION IS NOT PERFORMED.  THE DCB OF THE LINE TO BE * 00030621
*    STOPPED IS COMPARED TO THE DCB OF THE SOURCE TERMINAL IF THE     * 00030821
*    DCB'S ARE THE SAME AND 'ALL' HAS BEEN SPECIFIED OR THE LINE TO BE* 00031021
*    STOPPED IS THE SOURCE LINE, THE FUNCTION IS NOT PERFORMED. IF THE* 00031221
*    DCB'S ARE NOT EQUAL BUT THE DCB FOR THE SPECIFIED LINE IS NOT    * 00031421
*    OPEN, THE FUNCTION IS NOT PERFORMED.  IF THE RLN IN THE QCB IS   * 00031621
*    GREATER THAN THE NUMBER OF EXTENTS IN THE DEB, THE FUNCTION IS   * 00031821
*    NOT PERFORMED.  FOR INTREL, IF THE LINE IS ALREADY STOPPED       * 00032021
*    (LCBSTATE=0), THE FUNCTION IS NOT PERFORMED.  FOR THE ABOVE      * 00032221
*    ERRORS, THE MESSAGE IS THEN ROUTED BACK TO THE SOURCE TERMINAL   * 00032421
*    AFTER ZEROING THE INTREL SWITCH (SW1).                           * 00032621
*         IF FUNCTION CAN BE PERFORMED, MESSAGE SIZE IS SET TO 56     * 00032821
*    BYTES.  IF LCBERCCW + 2 HAS THE 2 BIT ON, THE ROUTINE LOOPS UNTIL* 00033021
*    THE PREVIOUS STARTLN OR STOPLN HAS COMPLETED. (THIS BIT IS SET IN* 00033221
*    STARTLN, STOPLN, OR OPEN BEFORE A SIO AND IS TURNED OFF WHEN THE * 00033421
*    INTERRUPT IS RECEIVED.)  IF STOPLN 'ALL' WAS SPECIFIED, AN INDEX * 00033621
*    IS SET FOR THE NUMBER OF LINES IN THE LINE GROUP   AN SVC QPOST  * 00033821
*    IS ISSUED TO POST THE STOP QCB TO ITSELF TO GAIN CONTROL IN      * 00034021
*    DISABLED CODE.                                                   * 00034221
*         STOP1 SUBTASK STORES THE ADDRESS OF IECKOPAW IN THE BUFFER  * 00034421
*    RECALL/CLEANUP ADDRESS IN MODULE IGG019NG TO INSURE THE IECKOPAW * 00034621
*    IS EXECUTED AT BUFFER CLEANUP TIME.  THE SIZE OF THE LCB FROM THE* 00034821
*    DCB IS SAVED AT HDSTRT + 21 AND THE LINE NUMBER AT HDSTRT FIELD  * 00035021
*    OF THE BUFFER.  EACH LCB OF THE LINE GROUP IS PROCESSED THROUGH  * 00035221
*    A LOOP.  IF THE LINE IS NOT ACTIVE, LCBSTATE=0, EXIT IS MADE TO  * 00035421
*    LOOP CONTROL.  IF THE FIRST STCB IN THE LCB IS FOR AN OPCTL FOR  * 00035621
*    STOPLN, THE STOPLN REQUEST IS IGNORED AND EXIT IS MADE TO LOOP   * 00035821
*    CONTROL.                                                         * 00036021
*         IF THE LINE IS FOR A NONDIAL 2740 (CHECKED BY SENSE CCW IN  * 00036221
*    LCBCPA+16), THE TP OP CODE OF THE SENSE CCW IS CHECKED FOR ZERO. * 00036421
*    IF TP OP CODE IS NOT ZERO, INDICATING THAT THE SENSE HAS NOT BEEN* 00036621
*    ISSUED AND THEREFORE THE LINE IS NOT BUSY, A HALT I/O IS NEEDED. * 00036821
*    FOR A DIAL LINE, THE LINE IS CHECKED FOR ACTIVE TRANSMISSION BY  * 00037021
*    TESTING LCBINCAM FOR A 2.  IF THE LINE IS IN ACTIVE TRANSMISSION,* 00037221
*    A CHECK FOR A 2740 MUST BE MADE.  IF A 2740 TERMINAL AND THE TP  * 00037421
*    OP CODE OF THE SENSE INDICATES THE LINE IS NOT BUSY, LCBINCAM IS * 00037621
*    SET TO A 3 AND A HIO MUST BE ISSUED.  IF DIAL LINE (NOT A 2740)  * 00037821
*    IS NOT IN ACTIVE TRANSMISSION, LCBINCAM IS SET TO A 3 AND A HIO  * 00038021
*    MUST BE ISSUED.  BEFORE ISSUING THE HIO,THE ERP FLAGS ARE CLEARED* 00038221
*    IN LCBFLAG1, AND HIO FLAG (X'48') FOR LINE END IS SET IN         * 00038421
*    LCBECBPT. THE ADDRESS OF THE HIO ROUTINE IS OBTAINED FROM THE    * 00038621
*    CVT. LINKAGE IS MADE TO THE HIO ROUTINE TO CLEAR THE ENABLE.     * 00038821
*         FOR EITHER DIAL OR NONDIAL LINES, THE BUFFER AREA IS CHECKED* 00039021
*    FOR A STCB.  IF THE STCB IS NOT IN THE BUFFER, THE ADDRESS OF    * 00039221
*    STOP2 QCB IS MOVED INTO LCBDESTQ TO CAUSE THE BUFFER TO BE POSTED* 00039421
*    TO STOP2QCB FOR A DESTINATION QCB.  EXIT IS MADE TO DISPATCH     * 00039621
*    RETURNS TO RSTOPLN ROUTINE.  RSTOPLN RETURNS TO THE MACRO EXPAN- * 00039821
*    SION WHICH BRANCHES TO ENDRCV SECTION.  IF THE STCB IS IN THE    * 00040021
*    BUFFER (SET UP BY PREVIOUS PASS OF STOPLN ALL), A BRANCH IS      * 00040221
*    TAKEN TO THE SUBTASK OF STOP2 QCB.                               * 00040421
*         STOP3- THIS ROUTINE GAINS CONTROL BY EITHER A BRANCH FROM   * 00040621
*    STOP1 OR STOP3 SUBTASK GAINING CONTROL WHEN A BUFFER IS POSTED TO* 00040821
*    IT'S DESTINATION QUEUE (STOP2).  THE ADDRESS OF THE LCB FOR THE  * 00041021
*    LINE TO BE STOPPED IS RETRIEVED FROM THE STOP2 QCB.  THE COUNT   * 00041221
*    AND ADDRESS OF IECKLNCH IS STORED AT HDSTART + 16 IN THE BUFFER. * 00041421
*    A STCB IS BUILT IN THE BUFFER USING A PRIORITY OF X'E4', X'6C'   * 00041621
*    AS THE BRANCH OFFSET, AND STCB ADDRESS IN THE FIRST WORD. A SUB- * 00041821
*    TASK CONTAINING A LOAD AND BRANCH INSTRUCTIONS TO SUBTASK1 IS    * 00042021
*    MOVED INTO THE BUFFER.  THIS STCB IS INSERTED AS THE FIRST STCB  * 00042221
*    IN THE LCB CHAIN OF STCB'S.  IF THE LINE IS RECEIVING AND USES   * 00042421
*    THE AUTOPOLL FEATURE, X'FE' IS SET IN LCBCPA + 47 AND THE TIC AT * 00042621
*    LCBCPA + 40 IS NOPED TO STOP THE LINE.                           * 00042821
*         IF ENTRY IS FROM INTREL, THE INTREL SWITCH (SW1) IS CLEARED,* 00043021
*    THE LCB INTREL SWITCH AT LCBDCBPT (HIGH ORDER BYTE) IS SET TO    * 00043221
*    ONE, AND THE COUNT INDEX IS ZEROED AT HDSTART+16 IN THE BUFFER.  * 00043421
*    FOR EITHER INTREL OR STOPLN, THE STATUS OF THE LINE IS CHECKED.  * 00043621
*    IF THE LINE IS FREE (LCBSTATE=1), THE LINE IS POSTED TO ITSELF   * 00043821
*    TO ACTIVATE THE STCB.  IF THE LINE IS NOT FREE OR ON THE TIME    * 00044021
*    DELAY QUEUE, A BRANCH IS TAKEN TO DISPATCH TO RETURN TO RSTOPLN. * 00044221
*         THIS PROCEDURE IS FOLLOWED FOR EACH LINE IN THE LINE GROUP  * 00044421
*    TO BE STOPPED. WHEN ALL LINES HAVE BEEN PROCESSED AND THE ENTRY  * 00044621
*    IS FOR STOPLN, THE BUFFER IS CHECKED FOR A FIRST TIME PASS.  IF  * 00044821
*    THE STCB WAS NOT BUILT, THE BUFFER IS POSTED TO THE AVAILABLE    * 00045021
*    BUFFER QUEUE TO FREE THE BUFFER. IF THE STCB HAS BEEN USED, THE  * 00045221
*    SERVICE BIT IS SET IN THE BUFFER AND A BRANCH IS TAKEN TO DIS-   * 00045421
*    PATCH TO RETURN TO THE RSTOPLN ROUTINE TO FREE THE BUFFER. IF    * 00045621
*    THE SUBTASK WAS FOR INTREL, A BRANCH IS TAKEN TO DISPATCH        * 00045821
*    SUBTASK1.                                                        * 00046021
*         SUBTASK1- THIS ROUTINE IS ENTERED WHEN THE STCB IS ACTIVATED* 00046221
*    BY THE QCB BEING POSTED TO ITSELF BY CLEANUP OR STOP3. THE STCB  * 00046421
*    IS REMOVED FROM THE LCB CHAIN.  LCBSTATE IS SET TO 0 TO INDICATE * 00046621
*    THE LINE IS STOPPED.  THE OFFSET AND STCB ADDRESS IN THE BUFFER  * 00046821
*    ARE ZEROED.                                                      * 00047021
*         FOR DIAL LINES, A DISABLE CCW IS SET UP IN THE LCBERCCW AND * 00047221
*    LCBSTATE IS SET TO POINT TO LCBERCCW.  A FLAG OF X'FE' IS SET IN * 00047421
*    LCBCPA + 32 TO INDICATE 'OPEN IDLE'. LCBINCAM IS SET TO 7 SO     * 00047621
*    THAT THE LINE WILL NOT BE SELECTED FOR SENDING.  THE STCB CHAIN  * 00047821
*    OF THE LCB IS SEARCHED TO REMOVE THE SEND SCHEDULER.  THE        * 00048021
*    TERMINAL OFFSET IN LCBTTIND IS ZEROED AND THE SEND SCHEDULER IS  * 00048221
*    PLACED IN THE DESTINATION QCB. IF QFAC IS LESS THAN QNAGSEG,     * 00048421
*    THERE ARE NO MESSAGES TO SEND SO THE SEARCH OF STCB'S IS CONTIN- * 00048621
*    UED.                                                             * 00048821
*         IF THERE ARE MESSAGES TO SEND AND ENTRY WAS FOR INTREL, A   * 00049021
*    DUMMY PRIMER ELEMENT MUST BE POSTED TO THE QCB SO ANOTHER LINE   * 00049221
*    MAY BE ASSIGNED TO THIS TERMINAL.  THE PRIMER  ELEMENT (DEFINED  * 00049421
*    IN THIS ROUTINE) IS PLACED AS THE NEXT ITEM AFTER THE LCB ON THE * 00049621
*    READY QUEUE.  A FLAG OF X'02' IS SET IN LCBERCCW+2 TO INDICATE   * 00049821
*    TO STARTLN THAT THE DISABLE HAS NOT COMPLETED. EXCP IS ISSUED TO * 00050021
*    EXECUTE THE DISABLE TO HANG UP THE LINE.                         * 00050221
*         IF THERE ARE MESSAGES TO SEND AND ENTRY WAS FOR STOPLN, THE * 00050421
*    SEND SCHEDULER IS PUT IN THE DIAL-OUT CALL QUEUE FOR THAT LINE.  * 00050621
*    A FLAG OF X'02' IS SET IN LCBERCCW + 2 FOR THE STARTLN ROUTINE   * 00050821
*    AN EXCP IS ISSUED TO DISABLE THE LINE.                           * 00051021
*         FOR DIAL OR NONDIAL LINES, IF ENTRY WAS FOR INTREL, A BRANCH* 00051221
*    IS TAKEN TO SUBTASK2.  IF ENTRY IS FOR STOPLN, THE LCB IS        * 00051421
*    REMOVED FROM THE READY QUEUE.  THIS IS DONE SO THAT THE QKEY     * 00051621
*    FIELD (LCBSTATE) CAN REMAIN A ZERO.  IF THERE ARE MORE LINES TO  * 00051821
*    STOP, THE ROUTINE LOOPS BACK TO FOLLOW THE SAME PROCEDURE TO     * 00052021
*    STOP THE NEXT LINE.  WHEN THERE ARE NO MORE LINES TO STOP, THE   * 00052221
*    BUFFER IS POSTED TO THE AVAILABLE BUFFER QUEUE TO FREE THE       * 00052421
*    BUFFER.                                                          * 00052621
*         SUBTASK2- THIS ROUTINE IS ENTERED FOR INTREL.  THE LCB IS   * 00052821
*    REMOVED FROM THE READY QUEUE TO PRESERVE  'QKEY' (LCBSTATE = 0). * 00053021
*    THE INTREL SWITCH (SW1) IS ZEROED.  THE ADDRESS OF A STCB FOR    * 00053221
*    STCB2 IS PLACED IN THE BUFFER.  IF ENTRY TO ROUTINE WAS FROM AN  * 00053421
*    I/O INTERRUPT, THE GETSVC1 QCB IS POSTED TO THE LPS CONTROL      * 00053621
*    ROUTINE TO ENTER UNDER SVC CONTROL.  WHEN ENTRY IS FROM AN SVC   * 00053821
*    (X'FF' IN IOSSAVE), THE BUFFER IS MADE TO LOOK LIKE AN LCB BY    * 00054021
*    ZEROING LCBSCHAD AND SETTING LCBSTATE TO X'0C'. A 2 MINUTE       * 00054221
*    INTERVAL IS SET UP.  A BRANCH IS TAKEN TO THE TIME DELAY ROUTINE * 00054421
*    IN MODULE IGG019NG TO PLACE THE BUFFER IN THE TIME QUEUE.        * 00054621
*         STCB2- WHEN THE 2 MINUTE INTERVAL HAS ELAPSED, STCB2 SUBTASK* 00054821
*    IS DISPATCHED.  THE FIRST WORD OF THE BUFFER,WHICH IS ALREADY ON * 00055021
*    THE READY QUEUE, IS SET TO THE AVAILABLE BUFFER QUEUE TO FREE    * 00055221
*    THE BUFFER.  THE LCB IS POSTED TO ITSELF TO ACTIVATE THE LINE.   * 00055421
*         STOP5- WHEN THE OPERATOR AWARENESS ROUTINE HAS AN IRRECOVER-* 00055621
*    ABLE ERROR ON A LINE THAT IS IN INTREL, IT GETS A BUFFER AND     * 00055821
*    CLEANUP POSTS THAT BUFFER TO STOP4 QCB FOR THE STOP5 SUBTASK.  IF* 00056021
*    THE LINE IS ACTIVE, THE INTREL SWITCH (SW1) IS SET TO 1 AND A    * 00056221
*    BRANCH IS TAKEN TO STOP3 SUBTASK TO STOP THE LINE.  IF THE LINE  * 00056421
*    IS NOT ACTIVE A BRANCH IS TAKEN TO THE SUBTASK2 SUBTASK TO PUT   * 00056621
*    THE LINE IN THE TIME DELAY QUEUE.                                * 00056821
*         SUB1- THIS SUBROUTINE IS USED TO OBTAIN THE TERMINAL TABLE  * 00057021
*    ENTRY ADDRESS AND BUFFER SIZE.  THE ADDRESS OF IECKSCAN IS OB-   * 00057221
*    TAINED FROM LPSTART MACRO EXPANSION.  THE SCAN ROUTINE IS USED TO* 00057421
*    OBTAIN THE NEXT FIELD (TERMINAL NAME) IN A WORKAREA.  THE SCAN   * 00057621
*    POINTER IS SET TO POINT TO THE BLANK FOLLOWING THE TERM NAME.    * 00057821
*    LINKAGE IS MADE TO IECKDRCT TO OBTAIN THE TERMINAL TABLE OFFSET  * 00058021
*    FOR THE TERMINAL ID.  IF THE TERMINAL TABLE ENTRY WAS NOT FOUND, * 00058221
*    THE MESSAGE IS REROUTED BACK TO THE SOURCE TERMINAL.  THE BUFFER * 00058421
*    SIZE IS OBTAINED BY A V-CON OF IECKBFSZ WHICH IS IN THE BUFFER   * 00058621
*    MACRO EXPANSION.  AFTER ADDING 8 TO THE BUFFER SIZE FOR THE RECB,* 00058821
*    THE SCAN POINTER OFFSET IS SUBTRACTED TO OBTAIN THE AMOUNT OF    * 00059021
*    SPACE LEFT IN BUFFER PASSED IN REGISTER 9.  IN REGISTER 10 IS    * 00059221
*    PASSED THE ADDRESS OF THE TERMINAL TABLE ENTRY.                  * 00059421
*         UNPAK- THIS SUBROUTINE IS USED BY COPYT, CHNGT, OR COPYC TO * 00059621
*    UNPACK THE TERMINAL TABLE ENTRY OR COUNTERS INTO EBCDIC. THE DATA* 00059821
*    IS UNPACKED INTO THE BUFFER 8 BYTES AT A TIME UNTIL THERE IS LESS* 00060021
*    THAN 8 BYTES TO CONVERT. WHEN THIS OCCURS, THE NEXT 8 BYTES ARE  * 00060221
*    CONVERTED INTO A WORKAREA AND THEN THE CORRECT NUMBER IS MOVED   * 00060421
*    INTO THE BUFFER.  THE BUFFER DATA IS TRANSLATED INTO EBCDIC. A   * 00060621
*    CHECK IS MADE TO SEE IF EOB AND EOT CHARACTERS CAN FIT INTO THE  * 00060821
*    BUFFER.  IF NOT, EOB AND EOT ARE MOVED INTO THE LAST TWO CHAR-   * 00061021
*    ACTERS OF THE BUFFER; OTHERWISE, THEY ARE MOVED AFTER THE DATA.  * 00061221
*    THE ACTUAL SIZE OF THE DATA IS STORED IN MSEGSZE FIELD OF THE    * 00061421
*    BUFFER PREFIX.                                                   * 00061621
*                                                                     * 00061821
* ENTRY POINTS- ENTRY MAY BE MADE TO THE FIRST BYTE OF THE MODULE     * 00062021
*         WHEN THE OPTCL MACRO INSTRUCTION IS EXECUTED.               * 00062221
*         ENTRY MAY BE MADE AT COPYCLR1 + 6 WHEN THE SUBTASK FOR      * 00062421
*         COPYCLR QCB IS DISPATCHED.                                  * 00062621
*         ENTRY MAY BE MADE AT CHANGE1 + 6  WHEN THE SUBTASK FOR      * 00062821
*         CHANGE QCB IS DISPATCHED.                                   * 00063021
*         ENTRY MAY BE MADE AT STOP1 + 6 WHEN THE SUBTASK FOR STOP QCB* 00063221
*         IS DISPATCHED.                                              * 00063421
*         ENTRY MAYBE MADE AT STOP3 + 8 WHEN THE SUBTASK FOR STOP2    * 00063621
*         QCB IS DISPATCHED.                                          * 00063821
*         ENTRY MAY BE MADE AT STCB2 + 6 WHEN 2 MINUTE INTERVAL HAS   * 00064021
*         EXPIRED.                                                    * 00064221
*         ENTRY MAY BE MADE AT GETSVC2 + 8 WHEN THE SUBTASK FOR       * 00064421
*         GETSVC1 IS DISPATCHED.                                      * 00064621
*         ENTRY MAY BE MADE AT STOP5 + 8 WHEN THE SUBTASK FOR STOP4   * 00064821
*         QCB IS DISPATCHED.                                          * 00065021
*                                                                     * 00065221
* INPUT-                                                              * 00065421
*    REGISTER 1 - PARAMETER LIST FROM MACRO EXPANSION.                * 00065621
*    REGISTER 14 - RETURN ADDRESS OF MACRO EXPANSION.                 * 00065821
*    REGISTER 15 - BASE OF IECKOCTL.                                  * 00066021
*                                                                     * 00066221
* OUTPUT = EXIT VIA BRANCH ON RETURN REGISTER                         * 00066421
*    REGISTER 14 - ADDRESS OF OPCTL MACRO EXPANSION                   * 00066621
*          EXIT VIA BRANCH TO POST                                    * 00066821
*    REGISTER 1 - ELEMENT ADDRESS                                     * 00067021
*    REGISTER 2 - QCB ADDRESS                                         * 00067221
*    REGISTER 12 - BASE FOR IECKQQ01                                  * 00067421
*          BUFFER CONTAINING TERMINAL TABLE ENTRY                     * 00067621
*                                                                     * 00067821
* EXTERNAL REFERENCES-                                                * 00068021
*         SVC QPOST                                                   * 00068221
*         IECKSCAN                                                    * 00068421
*         IECKDRCT                                                    * 00068621
*         IECKBFSZ                                                    * 00068821
*                                                                     * 00069021
* EXITS, NORMAL- A BRANCH TO DISPATCH OR POST IN IECKQQ01, OR         * 00069221
*         SVC QPOST, OR                                               * 00069421
*         A BRANCH ON REGISTER 14 TO RETURN TO OPCTL MACRO EXPANSION. * 00069621
*                                                                     * 00069821
* EXITS, ERROR A BRANCH TO MACRO EXPANSION TO RETURN BUFFER IN ERROR  * 00070021
*                                                                     * 00070221
* TABLES AND WORK AREAS                                               * 00070421
*    TABLE- TO TRANSLATE HEX TO EBCDIC                                * 00070621
*    TABLETRN - TO USE FOR TRANSLATION AND TRANSLATE AND TEST         * 00070821
*    AREA- TO UNPACK INTO.                                            * 00071021
*                                                                     * 00071221
* ATTRIBUTES- REUSABLE, ENABLED OR DISABLED, PROBLEM PROGRAM MODE OR  * 00071421
*    SUPERVISOR MODE, RESIDENT                                        * 00071621
*                                                                     * 00071821
* CHARACTER CODE DEPENDENCY - NONE                                    * 00072021
*                                                                     * 00072221
* NOTES - NONE                                                        * 00072421
*********************************************************************** 00072621
         TITLE 'IECKOCTL - OPERATOR CONTROL ROUTINE - OS QTAM III'      00100013
IECKOCTL START                                                          00200013
* 451000-461000,475700,476100-477300,487200-487600,507520-507580, M1604 00208020
* 509400-510200,512000,514300-514600,523010-5123650               M1604 00216020
* 688500                                                         A39103 00224020
* 773100-774100                                                  A39114 00232020
* 767000                                                           00PS 00240020
*A523035                                                         A41219 00245021
*A000002-000726                                                  S21016 00252021
*A523101-523105,C523110,A628100-628500,C629000,                  A52229 00254021
*A711100-711500,C712000,A817500                                  A52229 00256021
*1210538000                                                        5645 00260016
*1210564200-565600                                                 6646 00270016
*1210583500-584500                                                 5044 00280016
*2540569000,570200-572800                                          00PS 00290017
* 507530-507560                                                   M3144 00290318
* 627000,633200-634200                                            M3170 00290618
* 682200,682904-682914                                            M3147 00290918
* 682685-682693,682804-682894                                     M00PS 00291218
* 682734-682794                                                   M3167 00291518
*1200089500,475200-475800,50710-507700                            21213 00292018
*1200563200-563600,567000,569700,571000,572900-575800             22760 00294018
*1200681500-682500,823600                                         22760 00296018
*1990567000,584580-584900                                         22438 00297018
*1990571000                                                        00PS 00298018
*1990574800,682510-682780                                         22760 00299018
* 438200-439700,682628-682756,703400-703800                       25340 00299218
* 508300-508600                                                    00PS 00299418
* 584950                                                          22438 00299618
* 417200-417600,873000                                           A27860 00299819
R0       EQU   0                   WORK REGISTER                        00300013
R1       EQU   1                   POINTER TO PASSED PARAMETER LIST     00400013
KREG     EQU   2                   WORKWORD ADDRESS FOR IECKSCAN        00500013
RREG2    EQU   3                   LINK REGISTER FOR IECKSCAN           00600013
LCBREG   EQU   4                   POINTER TO LCB                       00700013
SPREG    EQU   5                   SCAN POINTER FOR MESSAGE HEADER      00800013
MSREG    EQU   6                   ADDRESS OF BUFFER                    00900013
LGREG    EQU   7                   POINTER TO LPSTART                   01000013
TERMREG  EQU   8                   BASE FOR TERMINAL TABLE ENTRY        01100013
BREG     EQU   8                   TEMPORARY BASE FOR ERROR COUNTERS    01200013
WREG1    EQU   9                   WORK REGISTER                        01300013
WREG3    EQU   10                  WORK REGISTER                        01400013
EOSREG   EQU   11                  END OF SEGMENT ADDRESS FOR IECKSCAN  01500013
WREG2    EQU   12                  WORK REGISTER -QCB BASE REGISTER     01600013
NGREG    EQU   13                  POINTER TO IGG019NG                  01700013
RREG1    EQU   14                  RETURN REGISTER TO MACRO             01800013
SREG     EQU   15                  BASE FOR THIS ROUTINE                01900013
         ENTRY IECKNTRL                                                 02000013
         USING IECKTERM,TERMREG                                         02100013
         USING QBLOCK,WREG2                                             02200013
         USING LCB,LCBREG                                               02300013
         USING IECKPREF,MSREG                                           02400013
         USING *,SREG                                                   02500013
         LR    R0,SREG             SAVE BASE REGISTER                   02600013
         LA    R1,4(R1)            BUMP LIST ADDRESS TO DATA USED       02700013
         ST    RREG1,SAVEAREA      SAVE RETURN REGISTER TO MACRO        02800013
         ST    SPREG,SAVEAREA+4    SAVE SCAN POINTER                    02900013
         LA    RREG1,VAR           INDICATE VARIABLE LENGTH TO SCAN     03000013
         L     SREG,4(LGREG)       GET ADDRESS OF SCAN ROUTINE          03100013
         BALR  RREG2,SREG          LINK TO SCAN ROUTINE FOR MESSAGE ID  03200013
         LR    SREG,R0             RESTORE BASE REGISTER                03300013
         LTR   WREG1,WREG1         TEST FOR HEADER ERROR IN SCAN        03400013
         BE    RETURN1             EXIT TO NEXT LPS IF ERROR            03500013
         OC    0(8,KREG),MASK      ENSURE UPPER CASE IN WORKWORD        03600013
         MVC   WK1(8),MASK         BLANK OUT WORKAREA                   03700013
         IC    WREG2,0(R1)         GET LENGTH OF MESSAGE NAME FROM LIST 03800013
         BCTR  WREG2,0             DECREMENT FOR EXECUTE                03900013
         TM    1(R1),X'03'         ALTERNATE AND INTERCEPT SPECIFIED    04000013
         BO    HAVE2               BRANCH IF YES                        04100013
         TM    1(R1),X'02'         INTERCEPT ONLY SPECIFIED             04200013
         BO    HAVE1               BRANCH IF YES                        04300013
         TM    1(R1),X'01'         ALTERNATE ONLY SPECIFIED             04400013
         BO    HAVE1               BRANCH IF YES                        04500013
         EX    WREG2,MOVA          CAUSE MESSAGE NAME TO GO TO WORKAREA 04600013
         B     COMPARE             GO TO COMPARE                        04700013
HAVE1    EX    WREG2,MOVB          CAUSE MESSAGE NAME TO GO TO WORKAREA 04800013
         B     COMPARE             GO TO COMPARE                        04900013
HAVE2    EX    WREG2,MOVC          CAUSE MESSAGE NAME TO GO TO WORKAREA 05000013
COMPARE  CLC   0(8,KREG),WK1       IS THIS A CONTROL MESSAGE            05100013
         BE    CTLMSG              BRANCH IF YES                        05200013
RETURN   NI    LCBERRST,251        RESET END OF SEGMENT SCAN ERROR      05300013
RETURN1  L     RREG1,SAVEAREA      RESTORE LINKAGE TO LPS               05400013
         L     SPREG,SAVEAREA+4    RESTORE SAVED SCAN POINTER           05500013
         B     4(RREG1)            AND RETURN TO NEXT LPS INSTRUCTION   05600013
         SPACE                                                          05700013
CTLMSG   ST    NGREG,SAVE+4        SAVE ADDRESS OF IGG019NG             05800013
         MVI   SW1,0               RESET STOPLN SWITCH            M1604 05850000
         TM    MSTATUS,2           IS THIS A SINGLE SEGMENT MESSAGE     05900013
         BZ    ROUTE               BRANCH IF NO TO RETURN TO SOURCE     06000013
         ST    SPREG,SAVEAREA+4    SAVE THE SCAN POINTER                06100013
         L     SREG,4(LGREG)       GET ADDRESS OF SCAN ROUTINE          06200013
         BALR  RREG2,SREG          LINK TO SCAN ROUTINE - MESSAGE TYPE  06300013
         LR    SREG,R0             RESTORE BASE REGISTER                06400013
         OC    0(8,KREG),MASK      ENSURE UPPER CASE IN WORKWORD        06500013
         ST    TERMREG,SAVEAREA+8  SAVE TERMREG FOR LATER USAGE AS LINK 06600013
         CLC   COPYC,0(KREG)       COPY ERROR COUNTERS SPECIFIED        06700013
         BE    RCOPYC                   BRANCH IF YES                   06800013
         CLC   COPYT,0(KREG)       COPY TERMINAL TABLE ENTRY SPECIFIED  06900013
         BE    RCOPYT                   BRANCH IF YES                   07000013
         CLC   CHNGT,0(KREG)       CHANGE TERMINAL TABLE SPECIFIED      07100013
         BE    RCHNGT                   BRANCH IF YES                   07200013
         CLC   INTERCPT,0(KREG)    INTERCEPT MESSAGES SPECIFIED         07300013
         BE    RINTRCPT                 BRANCH IF YES                   07400013
         CLC   INTREL,0(KREG)      INTERCEPT-RELEASE SPECIFIED          07500013
         BE    RINTREL                  BRANCH IF YES                   07600013
         CLC   RELEASEM,0(KREG)    RELEASE MESSAGES SPECIFIED           07700013
         BE    RRELEASM                 BRANCH IF YES                   07800013
         CLC   STOPLN,0(KREG)      STOP LINE SPECIFIED                  07900013
         BE    RSTOPLN                  BRANCH IF YES                   08000013
         CLC   STARTLN,0(KREG)     START LINE SPECIFIED                 08100013
         BE    RSTARTLN                 BRANCH IF YES                   08200013
         CLC   SWITCH,0(KREG)      SWITCH PRIMARY TERMINAL SPECIFIED    08300013
         BE    RSWITCH                  BRANCH IF YES                   08400013
ROUTE    MVC   TTDKEY(2),TTSKEY    INSERT OFFSET TO SOURCE TERMINAL IN  08500013
*                                    DESTINATION FIELD OF HEADER PREFIX 08600013
         L     TERMREG,=V(TERMTBL) GET ADDRESS OF TERMINAL TABLE        08700013
         AH    TERMREG,TTSKEY      ACCESS CONTROL TERMINAL ENTRY        08800013
         MVC   LCBDESTQ(3),TQCBADDR PUT QCB FOR SOURCE TERMINAL IN LCB  08900013
         MVI   SW1,0                   RESTORE SWITCH TO 0        21213 08950018
RETURN2  L     RREG1,SAVEAREA      RESTORE LINKAGE TO MACRO             09000013
         L     SPREG,SAVEAREA+4    RESTORE SAVED SCAN POINTER           09100013
         L     NGREG,SAVE+4        RELOAD ADDRESS OF IGG019NG           09200013
         L     TERMREG,SAVEAREA+8  RELOAD TERMINAL BASE FOR CANCEL 00PS 09250015
         BR    RREG1               EXIT TO MACRO TO GO TO ENDRCV        09300013
REENTER  OI    MSTATUS,X'10'       SET SERVICED BIT IN PREFIX           09400013
         B     RETURN2             EXIT TO RETURN BUFFER                09500013
         SPACE 2                                                        09600013
MOVA     MVC   WK1(1),4(R1)        MOVE WHEN NEITHER ALTERNATE OR ITCP  09700013
MOVB     MVC   WK1(1),6(R1)        MOVE NAME WHEN ALTERNATE OR INTERCPT 09800013
MOVC     MVC   WK1(1),8(R1)      MOVE WHEN BOTH ALTERNATE AND INTERCEPT 09900013
         SPACE 2                                                        10000013
SUB1     ST    SPREG,SAVEAREA+4    SAVE SCAN POINTER                    10100013
         L     SREG,4(LGREG)       GET ADDRESS OF SCAN ROUTINE          10200013
         BALR  RREG2,SREG          LINK TO SCAN ROUTINE FOR TERMNAME    10300013
         LR    SREG,R0             RESTORE BASE REGISTER                10400013
         CH    WREG1,H8            WAS TERMNAME MAXIMUM SIZE OF 8 BYTES 10500013
         BNE   *+16                BRANCH IF NO - SPREG POINTS TO BLANK 10600013
         CLI   1(SPREG),C' '       ELSE SPREG POINTS TO LAST CHARACTER  10700013
*                                       IN TERMNAME - IS NEXT BLANK     10800013
         BNE   *+8                 BRANCH IF NO-BLANK DELIMITER ABSENT  10900013
         LA    SPREG,1(SPREG)      ADJUST SPREG TO POINT TO BLANK       11000013
         L     SREG,=V(IECKDRCT)   GET ADDRESS OF LOOKUP ROUTINE        11100013
         LR    RREG2,R1            SAVE POINTER TO MACRO PARAMETER LIST 11200013
         BALR  RREG1,SREG          LINK TO LOOKUP ROUTINE FOR TERMID    11300013
         LR    SREG,R0             RESTORE BASE REGISTER                11400013
         LR    R0,R1               SAVE TERMTBL POINTER FROM LOOKUP     11500013
         LR    R1,RREG2            RESTORE PARAMETER LIST POINTER       11600013
         TM    LCBERRST,X'80'      WAS TERMINAL ENTRY FOUND IN TERMTBL  11700013
         BO    ROUTE               BRANCH IF NO TO RETURN TO SOURCE     11800013
         L     RREG2,=V(IECKBFSZ)  GET ADDRESS OF BUFFER SIZE LOCATION  11900013
         SR    WREG1,WREG1         CLEAR WORK REGISTER                  12000013
         LH    WREG1,0(RREG2)      GET BUFFER SIZE IN WORK REGISTER     12100013
         LA    WREG1,MSEGSZE-1(WREG1) GET ADDRESS OF LAST CHARACTER IN  12200013
*                                       THE BUFFER                      12300013
         LR    RREG2,WREG1         SAVE ADDRESS OF LAST CHARACTER       12400013
         SR    WREG1,SPREG         GET BUFFER REMAINING FOLLOWING THE   12500013
*                                       TERMNAME ENTRY IN OPCTL MESSAGE 12600013
         AR    WREG3,R0            GET ADDRESS OF TERMTBL ENTRY         12700013
         BR    TERMREG             RETURN TO CALLING SUBROUTINE         12800013
         SPACE 2                                                        12900013
UNPAK    CH    WREG1,H14           WREG1 HAS CHARACTER COUNT            13000013
         BNH   LASTSECT            BRANCH IF LESS THAN 8 TO BE UNPACKED 13100013
         UNPK  1(15,SPREG),4(8,WREG3) UNPACK 8 BYTES FROM TERMTBL ENTRY 13200013
*                                       (OR ERROR COUNTERS LOCATION)    13300013
*                                       INTO BUFFER STARTING WITH       13400013
*                                       TSEQUIN AND 1ST CHARACTER IN    13500013
*                                       BUFFER FOLLOWING SCAN POINTER   13600013
         LA    SPREG,14(SPREG)     BUMP SCAN POINTER TO OVERLAY THE     13700013
*                                       RIGHTMOST BYTE PREVIOUSLY       13800013
*                                       UNPACKED IN BUFFER              13900013
         LA    WREG3,7(WREG3)      BUMP TERMTBL ENTRY OR ERROR COUNTER  14000013
*                                       POINTER 7 BYTES                 14100013
         SH    WREG1,H14           ADJUST COUNT FOR THOSE UNPACKED      14200013
         B     UNPAK               AND RELOOP                           14300013
         SPACE                                                          14400013
LASTSECT UNPK  AREA(15),4(8,WREG3) UNPACK 8 MORE BYTES FROM TERMTBL     14500013
*                                       ENTRY OR ERROR COUNTERS TO      14600013
*                                       WORKAREA (NONE OR A PORTION OF  14700013
*                                       THE EIGHT BYTES MAY BE USEFUL   14800013
*                                       INFORMATION)                    14900013
         BCTR  WREG1,0             DECREMENT COUNT FOR EXECUTE MOVE     15000013
         EX    WREG1,MOV1          CAUSE WORKAREA TO BE MOVED TO BUFFER 15100013
         LA    SPREG,3(SPREG,WREG1) GET ADDRESS OF LAST BYTE MOVED+2    15200013
         L     WREG1,SAVEAREA+4    RETRIEVE ADDRESS OF 1ST BYTE UNPAKED 15300013
         BCTR  KREG,0              DECREMENT FOR EXECUTE                15400013
         EX    KREG,TRANS          EXECUTE TRANSLATE                    15500013
         CR    SPREG,RREG2         IS LAST CHARACTER MOVED WITHIN 2     15600013
*                                       BYTES OF THE END OF THE BUFFER  15700013
         BNL   ENDBUF              BRANCH IF YES                        15800013
         SPACE                                                          15900013
         LR    RREG2,SPREG         SET UP TO MOVE EOB-EOT INTO BUFFER   16000013
*                                       FOLLOWING LAST CHARACTER THAT   16100013
*                                       WAS UNPACKED                    16200013
ENDBUF   BCTR  RREG2,0             DECREMENT FOR 2 BYTE MOVE            16300013
         MVC   0(2,RREG2),EOBEOT   MOVE IN EOB-EOT INTO EITHER          16400013
*                                       1) LAST 2 BYTES OF BUFFER OR    16500013
*                                       2) FOLLOWING LAST CHARACTER     16600013
*                                            UNPACKED INTO BUFFER       16700013
         LR    SPREG,RREG2         POINT SPREG TO THE EOB               16800013
         LA    WREG1,7(MSREG)      GET BUFFER PLUS 7                    16900013
         SR    RREG2,WREG1         GET SEGMENT SIZE TO BE WRITTEN       17000013
         STH   RREG2,MSEGSZE       RESET SEGMENT SIZE IN PREFIX         17100013
         BR    WREG2               RETURN TO RCOPYT, RCOPYC OR RCHNGT   17200013
         SPACE 2                                                        17300013
MOV1     MVC   1(1,SPREG),AREA     MOVE WORKAREA CHARACTERS TO BUFFER   17400013
TRANS    TR    1(1,WREG1),TABLE-240  TRANSLATE BUFFER TO EBCDIC         17500013
         SPACE 2                                                        17600013
RCOPYT   BAL   TERMREG,SUB1        LINK TO GET TERMINAL ADDRESS IN      17700013
*                                       TERMTBL AND BUFFER SIZE INFO    17800013
         L     TERMREG,SAVEAREA+8  RESTORE TERMREG                      17900013
         IC    WREG2,0(WREG3)      ACCESS SIZE OF TERMTBL ENTRY         18000013
         SH    WREG2,H4            ADJUST TNTRYSZE FOR PART NOT COPIED  18100013
         SLL   WREG2,1             DOUBLE TERMTBL ENTRY SIZE            18200013
         CR    WREG1,WREG2         COMPARE SIZE OF REMAINING BUFFER     18300013
*                                       AREA WITH TERMTBL ENTRY SIZE    18400013
*                                       TO BE COPIED                    18500013
         BNH   *+6                 BRANCH TO USE BUFFER SIZE IF LO/EQ   18600013
         LR    WREG1,WREG2         ELSE USE TERMTBL ENTRY SIZE          18700013
         LR    KREG,WREG1          SAVE COUNT FOR TRANSLATE             18800013
         ST    SPREG,SAVEAREA+4    SAVE SCAN POINTER FOR TRANSLATE      18900013
         BAL   WREG2,UNPAK         LINK TO UNPACK-TRANSLATE INTO BUFFER 19000013
         BCTR  SPREG,0             ADJUST TO LAST BYTE MOVED            19100013
         ST    SPREG,SAVEAREA+4    STORE FOR INSERTIONS IN SEND LPS     19200013
         B     ROUTE               GO SEND COPIED ENTRY TO SOURCE       19300013
         SPACE 2                                                        19400013
RCOPYC   BAL   TERMREG,SUB1        LINK TO ACCESS TERMINAL ADDRESS IN   19500013
*                                       TERMTBL AND BUFFER SIZE INFO    19600013
         L     WREG2,0(WREG3)      GET QCB ADDRESS FROM TERMTBL ENTRY   19700013
         CLI   8(WREG2),X'68'      IS THIS A TERMINAL ENTRY             19800013
         BNE   ROUTE               BRANCH IF NO TO RETURN MESSAGE TO    19900013
*                                       SOURCE (A LIST OR PROCESS ENTRY 20000013
*                                       HAS BEEN ACCESSED)              20100013
         SR    WREG3,WREG3         CLEAR FOR INSERTION OF RLN           20200013
         IC    WREG3,QRLN          GET RELATIVE LINE NUMBER FROM QCB    20300013
         L     BREG,QDCB-1         GET DCB ADDRESS FROM QCB             20400013
         TM    DCBOFLGS(BREG),X'10'  HAS THE LINE BEEN OPENED           20500013
         BNO   ROUTE               BRANCH IF NO TO RETURN MESSAGE       20600013
         SR    R1,R1               PARAMETER LIST POINTER NOT NEEDED    20700013
         IC    R1,DCBEIOBX(BREG)   GET THE SIZE OF AN LCB-IOB           20800013
         LA    WREG3,1(WREG3)      BUMP LINE NUMBER TO NEXT LCB         20900013
         MR    R0,WREG3            LCB-IOB SIZE TIMES LINE NUMBER       21000013
         L     BREG,DCBLCBAD(BREG) GET THE START OF THE LCB'S           21100013
         LA    BREG,0(BREG,R1)     ADDRESS OF NEXT LCB                  21200013
         SH    BREG,H16            GET ADDRESS OF CUMULATIVE            21300013
*                                       TRANSMISSION COUNTER IN LCB     21400013
*                                       INDICATED BY THE LINE NUMBER    21500013
         LA    R1,COPYCLR          GET ADDRESS OF COPY QCB              21600013
         LR    KREG,R1             SET UP FOR POSTING                   21700013
         STM   14,11,SAVE+12       SAVE REGISTERS DESTROYED BY IECKQQ01 21800013
         SVC   QPOST               POST COPY QCB TO ITSELF SO THAT THE  21900013
*                                       COUNTERS CAN BE MANIPULATED IN  22000013
*                                       DISABLED MODE                   22100013
         L     TERMREG,SAVEAREA+8  RELOAD SAVED REGISTER                22200013
         B     ROUTE               GO SEND COPIED COUNTERS TO SOURCE    22300013
         SPACE 2                                                        22400013
*  COPY AND CLEAR ERROR COUNTERS STCB COMBINED WITH QCB                 22500013
*         PROGRAM ENTRY--ENTERS THE ROUTINE AT COPYCLR1+6               22600013
         USING COPYCLR,WREG1       PROVIDE SAVE AREA ADDRESSABILITY     22700013
COPYCLR  DC    A(COPYCLR)                                               22800013
         DC    X'FE'                                                    22900013
         DC    AL3(COPYCLR)                                             23000013
COPYCLR1 DC    X'02'                                                    23100013
         DC    AL3(COPYCLR1)                                            23200013
         DC    X'0000'                                                  23300013
         SPACE                                                          23400013
         USING IECKLERB,BREG       TEMPORARY BASE FOR DSECT             23500013
         LM    14,11,SAVE+12       RESTORE REGISTERS SAVED BEFORE QPOST 23600013
         DROP  WREG1               SAVE AREA ACCESSED                   23700013
         L     WREG3,LERACTR       GET CUMULATIVE TRANSMISSIONS COUNTER 23800013
         SR    R1,R1               CLEAR WORKING REGISTER               23900013
         IC    R1,LERTHTR          GET TRANSMISSION THRESHOLD COUNTER   24000013
         ALR   WREG3,R1            ADD THRESHOLD TO CUMULATIVE          24100013
         ST    WREG3,LERACTR       STORE TOTAL IN CUMULATIVE COUNTER    24200013
         LH    WREG3,LERACDC       GET CUMULATIVE DATA CHECK COUNTER    24300013
         IC    R1,LERTHDC          GET DATA CHECK THRESHOLD COUNTER     24400013
         ALR   WREG3,R1            ADD THRESHOLD TO CUMULATIVE          24500013
         STH   WREG3,LERACDC       STORE TOTAL IN CUMULATIVE COUNTER    24600013
         LH    WREG3,LERACIR       GET CUMULATIVE INTERVENTION REQUIRED 24700013
         IC    R1,LERTHIR          GET INTERVENTION REQUIRED THRESHOLD  24800013
         ALR   WREG3,R1            ADD THRESHOLD TO CUMULATIVE          24900013
         STH   WREG3,LERACIR       STORE TOTAL IN CUMULATIVE COUNTER    25000013
         LH    WREG3,LERACTO       GET CUMULATIVE TIME OUT COUNTER      25100013
         IC    R1,LERTHTO          GET TIME OUT THRESHOLD COUNTER       25200013
         ALR   WREG3,R1            ADD THRESHOLD TO CUMULATIVE          25300013
         STH   WREG3,LERACTO       STORE TOTAL IN CUMULATIVE COUNTER    25400013
         ST    WREG2,QQPTR         SAVE BASE FOR IECKQQ01               25500013
         LA    WREG2,20            DOUBLE SIZE OF COUNTER AREA          25600013
         CR    WREG1,WREG2         COMPARE SIZE OF REMAINING BUFFER     25700013
*                                       AREA WITH COUNTER AREA TO BE    25800013
*                                       COPIED                          25900013
         BNH   *+6                 BRANCH TO USE BUFFER SIZE IF LESS/EQ 26000013
         LR    WREG1,WREG2         OTHERWISE USE COUNTERS SIZE          26100013
         LR    KREG,WREG1          SAVE COUNT FOR TRANSLATE             26200013
         ST    SPREG,SAVEAREA+4    SAVE SCAN POINTER FOR TRANSLATE      26300013
         LR    WREG3,BREG          GET COUNTER ADDRESS                  26400013
         SH    WREG3,H4            SUBTRACT 4 FOR INTERFACE TO UNPAK    26500013
         BAL   WREG2,UNPAK         LINK TO UNPACK-TRANSLATE INTO BUFFER 26600013
         XC    LERTHTR(4),LERTHTR  CLEAR THRESHOLD COUNTERS             26700013
         L     WREG2,QQPTR         GET ADDRESS OF IECKQQ01              26800013
         BCTR  SPREG,0             ADJUST TO LAST BYTE MOVED            26900013
         ST    SPREG,SAVEAREA+4    STORE FOR INSERTIONS IN SEND LPS     27000013
         B     DISPATCH-2(WREG2)   GO DISPATCH NEXT ITEM ON READY       27100013
*                                       (RETURNS TO RCOPYC ROUTINE)     27200013
         USING IECKTERM,TERMREG    REESTABLISH TERMTBL BASE             27300013
         SPACE 2                                                        27400013
RSWITCH  TM    1(R1),X'01'         WAS ALTERNATE TERMINAL SPECIFIED     27500013
         BC    8,ROUTE             BRANCH IF NO TO RETURN MESSAGE       27600013
         XC    4(2,R1),2(R1)       ELSE SWITCH OFFSETS TO ALTERNATE     27700013
         XC    2(2,R1),4(R1)            AND PRIMARY TERMINALS IN THE    27800013
         XC    4(2,R1),2(R1)            MACRO PARAMETER LIST            27900013
         B     REENTER             BRANCH TO 'LOSE' BUFFER              28000013
         SPACE 2                                                        28100013
RCHNGT   BAL   TERMREG,SUB1        LINK TO GET TERMINAL ADDRESS IN      28200013
*                                       TERMTBL AND BUFFER SIZE INFO    28300013
         ST    SPREG,SAVEAREA+4    SAVE SCAN POINTER                    28400013
CHKBLK   CLI   1(SPREG),C' '       CHECK FOR BLANK FOLLOWING DELIMITER  28500013
         BNE   NOBLANK             BRANCH IF NOT BLANK - NO ADJUSTMENT  28600013
         LA    SPREG,1(SPREG)      ELSE BUMP SCAN POINTER - SKIP BLANKS 28700013
         BCT   WREG1,CHKBLK        DECREMENT BUFFER SIZE REMAINING      28800013
         B     RETURN1             RETURN TO LPS WHEN BUFFER BLANK      28900013
NOBLANK  BCTR  WREG1,0             DECREMENT FOR EXECUTE                29000013
         SR    R1,R1               CLEAR FOR ADDRESS LOAD IN TRT        29100013
         EX    WREG1,TRANS1        TRANSLATE FROM 1ST CHARACTER AFTER   29200013
*                                       TERMNAME IN BUFFER (EXCLUDING   29300013
*                                       LEADING BLANKS) TO BUFFER END   29400013
         EX    WREG1,TRANSTST      SCAN BUFFER FOR DELIMITER - BLANK,   29500013
*                                       EOB, EOT OR INVALID CHARACTER   29600013
         BZ    INVALID             RETURN MESSAGE IF NOT FOUND          29700013
         STC   KREG,WK1+7          STORE RETURNED CHARACTER TO COMPARE  29800013
         CLI   WK1+7,X'07'         WAS RETURNED CHARACTER A VALID       29900013
*                                       DELIMITER (BLANK, EOB OR EOT)   30000013
         BE    VALID               BRANCH IF VALID                      30100013
INVALID  L     SPREG,SAVEAREA+4    ELSE RELOAD END OF TERMNAME POINTER  30200013
         LTR   WREG1,WREG1         CAN EOB-EOT BE INSERTED INTO BUFFER  30300013
         BH    *+14                BRANCH IF YES                        30400013
         MVC   1(1,SPREG),EOBEOT+1 ELSE PUT EOT IN BUFFER               30500013
         B     ROUTE               AND RETURN MESSAGE                   30600013
         LA    RREG2,2(SPREG)      SET UP INTERFACE TO COMMON CODE      30700013
         BAL   WREG2,ENDBUF        LINK TO PUT EOB-EOT INTO BUFFER      30800013
*                                       FOLLOWING TERMNAME              30900013
         B     ROUTE               RETURN MESSAGE (THRU TERMNAME) TO    31000013
*                                       SOURCE IF INVALID CHARACTER     31100013
VALID    BCTR  R1,0                GET POINTER TO DELIMITER-1           31200013
         SR    R1,SPREG            GET LENGTH OF DATA TO BE INSERTED    31300013
         BNH   REENTER             EXIT TO 'LOSE' BUFFER WHEN NO DATA   31400013
*                                       IS TO BE MOVED                  31500013
         LA    TERMREG,1           INSERT A 1 INTO TERMREG TO TEST ODD  31600013
         NR    TERMREG,R1          TEST FOR ODD NUMBER OF CHARACTERS    31700013
         BNZ   INVALID             BRANCH IF ODD NUMBER SPECIFIED       31800013
         IC    WREG2,0(WREG3)      ACCESS SIZE OF TERMTBL ENTRY         31900013
         SH    WREG2,H4            ADJUST TNTRYSZE FOR PART NOT CHANGED 32000013
         SRL   R1,1                DIVIDE DATA TO BE INSERTED BY TWO    32100013
         CR    R1,WREG2            WILL BUFFER DATA FIT INTO TERMTBL    32200013
         BH    INVALID             BRANCH IF NO TO RETURN MESSAGE       32300013
         LR    BREG,R1             USE BUFFER LENGTH FOR MOVE           32400013
         LA    R1,CHANGE           GET ADDRESS OF CHANGE QCB            32500013
         LR    KREG,R1             SET UP FOR POSTING                   32600013
         STM   14,11,SAVE+12       SAVE REGISTERS                       32700013
         SVC   QPOST               POST CHANGE QCB TO ITSELF SO THAT    32800013
*                                       THE TERMINAL TABLE ENTRY CAN BE 32900013
*                                       CHANGED WHILE DISABLED          33000013
         B     REENTER             BRANCH TO 'LOSE' BUFFER              33100013
         SPACE 2                                                        33200013
*  CHANGE TERMINAL TABLE STCB COMBINED WITH QCB                         33300013
*        PROGRAM ENTRY--ENTERS THE ROUTINE AT CHANGE1+6                 33400013
         USING CHANGE,WREG1        PROVIDE SAVE AREA ADDRESSABILITY     33500013
CHANGE   DC    A(CHANGE)                                                33600013
         DC    X'FE'                                                    33700013
         DC    AL3(CHANGE)                                              33800013
CHANGE1  DC    X'02'                                                    33900013
         DC    AL3(CHANGE1)                                             34000013
         DC    X'0000'                                                  34100013
         SPACE 1                                                        34200013
         LM    14,11,SAVE+12       RESTORE REGISTERS SAVED BEFORE QPOST 34300013
         DROP  WREG1               SAVE AREA ACCESSED                   34400013
         ST    WREG2,QQPTR         SAVE BASE FOR IECKQQ01               34500013
         L     WREG2,0(WREG3)      ACCESS QCB ADDRESS FOR TERMINAL      34600013
*                                       ENTRY TO BE CHANGED             34700013
         CLI   8(WREG2),X'68'      IS THIS A DESTINATION QUEUE QCB      34800013
         BNE   INACTIVE            BRANCH IF NOT TERMINAL               34900013
         SR    KREG,KREG           CLEAR WORKING REGISTER               35000013
         IC    KREG,QRLN-QBLOCK(WREG2) GET RELATIVE LINE NUMBER OF LCB  35100013
         L     RREG2,QDCB-1-QBLOCK(WREG2) GET DCB ADDRESS FROM QCB      35200013
         TM    DCBOFLGS(RREG2),X'10' HAS THE LINE BEEN OPENED           35300013
         BNO   INACTIVE            BRANCH IF NO - NO LCB AVAILABLE      35400013
         SR    R1,R1               CLEAR WORKING REGISTER               35500013
         IC    R1,DCBEIOBX(RREG2)  GET THE SIZE OF AN LCB-IOB           35600013
         MR    R0,KREG             LCB-IOB SIZE TIMES LINE NUMBER       35700013
         L     RREG2,DCBLCBAD(RREG2) GET THE START OF THE LCB'S         35800013
         LA    RREG2,0(RREG2,R1)   GET LCB ADDRESS                      35900013
         CLI   LCBSTATE-LCB(RREG2),0 IS THE LINE ACTIVE                 36000013
*  IF STOPLINE HAS BEEN EXECUTED THEN THE SEQUENCE NUMBERS WILL NOT BE  36100013
*  INCREMENTING AND THE TERMINAL TABLE ENTRY CAN BE MODIFIED BEGINNING  36200013
*  WITH THE SEQUENCE NUMBERS - OTHERWISE THE SEQUENCE NUMBERS WILL      36300013
*  REMAIN INTACT                                                        36400013
         BE    INACTIVE            BRANCH IF LINE NOT ACTIVE            36500013
         AH    SPREG,H8            BUMP SCAN POINTER PAST SEQUENCE NOS. 36600013
         AH    WREG3,H4            ADJUST TERMTBL ENTRY POINTER         36700013
         SH    BREG,H4             ADJUST COUNT TO BE MOVED             36800013
         BNH   EXIT                EXIT IF NO MORE TO MOVE              36900013
INACTIVE AH    WREG3,H4            BUMP TERMTBL ENTRY POINTER PAST SIZE 37000013
*                                       AND QCB ADDRESS (ADJUSTS PAST   37100013
*                                       SEQUENCE NUMBERS IF LINE HAS    37200013
*                                       NOT BEEN STOPPED)               37300013
         MVC   AREA(8),MASK        BLANK OUT AREA TO BE USED            37400013
PACK     PACK  AREA(8),1(15,SPREG) PACK FROM BUFFER INTO WORKAREA       37500013
         CH    BREG,H7             BREG HAS CHARACTER COUNT             37600013
         BNH   ENDPACK             BRANCH IF LESS THAN 16 TO BE PACKED  37700013
         MVC   0(7,WREG3),AREA     MOVE 7 CHARACTERS TO TERMTBL ENTRY   37800013
         AH    WREG3,H7            BUMP TERMTBL POINTER BY 7 BYTES      37900013
         AH    SPREG,H14           BUMP BUFFER POINTER BY 14 BYTES      38000013
         SH    BREG,H7             DECREMENT CHARACTER COUNT BY 7 BYTES 38100013
         B     PACK                RELOOP TO PACK AGAIN                 38200013
         SPACE 1                                                        38300013
ENDPACK  BCTR  BREG,0              DECREMENT FOR EXECUTE                38400013
         EX    BREG,MOV2           CAUSE LAST CHANGE TO BE MADE         38500013
EXIT     L     WREG2,QQPTR         RESTORE ADDRESS OF IECKQQ01          38600013
         B     DISPATCH-2(WREG2)   GO DISPATCH NEXT ITEM ON READY       38700013
*                                       (RETURNS TO RCHNGT ROUTINE)     38800013
         SPACE 2                                                        38900013
MOV2     MVC   0(1,WREG3),AREA     MOVE LAST BYTES TO TERMTBL ENTRY     39000013
TRANS1   TR    1(1,SPREG),TABLETRN TRANSLATE BUFFER FOR CHNGT           39100013
TRANSTST TRT   1(1,SPREG),TABLETST SCAN FOR SPECIAL CHARACTER IN BUFFER 39200013
         SPACE 2                                                        39300013
*   WHEN THE INTERCEPT FUNCTION IS TO BE USED BY OPERATOR CONTROL, THE  39400013
*   INTERCPT MACRO MUST BE SPECIFIED IN THE ENDSEND SECTION OF LPS WITH 39500013
*   AN ERROR MASK OF X'4000'.  THE ACTIVATE ROUTINE IN IGG019NG WILL    39600013
*   DETECT THE ABSENCE OF THE SEND BIT IN THE TERMTBL ENTRY AND SET THE 39700013
*   TERMINAL INOPERATIVE BIT IN LCBERRST BEFORE EXITING TO LPS WHEN     39800013
*   MESSAGES ARE TO BE SENT TO THE DESTINATION TERMINAL.  THE X'4000'   39900013
*   ALLOWS THE IECKITCP ROUTINE TO DETECT THE TERMINAL INOPERATIVE BIT  40000013
*   AND PERFORM THE INTERCEPT FUNCTION ON THE DESTINATION QUEUE.        40100013
RINTRCPT TM    1(R1),X'02'         WAS INTERCEPT SPECIFIED IN MACRO     40200013
         BZ    ROUTE               BRANCH IF NO - RETURN MESSAGE        40300013
         BAL   TERMREG,SUB1        LINK TO GET TERMINAL ADDRESS         40400013
         L     WREG2,0(WREG3)      GET QCB ADDRESS FROM TERMTBL ENTRY   40500013
         CLI   8(WREG2),X'68'      IS THIS A TERMINAL ENTRY             40600013
         BNE   ROUTE               BRANCH IF NO TO RETURN MESSAGE TO    40700013
*                                       SOURCE (A LIST OR PROCESS ENTRY 40800013
*                                       HAS BEEN ACCESSED)              40900013
         LR    TERMREG,WREG3       SET UP TERMINAL ADDRESS FOR BASE     41000013
         NI    TSTATUS,X'FD'       TURN OFF THE SEND BIT                41100013
         B     REENTER             BRANCH TO 'LOSE' BUFFER              41200013
         SPACE 2                                                        41300013
RRELEASM TM    1(R1),X'02'         WAS INTRCPT SPECIFIED IN MACRO       41400013
         BZ    ROUTE               BRANCH IF NO - RETURN MESSAGE        41500013
         BAL   TERMREG,SUB1        LINK TO GET TERMINAL ADDRESS         41600013
         LR    TERMREG,WREG3       LOAD BASE REGISTER FOR TERMINAL      41700013
         L     WREG3,TQCBADDR-1   QCB ADDRESS OF TTENTRY         A27860 41720019
         CLC   QLINK-QBLOCK(3,WREG3),ZERO IS RESTART IN PROGRESS A27860 41740019
         BNE   ROUTE              YES, RETURN MESSAGE            A27860 41760019
         TM    TSTATUS,4           IS THE TERMINAL IN INTERCEPT         41800013
         BZ    REENTER             BRANCH IF NO TO LOSE BUFFER          41900013
         TM    1(R1),X'01'         WAS ALTERM SPECIFIED IN MACRO        42000013
         BNO   *+12                BRANCH IF NO                         42100013
         LH    WREG2,6(R1)         LOAD OFFSET TO INTERCEPT FIELD       42200013
         B     *+8                 AND GO RELEASE                       42300013
         LH    WREG2,4(R1)         LOAD OFFSET TO INTERCEPT FIELD       42400013
         AR    WREG2,TERMREG       ADD IN TERMINAL ENTRY FOR ADDRESS    42500013
         L     WREG3,TQCBADDR-1    GET QCB ADDRESS FROM TABLE ENTRY     42600013
         CLC   1(3,WREG3),0(WREG2) COMPARE MESSAGE HEADER ADDRESS IN    42700013
*                                       TERMTBL INTERCEPT FIELD TO      42800013
*                                       ADDRESS OF FIRST ELEMENT IN     42900013
*                                       THE QUEUE                       43000013
         BNH   *+10                BRANCH IF HEADER ADDRESS GREATER     43100013
*                                       THAN MESSAGE ADDRESS IN QUEUE   43200013
*                                       (PRIORITY MESSAGES HAVE BEEN    43300013
*                                        INTERCEPTED)                   43400013
         MVC   1(3,WREG3),0(WREG2) INSERT HEADER ADDRESS OF INTERCEPTED 43500013
*                                       MESSAGES AS 1ST MESSAGE TO BE   43600013
*                                       RELEASED                        43700013
         NI    TSTATUS,251         RESET INTERCEPT BIT TO 0 IN TSTATUS  43800013
         OI    TSTATUS,8          SET RELEASE PENDING BIT ON       00PS 43820018
         L     R1,QTRAN-QBLOCK(WREG3)  GET STCB POINTER FROM QCB  25340 43840018
         CLI   0(R1),X'68'         IS THE SEND SCHEDULER ACTIVE   25340 43860018
         BNE   REENTER             YES, NO PRIMER NEEDED          25340 43880018
         LA    R1,PRIMER           PUT PRIMER ADDRESS IN R1       25340 43900018
         LA    KREG,0(0,WREG3)     QCB ADDRESS TO R2              25340 43920018
         SVC   QPOST               POST PRIMER ELEMENT TO THE     25340 43940018
*                                 SEND SCHEDULER TO START SENDING 25340 43960018
         B     REENTER             BRANCH TO LOSE BUFFER                44000013
         SPACE 2                                                        44100013
RSTARTLN MVI   SW1,2               SET STARTLN INDICATOR          M1604 45100000
         B     RSTOPLN             AND USE COMMON CODE            M1604 46100000
SW1      DC    X'00'                    SW FOR STOPLN & INTREL    21213 47520018
*                                           X'00' - STOPLN CONTROL21213 47540018
*                                           X'01' - INTREL CONTROL21213 47560018
*                                           X'02' - STARTLN ENTRY M1604 47570000
RINTREL  MVI   SW1,1              SET INTREL INDICATOR FOR RSTOPLN21213 47580018
RSTOPLN  BAL   TERMREG,SUB1        LINK TO GET TERMINAL ADDRESS         47600013
         ST    SPREG,SAVEAREA+4    SAVE SCAN POINTER              M1604 47610000
         L     WREG2,0(WREG3)      ACCESS QCB FRO TERMINAL ENTRY  M1604 47620000
         CLI   8(WREG2),X'68'      IS THIS A TERMINAL ENTRY       M1604 47630000
         BNE   ROUTE               BRANCH IF NO TO RETURN         M1604 47640000
*                                    MESSAGE TO SOURCE ( A DLIST  M1604 47650000
*                                    OR PROCESS ENTRY HAS BEEN    M1604 47660000
*                                    ACCESSED)                    M1604 47670000
         L     R0,QRLN-QBLOCK(WREG2) GET RLN AND DCB ADDRESS      M1604 47680000
CHKBLK1  CLI   1(SPREG),C' '       CHECK FOR BLANK                M1604 47690000
         BNE   *+12                BRANCH IF NOT BLANK            M1604 47700000
         LA    SPREG,1(SPREG)      ELSE BUMP SCAN POINTER         M1604 47710000
         BCT   WREG1,CHKBLK1       DECREMENT BUFFER SIZE          M1604 47720000
*                                    REMAINING AND SKIP BLANKS    M1604 47730000
         LA    WREG1,HDSTRT-1      GET START OF TEXT-1                  47800013
         SR    RREG2,WREG1         GET BUFFER SIZE FOLLOWING PREFIX     47900013
         LA    WREG1,22            LOAD MINIMUM BUFFER SIZE NECESSARY   48000013
         CR    RREG2,WREG1         DOES BUFFER HAVE 22 USEABLE BYTES    48100013
         BL    ROUTE               RETURN TO SOURCE IF NO               48200013
         SR    WREG1,WREG1         CLEAR WORKING REGISTER               48300013
         LA    WREG3,1             SET NUMBER OF LINES TO 1             48400013
         IC    WREG1,QRLN-QBLOCK(WREG2) GET RELATIVE LINE NUMBER OF LCB 48500013
         LR    RREG2,R0            GET DCB ADDRESS ACCESSED IN SUB2     48600013
         LA    RREG2,0(RREG2)      CLEAR HI ORDER OF DCB ADDRESS        48700013
         CLI   SW1,2               IS THIS STARTLN ENTRY          M1604 48720000
         BE    STOPOK              YES, BYPASS TEST FOR STARTLN   M1604 48740000
*                                    ON SOURCE TERMINAL LINE GROUPM1604 48760000
         L     TERMREG,=V(TERMTBL) GET TERMINAL TABLE ADDRESS           48800013
         AH    TERMREG,TTSKEY      GET ADDRESS OF SOURCE TERMINAL ENTRY 48900013
         L     R1,TQCBADDR-1       ACCESS QCB FOR SOURCE TERMINAL       49000013
         SR    TERMREG,TERMREG     CLEAR FOR RELATIVE LINE NUMBER       49100013
         IC    TERMREG,QRLN-QBLOCK(R1) GET SOURCE RELATIVE LINE NUMBER  49200013
         L     R1,QDCB-1-QBLOCK(R1)  ACCESS DCB FOR SOURCE TERMINAL     49300013
         LA    R1,0(R1)            CLEAR HIGH ORDER                     49400013
         CR    RREG2,R1            STOPLN ISSUED FOR SOURCE LINE GROUP  49500013
         BNE   STOPOK              BRANCH IF NO - NOT THIS LINE GROUP   49600013
         CLC   ALL,1(SPREG)        IS STOP ALL SPECIFIED IN MESSAGE     49700013
         BE    ROUTE               BRANCH IF YES - RETURN TO SOURCE     49800013
         CR    WREG1,TERMREG       STOP SOURCE LINE SPECIFIED           49900013
         BE    ROUTE               BRANCH IF YES TO RETURN MESSAGE      50000013
STOPOK   TM    DCBOFLGS(RREG2),X'10' HAS THE DCB BEEN OPENED            50100013
         BNO   ROUTE               BRANCH IF NO (NO DEB AVAILABLE)      50200013
         L     BREG,DCBDEBAD(RREG2) GET DEB ADDRESS FROM THE DCB        50300013
         SR    R1,R1               CLEAR FOR NUMBER OF EXTENTS          50400013
         IC    R1,DEBEXT(BREG)     GET DEB NUMBER OF EXTENTS            50500013
         CR    WREG1,R1            IS QCB LINE NUMBER TOO HIGH          50600013
         BH    ROUTE               RETURN MESSAGE IF YES                50700013
         LR    R1,WREG1                 GET REL. LINE NO. IN R1   21213 50710018
         SR    R0,R0                    CLEAR REGISTER            21213 50720018
         IC    R0,DCBEIOBX(RREG2)       GET SIZE OF AN LCB        21213 50730018
         MR    R0,R0                    GET NO. FOR FINDING LCB   21213 50740018
         A     R1,DCBLCBAD(RREG2)       GET RIGHT LCB             21213 50750018
         CLI   SW1,1               CHECK FOR STARTLN, STOPLN,     M1604 50752000
*                                    OR INTREL                    M1604 50754000
         BH    XXX                 BRANCH IF STARTLN              M1604 50756000
         BL    *+12                BRANCH IF STOPLN               M1604 50758000
         CLI   LCBSTATE-LCB(R1),0       SEE IF LCB ALREADY STOPPED21213 50760018
         BE    ROUTE                    IF SO, RETURN MESSAGE     21213 50770018
         MVC   MSEGSZE(2),H56      PREVENT EOT OVERLAYING STCB          50800013
XXX      TM    LCBCPA-6-LCB(R1),2  WAIT FOR INTERRUPT FROM ANY     00PS 50830018
         BO    XXX                PREVIOUS STARTLINE               00PS 50860018
         CLI   SW1,1               WAS ENTRY FOR INTREL           M1604 50940000
         BE    SUBTASK             YES, BYPASS TEST FOR ALL       M1604 51020000
         CLC   ALL,1(SPREG)        IS STOP 'ALL' SPECIFIED IN MESSAGE   51100013
         BNE   CHKSTART            BRANCH IF NO                   M1604 51200000
         LA    WREG1,1             ELSE SET LINE NUMBER TO 1            51300013
         IC    WREG3,DEBEXT(BREG)  SET INDEX TO COUNT OF LINES          51400013
CHKSTART CLI   SW1,2               WAS ENTRY FOR STARTLN          M1604 51430000
         BE    START               YES, ISSUE SIO ON LINES        M1604 51460000
SUBTASK  LA    R1,STOP             GET ADDRESS OF STOP QCB              51500013
         LR    KREG,R1             SET UP FOR POSTING                   51600013
         STM   14,11,SAVE+12       SAVE REGISTERS TO BE USED IN SUBTASK 51700013
         SVC   QPOST               POST QCB TO ITSELF TO GET DISABLED   51800013
         B     RETURN2             RETURN TO ENDRCV IN LPS WITHOUT THE  51900013
*                                       SERVICED BIT SET SO THAT THE    52000013
*                                       CLEANUP ROUTINE IN IGG019NG CAN 52100013
*                                       POST THE BUFFER TO THE QUEUE    52200013
*                                       IN THIS ROUTINE                 52300013
         SPACE 3                                                  M1604 52301000
START    SR    R1,R1               CLEAR REGISTER FOR IC          M1604 52302000
         IC    R1,DCBEIOBX(RREG2)  GET LCB SIZE                   M1604 52303000
         L     BREG,DCBDEBAD(RREG2)  GET DEB ADDRESS FROM DCB    A41219 52303521
         MR    R0,WREG1            MULTIPLY BY LINE NUMBER        M1604 52304000
         AL    R1,DCBLCBAD(RREG2)  GET LCB ADDRESS                M1604 52305000
         LR    KREG,WREG1          COPY RLN                       M1604 52306000
         SLL   KREG,2              MULTIPLY BY FOUR               M1604 52307000
         L     KREG,DEBUCBAD-4(KREG,BREG)  UCB ADDRESS            M1604 52308000
         DROP  LCBREG                                             M1604 52309000
         USING LCB,R1                                             M1604 52310000
         SR    WREG2,WREG2       CLEAR WORK REG                  A52229 52310121
         IC    WREG2,LCBUCBX     GET REL LINE #                  A52229 52310221
         SLA   WREG2,2              TIMES 4                      A52229 52310321
         A     WREG2,LCBDCBPT    ADD DCB ADDRESS                 A52229 52310421
         LA    WREG2,DCBCPOLL(WREG2) POINT TO CPOLL FOR THIS LINEA52229 52310521
         NI    0(WREG2),X'FB'    TURN OFF INTREL BIT             A52229 52311021
         CLI   LCBSTATE,0          IS LINE ALREADY ACTIVE         M1604 52312000
         BNE   TRYEXIT2            YES, BYPASS STARTLN            M1604 52313000
         XC    LCBCPA(24),LCBCPA   CLEAR FIRST 3 CCW SLOTS        M1604 52314000
         LA    BREG,LCBSCHAD-4     SET UP FOR LOOP                M1604 52315000
LOOP3    LR    SPREG,BREG          SAVE LAST STCB ADDRESS         M1604 52316000
         L     BREG,4(SPREG)       GET NEXT STCB IN CHAIN         M1604 52317000
         CLI   0(BREG),X'12'       IS THIS THE RECEIVE SCHEDULER  M1604 52318000
         BE    START2              BRANCH IF YES                  M1604 52319000
         CLI   4(BREG),255         IS THIS END OF CHAIN           M1604 52320000
         BNE   LOOP3               BRANCH IF NOT END              M1604 52321000
         TM    LCBCPRI,X'80'       WAS RECEIVE SCHEDULER REMOVED  M1604 52322000
*                                    BY STOPLN                    M1604 52323000
         BZ    START2              NO, DO NOT RESTORE SCHEDULER   M1604 52324000
         NI    LCBCPRI,X'7F'       TURN OFF FLAG                  M1604 52325000
         IC    R0,LCBCPRI          SAVE SCHEDULER PRIORITY        M1604 52326000
         ST    BREG,LCBSCHLK-1     SET LINK FIELD TO DUMMY        M1604 52327000
*                                    END ELEMENT                  M1604 52328000
         STC   R0,LCBCPRI          RESTORE PRIORITY               M1604 52329000
         LA    BREG,LCBSCHAD       GET RECEIVE SCHEDULER ADDRESS  M1604 52330000
         IC    R0,4(SPREG)         SAVE PRIORITY OF LAST STCB     M1604 52331000
         ST    BREG,4(SPREG)       SET RECEIVE SCHEDULER AS LAST  M1604 52332000
*                                    STCB IN CHAIN                M1604 52333000
         STC   R0,4(SPREG)         AND RESTORE STCB PRIORITY      M1604 52334000
START2   MVI   LCBCPA+32,X'FF'     SET STARTLN FLAG               M1604 52335000
         MVI   LCBCPA,3            SET NOP COMMAND                M1604 52336000
         MVC   LCBCPA+4(4),C1      SET FLAGS AND COUNT            M1604 52337000
         LA    RREG1,LCBERCCW      SET CCW POINTER                M1604 52338000
         IC    BREG,19(KREG)       CONTROL UNIT TYPE FROM UCB     M1604 52339000
         N     BREG,ANDMASK        CLEAR UNUSED BITS              M1604 52340000
         BCT   BREG,NOT2702        BRANCH IF 2701 OR 2703         M1604 52341000
         IC    BREG,17(KREG)       DETERMINE SAD TYPE             M1604 52342000
         N     BREG,ANDMASK        CLEAR UNUSED BITS              M1604 52343000
         IC    BREG,SADCODE(BREG)  GET PROPER SAD CODE            M1604 52344000
         STC   BREG,LCBCPA         AND STORE IN CPA               M1604 52345000
         LA    RREG1,8(RREG1)      RESET CCW POINTER              M1604 52346000
NOT2702  CLI   19(KREG),X'82'      IBM III ADAPTER                M1604 52347000
         BE    SIO                 YES, NO ENABLE NEEDED          M1604 52348000
         TM    17(KREG),X'90'      SWITCHED LINE                  M1604 52349000
         BNZ   SIO                 YES, NO ENABLE NEEDED          M1604 52350000
         MVI   8(RREG1),X'27'      ELSE SET ENABLE OP CODE        M1604 52351000
         MVC   12(4,RREG1),C1      STORE FLAGS AND COUNT          M1604 52352000
         MVI   4(RREG1),X'60'      SET CHAINING IN PREVIOUS CCW   M1604 52353000
SIO      LA    BREG,LCBCPA         GET CPA ADDRESS                M1604 52354000
         ST    BREG,LCBSTART-1     INITIALIZE IOBSTART            M1604 52355000
         OI    LCBCPA-6,2          SET FLAG TO PREVENT DOUBLE SIO M1604 52356000
         LA    R1,LCBFLAG1         GET IOB ADDRESS FOR EXCP       M1604 52357000
         LR    BREG,SREG           SAVE BASE REG. FOR EXCP        M1604 52357500
         SVC   0                   DO SIO                         M1604 52358000
         LR    SREG,BREG           RESTORE BASE REGISTER          M1604 52358500
         DROP  R1                                                 M1604 52359000
         USING LCB,LCBREG                                         M1604 52360000
TRYEXIT2 LA    WREG1,1(WREG1)      INCREMENT LINE NUMBER          M1604 52361000
         BCT   WREG3,START         RELOOP FOR NEXT LINE           M1604 52362000
         B     REENTER             RETURN IF LAST LINE            M1604 52363000
ANDMASK  DC    F'3'                                               M1604 52364000
SADCODE  DC    X'13171B1F'         SAD CWW OP CODES               M1604 52365000
         SPACE 2                                                        52400013
*  STOP LINE STCB COMBINED WITH QCB                                     52500013
*        PROGRAM ENTRY--ENTERS THE ROUTINE AT STOP1+6                   52600013
         USING STOP,WREG1          PROVIDE SAVE AREA ADDRESSABILITY     52700013
STOP     DC    A(STOP)                                                  52800013
         DC    X'FE'                                                    52900013
         DC    AL3(STOP)                                                53000013
STOP1    DC    X'02'                                                    53100013
         DC    AL3(STOP1)                                               53200013
         DC    X'0000'                                                  53300013
         SPACE 1                                                        53400013
         LM    14,11,SAVE+12       RESTORE REGISTERS SAVED BEFORE QPOST 53500013
         DROP  WREG1               SAVE AREA ACCESSED                   53600013
         L     R1,0(NGREG)         GET LPS QUEUE ADDRESS                53700013
         MVC   321(3,R1),=VL3(IECKOPAW)  MOVE ADDR OF IECKOPAW IN  5645 53800016
*                                       IGG019NG SO THAT ENTRY WILL     54000013
*                                       ALWAYS BE TO IECKOPAW AT        54100013
*                                       POSTRCV OR POSTSEND TO CHECK    54200013
*                                       FOR UNRECOVERABLE ERRORS FOR    54300013
*                                       INTREL                          54400013
         SR    R1,R1               CLEAR WORKING REGISTER               54500013
         IC    R1,DCBEIOBX(RREG2)  GET THE SIZE OF AN LCB-IOB           54600013
         STC   R1,HDSTRT+21        SAVE LCB SIZE IN THE BUFFER          54700013
         STC   WREG1,HDSTRT        SAVE LINE NUMBER IN BUFFER           54800013
         MR    R0,WREG1            LCB-IOB SIZE TIMES LINE NUMBER       54900013
         L     RREG2,DCBLCBAD(RREG2) GET THE START OF THE LCB'S         55000013
LOOP1    LA    RREG2,0(RREG2,R1)   GET LCB ADDRESS FOR THIS LINE        55100013
         CLI   LCBSTATE-LCB(RREG2),0 IS THE LINE ACTIVE                 55200013
         BE    TRYEXIT             BRANCH IF NO - LINE STOPPED          55300013
         L     KREG,LCBSCHAD-LCB(RREG2) ACCESS 1ST STCB IN THE LCB      55400013
         CLI   0(KREG),X'6C'       IS AN OPCTL TYPE STCB PENDING        55500013
         BNE   *+18                BRANCH IF NO                         55600013
         L     R1,16(KREG)         ELSE ACCESS IECKOCTL BASE FROM STCB  55700013
         LA    R1,0(R1)            CLEAR HIGH ORDER BYTE                55800013
         CR    R1,SREG             IS AN OPCTL STOPLN PENDING           55900013
         BE    TRYEXIT             BRANCH IF YES - IGNORE THE STOPLN    56000013
         LR    R1,WREG1            COPY RELATIVE LINE NUMBER            56100013
         SLL   R1,2                RELATIVE LINE NUMBER TIMES 4         56200013
         L     KREG,28(R1,BREG)    GET UCB ADDRESS FOR THIS LINE        56300013
         ST    RREG2,STOP2+4       SAVE LCB ADDRESS TO BE STOPPED 22760 56320018
         MVI   STOP2+4,X'FE'       RESTORE PRIORITY               22760 56340018
         STC   WREG3,BASE          SAVE COUNT INDEX IN THE QCB    22760 56360018
         TM    17(KREG),X'90'      IS THIS A DIAL LINE                  56400013
         BO    *+24                    BRANCH IF DIAL              6646 56420016
         CLI   LCBCPA-LCB+16(RREG2),X'04' IS THIS A SENSE COMMAND  6646 56440016
*                            (2740 BASIC OR WITH CHECKING)         6646 56460016
         BNE   NOTDIAL                 NOT 2740 OR DIAL            6646 56480016
         CLI   LCBCPA-LCB+21(RREG2),X'00' IF TP OP CODE =00, LINE  6646 56500016
*                            IS BUSY, NO HIO ISSUED                6646 56520016
         BE    NOTDIAL                 2740 IS BUSY - NO HIO       6646 56540016
         B     *+16                    HIO TO ALLOW SENDING        6646 56560016
         CLI   LCBINCAM-LCB(RREG2),2 IS LINE IN ACTIVE TRANSMISSION     56600013
         BE    CHEK2740           CHECK FOR 2740                  22438 56700018
         OI    LCBINCAM-LCB(RREG2),3  SET SO LINE WILL BE REDIALED      56800013
HIOLOOP  NI    LCBFLAG1-LCB(RREG2),X'DB' TURN OFF ERP FLAGS        00PS 56960015
         MVI   LCBECBPT-LCB(RREG2),X'48' SET HIO FLAG FOR LINE-END22437 56970018
UCBFLAGS EQU   6                                                   00PS 56980017
UCBRQEAD EQU   20                                                  00PS 57000017
CVT      EQU   16                                                  00PS 57020017
CVTIXAVL EQU   124                                                 00PS 57040017
HIORTN   EQU   8                                                   00PS 57060017
         IC    R0,UCBFLAGS(KREG)     SAVE UCBFLAG STATUS           00PS 57080017
         STM   1,15,SAVE+12     SAVE REGISTERS FOR HALT I/O        00PS 57100018
         LR    BREG,KREG      UCB ADDRESS TO BREG                  00PS 57120017
         LH    WREG1,UCBRQEAD(BREG)  RQE ADDRESS IN REG 9          00PS 57140017
         LR    R1,SREG        SAVE BASE REGISTER                   00PS 57160017
         L     WREG3,CVT      CVT ADDRESS                          00PS 57180017
         L     WREG3,CVTIXAVL(WREG3) PARAMETER LIST ADDRESS        00PS 57200017
         L     WREG3,HIORTN(WREG3)   HALT I/O ROUTINE ADDRESS      00PS 57220017
         BALR  SREG,WREG3     LINK TO HALT I/O ROUTINE             00PS 57240017
         LM    1,15,SAVE+12-IECKOCTL(R1)  RESTORE REGISTERS        00PS 57260017
         STC   R0,UCBFLAGS(KREG)     RESTORE UCBFLAGS STATUS       00PS 57280017
NOTDIAL  EQU   *                                                  22760 57480018
         CLC   HDSTRT+8(8),STCB    IS THIS THE FIRST PASS               57700013
         BE    *+14                BRANCH IF NO (STOP 'ALL' SPECIFIED)  57800013
         MVC   LCBDESTQ(3),STOP2+1 LOAD LCBDESTQ SO THAT CONTROL WILL   57900013
*                                       BE RETURNED FOLLOWING RELEASE   58000013
*                                       IN CLEANUP IN IGG019NG          58100013
         B     DISPATCH-2(WREG2)   EXIT TO RSTOPLN ROUTINE              58200013
         LR    R1,MSREG            SET UP INTERFACE TO BUILD STCB       58300013
         STC   WREG1,HDSTRT       STORE REL LINE NO. IN BUFFER     5044 58350016
         LA    WREG1,STOP2         SET UP BASE REGISTER            5044 58400016
         B     BASE+4                                              5044 58450016
CHEK2740 CLI   LCBCPA+32,4        DOES CHANNEL PROGRAM CONTAIN          58458018
*                                  SENSE COMMAND                  22438 58466018
         BNE   NOTDIAL            NO, LOOK AT STCB CHAIN          22438 58474018
         CLI   LCBCPA+37,0        IF TP OP CODE=0, LINE IS BUSY   22438 58482018
         BNE   HIOLOOP-4          BRANCH IF HIO NECESSARY         22438 58490018
         B     NOTDIAL                                            22438 58495018
         SPACE 2                                                        58500013
*  THIS QCB IS USED TO GET CONTROL BACK HERE WHEN CLEANUP IN IGG019NG   58600013
*  POSTS THE BUFFER TO THE DESTINATION QUEUE (ACTUALLY STOP2)           58700013
         DS    0F                                                       58800013
         USING STOP2,WREG1         SET UP BASE FOR THIS SECTION OF CODE 58900013
STOP2    DC    X'03'                                                    59000013
         DC    AL3(STOP2)                                               59100013
         DC    X'FE'                                                    59200013
         DC    AL3(0)                                                   59300013
STOP3    DC    X'6C'                                                    59400013
         DC    AL3(STOP3)                                               59500013
BASE     DC    A(IECKOCTL)                                              59600013
         L     SREG,BASE           RESTORE BASE REGISTER                59700013
         DROP  WREG1                                                    59800013
         LR    MSREG,R1            SET UP BUFFER BASE                   59900013
         TM    MSTATUS,X'01'       IS THIS OTHER THAN THE HEADER BUFFER 60000013
         BO    FREEBUF             BRANCH IF YES TO FREE BUFFER         60100013
         L     RREG2,STOP2+4       SET UP LCB ADDRESS TO BE STOPPED     60200013
*     THE FOLLOWING IS DYNAMIC GENERATION OF AN STCB IN THE BUFFER      60300013
*     FOR THE LCB SUBTASK CHAIN                                         60400013
GENSTCB  ST    SREG,HDSTRT+16      STORE BASE IN BUFFER FOR FUTURE USE  60500013
         MVC   HDSTRT+20(1),HDSTRT MOVE SAVED CURRENT LINE NUMBER       60600013
         LA    R1,HDSTRT           GET ADDRESS OF DYNAMIC BUFFER STCB   60700013
         ST    R1,HDSTRT           STORE STCB ADDRESS IN STCB           60800013
         MVI   HDSTRT,X'6C'        MOVE IN BRANCH OFFSET                60900013
         MVI   HDSTRT+4,X'E4'      SET STCB PRIORITY IN BUFFER          61000013
         MVC   HDSTRT+8(8),STCB    MOVE LOAD AND BRANCH INTO BUFFER     61100013
         MVC   HDSTRT+5(3),LCBSCHAD+1-LCB(RREG2) LINK STCB CHAIN OF LCB 61200013
*                                       TO THE STCB BEING BUILT IN THE  61300013
*                                       BUFFER                          61400013
         MVC   LCBSCHAD+1-LCB(3,RREG2),HDSTRT+1 INSERT ADDRESS OF THE   61500013
*                                       STOPLN STCB AS 1ST STCB IN STCB 61600013
*                                       CHAIN OF THE LCB                61700013
*  THE FOLLOWING CODE IS NECESSARY FOR AUTOPOLLED LINES                 61800013
         TM    LCBSTATE-LCB(RREG2),X'08' IS THE LINE RECEIVING          61900013
         BNO   NOAUTOPL            BRANCH IF NO - NO AUTOPOLL SET UP    62000013
         TM    LCBFLAG2-LCB(RREG2),X'01' IS THE LINE AUTOPOLLED         62100013
         BNO   NOAUTOPL            BRANCH IF NO - NO AUTOPOLL SET UP    62200013
         MVI   LCBCPA+47-LCB(RREG2),X'FE' PUT AUTOPOLL FLAG IN CHANNEL  62300013
*                                       PROGRAM AREA                    62400013
         MVI   LCBCPA+40-LCB(RREG2),X'03' PUT NOP INTO TIC CCW          62500013
NOAUTOPL CLI   SW1,0               WAS ENTRY FROM THE INTREL ROUTINE    62600013
         BE    LINEFREE            NO, CHECK FOR LINE FREE        M3170 62700018
         MVI   SW1,0               CLEAR THE INTREL CONTROL SWITCH      62800013
         SR    WREG3,WREG3       CLEAR WORK REG                  A52229 62810021
         IC    WREG3,LCBUCBX-LCB(RREG2)  GET REL LINE #          A52229 62820021
         SLA   WREG3,2           TIMES 4                         A52229 62830021
         A     WREG3,LCBDCBPT-LCB(RREG2)   ADD DCB ADDRESS       A52229 62840021
         LA    WREG3,DCBCPOLL(WREG3)   POINT TO CPOLL FOR THIS LINE2229 62850021
         OI    0(WREG3),4        SET INTREL SWITCH               A52229 62900021
         MVI   HDSTRT+16,0         ZERO COUNT INDEX IN THE BUFFER STCB  63000013
*                                       SO THE STARTLN STCB CAN BE      63100013
*                                       BUILT WHEN THE LINE IS STOPPED  63200013
*                                       AND THE SWITCH IS FOUND TO BE 0 63300013
LINEFREE CLI   LCBSTATE-LCB(RREG2),1 IS LINE FREE                 M3170 63320018
         BNE   DISPATCH-2(WREG2)   IF NO, DISPATCH NEXT ITEM      M3170 63340018
         LA    R1,0(RREG2)         CLEAR HIGH ORDER BYTE AND PUT  M3170 63360018
*                                    LCB ADDRESS IN R1            M3170 63380018
         LR    KREG,R1             LCB ADDRESS TO R2              M3170 63400018
         B     POST-2(WREG2)       POST LCB TO ITSELF TO ACTIVATE M3170 63420018
TRYEXIT  LA    WREG1,1(WREG1)      BUMP TO NEXT RELATIVE LINE NUMBER    63500013
         BCT   WREG3,RELOOP        BRANCH IF MORE LINES TO CHECK        63600013
         BCTR  WREG1,0             RESET THE LINE NUMBER                63700013
         CLI   SW1,0               WAS ENTRY FROM THE INTREL ROUTINE    63800013
         BNE   TIMEQ               BRANCH IF YES                        63900013
         CLC   HDSTRT+8(8),STCB    IS THIS THE FIRST PASS               64000013
         BE    FREEBUF             BRANCH IF NO - BUFFER MUST BE FREED  64100013
         OI    MSTATUS,X'10'       SET SERVICED BIT TO FREE BUFFER      64200013
         B     DISPATCH-2(WREG2)   GO DISPATCH NEXT ITEM ON READY       64300013
*                                       (RETURNS TO RSTOPLN ROUTINE)    64400013
RELOOP   SR    R1,R1               CLEAR SIZE REGISTER                  64500013
         IC    R1,HDSTRT+21        GET LCB SIZE STORED ABOVE IN BUFFER  64600013
         B     LOOP1               GO CHECK NEXT LCB                    64700013
         SPACE 2                                                        64800013
*  THE FOLLOWING CODE IS ENTERED WHEN THE LCB IS POSTED TO ITSELF IN    64900013
*  THE CLEANUP ROUTINE IN IGG019NG AND THE STCB CHAIN CONTAINS THE      65000013
*  BUFFER CONSTRUCTED ABOVE. WHEN THE SUBTASK SPECIFIED BY THE STCB IN  65100013
*  THE BUFFER IS ACTIVATED, CONTROL IS GIVEN TO THE FOLLOWING ROUTINE.  65200013
         SPACE 1                                                        65300013
SUBTASK1 MVC   LCBSCHAD+1-LCB(3,WREG1),5(KREG) REMOVE THE OPCTL STOPLN  65400013
*                                       STCB FROM THE LCB'S STCB CHAIN  65500013
*                                       (UPON ENTRY TO THIS SUBTASK,    65600013
*                                       WREG1 HAS A POINTER TO THE LCB  65700013
*                                       ON READY QUEUE AND KREG HAS A   65800013
*                                       POINTER TO THE STCB FOR THIS    65900013
*                                       SUBTASK)                        66000013
         MVI   LCBSTATE-LCB(WREG1),0 DEACTIVATE THE LCB                 66100013
         SR    WREG3,WREG3         CLEAR INDEX REGISTER                 66200013
         ST    WREG3,0(KREG)       CLEAR X'6C' AND HDSTRT IN BUFFER     66300013
         IC    WREG3,16(KREG)      LOAD COUNT REMAINING IN WREG3        66400013
         SH    KREG,H32            ADJUST KREG TO START OF BUFFER       66500013
         LR    MSREG,KREG          SET UP BUFFER BASE REGISTER          66600013
         L     RREG2,LCBDCBPT-LCB(WREG1) ACCESS DCB FROM LCB            66700013
         L     BREG,DCBDEBAD(RREG2) ACCESS DEB FROM DCB                 66800013
         LR    RREG2,WREG1         TRANSFER LCB ADDRESS                 66900013
         SR    WREG1,WREG1         CLEAR LINE NUMBER REGISTER           67000013
         IC    WREG1,HDSTRT+20     LOAD RELATIVE LINE NUMBER INTO WREG1 67100013
         LR    R1,WREG1            COPY RELATIVE LINE NUMBER            67200013
         SLL   R1,2                RELATIVE LINE NUMBER TIMES 4         67300013
         L     R1,28(R1,BREG)      GET UCB ADDRESS FOR THIS LINE        67400013
         TM    17(R1),X'90'        IS THIS A DIAL LINE                  67500013
         BNO   NOTDIAL1            BRANCH IF NO                         67600013
         MVI   LCBERCCW-LCB(RREG2),X'2F' SET UP DISABLE COMMAND         67700013
         MVC   LCBERCCW+4-LCB(4,RREG2),C1 MOVE IN FLAG AND COUNT        67800013
         LA    R1,LCBERCCW-LCB(RREG2) GET ERROR CCW ADDRESS             67900013
         ST    R1,LCBSTART-1-LCB(RREG2) AND STORE IT IN RESTART         68000013
         MVI   LCBCPA+32-LCB(RREG2),X'FE' INDICATE OPEN IDLE TO APNDAGE 68100013
         MVI   LCBINCAM-LCB(RREG2),7  FLAG THE LCB SO THE SEND    22760 68150018
*                                      SCHEDULER WILL NOT ASSIGN  22760 68200018
         STM   BREG,WREG1,SAVE+12  SAVE REGISTERS USED BY STCBLOOPM3147 68220018
*                                      THE LINE TO ANOTHER TERM   22760 68250018
         LA    R1,LCBSCHAD-4-LCB(RREG2)  SET UP FOR LOOP          22760 68251018
STCBLOOP LR    WREG1,R1            SAVE LAST STCB ADDRESS         22760 68252018
         L     R1,4(WREG1)         GET NEXT STCB IN CHAIN         22760 68253018
         CLI   4(R1),255           255 SIGNALS END OF CHAIN       22760 68254018
         BE    NOMOSTCB            BRANCH IF END                  22760 68255018
         CLI   0(R1),X'68'         IS THIS A SEND SCHEDULER       22760 68256018
         BNE   STCBLOOP            BRANCH IF NOT                  22760 68257018
         MVC   5(3,WREG1),5(R1)    REMOVE SEND SCHEDULER          22760 68258018
         XC    LCBTTIND-LCB(2,RREG2),LCBTTIND-LCB(RREG2)  AND ZERO22760 68259018
*                                   TERMINAL OFFSET IN LCB        22760 68260018
         LR    BREG,R1             SET BREG TO SEND SCHEDULER     22760 68261018
         SH    R1,H8               BACK UP TO QCB                 22760 68262018
         MVC   QTRAN+5-QBLOCK(3,R1),1(BREG)  POINT SEND           25340 68262818
*                                   SCHEDULER TO END ELEMENT      25340 68263618
*                                   (DESTINATION-DASD)            25340 68264418
         ST    BREG,0(BREG)        PUT SEND SCHEDULER IN QCB      25340 68265218
         MVI   0(BREG),X'68'       RESTORE ENTRY CODE             25340 68266018
         CLC   QFAC-QBLOCK(3,R1),QNASEG-QBLOCK(R1)  IS QFAC LESS  25340 68266818
*                                   THAN QNASEG                   25340 68267618
         BNL   STCBLOOP+2          NO, THERE ARE NO OUTGOING      25340 68268418
*                                    MESSAGES TO SEND              00PS 68268518
         LTR   WREG3,WREG3             WAS THIS ENTRY FOR INTREL   00PS 68268618
         BZ    PRIME                   YES, PRIMING IS NEEDED      00PS 68268718
         BCTR  WREG3,0                 DECREMENT COUNT OF LINES  1 00PS 68268818
         LTR   WREG3,WREG3             WAS COUNT ONE               00PS 68268918
         LA    WREG3,1(WREG3)          RESTORE ORIGINAL COUNT      00PS 68269018
         BNZ   CALLQ                   NO, PUT SEND SCHEDULER ON   00PS 68269118
*                                      DIAL-OUT CALL QUEUE         00PS 68269218
PRIME    EQU   *                                                   00PS 68269318
         LA    R1,0(0,R1)          CLEAR HIGH ORDER BYTE          25340 68270018
         ST    R1,PRIMER           POST DUMMY PRIMER ELEMENT TO   25340 68270818
*                                   QCB SO ANOTHER LINE WILL BE   25340 68271618
*                                   ASSIGNED TO TERMINAL          25340 68272418
         MVC   PRIMER+5(3),LCBRCADD-LCB(RREG2) POINT PRIMER TO    M3167 68273418
*                            NEXT READY ITEM AFTER LCB            M3167 68274418
         LA    BREG,PRIMER        AND PLACE PRIMER AS NEXT READY  M3167 68275418
*                                 ITEM AFTER LCB                  M3167 68276418
         ST    BREG,LCBRCADD-1-LCB(RREG2)   ON READY QUEUE        M3167 68277418
         MVI   LCBCECB-LCB(RREG2),X'E4'    RESET LCB PRIORITY     M3167 68278418
         B     NOMOSTCB            GO TO EXECUTE DISABLE CCW      M3167 68279418
CALLQ    L     R1,LCBDCBPT-LCB(RREG2)  ACCESS DCB POINTER FROM LCB 00PS 68280418
         L     R1,DCBDEBAD(R1)         ACCESS DEB ADDRESS FROM DCB 00PS 68281418
         SH    R1,H16                  BACK UP TO CALL QUEUE       00PS 68282418
         MVC   1(3,BREG),5(BREG)       PLACE DEST-DASD AS FIRST    00PS 68283418
*                                      SUBTASK IN QCB              00PS 68284418
         MVC   5(3,BREG),1(R1)         POINT SENT SCHEDULER TO NEXT00PS 68285418
*                                      ITEM ON DIAL-OUT CALL QUEUE 00PS 68286418
         ST    BREG,0(R1)              PUT SEND SCHEDULER AT HEAD  00PS 68287418
*                                      OF DIAL-OUT CALL QUEUE      00PS 68288418
         MVI   0(R1),0                 ZERO HIGH ORDER BYTE OF ADD.00PS 68289418
NOMOSTCB EQU   *                                                  M3147 68290418
         LM    BREG,WREG1,SAVE+12  RESTORE REGISTERS              M3147 68291418
         LA    R1,LCBFLAG1-LCB(RREG2)  SET UP IOB ADDRESS FOR EXCP      68300013
         OI    LCBERCCW+2-LCB(RREG2),2     SET SO THAT A START LINE     68400013
*                                       CANNOT ISSUE SIO PRIOR TO       68500013
*                                       COMPLETION OF DISABLE.  (ABOUT  68600013
*                                       3 SECONDS)                      68700013
         SVC   0                   EXECUTE THE DISABLE TO HANG UP LINE  68800013
         MVI   IOSSAVE-2(WREG2),X'FF' RESET SVC ENTRY            A39103 68850020
         L     SREG,48(KREG)       RESTORE BASE REGISTER FROM BUFFER    68900013
NOTDIAL1 LTR   WREG3,WREG3         WAS ENTRY FROM THE INTREL ROUTINE    69000013
         BZ    SUBTASK2            BRANCH IF YES                        69100013
         L     R1,36(KREG)         ACCESS NEXT STCB FROM THE LCB        69200013
         TM    0(R1),X'FF'         IS IT A FULL STCB                    69300013
         BZ    *+10                BRANCH IF FULL STCB                  69400013
         MVC   READY+1(3,NGREG),5(RREG2) REMOVE LCB FROM READY QUEUE    69500013
         BCT   WREG3,LOOP2         BRANCH IF MORE LINES TO STOP         69600013
FREEBUF  LR    R1,MSREG            ELSE SET UP TO FREE BUFFER           69700013
         L     KREG,0(NGREG)       GET ADDRESS OF LPS QUEUE             69800013
         LA    KREG,24(KREG)       GET AVAILABLE BUFFER QUEUE ADDRESS   69900013
         MVI   4(R1),X'E4'         SET BUFFER PRIORITY TO POST          70000013
         B     POST-2(WREG2)       EXIT TO POST BUFFER TO FREE          70100013
LOOP2    LA    WREG3,1(WREG3)      RESTORE INDEX DECREMENTED ABOVE      70200013
         B     TRYEXIT             GO FIND A LINE TO STOP               70300013
         SPACE 2                                                        70320018
PRIMER   DC    A(PRIMER)                                          25340 70340018
         DC    X'FE'                                              25340 70360018
         DC    AL3(PRIMER)                                        25340 70380018
         SPACE 1                                                        70400013
*     THE FOLLOWING TWO INSTRUCTIONS WILL BE INSERTED INTO THE BUFFER   70500013
*     FOLLOWING THE DYNAMICALLY CREATED STCB AT HDSTRT+8.  THEY ARE     70600013
*     USED FOR ACTIVATING SUBTASK1.                                     70700013
STCB     L     SREG,16(KREG)       GET THE BASE ADDRESS STORED EARLIER  70800013
         B     SUBTASK1            BRANCH TO STOPLN SUBTASK             70900013
         SPACE 2                                                        71000013
TIMEQ    MVI   SW1,0               CLEAR THE INTREL CONTROL SWITCH      71100013
         SR    R0,R0             CLEAR WORK REG                  A52229 71110021
         IC    R0,LCBUCBX-LCB(RREG2)   GET REL LINE #            A52229 71120021
         SLA   R0,2              TIMES 4                         A52229 71130021
         A     R0,LCBDCBPT-LCB(RREG2)   ADD DCB ADDRESS          A52229 71140021
         LA    R0,DCBCPOLL(R0)   POINT TO CPOLL FOR THIS LINE    A52229 71150021
         OI    0(R0),4     SET THE INTREL SWITCH                 A52229 71200021
         CLI   LCBSTATE-LCB(RREG2),0 IS THE LCB ALREADY DEACTIVATED     71300013
         BE    BUILD2              BRANCH IF YES TO BUILD RELEASE STCB  71400013
         MVI   HDSTRT+16,0         ZERO COUNT INDEX IN THE BUFFER STCB  71500013
*                                       SO THE STARTLN STCB CAN BE      71600013
*                                       BUILT WHEN THE LINE IS STOPPED  71700013
*                                       AND THE SWITCH IS FOUND TO BE 0 71800013
         B     DISPATCH-2(WREG2)   RETURN TO RSTOPLN ROUTINE            71900013
         SPACE 2                                                        72000013
*  SET UP THE BUFFER TO INSERT IT INTO THE TIME QUEUE IN IGG019NG       72100013
*  LOOKING LIKE AN LCB.  WHEN THE BUFFER COMES OUT OF THE TIME QUEUE    72200013
*  THE ROUTINE AT STCB2 GETS CONTROL.                                   72300013
SUBTASK2 MVC   READY+1(3,NGREG),5(RREG2) REMOVE LCB FROM READY QUEUE    72400013
         MVI   SW1,0               CLEAR THE INTREL CONTROL SWITCH      72500013
BUILD2   LA    R1,STCB2            GET STCB FOR BUFFER                  72600013
         ST    R1,8(MSREG)         INSERT INTO STCB FIELD OF BUFFER     72700013
         ST    RREG2,20(MSREG)     SAVE LCB ADDRESS IN BUFFER           72800013
         SPACE 1                                                        72900013
*   PUT THE BUFFER IN THE TIME QUEUE IN IGG019NG WITH A 2 MINUTE DELAY  73000013
HAVESVC  CLI   IOSSAVE-2(WREG2),255 WAS ENTRY FROM AN SVC               73100013
         BNE   GETSVC              BRANCH IF NO - I/O INTERRUPT         73200013
         LA    LCBREG,0(MSREG)     MAKE BUFFER LOOK LIKE LCB TO TIMEQ   73300013
         LA    MSREG,X'78'         SET UP 120 SECOND INTERVAL IN HEX    73400013
         MVI   LCBSCHAD,0          ZERO LCB+8  FOR TIME ROUTINE         73500013
         MVI   LCBSTATE-LCB(RREG2),X'0C' PREVENT LCB BEING STARTED WHEN 73600013
*                                       THE BUFFER IS IN THE TIME QUEUE 73700013
         SPACE 1                                                        73800013
         SPACE 1                                                        73900013
*  NOW PUT THE BUFFER FOR THE STOPPED LINE IN THE TIME DELAY QUEUE      74000013
SCANDONE L     KREG,0(NGREG)       GET LPS QUEUE ADDRESS                74100013
         B     TIMENT(KREG)        TO DELAY ROUTINE IN IGG019NG         74200013
         SPACE 2                                                        74900013
*  THE FOLLOWING CODE IS ENTERED WHEN THE 2 MINUTE INTERVAL HAS EXPIRED 75000013
*  FOR THE BUFFER WHICH WAS INSERTED INTO TIMEQ IN IGG019NG.  AT THIS   75100013
*  POINT THE LINE CAN BE RESTARTED AND THE BUFFER CONTAINING THE STCB   75200013
*  WHICH ACTIVATED THIS ROUTINE CAN BE FREED.                           75300013
         SPACE 1                                                        75400013
         DS    0H                                                       75500013
STCB2    DC    X'02'               STCB FOR BUFFER IN TIME QUEUE        75600013
         DC    XL5'0'                                                   75700013
         L     R1,20(WREG1)        ACCESS LCB ADDRESS FROM THE BUFFER   75800013
         L     RREG2,0(NGREG)      GET LPS QUEUE ADDRESS FROM IGG019NG  75900013
         LA    RREG2,24(RREG2)     GET AVAILABLE BUFFER QUEUE ADDRESS   76000013
         ST    RREG2,0(WREG1)      STORE IN FIRST WORD OF BUFFER        76100013
         LR    KREG,R1             SET UP TO POST LCB TO ITSELF         76200013
         B     POST-2(WREG2)       EXIT TO POST LCB TO ITSELF           76300013
         SPACE 2                                                        76400013
         USING GETSVC1,WREG1                                            76500013
GETSVC1  DC    A(GETSVC1)                                               76600013
         DC    X'E3'                                               00PS 76700020
         DC    AL3(GETSVC1)                                             76800013
GETSVC2  DC    X'6C'                                                    76900013
         DC    AL3(GETSVC2)                                             77000013
         DC    F'0'                                                     77100013
         LM    14,11,SAVE+12       RESTORE REGISTERS SAVED BEFORE QPOST 77200013
         DROP  WREG1               SAVE AREA ACCESSED                   77300013
         L     R1,CVT             GET CVT ADDRESS                A39114 77310020
         L     R1,CVTTCB(R1)      GET TCB POINTER                A39114 77320020
         L     KREG,0(NGREG)      GET LPS Q ADDRESS              A39114 77330020
         CLC   CURTCB(3,R1),CTLTCB(KREG)  IS CONTROL UNDER MCP   A39114 77340020
*                                          TCB?                  A39114 77350020
         BE    HAVESVC            IF YES, CONTINUE PROCESSING    A39114 77360020
         ST    KREG,GETSVC1       IF NOT, POST ELEMENT TO LPS    A39114 77370020
         B     DISPATCH-2(WREG2)  QUEUE (GETSVC1 ON READY QUEUE) A39114 77380020
CVTTCB   EQU   0                                                 A39114 77390020
CURTCB   EQU   5                                                 A39114 77400020
CTLTCB   EQU   289                                               A39114 77410020
         SPACE 2                                                        77500013
*  SET UP TO POST GETSVC1 QCB TO LPS QUEUE TO ENSURE SVC ENTRY          77600013
GETSVC   LA    R1,GETSVC1          GET QCB ADDRESS FOR POSTING          77700013
         L     KREG,0(NGREG)       GET ADDRESS OF LPS QUEUE             77800013
         STM   14,11,SAVE+12       SAVE REGISTERS                       77900013
         B     POST-2(WREG2)       GO POST TO LPS QUEUE                 78000013
         SPACE 2                                                        78100013
*  THIS QCB IS USED BY THE OPERATOR AWARENESS ROUTINE TO RETURN THE LCB 78200013
*  TO INTREL CONTROL WHEN AN UNRECOVERABLE ERROR OCCURS AND THE LINE    78300013
*  HAS BEEN PREVIOUSLY PUT IN INTREL.  A BUFFER IS OBTAINED BY IECKOPAW 78400013
*  AND THE CLEANUP ROUTINE POSTS THE BUFFER TO THE QUEUE BELOW.         78500013
         DS    0F                                                       78600013
         USING STOP4,WREG1                                              78700013
STOP4    DC    X'03'                                                    78800013
         DC    AL3(STOP4)                                               78900013
         DC    X'FE'                                                    79000013
         DC    AL3(0)                                                   79100013
STOP5    DC    X'6C'                                                    79200013
         DC    AL3(STOP5)                                               79300013
BASE1    DC    A(IECKOCTL)                                              79400013
         L     SREG,BASE1          RESTORE BASE REGISTER                79500013
         DROP  WREG1                                                    79600013
         LR    MSREG,R1            SET UP BUFFER BASE                   79700013
         L     RREG2,STOP4+4       ACCESS LCB ADDRESS FROM IECKOPAW     79800013
         SR    WREG1,WREG1         CLEAR FOR LINE NUMBER                79900013
         IC    WREG1,LCBUCBX-LCB(RREG2)  ACCESS UCB INDEX FROM LCB      80000013
         LA    WREG1,1(WREG1)      BUMP TO RELATIVE LINE NUMBER         80100013
         STC   WREG1,HDSTRT        STORE LINE NUMBER IN BUFFER          80200013
         CLI   LCBSTATE-LCB(RREG2),0  IS THE LCB ACTIVE                 80300013
         BE    BUILD2              BRANCH IF NO TO PUT LCB IN TIMEQ     80400013
         MVI   SW1,1               SET INTREL CONTROL SWITCH            80500013
         B     GENSTCB             BRANCH TO STOP THE LINE              80600013
         SPACE 1                                                        80700013
IECKNTRL EQU   STOP4               A BUFFER WILL BE POSTED TO THIS      80800013
*                                       QUEUE BY IECKOPAW TO RETURN THE 80900013
*                                       LCB TO THE TIME QUEUE           81000013
         EJECT                                                          81100013
DEBEXT   EQU   16                  OFFSET TO NUMBER OF EXTENTS IN DEB   81200013
DEBUCBAD EQU   32                  OFFSET TO UCB IN THE DEB             81300013
DCBLCBAD EQU   32                  OFFSET TO LCB ADDRESS IN DCB         81400013
DCBEIOBX EQU   36                  OFFSET TO SIZE OF LCB IN DCB         81500013
DCBDEBAD EQU   44                  OFFSET TO DEB ADDRESS IN DCB         81600013
DCBOFLGS EQU   48                  OFFSET TO FLAGS FIELD IN DCB         81700013
DCBCPOLL EQU   56                OFFSET TO CPOLL IN DCB          A52229 81750021
QPOST    EQU   67                                                       81800013
TIMENT   EQU   308                 OFFSET FROM LPS QUEUE FOR TIME ENTRY 81900013
POST     EQU   X'82'               OFFSET TO POST IN IECKQQ01           82000013
DISPATCH EQU   X'F8'               OFFSET TO DISPATCH IN IECKQQ01       82100013
READY    EQU   X'50'               OFFSET TO READY QUEUE IN IGG019NG    82200013
IOSSAVE  EQU   X'1DC'                                                   82300013
CVTTRMTB EQU   156                 OFFSET TO TERMTBL ADDRESS      22760 82350018
QQPTR    DC    A(0)                SAVE AREA FOR IECKQQ01 POINTER       82400013
H7       DC    H'7'                                                     82500013
H16      DC    H'16'                                                    82600013
H32      DC    H'32'                                                    82700013
H56      DC    H'56'                                                    82800013
C1       DC    X'20000001'                                              82900013
SAVEAREA DC    3F'0'               ROUTINE PROVIDED SAVE AREA           83000013
AREA     DC    XL16'0'             WORKAREA                             83100013
SAVE     DC    18F'0'              SAVE AREA BEFORE ENTRY TO IECKQQ01   83200013
TABLE    DC    C'0123456789ABCDEF' TRANSLATE TABLE - HEX TO EBCDIC      83300013
ALL      DC    C'ALL'                                                   83400013
*                                                                       83500013
*   THE FOLLOWING TABLE IS USED FOR BOTH TRANSLATION                    83600013
*  AND TRANS AND TEST. CONSTANTS ARE INTERSPERSED IN                    83700013
*  THE TABLE. EXAMINE CAREFULLY BEFORE CHANGING.                        83800013
*                                                                       83900013
TABLETRN DS    0H                                                       84000013
H4       DC    H'4'                                                     84100013
VAR      DC    X'00FF'             VARIABLE FIELD INDICATOR FOR SCAN    84200013
H8       DC    H'8'                                                     84300013
H14      DC    H'14'                                                    84400013
WK1      DC    2F'0'                                                    84500013
TABLETST EQU   *                                                        84600013
MASK     DC    X'4040404040404040' MASK TO ENSURE UPPER CASE IN HEADER  84700013
EOBEOT   DC    X'2637'             EOB-EOT FOR 2740-1050 OUTGOING       84800013
COPYC    DC    C'COPYC '                                                84900013
COPYT    DC    C'COPYT '                                                85000013
         DC    X'EF'                                                    85100013
CHNGT    DC    C'CHNGT '                                                85200013
INTERCPT DC    C'INTERCPT'                                              85300013
         DC    X'2222EF'                                                85400013
RELEASEM DC    C'RELEASEM'                                              85500013
         DC    X'EF'                                                    85600013
INTREL   DC    C'INTREL '                                               85700013
         DC    X'22222222F2F9'                                          85800013
STOPLN   DC    C'STOPLN '                                               85900013
SWITCH   DC    C'SWITCH '                                               86000013
         DC    X'F8F0F3'                                                86100013
STARTLN  DC    C'STARTLN '                                              86200013
         DC    X'2222222222F522F722'                                    86300013
         DC    X'22222222222222222222F42222F6F122'                      86400013
         DC    X'22FAFBFCFDFEFF222222222222222222'                      86500013
         DC    X'22222222222222222222222222222222'                      86600013
         DC    X'22222222222222222222222222222222'                      86700013
         DC    X'22222222222222222222222222222222'                      86800013
         DC    X'22FAFBFCFDFEFF222222222222222222'                      86900013
         DC    X'22222222222222222222222222222222'                      87000013
         DC    X'22222222222222222222222222222222'                      87100013
         DC    X'F0F1F2F3F4F5F6F7F8F9222222222207'                      87200013
ZERO     DC    X'00000000000000000000000000000000'               A27860 87300019
*                                                                       87400013
         EJECT                                                          87500013
         PREFIXD                                                        87600013
         EJECT                                                          87700013
         LCBD  QTAM=3                                                   87800013
         SPACE 2                                                        87900013
IECKLERB DSECT                                                          88000013
LERBLOCK EQU   IECKLERB                                                 88100013
LERACTR  DS    A                   CUMULATIVE TRANSMISSIONS COUNTER     88200013
LERACDC  DS    H                   CUMULATIVE DATA CHECK COUNTER        88300013
LERACIR  DS    H                   CUMULATIVE INTERVENTION REQUIRED     88400013
LERACTO  DS    H                   CUMULATIVE TIMEOUT COUNTER           88500013
LERTHTR  DS    XL1                 THRESHOLD TRANSMISSION COUNTER       88600013
LERTHDC  DS    XL1                 THRESHOLD DATA CHECK COUNTER         88700013
LERTHIR  DS    XL1                 THRESHOLD INTERVENTION REQUIRED      88800013
LERTHTO  DS    XL1                 THRESHOLD TIMEOUT COUNTER            88900013
LERFLG1  DS    XL1                                                      89000013
         EJECT                                                          89100013
         TERMTBLD                                                       89200013
         EJECT                                                          89300013
         QCBD                                                           89400013
         END                                                            89500013
