         TITLE 'IECKPAUS  QTAM PAUSE (PAUSE)'                           00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-                                                                * 01600013
*   IECKPAUS    QTAM PAUSE (PAUSE)                                    * 02000013
*                                                                     * 02400013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 02800013
*                                                                     * 03200013
*FUNCTION-                                                            * 03600013
*        IECKPAUS WILL CAUSE CERTAIN USER SPECIFIED CHARACTERS TO     * 04000013
*   BE SENT TO A TERMINAL WHEN A GIVEN CHARACTER OR CHARACTER         * 04400013
*   SEQUENCE IS FOUND IN A SEGMENT OF THE MESSAGE CURRENTLY BEING     * 04800013
*   SENT.                                                             * 05200013
*        THE ADDRESS OF THE FIRST BYTE OF THE MESSAGE SEGMENT IS      * 05600013
*   OBTAINED FROM THE LCBTRST (LBC + 82) FIELD OF THE LCB.  IF IT     * 06000013
*   IS NOT A TEXT SEGMENT, THE SIZE OF THE PREFIX AND EXPANSION       * 06400013
*   FIELDS IS ADDED TO THE POINTER TO THE BEGINNING OF THE BUFFER     * 06800013
*   TO GET THE ADDRESS OF THE FIRST HEADER CHARACTER.                 * 07200013
*        THE MESSAGE IS THEN SCANNED FOR THE CONTROL CHARACTER        * 07600013
*   DEFINED IN THE PAUSE MACRO STATEMENT.  IF THE SEGMENT IS          * 08000013
*   DEPLETED AND THE CHARACTER OR CHARACTER SEQUENCE IS NOT FOUND,    * 08400013
*   CONTROL IS PASSED TO THE NEXT LPS INSTRUCTION.                    * 08800013
*        WHEN THE CHARACTER SEQUENCE IS FOUND, THE COUNT IS DECREMENT-* 09200013
*   ED BY ONE.  (IF THIS IS THE FIRST PAUSE FOR THIS SEGMENT, COUNT   * 09600013
*   WILL BE INITIALIZED TO THE NUMBER OF INSERT BLOCKS.  AFTER THE    * 10000013
*   FIRST PAUSE, COUNT WILL THEN BE THE NUMBER OF INSERT BLOCKS LEFT. * 10400013
*   THIS NUMBER WILL BE DIMINISHED BY ONE WHEN AN INSERT BLOCK IS     * 10800013
*   REQUESTED.)                                                       * 11200013
*        THE INSERT BLOCK WILL CONSIST MAINLY OF 3 CCWS:              * 11600013
*              1.   CCW TO WRITE INSERTED CHARACTERS,                 * 12000013
*              2.   CCW TO WRITE REMAINDER OF BUFFER,                 * 12400013
*              3.   CCW TO TIC TO NEXT BRB.                           * 12800013
*                                                                     * 13200013
*        WHEN THE INSERT BLOCK HAS BEEN ALLOCATED, THE ADDRESS OF THE * 13600013
*   CHARACTER AFTER THE CONTROL CHARACTER IS COMPUTED AND PLACED      * 14000013
*   INTO THE ADDRESS FIELD IN THE FIRST CCW IN THE INSERT BLOCK (IB). * 14400013
*   THE ADDRESS OF THE NEXT BRB IN THE CHAIN IS OBTAINED AND STORED   * 14800013
*   IN THE TIC ADDRESS IN THE IB TIC CCW.                             * 15200013
*        THE COUNT OF CHARACTERS IN THE REST OF THE BUFFER IS OBTAIN- * 15600013
*   ED AND INSERTED INTO THE COUNT FIELD IN THE FIRST IB CCW.  THE    * 16000013
*   ADDRESS OF THE BYTE AFTER THE CONTROL CHARACTERS IS MOVED INTO    * 16400013
*   THE DATA ADDRESS FIELD OF THIS CCW.                               * 16800013
*        THE COUNT OF CHARACTERS UP TO THE CONTROL CHARACTER(S) IS    * 17200013
*   COMPUTED AND PLACED INTO THE COUNT FIELD OF THE FIRST CCW IN      * 17600013
*   THE PREVIOUS BRB.                                                 * 18000013
*        THE COUNT OF IDLE CHARACTERS IS MOVED INTO THE FIRST CCW     * 18400013
*   IN THE IB.                                                        * 18800013
*        IN EFFECT, AT THE END OF THIS ROUTINE, THE BRB WITH THE      * 19200013
*   CCW TO SEND  THE ENTIRE MESSAGE NOW SENDS ONLY THOSE              * 19600013
*   CHARACTERS UP TO AND INCLUDING THE CONTROL CHARACTER(S). THE      * 20000013
*   INSERT BLOCK WILL HOLD THE CCWS TO SEND  THE DESIRED CHARACTER,   * 20400013
*   SEND THE REMAINDER OF THE BUFFER, AND TIC TO THE NEXT BRB.        * 20800013
*        AT THE COMPLETION OF THE ROUTINE, CONTROL IS PASSED TO       * 21200013
*   THE POINT NEXTCHAR TO CONTINUE SCANNING OF THE SEGMENT.           * 21600013
*                                                                     * 22000013
*ENTRY POINTS-                                                        * 22400013
*   IECKPAUS - EXPANSION OF THE PAUSE MACRO GENERATES A BALR TO THIS  * 22800013
*        POINT USING REGISTER 15 AS THE ENTRY POINT REGISTER, AND     * 23200013
*        REGISTER 3 AS THE RETURN POINT REGISTER.                     * 23600013
*                                                                     * 24000013
*INPUT-                                                               * 24400013
*   REGISTER  3- RETURN ADDRESS FROM THIS ROUTINE.                    * 24800013
*   REGISTER 11- ADDRESS OF END OF SEGMENT.                           * 25200013
*   REGISTER 14- PARAMETER REGISTER.  THE PARAMETER LIST PASSED       * 25600013
*        TO THE ROUTINE CONSISTS OF THE NUMBER OF CHARACTERS TO BE    * 26000013
*        SENT WHEN THE CONTROL CHARACTER(S) IS INCOUNTERED, THE       * 26400013
*        CONTROL CHARACTER(S), AND THE BIT CONFIGURATION TO BE        * 26800013
*        SENT.                                                        * 27200013
*                                                                     * 27600013
*OUTPUT-                                                              * 28000013
*   THE SPECIFIED NUMBER OF OUTPUT CHARACTERS WILL BE SENT TO THE     * 28400013
*        DESTINATION FOR EACH OCCURRANCE OF THE CONTROL CHARACTER     * 28800013
*        SEQUENCE IN THE MESSAGE HEADER.                              * 29200013
*                                                                     * 29600013
*EXTERNAL ROUTINES-                                                   * 30000013
*   QWAIT (IGG065 IN MODULE IECKQQ01)                                 * 30400013
*                                                                     * 30800013
*EXITS-                                                               * 31200013
*   NORMAL - WHEN THE ENTIRE HEADER HAS BEEN SCANNED, CONTROL IS      * 31600013
*        RETURNED TO THE NEXT LPS INSTRUCTION BY BRANCHING ON         * 32000013
*        REGISTER 3.                                                  * 32400013
*   ERROR - NONE.                                                     * 32800013
*                                                                     * 33200013
*TABLES/WORK AREAS-                                                   * 33600013
*   A QUEUE CONTROL BLOCK, INSERTQ, IS DEFINED IN THIS ROUTINE.       * 34000013
*                                                                     * 34400013
*ATTRIBUTES-                                                          * 34800013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 35200013
*                                                                     * 35600013
*NOTES-                                                               * 36000013
*   REGISTER  0-  WORK REGISTER                                       * 36400013
*   REGISTER  1-  ADDRESS OF THE INSERT BLOCK.                        * 36800013
*   REGISTER  2-  ADDRESS OF NEXT BRB ON RING.                        * 37200013
*   REGISTER  3-  BASE REGISTER FOR FULL STCB.                        * 37600013
*   REGISTER  4-  BASE REGISTER FOR LCB.                              * 38000013
*   REGISTER  6-  BASE REGISTER.                                      * 38400013
*   REGISTER  9-  SCAN POINTER FOR THIS ROUTINE.                      * 38800013
*   REGISTER 10-  INCREMENT FOR SCANNING SEGMENT.                     * 39200013
*   REGISTER 12-  WORK REGISTER.                                      * 39600013
*                                                                     * 40000013
*********************************************************************** 40400013
* 674000,706000,718000                                            23165 40600018
* 694000                                                         A37733 40700020
IECKPAUS START                                                          40800013
QWAIT    EQU   65                                                       41200013
DREG0    EQU   0                                                        41600013
FREG     EQU   1                                                        42000013
TREG     EQU   2                                                        42400013
RREG2    EQU   3                                                        42800013
Y        EQU   3                                                        43200013
LCBREG   EQU   4                                                        43600013
MSREG    EQU   6                                                        44000013
X        EQU   6                                                        44400013
WREG1    EQU   9                                                        44800013
QREG     EQU   9                                                        45200013
IREG     EQU   10                                                       45600013
TCBREG   EQU   10                                                       46000013
EOSREG   EQU   11                                                       46400013
WREG2    EQU   12                                                       46800013
BREG     EQU   12                                                       47200013
RREG1    EQU   14                                                       47600013
SREG     EQU   15                                                       48000013
         USING *,SREG                                                   48400013
         USING IECKLCB0,LCBREG                                          48800013
         USING IECKPREF,MSREG                                           49200013
         USING CTLPROG+2,BREG                                           49600013
         LH    IREG,LCBTRST        GET REL ADDR OF FIRST CHAR TO TRANS  50000013
         TM    MSTATUS,X'01'       TEST FOR TEXT SEGMENT                50400013
         BC    8,USETRST           IF HEADER,IREG IS SET OK             50800013
         TM    MSTATUS,X'20'       IS EOB BIT ON                        51200013
         BC    1,USETRST           IF YES,IREG IS SET OK                51600013
         LA    IREG,TXSTRT-MSEGSZE GET REL ADDR OF FIRST CHAR TO TRANS  52000013
