         TITLE 'IECKONLT-TERMINAL TEST RECOGNITION MODULE.'             00100013
*********************************************************************** 00170021
*                                                                     * 00240021
*STATUS-  CHANGE LEVEL= 19         JANUARY 1971                       * 00310021
*                                                                       00400013
*                                                                       00500013
* FUNCTION -        RECOGNIZE TERMINAL TEST ACTIVITY, CALL TERMINAL     00600013
*                   TEST TRANSIENT ROUTINES, CLEANUP, STOP AND          00700013
*                   RESTART LINE OPERATION.                             00800013
*                                                                       00900013
*                                                                       01000013
* ENTRY POINT -     ENTRY IS TO FIRST INSTRUCTION FROM LPSTART MACRO.   01100013
*                                                                       01200013
*                                                                       01300013
* INPUT -           REGISTER 1 - ADDRESS OF A PARAMETER LIST            01400013
*                                GENERATED BY THE LPSTART MACRO.        01500013
*                   REGISTER 6 - ADDRESS OF BUFFER TO BE PROCESSED.     01600013
*                   REGISTER 14 - RETURN ADDRESS                        01700013
*                                                                       01800013
*                                                                       01900013
* OUTPUT            REGISTER 0 - ADDRESS OF THE TEST ACTIVATION CODE.   02000013
*                   REGISTER 1 - ADDRESS OF A PARAMETER LIST TO BE      02100013
*                                UTILIZED BY THE TERMINAL TEST          02200013
*                                TRANSIENT ROUTINES.                    02300013
*                   REGISTER 15 - ADDRESS OF THE UNIT CONTROL BLOCK.    02400013
*                                                                       02500013
*                                                                       02600013
* EXTERNAL ROUTINES-  1.  IOS SVC 0 ROUTINE (EXECUTE CHANNEL PROGRAM).  02700013
*                     2.  QTAM IMPLEMENTATION MODULE (IGG019NG).        02800013
*                     3.  SVC 10 ROUTINE (FREEMAIN).                    02900013
*                     4.  QTAM CONTROL PROGRAM (IECKQQ01).              03000013
*                     5.  SVC 77 ROUTINE (TERMINAL TEST TRANSIENTS).    03100013
*                                                                       03200013
*                                                                       03300013
* EXITS-            1.  RETURN TO THE ADDRESS IN REGISTER 14 IF         03400013
*                       MESSAGE IS NOT A TEST REQUEST.                  03500013
*                   2.  TO BUFFER RECALL CLEANUP ROUTINE IN QTAM        03600013
*                       IMPLEMENTATION MODULE (IGG019NG) TO             03700013
*                       POST BUFFERS TO THE TEST QCB.                   03800013
*                   3.  TO DISPATCH ROUTINE IN QTAM CONTROL             03900013
*                       PROGRAM (IECKQQ01) TO DISPATCH THE NEXT         04000013
*                       ITEM ON THE READY QUEUE.                        04100013
*                   4.  TO THE DEFER-ENTRY ROUTINE IN QTAM CONTROL      04200013
*                       PROGRAM TO PLACE TEST STCB IN CHAIN             04300013
*                       OF LCB TO STOP THE LINE.                        04400013
*                                                                       04500013
*                                                                       04600013
* INLINE ROUTINES - THE LPSTART MACRO WILL GENERATE A LINKAGE TO THE    04700013
*                  ON-LINE-TERMINAL TEST MODULE WHICH TEST FOR BUFFER   04730021
*                  TO BE POSTED TO A ONLT QCB OR ONLT IN OPERATION. IF  04760021
*                  NOT, LCBSTATE IS TESTED FOR SENDING. IF THE LINE IS  04790021
*                  SENDING, RETURN IS MADE TO LPS FOR NORMAL PROCESS-   04820021
*                  ING OF THE MESSAGE.  IF NOT, A CHECK IS MADE FOR     04850021
*                   THE TEST ACTIVATION CODE. IF THE CODE IS NOT        04900013
*                   PRESENT, NORMAL OPERATION OF LPS WILL CONTINUE.     05000013
*                     IF THE TEST ACTIVATION CODE IS PRESENT, THE       05100013
*                   BUFFERS ASSOCIATED WITH THE LINE OPERATION ARE      05200013
*                   POSTED TO A TEST QUEUE CONTROL BLOCK. THE SUBTASK   05300013
*                   ACTIVATED WILL SET TEST IDENTIFICATION FLAGS IN     05400013
*                   THE BUFFER PREFIX CONTAINING THE TEST REQUEST AND   05500013
*                   POST IT TO THE LPS QUEUE. SUBSEQUENT BUFFERS WILL   05600013
*                   BE POSTED TO THE AVAILABLE BUFFER QUEUE. (TERMINAL  05700013
*                   TESTS WILL UTILIZE ONLY THE BUFFER CONTAINING THE   05800013
*                   HEADER SEGMENT.)                                    05900013
*                     THE TEST IDENTIFICATION FLAGS WILL BE RECOGNIZED  06000013
*                   AT ENTRY TO THE MODULE AND THE TERMINAL TEST        06100013
*                   TRANSIENT ROUTINES WILL BE CALLED. THESE ROUTINES   06200013
*                   WILL VALIDATE THE TEST REQUEST AND SET UP THE       06300013
*                   APPROPRIATE TEST.                                   06400013
*                     THE BUFFER WILL THEN BE POSTED TO ANOTHER TEST    06500013
*                   QUEUE CONTROL BLOCK. THE SUBTASK ACTIVATED WILL     06600013
*                   STOP THE LINE TO BE UTILIZED BY THE TERMINAL TESTS  06700013
*                   BY PLACING A TEST SUBTASK CONTROL BLOCK IN THE      06800013
*                   STCB CHAIN OF THE APPROPRIATE LCB.                  06900013
*                     AFTER THE LINE OPERATION HAS BEEN STOPPED,        07000013
*                   FURTHER IDENTIFICATION FLAGS ARE SET IN THE BUFFER  07100013
*                   PREFIX AND AGAIN IT IS POSTED TO THE LPS QUEUE.     07200013
*                   THESE FLAGS ARE RECOGNIZED AT ENTRY INTO THE        07300013
*                   MODULE AND THE TEST MESSAGE IS SENT TO THE          07400013
*                   TERMINAL.                                           07500013
*                     UPON COMPLETION OF THE TEST MESSAGE TRANSMISSION, 07600013
*                   THE LINE END APPENDAGE WILL POST THE BUFFER TO      07700013
*                   THE LPS QUEUE. ALL AREAS AND BUFFERS UTILIZED BY    07800013
*                   THE TERMINAL TESTS WILL THEN BE FREED AND QTAM      07900013
*                   LINE OPERATION WILL BE RESTARTED ON THE SUBJECT     08000013
*                   LINE.                                               08100013
*                                                                       08200013
*                   IF A TEST MESSAGE IS TO BE RETURNED TO THE          08300013
*                   REQUESTING TERMINAL ON A DIAL LINE, THE TRANSIENT   08400013
*                   ROUTINES ARE CALLED IMMEDIATELY UPON RECOGNITION    08500013
*                   OF THE TEST ACTIVATION CODE. THE TEST MESSAGE IS    08600013
*                   THEN SENT TO THE TERMINAL WITHOUT UTILZING THE      08700013
*                   STOP LINE SUBTASK. BUFFERS ARE RELEASED TO THE      08800013
*                   AVAILABLE BUFFER QUEUE BY THE BUFFER ROUTING        08900013
*                   SUBTASK.                                            09000013
*                                                                       09100013
*                   A SUBROUTINE LINKS BUFFERS TO THE READY QUEUE.      09200013
*                                                                       09300013
*                                                                       09400013
* ATTRIBUTES -      THIS ROUTINE IS SERIALLY REUSABLE.                  09500013
*                                                                       09600013
*                                                                       09700013
         EJECT                                                          09800013
