         TITLE 'IECKRETD  QTAM RETRIEVE-DASD (RETRIEVE)'                00500013
*********************************************************************** 01000013
*                                                                     * 01500013
*NAME-                                                                * 02000013
*   IECKRETD     QTAM RETREIVE-DASD                                   * 02500013
*                                                                     * 03000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 03500013
*                                                                     * 04000013
*FUNCTION-                                                            * 04500013
*        CAUSES A MESSAGE SEGMENT TO BE RETRIEVED AND PLACED IN THE   * 05000013
*   CALLING PROGRAM'S WORK AREA (SPECIFIED AS THE SECOND OPERAND OF   * 05500013
*   THE RETRIEVE MACRO) WHEN A REGISTER IS SPECIFIED AS THE FIRST     * 06000013
*   OPERAND OF THE MACRO.  THE SPECIFIED REGISTER MUST CONTAIN THE    * 06500013
*   DIRECT ACCESS DEVICE ADDRESS OF THE MESSAGE SEGMENT TO BE         * 07000013
*   RETRIEVED.  THE SEGMENT IS RETRIEVED FROM THE DASD DESTINATION    * 07500013
*   OR PROCESS QUEUES AND PLACED INTO THE WORK AREA.  THE REGISTERS   * 08000013
*   ARE STORED IN THE SAVE AREA POINTED TO BY REGISTER 13.            * 08500013
*        IF AN INVALID DISK ADDRESS IS RECEIVED (IF THE ADDRESS IS    * 09000013
*   GREATER THAN THE LAST ONE ASSIGNED), AN ERROR CODE OF A X'02'     * 09500013
*   IS PLACED IN REGISTER 15 AND RETURN IS TO THE NEXT INSTRUCTION    * 10000013
*   IN THE PROCESSING PROGRAM.                                        * 10500013
*        A COMBINATION BRB AND QCB IS BUILT IN THE CALLING ROUTINES'S * 11000013
*   WORK AREA AS FOLLOWS:                                             * 11500013
*        1) THE ADDRESS OF THE QUEUE-INSERT-BY-PRIORITY-STCB IS       * 12000013
*              PLACED IN THE QTRAN FIELD AT WORK AREA + 12.           * 12500013
*        2) THE DIRECT ACCESS ADDRESS IS PLACED IN THE BRB AT WORK    * 13000013
*              AREA + 16 AS THE RELATIVE RECORD ADDRESS OF THE NEXT   * 13500013
*              SEGMENT TO BE READ.                                    * 14000013
*        3) A X'09' IS PLACED IN THE MSTATUS FIELD OF THE BRB (AT     * 14500013
*              WORK AREA + 16) TO INDICATE THAT A DISK RECORD IS TO   * 15000013
*              BE READ.                                               * 15500013
*        4) THE PRIORITY AT WORK AREA + 8 IS SET TO A X'E4'.          * 16000013
*   THE BRB/QCB IS THEN POSTED (SVC 67) TO THE DISK QUEUE AND A       * 16500013
*   WAIT (SVC 65) IS ISSUED TO AWAIT DISK I/O COMPLETION.  ANOTHER    * 17000013
*   WAIT IS ISSUED TO ENSURE THAT THE BRB/QCB IS OFF THE READY QUEUE  * 17500013
*   SO THE WORK AREA CAN BE USED.  THE MESSAGE IS THEN MOVED INTO THE * 18000013
*   WORK AREA AND THE BUFFER IS MADE AVAILABLE AGAIN BY POSTING IT    * 18500013
*   TO THE AVAIABLE BUFFER QUEUE.  THEN THE REGISTERS ARE RESTORED    * 19000013
*   EXCEPT REGISTER 15 AND RETURN IS TO THE NEXT INSTRUCTION IN THE   * 19500013
*   CALLING ROUTINE.  REGISTER 15 NOW CONTAINS EITHER A CODE OF ZERO, * 20000013
*   SIGNIFYING COMPLETION OF RETRIEVAL, OR A CODE OF X'02', SIGNIFING * 20500013
*   THAT AN INVALID DIRECT ACCESS ADDRESS WAS PASSED.                 * 21000013
*                                                                     * 21500013
*ENTRY POINTS-                                                        * 22000013
*   IECKRETD - EXPANSION OF THE RETRIEVE MACRO WITH A REGISTER NAME   * 22500013
*              OR NUMBER ENCLOSED IN PARENTHESIS GIVEN AS THE FIRST   * 23000013
*              OPERAND GENERATES A BALR TO THIS POINT USING REGISTER  * 23500013
*              15 AS THE ENTRY POINT REGISTER AND REGISTER 14 AS THE  * 24000013
*              RETURN REGISTER.  ALTERNATE ENTRY IS FROM IECKRETS.    * 24500013
*                                                                     * 25000013
*INPUT-                                                               * 25500013
*   REGISTER  0- CONTAINS THE ADDRESS OF THE WORK AREA INTO WHICH     * 26000013
*              THE MESSAGE IS TO BE PLACED.                           * 26500013
*   REGISTER  1- CONTAINS THE DIRECT ACCESS ADDRESS OF THE MESSAGE    * 27000013
*              SEGMENT TO BE RETRIEVED.                               * 27500013
*   REGISTER 14- RETURN ADDRESS.                                      * 28000013
*   REGISTER 15- ENTRY POINT.                                         * 28500013
*                                                                     * 29000013
*OUTPUT-                                                              * 29500013
*   THE MESSAGE SEGMENT IS MOVED TO THE WORK AREA SPECIFIED IN THE    * 30000013
*              SECOND OPERAND OF THE RETRIEVE MACRO, UNLESS AN        * 30500013
*              INVALID DISK ADDRESS IS SPECIFIED, IN WHICH CASE A     * 31000013
*              CODE OF X'02' IS RETURNED IN REGISTER 15.              * 31500013
*   REGISTER 15- RETURN CODE OF X'00' FOR SEGMENT FOUND OR X'02' FOR  * 32000013
*              INVALID DIRECT ACCESS ADDRESS SPECIFIED.               * 32500013
*                                                                     * 33000013
*EXTERNAL ROUTINES-                                                   * 33500013
*   QWAIT- IGG065 IN MODULE IECKQQ01 TO WAIT FOR DISK I/O COMPLETION  * 34000013
*              AND TO WAIT FOR THE BRB/QCB TO BE REMOVED FROM THE     * 34500013
*              READY QUEUE.                                           * 35000013
*   QPOST-IGG067 IN MODULE IECKQQ01 TO POST THE BRB/QCB TO THE DISK   * 35500013
*              I/O QUEUE AND TO POST THE BUFFER USED TO THE ACTIVE    * 36000013
*              BUFFER QUEUE.                                          * 36500013
*                                                                     * 37000013
*EXITS-                                                               * 37500013
*   NORMAL- RETURN TO NEXT INSTRUCTION IN THE CALLING ROUTINE WITH    * 38000013
*              A CODE OF ZERO IN REGISTER 15.                         * 38500013
*   ERROR- RETURN TO NEXT INSTRUCTION IN THE CALLING ROUTINE WITH A   * 39000013
*              CODE OF X'02' IN REGISTER 15.                          * 39500013
*                                                                     * 40000013
*TABLES/WORK AREAS-                                                   * 40500013
*   NONE.                                                             * 41000013
*                                                                     * 41500013
*ATTRIBUTES-                                                          * 42000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 42500013
*                                                                     * 43000013
*NOTES-                                                               * 43500013
*   INTERNAL REGISTER USAGE IS AS FOLLOWS:                            * 44000013
*        REGISTER  1- CONTAINS BUFFER ADDRESS ON RETURN FROM QWAIT,   * 44500013
*                     WHICH IS USED AS INPUT TO QPOST.                * 45000013
*        REGISTER  2- CONTAINS RETURN CODE TO BE PLACED IN REGISTER   * 45500013
*                     15.                                             * 46000013
*        REGISTER  3- CONTAINS BRB/QCB ADDRESS FOR SETTING UP BRB/QCB.* 46500013
*        REGISTER  4- USED TO SAVE THE BUFFER ADDRESS RETURNED FROM   * 47000013
*                     QWAIT.                                          * 47500013
*        REGISTER  5- LOADED WITH ADDRESS OF IGG019NG.                * 48000013
*        REGISTER  6- LOADED WITH SIZE OF MESSAGE SEGMENT -1, USED    * 48500013
*                     TO EXECUTE MOVE TO PLACE SEGMENT IN WORK AREA.  * 49000013
*        REGISTER 10- LOADED WITH ADDRESS OF QUEUES IN IGG019NG.      * 49500013
*        REGISTER 12- LOADED WITH ADDRESS OF CVT.                     * 50000013
*        REGISTER 15- BASE REGISTER FOR THIS ROUTINE.                 * 50500013
*                                                                     * 51000013
*********************************************************************** 51500013
IECKRETD START                                                          52000013
*3410836000-843000,932000                                          8833 52200019
* 833000,967000                                                  A28773 52300019
R0     EQU     0   ADDR OF USER SPECIFIED WORK AREA AT ENTRY TO MODULE  52500013
FREG     EQU   1                                                        53000013
TREG     EQU   2                                                        53500013
QREG     EQU   3                                                        54000013
DREG     EQU   4                                                        54500013
SAVREG   EQU   5                                                        55000013
WREG2    EQU   6                                                        55500013
WREG0    EQU   9               CONTENTS OF R0 AT ENTRY                  56000013
RC       EQU   10              BASE REG FOR QUEUES IN IGG019NG          56500013
RD       EQU   12                                                       57000013
RETR     EQU   14                                                       57500013
SREG     EQU   15                                                       58000013
*                                                                       58500013
QWAIT    EQU   65                                                       59000013
QPOST    EQU   67                                                       59500013
*                                                                       60000013
* UPON ENTRY REGISTER 1 CONTAINS THE  3-BYTE RECORD ADDRESS             60500013
* REGISTER 0 CONTAINS THE  ADDRESS OF THE WORKAREA                      61000013
         SPACE                                                          61500013
         USING *,SREG                                                   62000013
         SAVE    (14,12)                                                62500013
         L     RD,CVTABLE(0,0)     GET ADDRESS OF COMM VECT TABLE       63000013
         L     RC,CVTTRMTB(0,RD)   GET TERMTBL ADDRESS FROM CVT         63500013
         L     SAVREG,TTQUES(0,RC)  GET ADDR OF IGG019NG                64000013
         L     RC,0(0,SAVREG)   GET ADDR OF QUEUES FROM IGG019NG WORD 1 64500013
