         TITLE 'IECKOPAW     OPERATOR AWARENESS'                        00300013
*********************************************************************** 00600013
*                                                                     * 00900013
*NAME-  IECKOPAW     OPERATOR AWARENESS                               * 01200013
*                                                                     * 01500013
*STATUS-  CHANGE LEVEL 000                               OS QTAM III  * 01800013
*                                                                     * 02100013
*FUNCTION-  IECKOPAW IS ENTERED FROM THE POSTSEND AND POSTRCV MACRO'S * 02400013
*   WHEN OPERATOR CONTROL IS INCLUDED IN THE LPS ROUTINE.  IT SENDS   * 02700013
*   AN I/O ERROR AND/OR A THRESHOLD MESSAGE TO THE OPERATOR CONTROL   * 03000013
*   TERMINAL.  IF LCBCPA+28 DOES NOT CONTAIN A X'FF', AN I/O ERROR    * 03300013
*   MESSAGE IS NOT TO BE SENT.  IF AN I/O ERROR MESSAGE IS TO BE      * 03600013
*   SENT, IT IS FORMATTED AS FOLLOWS-                                 * 03900013
*                                                                     * 04200013
*        AAA,I/O ERR,BB,CCCC,DDDD,EE00FFFF                            * 04500018
*   WHERE-                                                            * 04800013
*        AAA  = LINE NUMBER                                           * 05100013
*        BB   = OP CODE                                               * 05400013
*        CCCC = STATUS HALF WORD OF LCBCCW                            * 05700013
*        DDDD = SENSE INFORMATION                                     * 06000013
*        EE   = TP OP CODE                                            * 06300013
*        FFFF = TERMINAL IDENTIFIER                                   * 06600013
*                                                                     * 06900013
*   THE I/O ERROR MESSAGE IS THEN SENT TO THE OPERATOR CONTROL        * 07200013
*   TERMINAL.                                                         * 07500013
*        IF LCB+LCBSIZE-6 CONTAINS A ZERO, NO THRESHOLD MESSAGE IS    * 07800013
*   TO BE SENT.  IF A THRESHOLD MESSAGE IS TO BE SENT, IT IS FORMATTED* 08100013
*   AS FOLLOWS-                                                       * 08400013
*                                                                     * 08700013
*        THRESHOLD AAA TRANS=BBB DC=CCC IR=DDD TO=EEE                 * 09000013
*   WHERE-                                                            * 09300013
*        AAA = LINE NUMBER                                            * 09600013
*        BBB = TRANSMISSION NUMBER                                    * 09900013
*        CCC = DATA CHECK COUNTER                                     * 10200013
*        DDD = INTERVENTION REQUIRED COUNTER                          * 10500013
*        EEE = TIME OUT COUNTER                                       * 10800013
*                                                                     * 11100013
*   THE MESSAGE IS THEN SENT TO THE OPERATOR CONTROL TERMINAL AND     * 11400013
*   CONTROL IS PASSED TO THE BUFFER RECALL CLEANUP ROUTINE OF         * 11700013
*   IGG019NG.                                                         * 12000013
*                                                                     * 12300013
*ENTRY POINTS-  IECKOPAW - CONTROL IS PASSED HERE BY A BRANCH FROM    * 12600013
*   THE FIXED PORTION OF IGG019NG AFTER IT IS ENTERED BY A BRANCH     * 12900013
*   FROM THE POSTSEND AND POSTRCV MACRO'S WHEN OPERATOR CONTROL IS    * 13200013
*   SPECIFIED IN THE LPS ROUTINE.                                     * 13500013
*                                                                     * 13800013
*INPUT-  THE INPUT CONSISTS OF THE INFORMATION CONTAINED IN THE LCB   * 14100013
*   WHICH IS TO BE PLACED IN THE I/O ERROR AND THRESHOLD MESSAGES.    * 14400013
*   ADDITIONAL INPUT IS-                                              * 14700013
*        REGISTER  4- ADDRESS OF THE LCB.                             * 15000013
*        REGISTER  6- ADDRESS OF THE BUFFER.                          * 15300013
*        REGISTER 15- ENTRY POINT REGISTER.                           * 15600013
*                                                                     * 15900013
*OUTPUT-  THE I/O ERROR AND THRESHOLD MESSAGES WILL BE SENT TO THE    * 16200013
*   OPERATOR CONTROL TERMINAL.                                        * 16500013
*                                                                     * 16800013
*EXTERNAL ROUTINES-                                                   * 17100013
*        IECKRC - BUFFER RECALL OF IGG019NG TO RECALL THE HEADER.     * 17400013
*        IECKPR - BUFFER CLEANUP OF IGG019NG TO SEND THE LAST MESSAGE * 17700013
*                 AND TO RETURN ALL BUFFERS BEFORE RETURNING TO       * 18000013
*                 LPSTART.                                            * 18300013
*                                                                     * 18600013
*EXITS-  NORMAL - EXIT IS TO BUFFER CLEANUP ROUTINE OF IGG019NG.      * 18900013
*        ERRORS - NONE.                                               * 19200013
*                                                                     * 19500013
*TABLES/WORKAREAS-                                                    * 19800013
*        TRTABLE1 AND TRTABLE2 - TO TRANSLATE INFORMATION TO PRINTABLE* 20100013
*                                FORM.                                * 20400013
*                                                                     * 20700013
*ATTRIBUTES-  SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM   * 21000013
*   MODE.                                                             * 21300013
*                                                                     * 21600013
*********************************************************************** 21900013
         SPACE 2                                                        22200013