USETRST  LA    WREG1,MSEGSZE-1(IREG)    ADDR OF FIRST BYTE TO SCAN-1    52400013
         L     WREG2,LCBCLCCW      GET ADDR OF PREV CCW                 52800013
         L     FREG,=V(IECKBFSZ)   GET NUMBER OF INSERT BLOCKS          53200013
         LH    FREG,2(0,FREG)            CURRENTLY AVAILABLE            53600013
         L     TREG,8(0,WREG2)     GET ADDR OF NEXT BRB OR INSERT BLOCK 54000013
         CLI   12(TREG),128        WAS THERE APREVIOUS PAUSE            54400013
*  IN INSERT BLOCK, TEST FLAGS BYTE OF WRITE IDLES CCW                  54800013
*  IN BRB, TESTS LAST HALF OF TIC CCW WHICH IS TEMPORARILY              55200013
*        USED FOR THE LCB ADDRESS, THE FIRST BYTE OF WHICH IS ZERO      55600013
*  THEREFORE FOR PREVIOUS PAUSE, AN INSERT BLOCK WILL BE DETECTED       56000013
         BC    7,NEXTCHAR+4        BRANCH IF NO                         56400013
NEXTCHAR LH    FREG,COUNT          PREVIOUS COUNT OF PAUSES             56800013
         LA    IREG,1              GET INCR OF ONE                      57200013