*                                                                       65000013
*      TEST FOR VALID DISK ADDRESS                                      65500013
*                                                                       66000013
         C     FREG,196(RC)            DISK ADDRESS TO LAST ASSIGNED    66500013
         LA    TREG,2                  LOAD ERROR CODE                  67000013
         BH    RET                     BRANCH ON INVALID ADDRESS        67500013
*                                                                       68000013
*      BUILD A BRB/QCB IN USERS WORK AREA                               68500013
*                                                                       69000013
         LR    QREG,R0                 COPY ADDRESS OF THE WORKAREA     69500013
         LA    QREG,4(QREG)            ADD FOUR TO ADDRESS              70000013
         SRL   QREG,2                  ASSURE FULL WORD BOUNDRY         70500013
         SLL   QREG,2                  ASSURE FULL WORD BOUNDRY         71000013
         LA    TREG,QPRIRTY(0,RC)  GET ADDRESS OF QUEUE-INSERT-         71500013
*                                        BY-PRIORITY-STCB               72000013
         ST    TREG,8(0,QREG)   QTRAN (ADDR OF STCB)                    72500013
         ST    FREG,12(QREG)           PUT DASD ADDR INTO QCB/BRB       73000013
         MVI   12(QREG),9          9 IN MSTATUS-DISK RECORD TO BE READ  73500013