IECKONLT START                                                          09900013
*3410151000,157000-158000                                         20180 09930017
*3410193500-194000                                                 00PS 09960017
*0301151500                                                        00PS 09970017
*0340309000                                                       00PS  09980017
*1201175000,192600,210000,366000,368000,370000                    21843 09990018
* 350200-351800,354100-354600,358300-363700                        00PS 09995018
* 195470-194920,199000,202200-202800                             A26033 09996019
* 197200-197800,205000-206000                                    A27528 09997019
* 146300-146600                                                  A29191 09997719
* 197600-197800,205000-206000                                    A26033 09998419
* 199000,202200-202800,228000                                    A27528 09999119
*A001700-003100-048500                                           S21016 09999521
*A239000,241300-241600                                           A43634 09999721
*                                                                       10000013
*                                                                       10100013
IOREG    EQU   0             DATA AREA POINTER                          10200013
FREG     EQU   1             ELEMENT ADDRESS                            10300013
IOBREG   EQU   1             IOB ADDRESS FOR EXCP                       10400013
TREG     EQU   2             QCB ADDRESS                                10500013
Y        EQU   3             BASE FOR DCB                               10600013
LCBREG   EQU   4             LCB ADDRESS                                10700013
SPREG    EQU   5             SCAN POINTER                               10800013
WREG3    EQU   5             WORK REGISTER                              10900013
X        EQU   6             TEMP. REG FOR DCB OR 1ST LCB BASE          11000013
MSREG    EQU   6             BUFFER ADDRESS                             11100013
LGREG    EQU   7             BASE FOR USER'S LPS PROGRAM                11200013
SUBASE   EQU   7             SUBTASK BASE REGISTER                      11300013
BASEREG  EQU   8             MODULE BASE REGISTER                       11400013
QREG     EQU   9             BASE FOR QCB                               11500013
WREG1    EQU   9             WORK REGISTER                              11600013
WREG2    EQU   10            WORK REGISTER                              11700013
TCBREG   EQU   10            BASE FOR TASK CONTROL BLOCK                11800013
EOSREG   EQU   11            END OF SEGMENT ADDRESS                     11900013
BREG     EQU   12            BASE FOR IECKQQ01                          12000013
Z        EQU   13            BASE FOR IGG019NG                          12100013
LNKRG2   EQU   14            LINKAGE REGISTER                           12200013
RREG1    EQU   14            RETURN REGISTER                            12300013
UCBREG   EQU   15            UCB ADDRESS REGISTER                       12400013
SREG     EQU   15            LINK OUT REGISTER                          12500013
QWAIT    EQU   65            QTAM WAIT SVC                              12600013
QPOST    EQU   67            QTAM POST SVC                              12700013
TESTFLAG EQU   X'FF'         TERMINAL TEST FLAGS                        12800013
SWITCHON EQU   X'01'         TERMINAL TEST SWITCH ON INDICATOR          12900013
CLRBYTE  EQU   X'00'         CLEAR FIELD                                13000013
BCDZERO  EQU   X'15'         ZERO IN LINE CODE                          13100013
         USING SVCBASE+2,BREG                                           13200013
         USING IHADCB,Y                                                 13300013
         USING QBLOCK,QREG                                              13400013
         USING TBLOCK,TREG                                              13500013
         USING IECKLCB0,LCBREG                                          13600013
         USING IECKPREF,FREG                                            13700013
         USING ONLTBUF,MSREG                                            13800013
         USING IGG019NG,Z                                               13900013
         EJECT                                                          14000013
*                                                                       14100013
*        RECOGNITION OF TERMINAL TEST ACTIVITY AND OPERATING FLAGS      14200013
*                                                                       14300013
         STM   RREG1,BREG,12(Z)        SAVE REGISTERS                   14400013
         BALR  BASEREG,0               LOAD BASE REGISTER               14500013
         USING *,BASEREG                                                14600013
         TM    SAVE,X'21'         IS THIS A HEADER OR AFTER EOB  A29191 14630019
         BNZ   TESTBFR            BRANCH IF NO                   A29191 14660019
         CLC   TESTACTV(3),INTTFLAG    BUFFER TO BE POSTED TO ONLTTQCB? 14700013
         BNE   TESTSEND                BRANCH IF NO                     14800013
CALLTRAN MVI   FLAGBYTE,TESTFLAG       SET TERM. TEST OPERATING FLAGS   14900013
         ST    MSREG,ECBADDR           SAVE BUFFER ADDRESS              15000013
         L     WREG1,ADDRSAVE   LOAD ADDRESS OF ACTIVATION CODE   20180 15100017
         LR    IOREG,WREG1     LOAD R0 FOR SVC                     00PS 15150017
         LA    FREG,PARMLIST           LOAD ADDRESS OF PARAMETER LIST   15200013
         SVC   77                      CALL TERMINAL TEST TRANSIENT     15300013