INDICE   BXH   WREG1,IREG,0(RREG2) BUFFER SCANNER-RTRN TO LPS VIA MACRO 57600013
         CLC   0(1,WREG1),2(RREG1) TEST FOR SPECIAL CHAR                58000013
         BC    7,INDICE            IF NO,TEST NXT CHAR                  58400013
         BCT   FREG,GETCCW         COUNT PAUSES IN THIS BUFFER          58800013
         BC    15,0(0,RREG2)       EXIT IF LIMIT IS EXCEEDED            59200013
GETCCW   STH   FREG,COUNT          STORE NEW COUNT FOR NEXT BUFFER      59600013
         LA    TREG,INSERTQ        ELSE INSERT IDLES                    60000013
         SVC   QWAIT               REQUEST INSERT BLOCK                 60400013
         ST    TREG,20(0,FREG)     STORE ADDRESS OF INSERT Q INTO       60800013
*                                        INSERT BLOCK FOR RELEASE       61200013
         LA    DREG0,1(0,WREG1)    GET ADDR OF REST OF BUFFER           61600013
AGAIN    MVC   17(3,FREG),9(WREG2) PUT POINTER TO NEXT ELEMENT INTO IB  62000013
         LR    IREG,WREG2          SAVE ADDRESS OF PREVIOUS ELEMENT     62400013
         NI    19(FREG),252        CLEAR STATUS BITS FROM TIC ADDRESS   62800013
         L     TREG,16(0,FREG)     GET ADDRESS OF NEXT BLOCK IN CHAIN   63200013
         MVC   0(4,FREG),0(TREG)   PUT COMMAND & BUFFER ADDR INTO IB    63600013
         LA    WREG1,1(0,EOSREG)   IF NEXT CCW IS NOT INSERT USE EOS    64000013
         CLI   12(TREG),128        IS THE NEXT ELEMENT AN INSERT BLOCK  64400013
         BC    7,HERE              FROM A PREVIOUS PAUSE - BRANCH IF NO 64800013
         L     WREG1,16(0,TREG)    IF IT IS GET ADDRESS OF NEXT BLOCK   65200013
         L     WREG1,0(0,WREG1)         FROM INSERT BLOCK               65600013
         LA    WREG2,8(0,TREG)     AND LOOK AT NEXT ELEMENT             66000013
         LA    WREG1,0(0,WREG1)   CLEAR HIGH ORDER BYTE FOR SUBT  23165 66200018
