         TITLE 'IECKRELM   RELEASE INTERCEPTED MESSAGES (RELEASEM)'     00500013
*********************************************************************** 01000013
*                                                                     * 01500013
*NAME-                                                                * 02000013
*   IECKRELM    RELEASE INTERCEPTED MESSAGES (RELEASEM)               * 02500013
*                                                                     * 03000013
*STATUS-  CHANGE LEVEL= 18         JANUARY 1971                       * 03500021
*                                                                     * 04000013
*FUNCTION-                                                            * 04500013
*        IECKRELM RELEASES THE MESSAGES THAT WERE HELD ON THE QUEUE   * 05000013
*   OF A DESTINATION BY AN INTERCEPT MACRO INSTRUCTION FOR THAT       * 05500013
*   DESTINATION.                                                      * 06000013
*        THIS ROUTINE GETS THE ADDRESS OF THE TERMINAL TABLE AND      * 06500013
*   SCANS THE TABLE FOR THE DESTINATION SPECIFIED BY THE CALLING      * 07000013
*   ROUTINE.  IF THE DESTINATION CODE IS NOT FOUND, A RETURN CODE OF  * 07500013
*   X'20', FOR ENTRY NOT FOUND, IS PASSED TO THE CALLING ROUTINE VIA  * 08000013
*   A RETURN MACRO.                                                   * 08500013
*        IF THE INTERCEPT BIT (X'04') IS NOT ON OR RELEASEM PENDING   * 08700021
*   BIT (X'80') IS ON, CONTROL IS RETURN TO THE USER WITH A RETURN    * 08900021
*   CODE OF X'04'.  IF THE INTERCEPT BIT IS NOT ON, THE QCB ADDRESS   * 09100021
*   IS GOTTEN FROM THE TERMINAL TABLE ENTRY.  IF THE QLINK FIELD IS   * 09300021
*   ZERO, A RESTART IS IN PROGRESS AND A RELEASEM CANNOT BE DONE.     * 09500021
*   RETURN IS MADE TO THE USER WITH A RETURN CODE OF 2. THE           * 09700021
*   DCB IS RETRIEVED FROM THE QCB, AND THE ADDRESS OF LPS IS GOTTEN   * 10000013
*   FROM THE DCB.  THE OFFSET OF THE INTERCEPT FIELD IS               * 10500021
*   RETRIEVED FROM LPS ADDRESS+4. THIS VALUE IS ADDED TO THE VALUE IN * 11000013
*   THE TERMINAL TABLE BASE REGISTER TO GET THE ABSOLUTE ADDRESS OF   * 11500013
*   THE INTERCEPT FIELD FOR THIS DESTINATION.  THE RELQCB IS POSTED   * 11900021
*   TO ITSELF TO CAUSE RELSTCB SUBTASK, IN THIS MODULE, TO GAIN       * 12300021
*   CONTROL IN DISABLED STATE.                                        * 12700021
*        WHEN RELSTCB SUBTASK GAINS CONTROL, THE QCB ADDRESS IS       * 13100021
*   OBTAINED. IF THE MESSAGE HEADER ADDRESS IN THE INTERCEPT FIELD IS * 13500021
*   GREATER THAN THE MESSAGE ADDRESS IN QUEUE (QFAC), A PRIORITY      * 13900021
*   MESSAGE WAS INTERCEPTED.  EXCEPT FOR THIS PRIORITY SITUATION,     * 14300021
*   THE DISK ADDRESS SAVED IN THE INTERCEPT OPTION FIELD OF THE TERM  * 14700021
*   TABLE IS STORED IN QFAC. THIS WILL CAUSE TRANSMISSION OF MESSAGES * 15100021
*   STARTING WITH ADDRESS IN QFAC. IN ALL CASES, THE RELEASE PENDING  * 15500021
*   BIT (8) IS SET IN TSTATUS.  IF THE SEND SCHEDULER IS ACTIVE,      * 15900021
*   RETURN IS MADE TO DISPATCH NEXT ITEM.  IF SEND SCHEDULER IS NOT   * 16300021
*   ACTIVE, A PRIMER ELEMENT (IN MODULE) IS POSTED TO SEND SCHEDULER  * 16700021
*   TO CAUSE ACTIVATION OF SEND SCHEDULER.                            * 17100021
*        UPON RETURN FROM THE QPOST, RETURN IS MADE TO THE PROCESSING * 17500021
*   PROGRAM WITH A NORMAL RETURN CODE OF ZERO.                        * 17900021
*                                                                     * 19500013
*ENTRY POINTS-                                                        * 20000013
*   IECKRELM - EXPANSION OF THE RELEASEM MACRO INSTRUCTION GENERATES  * 20500013
*        A BALR TO THIS POINT, USING REGISTER 15 AS THE ENTRY POINT   * 21000013
*        REGISTER, AND REGISTER 14 AS THE RETURN REGISTER.            * 21500013
*                                                                     * 22000013
*INPUT-                                                               * 22500013
*   REGISTER  1- PARAMETER REGISTER. WILL HOLD THE ADDRESS OF THE     * 23000013
*        TERMINAL NAME.                                               * 23500013
*   REGISTER 14- RETURN ADDRESS REGISTER.                             * 24000013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 24500013
*                                                                     * 25000013
*OUTPUT-                                                              * 25500013
*   REGISTER 15- RETURN CODE.                                         * 26000013
*              X'00'- NO ERRORS                                       * 26500013
*              X'04'- TERMINAL NOT IN INTERCEPT MODE                  * 27000013
*              X'20'- TERMINAL ENTRY NOT FOUND.                       * 27500013
*              X'02'- RESTART IN PROGRESS.                            * 28500021
*                                                                     * 29500013
*EXTERNAL ROUTINES-                                                   * 30000013
*        SVC QPOST                                                    * 30500021
*                                                                     * 31000013
*EXITS-                                                               * 31500013
*   NORMAL - RETURN IS ACCOMPLISHED BY ISSUING A RETURN MACRO WITH    * 32000013
*        A RETURN CODE OF X'00'.                                      * 32500013
*   ERROR - SAME AS ABOVE, BUT WITH ONE OF THE FOLLOWING RETURN CODES:* 33000013
*        X'04'- TERMINAL NOT IN INTERCEPT MODE.                       * 33500013
*        X'20'- TERMINAL TABLE NOT FOUND.                             * 34000013
*        X'02'- RESTART IN PROGRESS.                                  * 34200021
*                                                                     * 34500013
*TABLES/WORK AREAS-                                                   * 35000013
*   NONE.                                                             * 35500013
*                                                                     * 36000013
*ATTRIBUTES-                                                          * 36500013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 37000013
*                                                                     * 37500013
*NOTES-                                                               * 38000013
*   REGISTER  2- WORK REGISTER. USED FOR PARAMETER TO QMOVE           * 38500013
*   REGISTER  3- WORK REGISTER. LENGTH FOR TSTUS CHANGE               * 39000013
*   REGISTER  4- WORK REGISTER. QCB ADDRESS. 'TO' ADDRESS FOR MOVE.   * 39500013
*   REGISTER  5- WORK REGISTER. ADDRESS OF INTERCEPT FIELD IN         * 40000013
*        TERMINAL TABLE ENTRY.                                        * 40500013
*   REGISTER  7- WORK REGISTER. ADDRESS OF TERMINAL TABLE.            * 41000013
*   REGISTER  8- BASE REGISTER FOR TERMINAL TABLE.                    * 41500013
*   REGISTER  9- WORK REGISTER.  ADDRESS OF LPS FOR THIS DESTINATION. * 42000013
*   REGISTER 11- WORK REGISTER.  ADDRESS OF LPS QUEUE.                * 42500013
*                                                                     * 43000013
*********************************************************************** 43500013
IECKRELM START                                                          44000013
*1171660000-755000,782000                                          5480 44200016
*341062000-627000,777000,786000-787000,847000                     19198 44300017
* 597000,605000,610000-620000,626000,695000-715000,782000-785000, 25340 44360018
* 787000,847060-849760,856000,857000                              25340 44420018
*A035000,087000-097000,105000,119000-179000,285000,305000,342000 S21016 44460021
FREG     EQU   1                                                        44500013
WORKREG  EQU   2                                                        45000013
XREG     EQU   3                                                        45500013
WREG     EQU   4                                                        46000013
RD       EQU   5                                                        46500013
DREG1    EQU   7                                                        47000013
TCREG    EQU   8                                                        47500013
WREG1    EQU   9                                                        48000013
WREG2    EQU   10                                                       48500013
LPSQUE   EQU   11                                                       49000013
IREG     EQU   12                                                       49500013
RREG1    EQU   14                                                       50000013
SREG     EQU   15                                                       50500013
         USING IECKTERM,TCREG                                           51000013
         USING *,SREG                                                   51500013
         SAVE    (14,12)           SAVE REGISTERS 14-12                 52000013
         SR    WREG1,WREG1         CLEAR WORKING REGISTER               52500013
         L     DREG1,16   GET COMMUNICATIONS VECTOR TABLE (CVT) ADDRESS 53000013
         L     DREG1,156(0,DREG1)  GET THE TERMTBL ADDRESS FROM THE CVT 53500013
         IC    WREG1,4(0,DREG1)    GET MAXIMUM SIZE OF TERMINAL NAME    54000013
         L     LPSQUE,4(DREG1)     GET ADDRESS OF IGG019NG              54500013
         L     LPSQUE,0(LPSQUE)    GET ADDRESS OF LPS QUEUE             55000013
         BCTR  WREG1,0             ADJUST COUNT FOR EXECUTE             55500013
         LR    TCREG,DREG1         SET UP THE BASE REGISTER FOR TERMTBL 56000013
         LA    RD,8                INITIALIZE FOR FIRST ENTRY           56500013