*                                                                       15400013
*        RETURN FROM TRANSIENT ROUTINES                                 15500013
*                                                                       15600013
         SR    WREG1,MSREG  OFFSET TO FIRST DATA POSITION         20180 15700017
         STH   WREG1,CHARCNT     SAVE OFFSET                      20180 15800017
         TM    NOTEST,SWITCHON         CHECK FOR TEST INITALIZED        15900013
         BO    CLEANUP                 ONE MEANS TEST NOT SET UP        16000013
         TM    ANSWTEST,SWITCHON       TEST FOR DIAL ANSWER             16100013
         BZ    SETPOST                 ZERO MEANS NOT ANSWER            16200013
         NI    ANSWTEST,CLRBYTE        CLEAR ANSWER SWITCH              16300013
         MVI   DEVICETP,TESTFLAG       SET ANSWER INDICATOR IN BUFFER   16400013
         B     SENDMSG                 GO TO SEND MESSAGE               16500013
*                                                                       16600013
SETPOST  LR    FREG,MSREG              LOAD BUFFER ADDRESS              16700013
         LA    TREG,ONLTTQCB           LOAD ADDRESS OF TERMINAL TESTQCB 16800013
POSTELEM SVC   QPOST                   POST BUFFER TO QCB               16900013
         MVI   NOTEST,CLRBYTE          CLEAR THE NO TEST SWITCH         17000013
         L     SREG,0(Z)               GET ADDRESS OF IGG019NG          17100013
         B     232(SREG)               GO TO LPS CONTROL ROUTINE        17200013
*                                                                       17300013
TESTSEND CLI   FLAGBYTE,TESTFLAG       TEST FOR TERM. TEST OPERATING    17400013
         BNE   SENDTEST           BRANCH IF NO                    21843 17500018
         TM    LINEFREE,TESTFLAG       CHECK FOR DIAL CLEANUP           17600013
         BO    CLEANUP                 ONE MEANS CLEANUP                17700013
         TM    LCBCPA,TESTFLAG         TEST FOR TEST MESSAGE COMPLETION 17800013
         BO    CLEANUP                                                  17900013
*                                                                       18000013
*        SEND TEST MESSAGE                                              18100013
*                                                                       18200013
SENDMSG  LA    IOBREG,LCBFLAG1         LOAD IOB ADDRESS                 18300013
         L     WREG1,CCWAREA           LOAD ADDRESS OF STCB + CCW AREA  18400013
         LA    WREG1,24(WREG1)         POINT TO ACTUAL CCWS             18500013
         ST    WREG1,LCBSTART-1        POINT LCB TO TEST CCWS           18600013
         ST    MSREG,LCBCPA+4          SAVE BUFFER ADDR. FOR LINE END   18700013
         MVI   LCBCPA,TESTFLAG         SET SWITCH FOR LINE END          18800013
         EXCP  (1)                     SEND TEST MESSAGE                18900013
         B     POSTELEM+2              RETURN TO LPS CONTROL ROUTINE    19000013
*                                                                       19100013
*        TEST FOR ACTIVATION CODE                                       19200013
SENDTEST TM    LCBSTATE,X'04'     IS TERMINAL SENDING             21843 19230018
         BO    RET    RETURN IF SENDING                           21843 19260018
*                                                                       19300013
         SR    WREG1,WREG1                                         00PS 19450015
         L     Y,LCBDCBPT         GET DCB ADDRESS                A26033 19457019
         IC    WREG1,LCBUCBX      INSERT UCB INDEX               A26033 19464019
         L     UCBREG,DCBDEBAD    LOAD DEB ADDRESS               A26033 19471019
         SLL   WREG1,2            MULTIPLY INDEX BY 4            A26033 19478019
         L     UCBREG,32(WREG1,UCBREG)  LOAD UCB ADDRESS         A26033 19485019
NEXTEST  SR    WREG1,WREG1        CLEAR REGISTER                 A26033 19492019
         IC    WREG1,0(FREG)           INSERT OFFSET TO INPUT DATA      19500013
         AR    WREG1,SPREG             ADD SCAN POINTER                 19600013
         LA    WREG2,5                 LOAD COMPARE COUNT               19700013
         CLI   0(FREG),X'01'      2740 BASIC ONLT CODE           A27528 19720019
         BNE   COMPACT            CONTINUE IF NOT EQUAL          A27528 19740019
         TM    17(UCBREG),X'40'   AUTOPOLL TERMINAL              A26033 19760019
         BO    INCR               IF YES, USE CODE OF 2          A26033 19780019
COMPACT  CLC   1(1,FREG),0(WREG1)      COMPARE FOR ACTIVATION CODE      19800013
         BNE   T2740              IF NOT, CHECK FOR 2740 BASIC   A27528 19900019
         LA    WREG1,1(WREG1)          POINT TO NEXT DATA CHARACTER     20000013
         BCT   WREG2,COMPACT           TO TO COMPARE NEXT CHARACTER     20100013
         B     REQFOUND                BRANCH TO PROCESS REQUEST        20200013
T2740    TM    16(UCBREG),X'04'   TEST FOR 2740                  127528 20220019
         BZ    TESTLAST           CONTINUE IF NOT 2740           A27528 20240019
         TM    17(UCBREG),X'DC'   BASIC OR CHECKING TERMINAL     A27528 20260019
         BZ    TESTBFR            YES, NOT ONLT MESSAGE          A27528 20280019
TESTLAST CLI   2(FREG),TESTFLAG        CHECK FOR LAST ENTRY             20300013
         BE    TESTBFR                 BRANCH IF LAST ENTRY             20400013
INCR     LA    FREG,2(FREG)       GET NEXT LIST ENTRY            A26033 20500019
         B     NEXTEST            TRY NEXT ENTRY                 A26033 20600019
*                                                                       20700013
TESTBFR  CLC   LCBDESTQ,TSTQCBAD       TEST FOR TERMINAL TEST BUFFERS   20800013
         BE    EXEOB                   GO TO EOB MACRO                  20900013
RET      LM    RREG1,BREG,12(Z)    RESTORE REGISTERS                    21000018
         BR    RREG1                   RETURN TO LPS                    21100013
*                                                                       21200013
REQFOUND SH    WREG1,=X'0005'          BACK UP POINTER TO FIRST NINE    21300013
         CR    SPREG,EOSREG                                             21400013
         BE    RET                 RETURN IF NINES ARE PAST END         21460018
