         TITLE ' QTAM RETRIEVE BY SEQUENCE NUMBER '                     00300013
*********************************************************************** 00600013
*                                                                     * 00900013
*NAME-                                                                * 01200013
*   IECKRETS     QTAM RETRIEVE BY SEQUENCE NUMBER                     * 01500013
*                                                                     * 01800013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 02100013
*                                                                     * 02400013
*FUNCTION-                                                            * 02700013
*        CAUSES A MESSAGE SEGMENT TO BE RETRIEVED AND PLACED IN THE   * 03000013
*   CALLING PROGRAM'S WORK AREA (SPECIFIED AS THE SECOND OPERAND OF   * 03300013
*   THE RETRIEVE MACRO) WHEN THE FIRST OPERAND OF THE MACRO IS THE    * 03600013
*   NAME OF THE DESTINATION TERMINAL TO WHICH THE MESSAGE SEGMENT     * 03900013
*   WAS SENT.  THE PURPOSE OF THIS ROUTINE IS TO PROVIDE THE PROPER   * 04200013
*   REGISTER SETUP FOR USE BY IECKRETD, WHICH RETRIEVES THE MESSAGE   * 04500013
*   WHEN REGISTER ONE CONTAINS THE DIRECT ACCESS ADDRESS OF THE       * 04800013
*   MESSAGE SEGMENT AND REGISTER 0 CONTAINS THE ADDRESS OF THE WORK   * 05100013
*   AREA INTO WHICH THE MESSAGE IS TO BE PLACED.  THE ROUTINE SAVES   * 05400013
*   ALL THE REGISTERS AND PLACES THE ADDRESS OF IT'S OWN SAVE AREA    * 05700013
*   INTO REGISTER 13 FOR USE BY IECKRETD.                             * 06000013
*        THE CVT (COMMUNICATIONS VECTOR TABLE) PROVIDES THE ADDRESS   * 06300013
*   OF THE TERMINAL TABLE AT CVT + 156.  THE TERMINAL TABLE IS        * 06600013
*   SEARCHED FOR A MATCHING DESTINATION NAME.  IF THERE IS NO         * 06900013
*   MATCHING NAME, A CODE OF X'20' IS PLACED IN REGISTER 15 AND       * 07200013
*   RETURN IS TO THE NEXT INSTRUCTION IN THE CALLING ROUTINE.  IF     * 07500013
*   A MATCHING NAME IS FOUND, THE OFFSET OF THE ENTRY FROM THE        * 07800013
*   START OF THE TERMINAL TABLE IS SAVED AND THE DESTINATION QUEUE    * 08100013
*   ADDRESS IS OBTAINED FROM THE TERMINAL TABLE ENTRY.  THE DISK      * 08400013
*   ADDRESS FOR THE START OF THE SEARCH IS THEN OBTAINED FROM THE     * 08700013
*   DESTINATION QUEUE.  THE ADDRESS OF THE SEQUENCE FIELD (EITHER     * 09000013
*   IN OR OUT AS DESIGNATED BY A NEGATIVE OR POSTITIVE NUMBER         * 09300013
*   RESPECTIVELY) IS COMPUTED, AND THE ROUTINE BRANCHES TO IECKRETD   * 09600013
*   TO RETRIEVE THE NEXT SEGMENT OF THE MESSAGE, UNLESS THE DIRECT    * 09900013
*   ACCESS ADDRESS IS ZERO, IN WHICH CASE THE REGISTERS ARE RESTORED  * 10200013
*   AND RETURN IS TO THE NEXT INSTRUCTION IN THE CALLING ROUTINE      * 10500013
*   WITH A CODE OF X'40' IN REGISTER 15.  IF THE SEQUENCE NUMBER      * 10800013
*   SPECIFIED BY THE CALLING ROUTINE IS GREATER THAN THE SEQUENCE     * 11100013
*   NUMBER OF THE RETRIEVED MESSAGE OF IF THE RETRIEVED MESSAGE WAS   * 11400013
*   A PRIORITY MESSAGE, THE NEXT MESSAGE IS OBTAINED BY IECKRETD.     * 11700013
*   THIS PROCESS CONTINUES UNTIL EITHER THE MESSAGE IS FOUND OR A     * 12000013
*   MESSAGE THAT IS NOT A PRIORITY MESSAGE WHICH HAS A LARGER         * 12300013
*   SEQUENCE NUMBER THAN THE ONE GIVEN BY THE CALLING ROUTINE.  THE   * 12600013
*   LATTER INDICATES AN INVALID SEQUENCE NUMBER AND IN THIS CASE      * 12900013
*   THE REGISTERS ARE RESTORED AND RETURN IS TO THE NEXT INSTRUCTION  * 13200013
*   IN THE CALLING ROUTINE WITH A CODE OF X'40' IN REGISTER 15.  IF   * 13500013
*   THE SEQUENCE NUMBER IS ZERO, WHICH INDICATES AN ERROR MESSAGE, THE* 13530000
*   SEARCH CONTINUES FOR THE MESSAGE IN ERROR. IN ORDER TO RETRIEVE   * 13560000
*   INTERCEPTED MESSAGES, THE FOLLOWING TESTS ARE MADE. IF THE MESSAGE* 13590000
*   IS NOT SERVICED AND FOR SEQUENCE OUT, THE RETRIEVE IS INVALID.    * 13620000
*   IF THE MESSAGE IS SERVICED AND FOR SEQUENCE OUT OR THE RETRIEVE   * 13650000
*   IS FOR SEQUENCE IN, A CHECK IS MADE FOR COMPLETE MESSAGE RECEIVED.* 13680000
*   IF LINE IS SENDING OR PARTIAL MSG BIT OFF, THEN MSG IS VALID. IF  * 13710000
*   THE PROPER SEQUENCE NUMBER IS FOUND, THE MESSAGE SEGMENT IS       * 13800013
*   MOVED TO THE CALLING ROUTINE'S WORK AREA (THIS IS DONE BY         * 14100013
*   IECKRETD), THE REGISTERS ARE RESTORED, AND RETURN IS TO THE NEXT  * 14400013
*   INSTRUCTION IN THE CALLING ROUTINE WITH A CODE OF ZERO IN         * 14700013
*   REGISTER 15.                                                      * 15000013
*                                                                     * 15300013
*ENTRY POINTS-                                                        * 15600013
*   IECKRETS - EXPANSION OF THE RETRIEVE MACRO WITH A DESTINATION     * 15900013
*              TERMINAL NAME AS THE FIRST OPERAND GENERATES A BALR    * 16200013
*              TO THIS POINT USING REGISTER 15 AS THE ENTRY POINT     * 16500013
*              REGISTER AND REGISTER 14 AS THE RETURN REGISTER.       * 16800013
*                                                                     * 17100013
*INPUT-                                                               * 17400013
*   REGISTER  0- ADDRESS OF THE WORK AREA INTO WHICH THE MESSAGE      * 17700013
*              SEGMENT IS TO BE PLACED.  THE DESTINATION TERMINAL     * 18000013
*              NAME WILL START IN THE FIRST BYTE OF THIS WORK AREA.   * 18300013
*                                                                     * 18600013
*OUTPUT-                                                              * 18900013
*   THE REQUESTED MESSAGE SEGMENT WILL BE MOVED TO THE WORK AREA      * 19200013
*              SPECIFIED AS THE SECOND OPERAND OF THE RETRIEVE        * 19500013
*              MACRO, UNLESS AN ERROR OCCURS, IN WHICH CASE THE       * 19800013
*              FOLLOWING RETURN CODES ARE PLACED IN REGISTER 15:      * 20100013
*                X'00' INDICATES NO ERRORS.                           * 20400013
*                X'20' INDICATES INVALID DESTINATION TERMINAL NAME.   * 20700013
*                X'40' INDICATES INVALID SEQUENCE NUMBER.             * 21000013
*                                                                     * 21300013
*EXTERNAL ROUTINES-                                                   * 21600013
*   IECKRETD - TO RETRIEVE THE MESSAGE SEGMENT BY DIRECT ACCESS       * 21900013
*              ADDRESS.                                               * 22200013
*                                                                     * 22500013
*EXITS-                                                               * 22800013
*   NORMAL- RETURN IS TO NEXT INSTRUCTION IN THE CALLING ROUTINE WITH * 23100013
*              THE REQUESTED MESSAGE CONTAINED IN THE WORK AREA AND   * 23400013
*              A CODE OF X'00' IN REGISTER 15.                        * 23700013
*   ERROR- RETURN IS TO THE NEXT INSTRUCTION IN THE CALLING ROUTINE   * 24000013
*              WITH ONE OF THE FOLLOWING CODES IN REGISTER 15:        * 24300013
*                X'20' INDICATING INVALID DESTINATION TERMINAL NAME.  * 24600013
*                X'40' INDICATING INVALID SEQUENCE NUMBER.            * 24900013
*                                                                     * 25200013
*TABLES/WORK AREAS-                                                   * 25500013
*   SECOND - A WORK AREA USED AS A SAVE AREA FOR REGISTERS DURING     * 25800013
*              SECOND LEVEL LINKAGE TO IECKRETD.                      * 26100013
*                                                                     * 26400013
*ATTRIBUTES-                                                          * 26700013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 27000013
*                                                                     * 27300013
*NOTES-                                                               * 27600013
*   INTERNAL REGISTER USAGES ARE AS FOLLOWS:                          * 27900013
*        REGISTER  1- USED FOR INTERNAL LINKAGE TO A ROUTINE WHICH    * 28200013
*                     CHECKS THE SEQUENCE NUMBER FOR VALIDITY WHEN    * 28500013
*                     EACH MESSAGE IS OBTAINED.                       * 28800013
*        REGISTER  2- LOADED WITH ADDRESS OF TERMINAL TABLE.          * 29100013
*        REGISTER  3- BASE REGISTER FOR THIS ROUTINE.                 * 29400013
*        REGISTER  4- LOADED WITH ADDRESS OF SEQUENCE NUMBER FIELD    * 29700013
*                     OF HEADER                                       * 30000013
*        REGISTER  5- LOADED WITH ADDRESS OF TERMINAL TABLE ENTRY.    * 30300013
*        REGISTER  6- LOADED WITH RETURN ADDRESS OF INTERNAL ROUTINE  * 30600013
*                     WHICH GETS THE NEXT RECORD.                     * 30900013
*        REGISTER  7- LOADED WITH CODE OF ZERO FOR SEQUENCE IN FIELD  * 31200013
*                     TO BE COMPARED WITH NUMBER PASSED IN REGISTER   * 31500013
*                     1 AND X'02' FOR SEQUENCE OUT FIELD.             * 31800013
*        REGISTER  8- LOADED WITH LENGTH OF TERMID FOR COMPARE AND    * 32100013
*                     USED TO COMPUTE OFFSET OF TABLE ENTRY FROM      * 32400013
*                     BEGINNING OF TERMINAL TABLE.                    * 32700013
*        REGISTER  9- USED TO SAVE WORK AREA ADDRESS PASSED IN        * 33000013
*                     REGISTER 0.                                     * 33300013
*        REGISTER 10- USED TO SAVE POSITIVE SEQUENCE NUMBER PASSED    * 33600013
*                     IN REGISTER 1.                                  * 33900013
*        REGISTER 11- USED TO SAVE MSHEAD FIELD OF HEADER WHICH       * 34200013
*                     CONTAINS DISK ADDRESS OF PREVIOUS MESSAGE       * 34500013
*                     HEADER.                                         * 34800013
*        REGISTER 12- USED TO SAVE MSLINK FIELD OF HEADER WHICH       * 35100013
*                     CONTAINS DISK ADDRESS OF NEXT MESSAGE HEADER.   * 35400013
*        REGISTER 13- LOADED WITH ADDRESS OF THIS ROUTINE'S SAVE AREA.* 35700013
*        REGISTER 14- SECOND LEVEL RETURN REGISTER FROM IECKRETD.     * 36000013
*        REGISTER 15- SECOND LEVEL ENTRY POINT REGISTER TO IECKRETD.  * 36300013
*                                                                     * 36600013
*********************************************************************** 36900013
IECKRETS START                                                          37200013
*1171699000-702000                                                 5619 37300000
*1171757000-758000                                                 00PS 37400000
*1201758300-758600                                                22427 37450000
* 626000                                                         A27523 37500000
* 758320-758800,444300-446400                                      00PS 37550000
* 625000-626000                                                   M3161 37600000
* 553000                                                           00PS 37630000
* 758426-758432,758583-758595                                    A31038 37660000
R0       EQU   0                                                        37700000
FREG     EQU   1                                                        37800013
TREG     EQU   2                                                        38100013
BASE     EQU   3                                                        38400013
HEAD     EQU   4                                                        38700013
TERM     EQU   5                                                        39000013
NEXT     EQU   6                                                        39300013
IO       EQU   7                                                        39600013
OFF      EQU   8                                                        39900013
AREA     EQU   9                                                        40200013
SEQ      EQU   10                                                       40500013
LINK     EQU   11                                                       40800013
DASD     EQU   12                                                       41100013
SAVE     EQU   13                                                       41400013
RET      EQU   14                                                       41700013
CODE     EQU   15                                                       42000013
INVALID  EQU   32                                                       42300013
CVTTRMTB EQU   156                                                      42600013
BADSEQ   EQU   64                                                       42900013
QBACK    EQU   29                                                       43200013
MSLINK   EQU   8                                                        43500013
TTSKEY   EQU   2                                                        43800013
TTDKEY   EQU   18                                                       44100013
MSTATUS  EQU   4                                                        44400013
TQCB     EQU   0                                                   00PS 44430000
QPRI     EQU   4                                                 A31038 44437000
QRET     EQU   8                                                 A31038 44444000
QPROC    EQU   12                                                A31038 44451000
QDCB     EQU   17                                                  00PS 44460000
QRLN     EQU   16                                                  00PS 44490000
DCBEIOBX EQU   36                                                  00PS 44520000
DCBLCBAD EQU   32                                                  00PS 44550000
MSLCB    EQU   5                                                   00PS 44580000
LCBSTATE EQU   0                                                   00PS 44610000
LCBCHDR  EQU   16                                                  00PS 44640000
         SAVE  (14,12)                                                  44700013
         BALR  BASE,0                                                   45000013
         USING *,BASE                                                   45300013
         ST    SAVE,SECOND+4      SAVE ADDRESS OF SAVE AREA             45600013
         LA    SAVE,SECOND        LOAD ADDRESS OF NEW SAVE AREA         45900013