IECKOPAW START                                                          22500013
*3170342000                                                        00PS 22600015
*1201603000-609000,786000,792000,805000-807000,813000-816000      18035 22660018
*1201829000-830000                                                18035 22720018
* 373000-377000,384000,514000-515000,562000-563000,654000,         00PS 22730018
* 804500,807000-808000,828500                                      00PS 22740018
* 434000-436000                                                   24119 22750018
* 786000                                                          18035 22760018
*A723500-725500,C726000                                          A52229 22780021
         SPACE 2                                                        22800013
DREG0    EQU   0                                                        23100013
DREG1    EQU   1                                                        23400013
KREG     EQU   2                                                        23700013
RREG2    EQU   3                                                        24000013
LCBREG   EQU   4                                                        24300013
SPREG    EQU   5                                                        24600013
MSREG    EQU   6                                                        24900013
LGREG    EQU   7                                                        25200013
WREG1    EQU   8                                                        25500013
WREG2    EQU   9                                                        25800013
TCREG    EQU   10                                                       26100013
EOSREG   EQU   11                                                       26400013
WREG3    EQU   12                                                       26700013
NGREG    EQU   13                                                       27000013
RREG1    EQU   14                                                       27300013
SREG     EQU   15                                                       27600013
CVTABLE  EQU   16                                                       27900013
CVTTRMTB EQU   156                                                      28200013
IDLE     EQU   X'17'                                                    28500013
EOA      EQU   X'7B'                                                    28800013
NEWLINE  EQU   X'15'                                                    29100013
         SPACE 2                                                        29400013
         USING *,SREG                                                   29700013
         USING IECKPREF,MSREG                                           30000013
         USING IECKLCB0,LCBREG                                          30300013
         USING IHADCB,KREG                                              30600013
         USING IECKTERM,TCREG                                           30900013
         USING QBLOCK,WREG2                                             31200013
         SPACE 3                                                        31500013