*                                    OF BUFFER                          21520018
         ST    WREG1,ADDRSAVE          SAVE FOR TRANSIENT ROUTINES      21600013
         SR    EOSREG,WREG1            GET CHARACTER COUNT              21700013
         LA    EOSREG,1(EOSREG)        SET CORRECT COUNT                21800013
         STH   EOSREG,CHARCNT          SAVE COUNT IN PREFIX             21900013
*                                                                       22000013
         CLI   5(WREG1),BCDZERO        TEST FOR FORMAT ZERO             22100013
         BNE   LOADDESQ            NO, NOT FORMAT ZERO TEST             22200018
*                                                                       22400013
CHECKLST TM    16(UCBREG),X'04'   TEST FOR 2740 TERMINAL         A27528 22800019
         BZ    TESTDIAL                BRANCH IF NOT 2740               23200013
         TM    17(UCBREG),X'DC'        TEST FOR BASIC 2740              23300013
         BZ    CHECKEOM            BRANCH IF BASIC 2740                 23400018
TESTDIAL TM    17(UCBREG),X'D0'        TEST FOR DIAL LINE               23600013
         BZ    LOADDESQ                BRANCH IF NOT DIAL               23700013
CHECKEOM TM    SAVE,X'02'              TEST FOR EOM IN FIRST BUFFER     23800013
         BZ    ERRPOST            POST MESSAGE TO ERROR QUEUE    A43634 23900021
         OI    ANSWTEST,SWITCHON       SET ANSWER SWITCH                24000013
         B     CALLTRAN                BRANCH TO CALL TRANSIENTS        24100013
ERRPOST  XC    CHARCNT(2),CHARCNT  ZERO TTDKEY WHEN POSTIN TO    A43634 24130021
         B     BFRPOST            ERROR QUEUE                    A43634 24160021
*                                                                       24200013
LOADDESQ MVC   LCBDESTQ,TSTQCBAD       MOVE ADDRESS OF TEST QCB         24300013
EXEOB    EQU   *                                                        24400013
         EOB                           SEND RESPONSE IF REQUIRED        24500013
BFRPOST  L     SREG,0(Z)               LOAD IGG019NG FIXED CODE ADDRESS 24600013
         B     244(SREG)               GO TO POST BUFFER TO TEST QCB    24700013
         EJECT                                                          24800013
*                                                                       24900013
*        ROUTINE TO CLEANUP TERMINAL TEST AREAS                         25000013
*                                                                       25100013
CLEANUP  TM    BYTE1030,TESTFLAG       TEST FOR 1030 MESSAGE SWITCH     25200013
         BZ    CHKAREA                 ZERO MEANS NOT 1030 MSG. SWITCH  25300013
         L     1,ADDR1030              LOAD 1030 DATA ADDRESS           25400013
         SR    0,0                     CLEAR REGISTER                   25500013
         IC    0,BYTE1030              INSERT AREA COUNT                25600013
         B     FREECORE                GO TO FREE AREA VIA FREEMAIN     25700013
*                                                                       25800013
CHKAREA  TM    DISPLACE,TESTFLAG       TEST FOR AREA IN USE             25900013
         BZ    FREECCWS                ZERO MEANS AREA NOT IN USE       26000013
         SR    WREG1,WREG1             CLEAR REGISTER                   26100013
         IC    WREG1,DISPLACE          INSERT PATTERN SELECT OFFSET     26200013
         A     WREG1,PATRNLST          ADD POINTER TO HEAD OF LIST      26300013
         SR    WREG2,WREG2             CLEAR REGISTER                   26400013
         IC    WREG2,0(WREG1)          INSERT PATTERN USAGE COUNT       26500013
         SH    WREG2,=X'0001'          DECREMENT USAGE COUNT            26600013
         STC   WREG2,0(WREG1)          STORE CORRECT COUNT BACK         26700013
         BNZ   FREECCWS                BRANCH IF AREA STILL IN USE      26800013
         SR    0,0                     CLEAR REGISTER                   26900013
         L     1,0(WREG1)              LOAD PATTERN ADDRESS             27000013
         IC    0,0(1)                  INSERT COUNT FOR FREEMAIN        27100013
FREECORE LA    1,0(1)                  CLEAR HIGH ORDER BYTE            27200013
         FREEMAIN R,LV=(0),A=(1)       FREE PATTERN AREA                27300013
*                                                                       27400013
*        FREE CCW AREA                                                  27500013
*                                                                       27600013
FREECCWS TM    CCWBYTES,TESTFLAG       TEST FOR CCW LOADED              27700013
         BZ    AVAILBFR                ZERO MEANS NO CCWS               27800013
         L     1,CCWAREA               LOAD CCW AREA ADDRESS            27900013
         SR    0,0                     CLEAR REGISTER                   28000013
         IC    0,CCWBYTES              INSERT COUNT FOR CCWS            28100013
         FREEMAIN R,LV=(0),A=(1)       FREE CCW AREA                    28200013
*                                                                       28300013
*        POST BUFFER TO AVAILABLE BUFFER QUEUE                          28400013
*                                                                       28500013
AVAILBFR MVI   FLAGBYTE,CLRBYTE        CLEAR TERMINAL TEST FLAG         28600013
         LR    WREG1,MSREG             LOAD BUFFER ADDRESS              28700013
         AH    WREG1,CHARCNT           ADD OFFSET TO FIRST DATA CHAR.   28800013
         MVI   1(WREG1),CLRBYTE        DISABLE ACTIVATION CODE          28900013
         TM    ANSWTEST,SWITCHON       TEST FOR ANSWER LIST SWITCH ON   29000013
         BO    CLRSW                   ONE MEANS SWITCH ON              29100013
         TM    DEVICETP,TESTFLAG       TEST FOR ANSWER MESSAGE COMPLETE 29200013
         BO    LOADDESQ                ONE MEANS MESSAGE COMPLETE       29300013
         L     TREG,0(Z)               GET ADDR. OF IGG019NG FIXED CODE 29400013
         LA    TREG,24(TREG)           GET ADDR. OF AVAILABLE BUFFER Q  29500013
         LR    FREG,MSREG              LOAD BUFFER ADDRESS              29600013
         SVC   QPOST                  POST BUFFER TO AVAILABLE BFR. Q   29700013