*                                                                       46200013
*      INITIALIZE IN/OUT REGISTER TO INDICATE SEQUENCE IN OR OUT        46500013
*                                                                       46800013
         LA    IO,2               INITIALIZE FOR SEQUENCE OUT           47100013
         LPR   SEQ,FREG           POSITIVE SEQUENCE NUMBER TO WORK REG. 47400013
         LTR   FREG,FREG          TEST SEQUENCE NUMBER PARAMETER        47700013
         BP    SETSEQ             BRANCH REGISTER POSITIVE (SEQ. OUT)   48000013
         SR    IO,IO              SET IN/OUT REGISTER TO SEQUENCE IN    48300013
*                                                                       48600013
*        LOCATE CORRECT ENTRY IN THE TERM TABLE                         48900013
*                                                                       49200013
SETSEQ   LR    AREA,R0            WORKAREA ADDRESS TO WORK REGISTER     49500013
         LA    CODE,INVALID       RETURN CODE IF TERMINAL NOT FOUND     49800013
         L     TREG,16            ADDRESS OF THE CVT                    50100013
         L     TREG,CVTTRMTB(TREG) ADDRESS OF QTAM TERMINAL TABLE       50400013
         L     LINK,0(TREG)       ADDRESS OF LAST TERM TABLE ENTRY      50700013
         LA    LINK,0(LINK)       CLEAR THE HIGH ORDER BYTE             51000013
         LR    TERM,TREG          TERM TABLE ADDRESS TO WORK REGISTER   51300013
         LA    HEAD,8             INITIALIZE LENGTH REGISTER            51600013
         IC    OFF,4(TREG)        LOAD MAXIMUM LENGTH OF TERM NAME      51900013
         BCTR  OFF,0              SUB ONE FOR COMPARE INSTRUCTION       52200013