COMPAR1  CL    TCREG,0(0,DREG1)    IS THIS END OF TABLE                 57000013
         BE    DESTERR             BRANCH IF END OF TABLE               57500013
         AR    TCREG,RD            INDEX NEXT ENTRY                     58000013
         IC    RD,TNTRYSZE         GET ENTRY SIZE                       58500013
         EX    WREG1,DESTCK2       IS THIS CORRECT TERMINAL ENTRY       59000013
         BC    7,COMPAR1           BRANCH IF NO                         59500013
         TM    TSTATUS,12          IS TERMINAL IN INTERCEPT OR    25340 59700018
*                                   IS RELEASEM PENDING           25340 59900018
         BNM   RETURN2             EXIT IF NOT INTERCEPTED OR     25340 60100018
*                                   IF RELEASEM PENDING WITH X'04'25340 60300018
*                                   RETURN CODE                   25340 60500018
         L     WREG,TQCBADDR-1     GET QCB ADDRESS FROM TABLE ENTRY     62500013
         CLC   QLINK-QBLOCK(3,WREG),ZEROS  IS RESTART IN PROGRESS 19198 62600018
         BNE   RETURN3            YES,DO NOT RELEASE              19198 62700017
         L     WREG1,16(0,WREG)    GET DCB ADDRESS FROM THE QCB         63000013
         L     WREG1,20(0,WREG1)   GET LPS ADDRESS FROM THE DCB         63500013
         IC    RD,4(0,WREG1)       GET OFFSET TO INTERCEPT FIELD        64000013