*   THE FOLLOWING ROUTINE TESTS FOR AN I/O ERROR MESSAGE TO BE SENT   * 31800013
*   AND FORMATS THE MESSAGE.                                          * 32100013
         SPACE 3                                                        32400013
         L     KREG,LCBDCBPT       LOAD DCB ADDRESS                     32700013
         CLI   LCBCPA+28,X'FF'     IS AN I/O ERROR MESSAGE TO BE SENT   33000013
         BNE   THRESH              IF NOT, GO CHECK FOR THRESHOLD MSG   33300013
         BAL   RREG1,RECALL        GO TO RECALL A BUFFER FOR MESSAGE    33600013
         MVI   LCBCPA+28,X'00'     CLEAR I/O ERROR INDICATION           33900013
         MVC   ERLINENO+1(2),LCBCPA+30  MOVE LINE NUMBER TO MESSAGE00PS 34200015
         UNPK  EROPCODE(3),LCBCPA+32(2) UNPACK OP CODE INTO MESSAGE     34500013
         UNPK  ERSTATUS(5),LCBCSW+4(3)  UNPACK STATUS INTO MESSAGE      35400013
         UNPK  ERSENSE(5),LCBSENSE(3)   UNPACK SENSE INFORMATION        36300013
         UNPK  ERTERMID(9),LCBRESTR(5)  UNPACK TP OP CODE AND TERMID    37200013
         TR    EROPCODE(21),TRTABLE2   TRANSLATE TO PRINTABLE FORM 00PS 37300018
         MVI   EROPCODE+2,C','          CLEAR LAST NUMBER          00PS 37400018
         MVI   ERSTATUS+4,C','          AND INSERT                 00PS 37500018
         MVI   ERSENSE+4,C','           PUNCTUATION FOR            00PS 37600018
         MVI   ERTERMID+8,C' '          PRINTABLE FORM             00PS 37700018
         LA    DREG1,IOERRMSG      LOAD MESSAGE ADDRESS                 38100013
         LA    WREG3,34                LOAD MSG. LENGTH            00PS 38400018
         SPACE 3                                                        38700013
*   THE FOLLOWING ROUTINE SENDS THE I/O ERROR OR THRESHOLD MESSAGES   * 39000013
*   TO THE OPERATOR CONTROL TERMINAL IF ONE IS SPECIFIED.             * 39300013
         SPACE 3                                                        39600013
SENDMSG  L    TCREG,CVTABLE        GET CVT ADDRESS                      39900013
         L     TCREG,CVTTRMTB(TCREG) GET TERMTBL ADDRESS                40200013
         SH    TCREG,FOUR          GET ADDRESS OF TERMTBL-4             40500013
         L     WREG2,0(TCREG)      GET ADDRESS OF OPCTL MACRO           40800013
         LH    WREG2,10(WREG2)     LOAD RELATIVE OFFSET                 41100013
         SLL   WREG2,16            CLEAR HIGH ORDER                     41400013
         SRL   WREG2,16              HALF WORD                          41700013
         LR    DREG0,WREG2         SAVE OFFSET                          42000013
         L     WREG2,4(TCREG,WREG2)  GET QCB ADDRESS OF OPCTL TERMINAL  42300013
         L     WREG1,QDCB-1        GET DCB ADDRESS OF OPCTL TERMINAL    42600013
         TM    DCBOFLGS-IHADCB(WREG1),X'10' HAS OPCTL TERM BEEN OPENED  42900013
         BZ    WTO                 IF NOT, DO WRITE TO OPERATOR         43200013
         L     WREG2,DCBCLPS-IHADCB(WREG1)  GET LPS ADD. OF OPCTL 24119 43400018
         LH    WREG2,8(WREG2)     GET NO. OF IDLES IN OPCTL LPS   24119 43600018
         LA    WREG2,2(WREG2)      ADD TWO FOR EOA AND NEW LINE         43800013
         LR    RREG2,WREG2         SAVE COUNT OF IDLES             00PS 44100018
         BCTR  WREG2,DREG0         SUBTRACT TWO                         44400013
         BCTR  WREG2,DREG0           FOR LOOP                           44700013
         LA    SPREG,HDSTRT             SET SCAN POINTER TO START OF    45000013
*                                         HEADER                        45300013
         LTR   WREG2,WREG2              IS NUMBER OF INSERTIONS ZERO    45600013
         BZ    NOIDLES                  IF YES, DO NOT INSERT IDLES     45900013
MOVEIDLE MVI   0(SPREG),IDLE       INSERT IDLE CHARACTER                46200013
         LA    SPREG,1(SPREG)      ADD ONE TO SCAN POINTER              46500013
         BCT   WREG2,MOVEIDLE      RETURN IF ALL IDLES HAVE NOT BEEN    46800013