TERMLOOP LA    TERM,0(TERM,HEAD)  COMPUTE NEXT TERM ENTRY ADDRESS       52500013
         EX    OFF,COMPARE        COMPARE TERM NAMES                    52800013
         BE    FOUND              BRANCH IF CORRECT ENTRY               53100013
         CR    TERM,LINK          END OF TERM TABLE                     53400013
         BE    EXIT               BRANCH IF YES TO RETURN ON ERROR      53700013
         IC    HEAD,0(TERM)       LOAD LENGTH OF THIS ENTRY             54000013
         B     TERMLOOP           BRANCH TO COMPARE NEXT TERM NAME      54300013
*                                                                       54600013
*      INITIALIZE FOR MESSAGE SEARCH                                    54900013
*                                                                       55200013
FOUND    L     OFF,TQCB(TERM)      LOAD QCB ADDRESS                00PS 55300000
         CLI   QRET(OFF),2         IS THIS A DISTRIBUTION LIST     00PS 55400000
         BE    EXIT                YES, RETURN ERROR CODE=X'20'    00PS 55500000
         LR    OFF,TERM            COPY TERM ENTRY ADDRESS         00PS 55600000
         SLR   OFF,TREG           COMPUTE OFFSET FROM TERM TABLE START  55800013
         STH   OFF,SECOND+8       PLACE OFFSET IN WORKAREA              56100013
         L     NEXT,0(TERM)       LOAD DESTINATION QUEUE ADDRESS        56400013
         L     DASD,QBACK-1(NEXT) DISK ADDRESS FOR START OF SEARCH      56700013
         LA    NEXT,GETNEXT       RETURN ADDRESS TO GET NEXT RECORD     57000013
         LA    HEAD,20(AREA,IO)    COMPUTE ADDRESS OF SEQUENCE FIELD    57300013