*                                                                       74000013
*      POST THE BRB/QCB TO THE DISK QUEUE                               74500013
*                                                                       75000013
         MVI   4(QREG),X'E4'           SET PRIOROITY                    75500013
         LA    TREG,DISK(0,RC)   DISK I/O STCB ADDR                     76000013
         LR    FREG,QREG               QCB/BRB ADDRESS TO FREG          76500013
         SVC   QPOST               POST BRB-QCB TO DISK QUEUE           77000013
*                                                                       77500013
*  QWAIT QCB NOW CREATED FROM BRB                                       78000013
*  WAIT FOR DISK COMPLETION                                             78500013
*                                                                       79000013
         LR    TREG,QREG   QCB ADDR TO TREG                             79500013
         SVC   QWAIT           WAIT FOR DISK I/O COMPLETION             80000013
         LR    DREG,FREG               SAVE THE BUFFER ADDRESS          80500013
         LA    TREG,QATTACH(0,SAVREG)  TREG HAS ADDR QATTACH QCB        81000013
         SVC   QWAIT                   ASSURE THE BRB/QCB IS OFF READY  81500013
         SPACE                                                          82000013
*  ON RETURN, DREG CONTAINS ADDR OF RECORD RETRIEVED FROM DISK          82500013
         USING IECKPREF,DREG                                            83000013
         LH    WREG2,BUFSIZE(RC)   USE BUFFER SIZE FOR MOVE      A28773 83300019
         LR    QREG,R0                                             8833 83600019
         LR    FREG,DREG     BUFFER ADDR TO FREG FOR POST          8833 83700019
         CH    WREG2,H256         IS BUFFER SIZE GREATER THAN256   8833 83800019
         BNH   LESS               BRANCH IF LESS OR EQUAL          8833 83900019
         MVC   0(256,QREG),FDATA-FBLOCK(DREG)  MOVE 256 OF BUFFER  8833 84000019
         AH    DREG,H256     ADD 256 TO BUFFER ADDR FOR NEXT MOVE  8833 84100019
         AH    QREG,H256      ADD 256 TO WORK AREA                 8833 84200019