*                                                                       29800013
         SPACE 3                                                        29900013
*                                                                       30000013
*        FREE LINE                                                      30100013
*                                                                       30200013
         TM    NOTEST,SWITCHON         CHECK FOR TEST NOT SET UP        30300013
         BO    POSTELEM+2              ONE MEANS TEST NOT SET UP        30400013
         TM    LINEFREE,TESTFLAG       TEST FOR FREE LINE FLAGS         30500013
         BO    POSTELEM+2              BRANCH IF LINE FREE              30600013
         MVI   LCBCPA,CLRBYTE          CLEAR TERMINAL TEST APP. FLAG    30700013
         NI    LCBINCAM,X'FC'          CLEAR LCB FLAGS                  30800013
         LR    TREG,LCBREG   GET LCB ADDRESS                      00PS  30900017
         LA    TREG,0(TREG)           CLEAR HIGH ORDER BYTE             31000013
         LR    FREG,TREG              LCB ADDRESS TO FREG               31100013
         B     POSTELEM               POST LCB TO ITSELF TO FREE LINE   31200013
*                                                                       31300013
CLRSW    NI    ANSWTEST,CLRBYTE        CLEAR SWITCH                     31400013
         MVI   LCBCPA,CLRBYTE     CLEAR TERMINAL TEST APP. FLAG         31500013
         MVI   DEVICETP,TESTFLAG       INDICATE MESSAGE COMPLETE        31600013
         B     LOADDESQ                GO TO RELEASE BUFFERS            31700013
*                                                                       31800013
*                                                                       31900013
         EJECT                                                          32000013
*                                                                       32100013
*        TERMINAL TEST QUEUE CONTROL BLOCK FOR STOP LINE                32200013
*                                                                       32300013
         DS    0F                                                       32400013
         USING *,SUBASE                                                 32500013
ONLTTQCB EQU   *                                                        32600013
         DC    X'01'                   QUEUE STATUS-INITALLY WAITING    32700013
         DC    AL3(TERMINAT)           ELEMENT CHAIN POINTER            32800013
         DC    X'E4'                   READY QUEUE PRIORITY             32900013
         DC    AL3(0)                  NEXT QCB ADDRESS                 33000013
STCBLNK  DC    X'00'                   FILLER BYTE                      33100013
         DC    AL3(STCBKEY)            LINK FOR STCB                    33200013
*                                                                       33300013
*                                                                       33400013
*        SUBTASK CONTROL BLOCK FOR TERMINAL TESTS                       33500013
*                                                                       33600013
STCBKEY  DC    X'6C'                   OFFSET FOR DISPATCH              33700013
         DC    AL3(0)                                                   33800013
         DC    X'E0'                   SUBTASK PRIORITY                 33900013
         DC    AL3(TERMSTCB)           LINK TO TERMINATING STCB         34000013
*                                                                       34100013
*        TERMINAL TEST STOP LINE SUBTASK                                34200013
*                                                                       34300013
*                                                                       34400013
         LR    SUBASE,TREG             LOAD STCB ADDRESS                34500013
         LA    WREG1,12                LOAD CONSTANT OF 12              34600013
         SR    SUBASE,WREG1            ADJUST BASE REGISTER             34700013
PROCBFR  LR    MSREG,FREG              ESTABLISH BUFFER BASE            34800013
         L     TREG,LCBADDR            LOAD LCB ADDRESS                 34900013
         TM    FEATURES,X'90'          TEST FOR DIAL                    35000013
         BNZ   CHEKDIAL                BRANCH IF DIAL LINE         00PS 35030018
         CLI   LCBCPA-LCB+16(TREG),X'04' IS THIS SENSE COMMAND     00PS 35060018
*              (2740 BASIC OR WITH CHECKING)                       00PS 35090018
         BNE   LOADQUAD                NOT DIAL OR 2740 BASIC      00PS 35120018
         CLI   LCBCPA-LCB+21(TREG),X'00'  IF TP OP CODE=00, LINE   00PS 35150018
*              IS BUSY, NO HIO ISSUED.                                  35180018
         BE    LOADQUAD                2740 IS BUSY - NO HIO       00PS 35210018
         B     HIOLOOP                                             00PS 35240018
CHEKDIAL EQU   *                                                        35270018
         TM    LCBINCAM-LCB(TREG),X'02' TEST FOR LINE AVAILABLE         35300013
         BZ    LINEAVAL                ZERO MEANS LINE AVAILABLE        35400013
         CLI   LCBCPA-LCB+32(TREG),4   SENSE COMMAND FOR 2740      00PS 35410018
*                           BASIC DIAL                             00PS 35420018
         BNE   LINEUSE                 BRANCH IF NOT               00PS 35430018
         CLI   LCBCPA-LCB+37(TREG),0   IF TP CODE=0, LINE IS BUSY  00PS 35440018
*                                      IF NOT 0, DO HIO            00PS 35450018
         BNE   LINEAVAL                2740 NOT BUSY - DO HIO      00PS 35460018
LINEUSE  MVI   LINEFREE,X'FF'          INDICATE LINE NOT FREE           35500013
         BAL   RREG1,RDYQLINK          PLACE BUFFER ON READY QUEUE      35600013
         B     DISPATCH                DISPATCH READY QUEUE ITEM        35700013
*                                                                       35800013
SAVEAREA DC    8F'0'                                               00PS 35830018
UCBFLAGS EQU   6                                                   00PS 35860018
UCBRQEAD EQU   20                                                  00PS 35890018
CVT      EQU   16                                                  00PS 35920018
CVTIXAVL EQU   124                                                 00PS 35950018
HIORTN   EQU   8                                                   00PS 35980018
WREG8    EQU   8                                                   00PS 36010018
LINEAVAL OI    LCBINCAM-LCB(TREG),7    SET SO LINE WILL BE REDIALED00PS 36040018
HIOLOOP  NI    LCBFLAG1-LCB(TREG),X'DB'     TURN OFF ERP FLAGS     00PS 36070018
         MVI   LCBECBPT-LCB(TREG),X'48'  SET HIO FLAG FOR LINE-END 00PS 36100018
         L     UCBREG,UCBADDR          LOAD UCB ADDRESS            00PS 36130018
         IC    WREG1,UCBFLAGS(UCBREG)  SAVE UCBFLAG STATUS         00PS 36160018
         STM   8,15,SAVEAREA           SAVE REGISTERS FOR HIO      00PS 36190018
         LR    WREG8,UCBREG            UCB ADDRESS TO REG 8        00PS 36220018
         L     WREG2,CVT               LOAD CVT ADDRESS            00PS 36250018
         L     WREG2,CVTIXAVL(WREG2)   PARAMETER LIST ADDRESS      00PS 36280018
         L     WREG2,HIORTN(WREG2)     HALT I/O ROUTINE ADDRESS    00PS 36310018
         BALR  UCBREG,WREG2            LINK TO HALT I/O ROUTINE    00PS 36340018
         LM    8,15,SAVEAREA                    RESTORE REGISTERS  00PS 36370018
         STC   WREG1,UCBFLAGS(UCBREG)  RESTORE UCBFLAG STATUS      00PS 36400018