*                                                                       57600013
*      RETRIEVE THE NEXT SEGMENT FROM THE DISK USING DIRECT ACCESS ADR. 57900013
*                                                                       58200013
GETNEXT  LA    DASD,0(DASD)       CLEAR THE HIGH ORDER BYTE             58500013
         LTR   DASD,DASD          TEST FOR ZERO ADDRESS                 58800013
         BZ    ERROR              BRANCH IF ZERO (END OF QUEUE)         59100013
         BAL   RET,RETR           GO RETRIEVE NEXT RECORD               59400013
         MVC   SECOND+21(6),MSLINK(AREA) MSLINK AND MSHEAD TO SAVE AREA 59700013
         LM    LINK,DASD,SECOND+20 LOAD MSLINK AND MSHEAD FIELDS        60000013
         SRL   DASD,8             POSITION ADDRESS IN REGISTER          60300013
         LTR   IO,IO              TEST FOR SEQUENCE IN OR SEQUENCE OUT  60600013
         BC    7,SEQOUT           BRANCH IF SEQUENCE OUT                60900013
*                                                                       61200013
*      CHECK FOR CORRECT SEQUENCE IN MESSAGE                            61500013
*                                                                       61800013
         CLC   SECOND+8(2),TTSKEY(AREA) IS SOURCE KEY CORRECT           62100013
         BNE   SEQOUT             BRANCH NO TO GET NEXT MESSAGE         62400013
         TM    MSTATUS(AREA),X'44'  HAS THIS MSG BEEN INTERCEPTED M3161 62500000
         BO    HEADERIN            BRANCH IF YES TO CHECK SEQ. NO.M3185 62600000
         TM    MSTATUS(AREA),X'40' IS THIS A DUPLICATE HEADER           62700013
         BO    SEQOUT              BRANCH IF YES                        63000013