*                                    MOVED                              47100013
NOIDLES  MVI   0(SPREG),EOA        INSERT EOA CHARACTER AFTER IDLES     47400013
         MVI   1(SPREG),NEWLINE    INSERT NEW LINE CHARACTER AFTER EOA  47700013
         LA    SPREG,2(SPREG)      BUMP SCAN POINTER PAST EOA AND NL    48000013
         LR    WREG2,SPREG         LOAD SCAN POINTER INTO WORK REGISTER 48300013
         L     WREG1,=V(IECKBFSZ)  GET ADDRESS OF BUFFER SIZE           48600013
         LH    WREG1,0(WREG1)      GET SIZE OF BUFFER                   48900013
         LA    WREG1,8(WREG1,MSREG) GET END OF BUFFER+1                 49200013
         SR    WREG1,WREG2         GET SPACE REMAINING IN BUFFER        49500013
         CR    WREG1,WREG3         IS MESSAGE TEXT LARGER THAN          49800013
*                                    REMAINING BUFFER                   50100013
         BC    12,TRUNC            IF YES, GO TO TRUNCATE MESSAGE       50400013
         LR    WREG1,WREG3         OTHERWISE USE MESSAGE SIZE           50700013
TRUNC    AR    SPREG,WREG1         SET SCAN POINTER TO END OF MESSAGE   51000013
         BCTR  WREG1,0             REDUCE COUNT BY ONE FOR EXECUTE      51300013
         AR    RREG2,WREG1         ADD IDLE COUNT TO MSG LENGTH    00PS 51400018
         STC   RREG2,MSPTR         SET MSPTR TO END OF MESSAGE     00PS 51500018
         EX    WREG1,MOVEMSG       MOVE ERROR MESSAGE TO BUFFER         51600013
         AR    WREG1,WREG2         GET ADDRESS OF LAST CHARACTER OF     51900013
*                                    MESSAGE IN BUFFER                  52200013
         LA    WREG2,MSEGSZE-1     GET ADDRESS OF START OF PREFIX-1     52500013
         SR    WREG1,WREG2         GET MESSAGE SIZE                     52800013
         STH   WREG1,MSEGSZE       AND STORE IT IN PREFIX               53100013
         MVI   MSTATUS,70          INDICATE SINGLE SEGMENT MESSAGE      53400013
         LR    WREG2,DREG0         RESTORE OFFSET TO OPCTL TERMINAL     53700013
         STH   WREG2,TTDKEY        STORE RELATIVE OFFSET OF OPCTL       54000013
*                                     TERMINAL ENTRY TO DESTINATION KEY 54300013
         LA    WREG2,5(TCREG,WREG2)  GET QCB ADDRESS OF OPCTL TERMINAL  54600013
         MVC   LCBDESTQ(3),0(WREG2)  MOVE QCB ADDRESS TO LCBDESTQ       54900013
         NI    LCBSTATE,X'FD'      TURN OFF PARTIAL MESSAGE SWITCH      55200013
         MVI   LCBPTEMP,C' '       BLANK OUT LCBPTEMP FIELD             55500013
         SR    WREG1,WREG1         CLEAR REGISTER                       55800013
         STH   WREG1,MSNUMOUT      CLEAR MSNUMOUT FIELD                 56100013
         STH   WREG1,MSNUMIN           CLEAR MSNUMIN FIELD         00PS 56200018
         STH   WREG1,TTSKEY            CLEAR TTSKEY FIELD          00PS 56300018
         SPACE 3                                                        56400013
*  THE FOLLOWING ROUTINE TESTS FOR A THRESHOLD MESSAGE TO BE SENT     * 56700013
*   AND FORMATS THE MESSAGE.                                          * 57000013
         SPACE 3                                                        57300013
THRESH   SR    WREG3,WREG3         CLEAR REGISTER FOR IC                57600013
         IC    WREG3,DCBEIOBX      INSERT LCB SIZE                      57900013
         ALR   WREG3,LCBREG        ADD LCB ADDRESS                      58200013
         LA    WREG3,0(WREG3)      CLEAR HIGH ORDER BYTE                58500013
         SH    WREG3,SIX           SUBTRACT 6 TO POINT TO THRESHOLD     58800013