LOADQUAD L     WREG3,CCWAREA           LOAD SAVE ADDRESS FOR SUBTASK    36500013
         TM    LCBSTATE-LCB(TREG),X'08'   TEST FOR LINE RECEIVING 21843 36600018
         BZ    MOVESTCB                ZERO MEANS NOT RECEIVING         36700013
         TM    LCBFLAG2-LCB(TREG),X'01'   TEST FOR AUTOPOLL       21843 36800018
         BZ    *+8                     ZERO MEANS NOT AUTOPOLL          36900013
         MVI   LCBCPA+40-LCB(TREG),X'03'  NO-OP AUTOPOLL TIC      21843 37000018
MOVESTCB MVC   0(24,WREG3),STPLSTCB    MOVE STCB                        37100013
         ST    MSREG,16(WREG3)         SAVE BUFFER ADDRESS              37200013
         ST    SUBASE,20(WREG3)        SAVE SUBTASK BASE REGISTER       37300013
         LR    FREG,WREG3          PUT ELEMENT ADDRESS IN REG 1         37380018
         LA    QREG,LCBSCHAD-LCB(TREG) POINT TO BEGINNING OF            37460018
*                                    LCB SUBTASK CHAIN                  37540018
         B     PRIORITY            GO TO PUT ELEMENT AS A SUBTASK       37620018
*                                    IN THE LCB SUBTASK CHAIN           37700018
*                                                                       37800013
POSTLPS  L     FREG,0(MSREG)           LOAD BUFFER ADDRESS              37900013
         LR    MSREG,FREG              LOAD BUFFER ADDRESS              38000013
         L     LCBREG,LCBADDR          ESTABLISH LCB BASE               38100013
         MVC   LCBSCHAD+1(3),5(TREG)   REMOVE TEST STCB FROM LCB CHAIN  38200013
         MVI   LCBSTATE,X'08'                                           38300013
         MVC   READY+1(3),LCBRCADD                                      38400013
         BAL   RREG1,RDYQLINK          PLACE BUFFER ON READY QUEUE      38500013
         CLC   ONLTTQCB+1(3),TERMADDR  IS ANOTHER BUFFER IN QCB CHAIN   38600013
         BE    DISPATCH                EQUAL MEANS NO OTHER BUFFER      38700013
         L     FREG,ONLTTQCB           LOAD NEXT BUFFER ADDRESS         38800013
         LA    FREG,0(FREG)            CLEAR HIGH ORDER BYTE            38900013
         MVC   ONLTTQCB+1(3),5(FREG)   REMOVE BUFFER FROM ELEMENT CHAIN 39000013
         B     PROCBFR                 GO TO PROCESS BUFFER             39100013
*                                                                       39200013
RDYQLINK LA    FREG,0(FREG)            CLEAR HIGH ORDER BYTE            39300013
         L     QREG,0(13)              LOAD ADDRESS OF LPS QCB          39400013
         ST    QREG,FKEY               STORE LPS QCB ADDR. IN ELEMENT   39500013
         LA    QREG,READY              POINT TO HEAD OF READY QUEUE     39600013
         MVC   FLINK,QFAC              LINK ADDR. OF OLD ITEM TO NEW    39700013
         IC    WREG3,QFAC-1            SAVE BYTE OF OLD LINK FIELD      39800013
         ST    FREG,QFAC-1             NEW ITEM ADDRESS TO OLD          39900013
         STC   WREG3,QFAC-1            RESTORE BYTE OF OLD LINK FIELD   40000013
         BR    RREG1                   RETURN TO CALLER                 40100013
*                                                                       40200013
TERMADDR DC    AL3(TERMINAT)           ADDRESS OF TERMINATING ELEMENT   40300013
*                                                                       40400013
*                                                                       40500013
*        STCB UTILIZED TO STOP AN INDIVIDUAL LINE                       40600013
*                                                                       40700013
         DS    0F                                                       40800013
         USING *,TREG                                                   40900013
STPLSTCB DC    X'6C'                   OFFSET FOR DISPATCH              41000013
         DC    AL3(0)                                                   41100013
         DC    X'E0'                   SUBTASK PRIORITY                 41200013
         DC    AL3(TERMSTCB)           LINK TO TERMINATING STCB         41300013
         L     SUBASE,BASEADDR         LOAD BASE FOR RETURN TO SUBTASK  41400013
         BAL   MSREG,POSTLPS-ONLTTQCB(0,SUBASE)  BRANCH TO SUBTASK      41500013
         DC    A(0)                    BUFFER ADDRESS                   41600013
BASEADDR DC    A(0)                    SUBTASK BASE ADDRSSS             41700013
         DROP  TREG                                                     41800013
*                                                                       41900013
         DS    0F                                                       42000013
TERMINAT DC    F'0'                    TERMINATING                      42100013
         DC    X'FF'                              ELEMENT               42200013
         DC    AL3(TERMINAT)                             CONTROL BLOCK  42300013
*                                                                       42400013
*                                                                       42500013
*                                                                       42600013
TERMSTCB DC    X'02'                   TERMINATING                      42700013
         DC    FL4'255'                           SUBTASK               42800013
         B     PRIORITY                                  CONTROL BLOCK  42900013
         DROP  SUBASE                                                   43000013
*                                                                       43100013
         EJECT                                                          43200013
*                                                                       43300013
*        QUEUE CONTROL BLOCK FOR TERMINAL TESTS- BUFFER ROUTING         43400013
*                                                                       43500013
         DS    0F                                                       43600013
