         TITLE 'IECKRRTE  QTAM REROUTE (REROUTE)'                       01000013
*********************************************************************** 02000013
*                                                                     * 03000013
*NAME-                                                                * 04000013
*   IECKRRTE    QTAM REROUTE (REROUTE)                                * 05000013
*                                                                     * 06000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 07000013
*                                                                     * 08000013
*FUNCTION-                                                            * 09000013
*        IECKRRTE WILL QUEUE A MESSAGE ON AN ALTERNATE DESTINATION    * 10000013
*   QUEUE (IN ADDITION TO THE DESTINATION(S) SPECIFIED BY THE         * 11000013
*   MESSAGE HEADER) WHEN ANY OF THE ERRORS SPECIFIED IN THE MASK      * 12000013
*   HAS BEEN DETECTED.                                                * 13000013
*        THE ROUTINE WILL OBTAIN THE MASK FROM THE PARAMETER LIST.    * 14000013
*   THIS MASK WILL BE AND'ED WITH THE ERROR HALFWORD.  IF THE         * 15000013
*   SPECIFIED ERRORS HAVE NOT OCCURRED, PROCESSING CONTINUES WITH     * 16000013
*   THE NEXT LPS INSTRUCTION.                                         * 17000013
*        IF ANY OF THE ERRORS HAVE OCCURRED, CONTROL IS PASSED TO     * 18000013
*   THE RECALL ROUTINE (IN MODULE IGG019NG) WHICH OBTAINS THE         * 19000013
*   HEADER.  IECKLKUP (LOOK-UP) IS USED TO GET THE DESTINATION CODE   * 20000013
*   IN THE TERMINAL TABLE AND PLACES THE RELATIVE ADDRESS IN THE      * 21000013
*   TTDKEY FIELD OF THE INCOMING HEADER PREFIX.  CONTROL IS PASSED    * 22000013
*   ON TO THE NEXT LPS INSTRUCTION FROM THE LOOK-UP ROUTINE.          * 23000013
*                                                                     * 24000013
*ENTRY POINTS-                                                        * 25000013
*   IECKRRTE - CONTROL IS PASSED HERE BY THE EXPANSION OF THE         * 26000013
*        REROUTE MACRO.  BRANCHING IS BY A BALR, USING REGISTER 15    * 27000013
*        AS THE ENTRY POINT REGISTER AND REGISTER 14 AS THE RETURN    * 28000013
*        ADDRESS REGISTER.                                            * 29000013
*                                                                     * 30000013
*INPUT-                                                               * 31000013
*   REGISTER  2- PARAMETER REGISTER PASSING THE ADDRESS OF THE        * 32000013
*        ALTERNATE DESTINATION.                                       * 33000013
*   REGISTER 14- RETURN ADDRESS                                       * 34000013
*        REGISTER 14 IS ALSO USED AS A PARAMETER REGISTER, PASSING    * 35000013
*        THE ADDRESS OF THE HALFWORD ERROR MASK IN HEX NOTATION.      * 36000013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 37000013
*                                                                     * 38000013
*OUTPUT-                                                              * 39000013
*   REGISTER 15- IF A DESIGNATED ERROR OCCURRED, THE ADDRESS OF       * 40000013
*        IECKLKUP WILL BE HERE. IF THERE WERE NO DESIGNATED ERROR,    * 41000013
*        THE ADDRESS OF IECKRRTE WILL BE HERE.                        * 42000013
*   IF ONE OF THE SPECIFIED ERRORS HAD OCCURRED, THEN THE MESSAGE     * 43000013
*        WILL HAVE BEEN RECALLED, AND THE ALTERNATE DESTINATION       * 44000013
*        RELATIVE ADDRESS IS IN THE TTDKEY FIELD OF THE HEADER        * 45000013
*        PREFIX.                                                      * 46000013
*                                                                     * 47000013
*EXTERNAL ROUTINES-                                                   * 48000013
*   RECALL (IECKRC IN MODULE IGG019NG)                                * 49000013
*   LOOK-UP (IECKLKUP)                                                * 50000013
*                                                                     * 51000013
*EXITS-                                                               * 52000013
*   NORMAL- RETURN IS BY A BRANCH ON REGISTER 14.                     * 53000013
*   ERROR- CONTROL WILL PASS TO RECALL. WHEN IT COMPLETES ITS         * 54000013
*        FUNCTION, IT RETURNS TO REROUTE WHICH THEN BRANCHES TO       * 55000013
*        LOOK-UP.  LOOK-UP FINALLY EXITS TO THE NEXT LPS INSTRUCTION. * 56000013
*                                                                     * 57000013
*TABLES/WORK AREAS-                                                   * 58000013
*   NONE.                                                             * 59000013
*                                                                     * 60000013
*ATTRIBUTES-                                                          * 61000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 62000013
*                                                                     * 63000013
*NOTES-                                                               * 64000013
*   REGISTER  3- SECOND LEVEL LINKAGE.  WILL CONTAIN RETURN ADDRESS   * 65000013
*        WHEN LINKING TO RECALL.                                      * 66000013
*   REGISTER  9- WORK REGISTER.  WILL CONTAIN THE LPS QUEUE ADDRESS   * 67000013
*        AS INPUT TO THE RECALL ROUTINE.                              * 68000013
*                                                                     * 69000013
*********************************************************************** 70000013
IECKRRTE START                                                          71000013
*1201844000-856000,920000                                          000D 71500018
DREG1    EQU   1                                                        72000013
RREG2    EQU   3                                                        73000013
LCBREG   EQU   4                                                        74000013
WREG1    EQU   9                                                        75000013
RREG1    EQU   14                                                       76000013
SREG     EQU   15                                                       77000013
         USING *,SREG                                                   78000013
         USING IECKLCB0,LCBREG                                          79000013
         LH    WREG1,0(0,RREG1)    LOAD ERROR HALF WORD FROM USER       80000013
         SLA   WREG1,16            SHIFT ERROR MASK TO HIGH ORDER BYTE  81000013
         BC    8,ERRACT1           BRANCH IF MASK IS ZERO               82000013
         N     WREG1,LCBERRST      TEST FOR DESIGNATED ERRORS           83000013
         BC    8,2(0,RREG1)        RETURN IF NO ERRORS                  84000013
ERRACT1  CLI   LCBCPA+29,X'FF'     IS THIS MESSAGE TO BE           000D 84400018
*                                    RETRANSMITTED TO 2740 MOD 2   000D 84800018
         BE    2(0,RREG1)          RETURN IF YES                   000D 85200018
         MVC   LCBCECB+1(3),LCBCHDR  MAKE HEADER ADDRESS AVAILABLE 000D 85600018
         L     WREG1,0(0,13)       GET LPS QUEUE ADDRESS FROM IGG019NG  86000013
         OI    LCBSTATE,X'10'      SET INITIATE BIT IN LCB              87000013
         BAL   RREG2,240(0,WREG1)  BRANCH TO RECALL SUBROUTINE FOR HDR  88000013
         L     SREG,=V(IECKLKUP)   GET ADDRESS OF LOOKUP ROUTINE        89000013
         BR    SREG                EXIT TO LOOKUP                       90000013
         EJECT                                                          91000013
         LCBD  QTAM=3                                              000D 92000018
         END                                                            93000013