*                                     COUNTERS                          59100013
         CLI   4(WREG3),0          IS A THRESHOLD MESSAGE TO BE SENT    59400013
         BE    RETURN              IF NOT, GO TO BUFFER RECALL CLEANUP  59700013
         BAL   RREG1,RECALL        GO TO RECALL A BUFFER FOR MESSAGE    60000013
         UNPK  LEMSG(4),4(2,WREG3) UNPACK UNIT NUMBER             18035 60300018
         MVI   LEMSG+3,C' ' BLANK OUT LAST NUMBER                 18035 60600018
         TR    LEMSG(3),TRTABLE2 TRANSLATE TO PRINTABLE FORM      18035 60900018
         SR    DREG1,DREG1         CLEAR REGISTER FOR IC                61200013
         LA    WREG1,7             LOAD DECREMENT                       61500013
         LNR   WREG1,WREG1            FOR BXH INSTRUCTION               61800013
         LA    WREG2,LEMSTR+5      LOAD STOPPING ADDRESS FOR BXH LOOP   62100013
         LA    RREG2,LEMSTO+4      LOAD STARTING ADDRESS FOR BXH LOOP   62400013
LOOP     BCTR  WREG3,0             DECREMENT POINTER TO NEXT COUNTER    62700013
         IC    DREG1,4(WREG3)      INSERT COUNTER                       63000013
         CVD   DREG1,UNPACK        CONVERT COUNTER TO DECIMAL           63300013
         UNPK  0(3,RREG2),UNPACK+6(2)  UNPACK TO PUT IN PRINTABLE FORM  63600013
         OI    2(RREG2),X'F0'      CLEAR SIGN OF LAST NUMBER            63900013
         BXH   RREG2,WREG1,LOOP    DECREMENT TO NEXT COUNTER AND RETURN 64200013
*                                     TO CONVERT NEXT COUNTER           64500013
         XC    4(5,WREG3),4(WREG3) CLEAR THRESHOLD COUNTERS             64800013
         LA    DREG1,LEMSG         LOAD MESSAGE ADDRESS                 65100013
         LA    WREG3,45                LOAD MSG. SIZE              00PS 65400018
         B     SENDMSG             GO TO SEND MESSAGE TO OPCTL TERMINAL 65700013
         SPACE 3                                                        66000013
*   THE FOLLOWING ROUTINE RECALLS THE BUFFER NEEDED FOR THE MESSAGE   * 66300013
         SPACE 3                                                        66600013
RECALL   TM    MSTATUS,X'10'       IS MESSAGE TO BE PLACED ON DISK      66900013
         BO    SKIPRC              IF NOT, SKIP RECALL                  67200013
         MVC   LCBCECB+1(3),LCBCHDR  MAKE HEADER ADDRESS AVAILABLE      67500013
         L     WREG1,0(NGREG)      GET ADDRESS OF LPS QUEUE             67800013
         LR    DREG0,WREG3         SAVE LCB ADDRESS BEFORE RECALL       68100013
         BAL   RREG2,240(WREG1)    BRANCH TO RECALL                     68400013
         LR    WREG3,DREG0         RESTORE LCB ADDRESS                  68700013
SKIPRC   BR    RREG1               RETURN TO SET UP MESSAGE             69000013
         SPACE 3                                                        69300013
*  THE FOLLOWING RETURNS TO BUFFER RECALL/CLEANUP IN IGG019NG         * 69600013
         SPACE 3                                                        69900013
WTO      SH    DREG1,TWELVE        BACK UP POINTER FOR WTO              70200013
         LR    WREG2,SREG          SAVE BASE REGISTER FOR WTO           70500013
         WTO   MF=(E,(1))                                               70800013
         LR    SREG,WREG2          RESTORE BASE REGISTER                71100013
         OI    MSTATUS,X'10'       SET MESSAGE SENT BIT                 71400013
         B     THRESH              CHECK FOR THRESHOLD MESSAGE          71700013