*                                                                       63300013
*      RETRIEVE HEADER IF NOT ALREADY RETRIEVED                         63600013
*                                                                       63900013
         TM    MSTATUS(AREA),1    IS THIS HEADER OF MESSAGE             64200013
         BC    8,HEADERIN         BRANCH IF YES                         64500013
         BAL   RET,RETR           GO RETRIEVE NEXT RECORD               64800013
         SR    RET,RET            SIGNAL NOT ORGINAL RECORD             65100013
         LR    DASD,LINK          SET ADDRESS OF NEXT RECORD IN QUEUE   65400013
*                                                                       65700013
*      HEADER IN CHECK SEQUENCE NUMBER                                  66000013
*                                                                       66300013
HEADERIN BAL   FREG,SEQCK         GO TEST SEQUENCE NUMBER               66600013
         LTR   RET,RET            WAS ORGINAL RECORD HEADER             66900013
         BCR   8,NEXT             ORGINAL RCD. NOT HEADER GO GET NEXT   67200013
         B     LOCATE             GO FIND CHAIN TO NEXT RECORD          67500013
*                                                                       67800013
*      CHECK FOR CORRECT SEQUENCE OUT MESSAGE                           68100013
*                                                                       68400013
SEQOUT   TM    MSTATUS(AREA),1    IS THE A HEADER SEGMENT               68700013
         BC    7,LOADDASD         BRANCH NOT HEADER SEGMENT             69000013