TESTQCB  EQU   *                                                        43700013
KEY      DC    X'01'                   QUEUE STATUS-INITIALLY WAITING   43800013
ELEMPTR  DC    AL3(ELEMTERM)           ELEMENT CHAIN POINTER            43900013
PRIOR    DC    X'E4'                   READY QUEUE PRIORITY             44000013
QCBLINK  DC    AL3(0)                  NEXT QCB ADDRESS                 44100013
STCBLINK DC    X'00'                   FILLER BYTE                      44200013
         DC    AL3(TESTSTCB)           LINK FOR STCB                    44300013
*                                                                       44400013
         ORG   TESTQCB+25                                               44500013
QSOURCE  DC    AL3(0)                  ADDR OF FIRST LCB IN CHAIN       44600013
         DS    XL4                                                      44700013
*                                                                       44800013
         DS    0F                                                       44900013
ELEMTERM DC    F'0'                    TERMINATING                      45000013
         DC    X'FF'                              ELEMENT               45100013
         DC    AL3(ELEMTERM)                             CONTROL BLOCK  45200013
*                                                                       45300013
         USING *,SUBASE                                                 45400013
*                                                                       45500013
TESTSTCB DC    X'02'                   OFFSET FOR DISPATCH              45600013
         DC    FL4'255'                                                 45700013
*                                                                       45800013
*        TERMINAL TEST BUFFER ROUTING SUBTASK                           45900013
*                                                                       46000013
         LR    SUBASE,TREG             ESTABLISH BASE REGISTER          46100013
         L     TREG,0(13)              ADDR. OF IGG019NG FIXED CODE     46200013
         TM    MSDLINK,X'FF'           TEST FOR DIAL ROUTING            46300013
         BO    *+12                    BRANCH IF DIAL                   46400013
         TM    MSTATUS,X'01'           TEST FOR HEADER SEGMENT          46500013
         BZ    LPSPOST                 GO TO POST BUFFER TO LPS QUEUE   46600013
         MVI   MSDLINK,CLRBYTE         CLEAR DIAL INDICATOR             46700013
         LA    TREG,24(TREG)           ADDR. OF AVAILABLE BUFFER QUEUE  46800013
         B     POST                    POST BUFFER TO AVAILABLE BUFFERQ 46900013
*                                                                       47000013
LPSPOST  MVC   MSLINK,INTTFLAG         SET TERMINAL TEST SWITCH FOR LPS 47100013
         MVI   MSTATUS,CLRBYTE         CLEAR MESSAGE STATUS             47200013
         MVI   FPRI,X'E0'          SET PRIORITY FOR POST                47250018
         B     POST                    POST BUFFER TO LPS QUEUE         47300013
         DROP  SUBASE                                                   47400013
TSTQCBAD DC    AL3(TESTQCB)                                             47500013
INTTFLAG DC    X'FFFFFF'               INITIATE TEST FLAGS              47600013
         EJECT                                                          47700013
*                                                                       47800013
*        PARAMETER LIST TO BE PASSED TO TRANSIENT ROUTINES              47900013
*                                                                       48000013
         DS    0D                                                       48100013
         DC    A(*+8)                  ADDRESS OF EP PARAMETER          48200013
         DC    A(0)                    DCB PARAMETER                    48300013
         DS    1D                      EP PARAMETER                     48400013
PARMLIST EQU   *                                                        48500013
ECBADDR  DC    A(0)                    ELEMENT CONTROL BLOCK ADDRESS    48600013
PATRNLST DC    A(PATNAME)              ADDRESS OF PATTERN LIST          48700013
         DC    A(CRIDLES)              ADDRESS OF CR & IDLES            48800013
NOTEST   DC    X'00'                   NO TEST SWITCH                   48900013
ANSWTEST DC    X'00'                   ANSWER LIST SWITCH               49000013
*                                                                       49100013
*        SPECIAL CHARACTERS AND PARAMETERS                              49200013
*                                                                       49300013
GETMAIN1 DC    A(0)                    LENGTH FOR GETMAIN MACRO         49400013
         DC    A(0)                    ADDR. OF ADDR. LIST              49500013
         DC    X'20FA'                                                  49600013
CRIDLES  DC    X'16'                   TERMINAL TEST                    49700013
         DC    3XL1'DF'                LINE                             49800013
         DC    X'5B'                   INITIALIZATION                   49900013
         DC    15XL1'DF'               CHARACTERS                       50000013
         DC    X'161F1F1F'             CIRCLE D AND CIRCLE C'S          50100013
         DC    X'761F1F1F37'           CIRCLE Y,CIRCLE C'S AND CIRCLE S 50200013
*                                                                       50300013
         EJECT                                                          50400013
*                                                                       50500013
*        ADDRESS OF GETMAIN PARAMETERS AND TERMINAL TEST PATTERN TABLE  50600013
*                                                                       50700013
         DS    0F                                                       50800013
PATNAME  EQU   *                                                        50900013
         DC    A(GETMAIN1)             ADDRESS OF GETMAIN PARAMETERS    51000013
BTTP5TLT DC    X'00'                   1050 TILT PATTERN USAGE COUNT    51100013
BTTA5TLT DC    AL3(0)                  1050 TILT ADDRESS                51200013
BTTP5ROT DC    X'00'                   1050 ROTATE PATTERN USAGE COUNT  51300013
BTTA5ROT DC    AL3(0)                  1050 ROTATE ADDRESS              51400013
BTTP5TWS DC    X'00'                   1050 TWIST PATTERN USAGE COUNT   51500013
BTTA5TWS DC    AL3(0)                  1050 TWIST ADDRESS               51600013
BTTP5ALC DC    X'00'                   1050 ALL CHARACTERS USAGE COUNT  51700013
BTTA5ALC DC    AL3(0)                  1050 ALL CHARACTERS ADDRESS      51800013
BTTP5SLA DC    X'00'                   1050 SELECTRIC ANALYZER USAGE CT 51900013
BTTA5SLA DC    AL3(0)                  1050 SELECTRIC ANALYZER ADDRESS  52000013
         SPACE                                                          52100013