RETURN   TM    LCBERRST+1,X'80'    HAS A PERMANENT ERROR OCCURRED       72000013
         BZ    NOINTREL            IF NOT, IGNORE INTREL SWITCH         72300013
         SR    WREG1,WREG1       CLEAR WORK REG                  A52229 72350021
         IC    WREG1,LCBUCBX     GET REL LINE #                  A52229 72400021
         SLA   WREG1,2           TIMES 4                         A52229 72450021
         A     WREG1,LCBDCBPT    ADD DCB ADDRESS                 A52229 72500021
         LA    WREG1,DCBCPOLL-IHADCB(WREG1) POINT TO DCBCPOLL    A52229 72550021
         TM    0(WREG1),X'04'    IS INTREL ENTRY INDICATED              72600021
         BZ    NOINTREL            IF NOT, DO NOT RETURN TO INTREL      72900013
         MVC   LCBCECB+1(3),LCBCHDR  MAKE HEADER ADDRESS AVAILABLE      73200013
         L     WREG1,0(NGREG)      GET ADDRESS OF LPS QUEUE             73500013
         BAL   RREG2,240(WREG1)    BRANCH TO RECALL                     73800013
         L     WREG1,=V(IECKNTRL)  GET ADDRESS OF INTREL QCB            74100013
         MVC   LCBDESTQ(3),1(WREG1)  SET DESTINATION TO INTREL QUEUE    74400013
         ST    LCBREG,4(WREG1)     SAVE LCB ADDRESS FOR INTREL          74700013
         MVI   4(WREG1),X'FE'      RESTORE PRIORITY                     75000013
NOINTREL EQU   *                                                        75300013
         L     SREG,0(13)          GET ADDRESS OF LPS QUEUE             75600013
         B     244(SREG)           BRANCH TO RECALL/CLEANUP             75900013
         SPACE 3                                                        76200013
*   CONSTANTS AND WORK AREAS USED BY THIS ROUTINE FOLLOW.             * 76500013
         SPACE 3                                                        76800013
MOVEMSG  MVC   0(1,WREG2),0(DREG1)                                      77100013
FOUR     DC    H'4'                                                     77400013
SIX      DC    H'6'                                                     77700013
TWELVE   DC    H'12'                                                    78000013
UNPACK   DS    D                                                        78300013
         DC    X'00398000'  MSG LENGTH AND MCSFLAGS FIELD         18035 78600018
         DC    CL8'IEC801I '                                            78900013
LEMSG    DC    CL13'    THRESHOLD'                                18035 79200018
LEMSTR   DC    CL10' TRANS=   '                                         79500013
LEMSDC   DC    CL7' DC=   '                                             79800013
LEMSIR   DC    CL7' IR=   '                                             80100013
LEMSTO   DC    CL7' TO=   '                                             80400013
         DC    X'40'                                               00PS 80450018
         DC    B'0001000000000000' DESCRIPTOR CODES               18035 80500018
         DC    B'0000000101000000' ROUTING CODES                  18035 80600018
         DS    0F                                                  00PS 80700018
         DC    X'002E8000'  MSG LENGTH AND MCSFLAGS FIELD         18035 80800018
         DC    CL8'IEA000I '                                            81000013
IOERRMSG DC    CL12'000,I/O ERR,'                                 18035 81300018
ERLINENO EQU   IOERRMSG                                           18035 81600018
EROPCODE DC    CL3'00,'                                                 81900013
ERSTATUS DC    CL5'0000,'                                               82200013
ERSENSE  DC    CL5'0000,'                                               82500013
ERTERMID DC    CL8'00000000'                                            82800013
         DC    X'40'                                               00PS 82850018
         DC    B'0001000000000000' DESCRIPTOR CODES               18035 82900018
         DC    B'0000000101000000' ROUTING CODES                  18035 83000018
TRTABLE1 EQU   *                                                        83100013
TRTABLE2 EQU   TRTABLE1-240                                             83400013
         DC    C'0123456789ABCDEF'                                      83700013
         EJECT                                                          84000013
         LCBD  QTAM=3                                                   84300013
         EJECT                                                          84600013
         PREFIXD                                                        84900013
         EJECT                                                          85200013
         DCBD  DSORG=(QX)                                               85500013
         EJECT                                                          85800013
         TERMTBLD                                                       86100013
         EJECT                                                          86400013
         QCBD                                                           86700013
         END                                                            87000013