LOCATE   CLC   SECOND+8(2),TTDKEY(AREA) COMPARE DESTINATION KEYS        69300013
         BNE   QUECK              BRANCH IF NOT CORRECT TERMINAL        69600013
         LTR   IO,IO              TEST FOR SEQUENCE IN OR SEQUENCE OUT  70500013
         BCR   8,NEXT             SEQUENCE IN GO GET NEXT RECORD        70800013
         BAL   FREG,SEQCK         GO TEST SEQUENCE NUMBER               71100013
         BR    NEXT               NOT CORRECT MSG. GO GET NEXT RECORD   71400013
*                                                                       71700013
*      DETERMINE IF DESTINATION QUEUE EQUALS SEARCH QUEUE               72000013
*                                                                       72300013
QUECK    MVC   SECOND+2(2),TTDKEY(AREA) DESTINATION KEY TO WORK AREA    72600013
         L     FREG,SECOND        LOAD TTDKEY                           72900013
         ALR   FREG,TREG          ADD IN START OF TERM TABLE            73200013
         CLC   1(3,FREG),1(TERM)  COMPARE QUEUE ADDRESSES               73500013
         BCR   8,NEXT             QUEUE'S DIFFERENT GO GET NEXT RECORD  73800013
LOADDASD LR    DASD,LINK          SET DISK ADDRESS OF THE NEXT RECORD   74100013
         BR    NEXT               GO GET NEXT RECORD (USE MSLINK PT.)   74400013
*                                                                       74700013
*      COMPARE SEQUENCE NUMBERS                                         75000013
*                                                                       75300013
SEQCK    MVC   SECOND+20(2),0(HEAD) SEQUENCE NUMBER TO WORK AREA        75600013
         OC    SECOND+20(2),SECOND+20   IS SEQUENCE NUMBER ZERO    00PS 75700000
         BCR   8,FREG                   BRANCH IF YES              00PS 75800000
         TM    MSTATUS(AREA),X'10'  IS MESSAGE SERVICED           22427 75830000
         BO    COMPLETE            YES, COMPARE FOR MSG. COMPLETE  00PS 75832000
         LTR   IO,IO               RETRIEVE BY SEQUENCE IN OR OUT  00PS 75834000
         BZ    COMPLETE            SEQUENCE IN, CAN DO RETRIEVE    00PS 75836000
         TM    MSTATUS(AREA),X'44' IS SEQUENCE NO. OUT ASSIGNED    00PS 75838000
         BCR   8,FREG              NO, CANNOT DO RETREIVE          00PS 75840000