HERE     SR    WREG1,DREG0         GET COUNT OF CHARS IN REST OF BUFFER 66400013
         BC    4,AGAIN             BRANCH IF END OF BUFFER              66800013
         ST    DREG0,0(0,TREG)     INSERT BUFFER ADDRESS IN NEXT ELEMNT 67200013
         MVI 0(TREG),1            SET WRITE OP CODE IN CCW        23165 67400018
         STH   WREG1,6(0,TREG)     PUT COUNT IN NEXT ELEMENT            67600013
         LR    WREG1,DREG0         RESTORE SCAN REGISTER AND            68000013
         S     DREG0,0(0,FREG)     GET COUNT UP TO INSERT IDLES         68400013
         STH   DREG0,6(0,FREG)           CHARACTER                      68800013
         ST    FREG,8(0,FREG)      USE 8(FREG) AS TEMPORARY STORAGE     69200013
         MVI   12(FREG),128        SET CDA FLAG IN SECOND CCW    A37733 69400020
         XC    9(3,IREG),17(FREG)  CLEAR ADDRESS FROM PREVIOUS TIC      69600013
         OC    9(3,IREG),9(FREG)   INSERT ADDR OF CCW1 IN PREV CCW      70000013
         MVI   4(FREG),136         SET CDA & PCI FLAGS IN FIRST CCW     70400013
         LA    DREG0,3(0,RREG1)    GET ADDR OF IDLE BUFFER              70800013
         ST    DREG0,8(0,FREG)     PUT INTO INSERT CCW2                 71200013
         MVC   14(2,FREG),0(RREG1) MOVE COUNT OF IDLE CHARS TO CCW2     72000013
         MVI   16(FREG),8          INSERT TIC COMMAND                   72400013
         LA    WREG2,8(0,FREG)     AND LOOK AT NEXTCCW                  72800013
         BCT   WREG1,NEXTCHAR      LOOK FOR NEXT SPEC CHAR              73200013
* ADDITIONAL-CCW QUEUE                                                  73600013
*      QCB--PRE-ASSEMBLED IN THE MODULE(IECKPAUS)                       74000013
*      INTRODUCED THROUGH THE APPEARANCE OF THE PAUSE                   74400013
*      MACRO-INSTR IN THE MESSAGE CONTROL PROGRAM,                      74800013
*      LABELED INSERTQ.                                                 75200013
*      ELEMENT CHAIN--GENERATED IN THE PROB PROG ON                     75600013
*      EXPANSION OF THE BUFFER MACRO-INSTR LABELED                      76000013
*      IECKISRT.  A CHAIN OF SPECIAL-PURPOSE BRB'S USED TO              76400013
*      SCHEDULE AND CONTAIN CHANNEL COMMANDS FOR THE TRANSMISSION       76800013
*      OF IDLE CHARACTERS.                                              77200013
*      STCB CHAIN--MAY CONTAIN THE STCB FOR THE LPS                     77600013
*      SUBTASK.  ALWAYS ENDS WITH THE STCB FOR THE QUEUE                78000013
*      INSERT SUBTASK.                                                  78400013
INSERTQ  DS    0F                                                       78800013
         DC    FL1'1'                                                   79200013
         DC    VL3(IECKISRT)                                            79600013
         DC    A(0)                                                     80000013
         DC    AL1(2)                                                   80400013
         DC    AL3(INSERTQ+8)                                           80800013
         DC    AL1(255)                                                 81200013
         B     LIFO                                                     81600013
COUNT    DC    H'1'                                                     82000013
         EJECT                                                          82400013
         DROP  MSREG                                                    82800013
         USING IECKPREF,FREG                                            83200013
         USING TBLOCK,Y                                                 83600013
         USING QBLOCK,QREG                                              84000013
         USING TCB,TCBREG                                               84400013
QATTACH  EQU   X'48'                                                    84800013
QSAVE    EQU   X'4C'                                                    85200013
READY    EQU   X'50'                                                    85600013
IRBSAVE  EQU   X'54'                                                    86000013
WAITRB   EQU   X'58'                                                    86400013
DUMMY    EQU   X'60'                                                    86800013
NRET     EQU   X'76'                                                    87200013
         SPACE                                                          87600013
CTLPROG  DSECT                                                          88000013
         CTLPROGD                                                       88400013
         EJECT                                                          88800013
         PREFIXD                                                        89200013
         EJECT                                                          89600013
         LCBD                                                           90000013
         EJECT                                                          90400013
         QCBD                                                           90800013
         EJECT                                                          91200013
         STCBD                                                          91600013
         EJECT                                                          92000013
         TCBD                                                           92400013
         END                                                            92800013