*                                    (STORED BY THE INTERCEPT ROUTINE)  64500013
         AR    RD,TCREG            ADD IN TERMINAL ENTRY ADDRESS TO GET 65000013
*                                    ADDRESS OF INTERCEPT FIELD         65500013
         LR    WREG,TCREG          COPY ADDRESS OF TERMTBL ENTRY   5480 68500016
         STM   WREG,RD,SAVE        SAVE REGISTERS FOR SUBTASK     25340 69500018
         LA    FREG,RELSTCB        SET R1 FOR QPOST               25340 70500018
         LR    WORKREG,FREG        SET R2 FOR QPOST               25340 71500018
         SVC   QPOST               CAUSE TSTATUS TO BE CHANGED          76000013
         RETURN  (14,12),RC=0      SET X'00' FOR NORMAL RETURN          76500013
DESTERR  RETURN  (14,12),RC=32     SET X'20' FOR ENTRY NOT FOUND        77000013
RETURN2  RETURN  (14,12),RC=4      SET X'04' TERMINAL NOT IN INTERCEPT  77500013
RETURN3  RETURN  (14,12),RC=2     SET RETURN CODE                19198  77700017
*                                                                       78000013
ZEROS    DC    X'000000'                                          19198 78600017
QPOST    EQU   67                                                       79000013
CVTABLE  EQU   16                                                       79500013
CVTTRMTB EQU   156                                                      80000013
*                                                                       80500013
*                                                                       81000013
DESTCK2  CLC   TERMID(1),0(FREG)   COMPARE TERMINAL NAME                81500013
         SPACE                                                          82000013