COMPLETE L     CODE,TQCB(TERM)     GET QCB ADDRESS                 00PS 75842000
         CLI   QRET(CODE),X'68'    IS THIS A DESTINATION QUEUE   A31038 75842600
         BNE   PROCQ               NO, CHECK FOR OPEN PROCESS Q  A31038 75843200
         SR    OFF,OFF             CLEAR REGISTER FOR IC           00PS 75844000
         STH   OFF,SECOND+28       CLEAR WORK AREA                 00PS 75846000
         IC    OFF,QRLN(CODE)      GET RLN FROM QCB                00PS 75848000
         L     CODE,QDCB-1(CODE)   GET DCB ADDRESS                 00PS 75850000
         MVC   SECOND+29(1),DCBEIOBX(CODE)  MOVE LCB SIZE TO       00PS 75852000
*                                    HALFWORD BOUNDARY             00PS 75854000
         MH    OFF,SECOND+28       RLN TIMES LCBSIZE               00PS 75856000
         A     OFF,DCBLCBAD(CODE)  ADD IN LCB ADDRESS              00PS 75858000
         B     TESTSEQ             GO TEST FOR SEQIN             A31038 75858300
PROCQ    CLI   QPRI(CODE),1        IS PROCESS QUEUE OPEN         A31038 75858600
         BNE   CHECKSEQ            NO, OK TO RETRIEVE            A31038 75858900
         L     OFF,QPROC(CODE)     ELSE LOAD LCB ADDRESS         A31038 75859200
TESTSEQ  EQU   *                                                 A31038 75859500
         LTR   IO,IO               RETRIEVE BY SEQUENCE OUT OR IN  00PS 75860000
         BZ    SEQIN               SEQ. IN, USE THIS LCB ADDRESS   00PS 75862000
         L     OFF,LCBSTATE(OFF)   ELSE USE ORIGINATING LCB ADDR.  00PS 75864000
SEQIN    TM    LCBSTATE(OFF),4     IS LINE SENDING                 00PS 75866000
         BO    CHECKSEQ            YES, OK TO RETRIEVE MESSAGE     00PS 75868000
         TM    LCBSTATE(OFF),2     IS PARTIAL MSG. ENQUEUED        00PS 75870000
         BZ    CHECKSEQ            NO, OK TO RETRIEVE MSG.         00PS 75872000
         CLC   LCBCHDR(3,OFF),MSLCB(AREA)   IS THIS SAME MESSAGE   00PS 75874000
         BCR   8,FREG              YES, MSG. NOT COMPLETE, CANNOT  00PS 75876000
*                                    BE RETRIEVED                  00PS 75878000
CHECKSEQ EQU   *                                                   00PS 75880000
         CH    SEQ,SECOND+20      COMPARE SEARCH SEQUENCE NUMBER TO IT  75900013
         BE    RETURN             MESSAGE RETRIEVED EXIT                76200013
         BCR   4,FREG             RETURN IF SEQUENCE NUMBER LOW         76500013
         TM    MSTATUS(AREA),4    TEST FOR PRIORITY MESSAGE             76800013
         BCR   7,FREG             RETURN MESSAGE IS PRIORITY MESSAGE    77100013
ERROR    LA    CODE,BADSEQ        LOAD ERROR CODE BAD SEQUENCE NUMBER   77400013
         B     EXIT                                                     77700013
*                                                                       78000013
*      RETRIEVE A RECORD FROM THE DISK                                  78300013
*                                                                       78600013
RETR     LR    FREG,DASD          DIRECT ACCESS ADDRESS TO REGISTER 1   78900013
         L     15,=V(IECKRETD)    ADDRESS OF RETRIEVE BY DISK ADDR. RT. 79200013
         BR    15                 LINK TO ROUTINE                       79500013
*                                                                       79800013
*      RETURN TO THE CALLER                                             80100013
*                                                                       80400013
RETURN   SR    CODE,CODE          SET VALID RETURN CODE                 80700013
EXIT     L     SAVE,SECOND+4      RELOAD ADDRESS OF USERS SAVE AREA     81000013
         L     RET,12(SAVE)       LOAD RETURN ADDRESS                   81300013
         RETURN (0,12)                                                  81600013
COMPARE  CLC   9(1,TERM),0(AREA)  COMPARE TERM NAMES                    81900013
SECOND   DC    18F'0'                                                   82200013
         END                                                            82500013