BTTP6TLT DC    X'00'                   1060 TILT PATTERN USAGE COUNT    52200013
BTTA6TLT DC    AL3(0)                  1060 TILT ADDRESS                52300013
BTTP6ROT DC    X'00'                   1060 ROTATE PATTERN USAGE COUNT  52400013
BTTA6ROT DC    AL3(0)                  1060 ROTATE ADDRESS              52500013
BTTP6TWS DC    X'00'                   1060 TWIST PATTERN USAGE COUNT   52600013
BTTA6TWS DC    AL3(0)                  1060 TWIST ADDRESS               52700013
BTTP6ALC DC    X'00'                   1060 ALL CHARACTERS USAGE COUNT  52800013
BTTA6ALC DC    AL3(0)                  1060 ALL CHARACTERS ADDRESS      52900013
BTTP6SLA DC    X'00'              1060 SELECTRIC ANALYZER USAGE COUNT   53000013
BTTA6SLA DC    AL3(0)             1060 SELECTRIC ANALYZER ADDRESS       53100013
         SPACE                                                          53200013
BTTP3TLT DC    X'00'              1030 TILT PATTERN USAGE COUNT         53300013
BTTA3TLT DC    AL3(0)             1030 TILT ADDRESS                     53400013
BTTP3ROT DC    X'00'              1030 ROTATE PATTERN USAGE COUNT       53500013
BTTA3ROT DC    AL3(0)             1030 ROTATE ADDRESS                   53600013
BTTP3TWS DC    X'00'              1030 TWIST PATTERN USAGE COUNT        53700013
BTTA3TWS DC    AL3(0)             1030 TWIST ADDRESS                    53800013
BTTP3ALC DC    X'00'              1030 ALL CHARACTERS USAGE COUNT       53900013
BTTA3ALC DC    AL3(0)             1030 ALL CHARACTERS ADDRESS           54000013
BTTP3SLA DC    X'00'              1030 SELECTRIC ANALYZER USAGE COUNT   54100013
BTTA3SLA DC    AL3(0)             1030 SELECTRIC ANALYZER ADDRESS       54200013
         SPACE                                                          54300013
BTTP2TLT DC    X'00'              2848 TILT PATTERN USAGE COUNT         54400013
BTTA2TLT DC    AL3(0)             2848 TILT ADDRESS                     54500013
BTTP2ROT DC    X'00'              2848 ROTATE PATTERN USAGE COUNT       54600013
BTTA2ROT DC    AL3(0)             2848 ROTATE ADDRESS                   54700013
BTTP2TWS DC    X'00'              2848 TWIST PATTERN USAGE COUNT        54800013
BTTA2TWS DC    AL3(0)             2848 TWIST ADDRESS                    54900013
BTTP2ALC DC    X'00'              2848 ALL CHARACTERS USAGE COUNT       55000013
BTTA2ALC DC    AL3(0)             2848 ALL CHARACTERS ADDRESS           55100013
*                                                                       55200013
         EJECT                                                          55300013
*                                                                       55400013
*        BUFFER PREFIX FOR ONLINE TERMINAL TESTS                        55500013
*                                                                       55600013
ONLTBUF  DSECT                                                          55700013
ECB      DS    XL8           QTAM ELEMENT CONTROL BLOCK                 55800013
CCWBYTES DS    0XL1          NUMBER OF BYTES FOR TERM TEST CHANNEL PROG 55900013
CCWAREA  DS    A             ADDRESS OF CCW AREA                        56000013
SAVE     DS    0XL1          SAVE BYTE FOR MSTATUS                      56100013
LCBADDR  DS    A             LINE CONTROL BLOCK ADDRESS                 56200013
TESTACTV DS    0XL3          TERMINAL TEST REQUEST FLAGS                56300013
BYTE1030 DS    0XL1          NUMBER OF BYTES FOR 1030 MESSAGE SWITCH    56400013
ADDR1030 DS    0A            ADDRESS OF 1030 SWITCH AREA                56500013
DIALINFO DS    XL2           ADDRESS OF COUNT DIAL DIGITS               56600013
ADDR2260 DS    XL2           2260 ADDRESSING CHARACTERS                 56700013
ADDRESS  DS    XL2           TERMINAL ADDRESSING CHARACTERS             56800013
DEVICETP DS    XL1           UCB ADAPTER + MODEL FIELDS                 56900013
FEATURES DS    0XL1          UCB FEATURES FIELD                         57000013
RESPONSE DS    XL1           RESPONSE CHARACTER-READ FROM TERMINAL      57100013
DISPLACE DS    XL1           DISPLACEMENT IN PATTERN USAGE TABLE        57200013
FLAGBYTE DS    XL1           TERMINAL TEST OPERATING FLAGS              57300013
CHARCNT  DS    XL2           CHARACTER COUNT FOR TERMINAL TESTS         57400013
ADDRSAVE DS    0A            SAVE AREA FOR DATA POINTER                 57500013
LINEFREE DS    0XL1          FREE LINE INDICATOR                        57600013
UCBADDR  DS    A             UCB ADDRESS                                57700013
OFFSET   EQU   ONLTBUF+10    TERMINAL TABLE ENTRY OFFSET                57800013
*                                                                       57900013
*                                                                       58000013
         EJECT                                                          58100013
         DCBD  DSORG=(QX)                                               58200013
         EJECT                                                          58300013
         LCBD  QTAM=3                                                   58400013
         EJECT                                                          58500013
         TCBD                                                           58600013
         EJECT                                                          58700013
         STCBD                                                          58800013
         EJECT                                                          58900013
         QCBD                                                           59000013
         EJECT                                                          59100013
         PREFIXD                                                        59200013
         EJECT                                                          59300013
DEB      DSECT                                                          59400013
         DS    XL16                                                     59500013
DEBNMEXT DS    FL1                                                      59600013
         DS    7X                                                       59700013
DEBDCBAD DS    A                                                        59800013
         DS    4X                                                       59900013
EXT1     DS    XL16                                                     60000013
*                                                                       60100013
*                                                                       60200013
*                                                                       60300013
IGG019NG DSECT                                                          60400013
         DS    XL72                                                     60500013
QSAVE    DS    0XL1                                                     60600013
QATTACH  DS    XL8                                                      60700013
READY    DS    XL5                                                      60800013
DUMMY    DS    XL3                                                      60900013
         ORG   IGG019NG+102                                             61000013
NRET     DS    XL4                                                      61100013
         USING TCB,TCBREG                                               61200013
         USING TBLOCK,Y                                                 61300013
SVCBASE  DSECT                                                          61400013
         CTLPROGD                                                       61500013
         END                                                            61600013