*  THE FOLLOWING ERROR FLAGS ARE PASSED TO THE USER RIGHT ADJUSTED      82500013
*    IN REGISTER 15 BY THIS ROUTINE                                     83000013
*                  X'00'    NO ERRORS                                   83500013
*                  X'04'    TERMINAL NOT IN INTERCEPT                   84000013
*                  X'20'    TERMINAL ENTRY NOT FOUND                    84500013
*                  X'02'   RELEASE CANNOT BE DONE DURING RESTART  19198 84700017
         EJECT                                                          84706018
*                                                                 25340 84712018
*        THE FOLLOWING SUBTASK IS ACTIVATED TO CHANGE THE TSTATUS 25340 84718018
*  FIELD OF THE TERMTABLE ENTRY, RESET QFAC IN THE QCB, AND POST  25340 84724018
*  A PRIMER ELEMENT TO THE SEND SCHEDULER TO START SENDING TO THE 25340 84730018
*  RELEASED TERMINAL                                              25340 84736018
*                                                                 25340 84742018
RELSTCB  DC    A(RELSTCB)                                         25340 84748018
         DC    X'FE'                                              25340 84754018
         DC    AL3(RELSTCB)                                       25340 84760018
RELQCB   DC    X'02'                                              25340 84766018
         DC    AL3(RELQCB)                                        25340 84772018
         DC    X'FF00'                                            25340 84778018
         USING RELQCB,WORKREG                                     25340 84784018
         USING QBLOCK,DREG1                                       25340 84790018
         LM    WREG,RD,SAVE        RELOAD SAVED REGISTERS         25340 84796018
         L     DREG1,0(WREG)       GET QCB ADDRESS                25340 84802018
         CLC   QFAC(3),0(RD)       COMPARE MESSAGE HEADER ADDRESS 25340 84808018
*                                   IN TERMTBL INTERCPT FIELD TO  25340 84814018
*                                   ADDRESS OF THE FIRST ELEMENT  25340 84820018
*                                   IN THE QUEUE                  25340 84826018
         BNH   *+10                BRANCH IF HEADER ADDRESS IS    25340 84832018
*                                   GREATER THAN MESSAGE ADDRESS  25340 84838018
*                                   IN QUEUE (PRIORITY MESSAGES   25340 84844018
*                                   HAVE BEEN INTERCEPTED)        25340 84850018
         MVC   QFAC(3),0(RD)       UPDATE QFAC WITH NEW RRN       25340 84856018
         OI    TSTATUS-IECKTERM(WREG),8  SHOW RELEASEM PENDING    25340 84862018
*                                   (TESTED IN DISK-END)          25340 84868018
         L     WREG,QTRAN          GET STCB POINTER FROM QCB      25340 84874018
         CLI   0(WREG),X'68'       IS THE SEND SCHEDULER ACTIVE   25340 84880018
         BNE   DISPATCH(IREG)      YES, RETURN TO DISPATCH NEXT   25340 84886018
*                                   READY ITEM                    25340 84892018
         LA    FREG,PRIMER         PUT PRIMER ADDRESS IN R1       25340 84898018
         LA    WORKREG,0(0,DREG1)  QCB ADDRESS TO R2 (NOTE, THIS  25340 84904018
*                                   DESTROYS THE BASE REGISTER)   25340 84910018
         B     POST(IREG)          GO TO POST PRIMER TO SNED      25340 84916018
*                                   SCHEDULER                     25340 84922018
         SPACE 3                                                        84928018
PRIMER   DC    A(PRIMER)                                          25340 84934018
         DC    X'FE'                                              25340 84940018
         DC    AL3(PRIMER)                                        25340 84946018
         SPACE 3                                                        84952018
SAVE     DS    2F                                                 25340 84958018
         SPACE 3                                                        84964018
POST     EQU   X'80'                                              25340 84970018
DISPATCH EQU   X'F6'                                              25340 84976018
         EJECT                                                          85000013
         TERMTBLD                                                       85500013
         EJECT                                                          85600018
         QCBD                                                           85700018
         END                                                            86000013