LESS     BCTR  WREG2,0            SUBTRACT ONE FOR EXECUTE         8833 84300019
         EX    WREG2,MOVSEG        EXECUTE MOVE                         85000013
*                                                                       85500013
*    RETURN BUFFER TO AVAILABLE BUFFER QUEUE                            86000013
*                                                                       86500013
         LA    TREG,BUFFER(0,RC)   GET ADDR OF AVAILABLE BUFFER QUEUE   87500013
         SVC   QPOST             POST BUFFER TO AVAILABLE BUFFER QUEUE  88000013
*                                                                       88500013
*      RETURN TO THE CALLER                                             89000013
*                                                                       89500013
         SR    TREG,TREG               SET VALID COMPLECTION CODE       90000013
RET      LR    15,TREG                 COMPLECTION CODE TO REGISTER 15  90500013
         RETURN (0,12)                                                  91000013
*                                                                       91500013
MOVSEG   MVC   0(0,QREG),FDATA-FBLOCK(DREG) MOVE SEG. TO WORK AREA      92000013
*                                                                       92500013
CVTABLE  EQU   16                                                       93000013
H256     DC    H'256'                                              8833 93200019
CVTTRMTB EQU   156                                                      93500013
TTQUES    EQU   4                                                       94000013
*                                                                       94500013
BUFFER   EQU   24              AVAILABLE BUFFER QCB                     95000013
DISK     EQU   36              DISK I/O QCB                             95500013
QPRIRTY  EQU   60              QUEUE INSERT BY PRIORITY STCB            96000013
QATTACH  EQU   72              QATTACH QCB                              96500013
BUFSIZE  EQU   154                                                M3621 96700019
*                                                                       97000013
         EJECT                                                          97500013
         PREFIXD                                                        98000013
         END                                                            98500013
