         TITLE 'IECKSCAN  QTAM SCAN HEADER'                             00700013
*********************************************************************** 01400013
*                                                                     * 02100013
*NAME-                                                                * 02800013
*   IECKSCAN     QTAM SCAN HEADER                                     * 03500013
*                                                                     * 04200013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04900013
*                                                                     * 05600013
*FUNCTION-                                                            * 06300013
*        IECKSCAN (SCAN) WILL PERFORM ONE OF TWO FUNCTIONS,DEPENDING  * 07000013
*   UPON THE PARAMETER PASSED TO IT BY THE ROUTINE USING SCAN.        * 07700013
*        1) SCAN WILL ADVANCE THE SCAN POINTER TO THE NEXT BLANK      * 08400013
*   CHARACTER (END OF FIELD) IF THE CALLING ROUTINE PASSES THE        * 09100013
*   VARIABLE FIELD INDICATOR (X'FF') AS THE PARAMETER, OR             * 09800013
*        2) IF THE CALLING ROUTINE PASSES A GIVEN BINARY NUMBER       * 10500013
*   LESS THAN OR EQUAL TO 8,SCAN WILL ADVANCE THE SCAN POINTER        * 11200013
*   TO THE LAST NONBLANK CHARACTER WHICH SATISFIES THE COUNT.         * 11900013
*   BLANK CHARACTERS ARE IGNORED AND NOT INCLUDED IN THIS COUNT.      * 12600013
*        IN EITHER CASE, EACH NON-BLANK CHARACTER ENCOUNTERED, UP TO  * 13300013
*   A MAXIMUM OF 8, WILL BE MOVED TO WORKWORD.  AFTER THE EIGHTH      * 14000013
*   CHARACTER IS MOVED, CONTROL WILL RETURN TO THE CALLING            * 14700013
*   ROUTINE WHETHER THE REQUIREMENTS ARE MET OR NOT.                  * 15400013
*        BOTH FUNCTIONS ARE CONTINGENT UPON THE SCAN POINTER NOT      * 16100013
*   REACHING THE END OF THE SEGMENT BEFORE SATISFYING THE REQUIREMENTS* 16800013
*   OF THE CALLING ROUTINE.  IF THIS SITUATION ARISES, BIT FIVE,      * 17500013
*   INCOMPLETE MESSAGE HEADER, IS SET IN THE ERROR HALFWORD (LCBERRST * 18200013
*   IS OR'ED WITH A X'04'), AND THE SCAN POINTER IS BACKED UP TO POINT* 18900013
*   TO THE END OF THE SEGMENT.                                        * 19600013
*        RETURN IS TO THE CALLING ROUTINE BY BRANCHING ON THE CONTENTS* 20300013
*   OF REGISTER 3.                                                    * 21000013
*                                                                     * 21700013
*ENTRY POINTS-                                                        * 22400013
*   IECKSCAN - ENTRY TO THIS POINTS IS BY A BALR WITH REGISTER 15 AS  * 23100013
*              THE BRANCH REGISTER, AND REGISTER 3 AS RETURN REGISTER.* 23800013
*              ENTRY IS FROM IECKPRTY, IECKSEQN, IECKSKPS, IECKMODE,  * 24500013
*              IECKROUT, IECKSRCE, OR IECKTYPE.                       * 25200013
*                                                                     * 25900013
*INPUT-                                                               * 26600013
*   REGISTER  3- RETURN REGISTER.                                     * 27300013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 28000013
*   REGISTER 14- POINTER TO MACRO GENERATED PARAMETER LIST.  THIS     * 28700013
*              PARAMETER IS EITHER THE FIELD LENGTH, OR THE VARIABLE  * 29400013
*              FIELD LENGTH INDICATOR.                                * 30100013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 30800013
*                                                                     * 31500013
*OUTPUT-                                                              * 32200013
*   REGISTER  2- POINTS TO THE WORKAREA CONTAINING THE TRANSFERRED    * 32900013
*              CHARACTERS.                                            * 33600013
*   REGISTER  5- POINTS TO THE LAST CHARACTER WHICH SATISFIED THE     * 34300013
*              FIELD SIZE COUNT, IF COUNT IS GIVEN.  POINTS TO NEXT   * 35000013
*              BLANK CHARACTER IF VARIABLE LENGTH INDICATOR IS GIVEN. * 35700013
*   REGISTER  9- CONTAINS THE NUMBER OF NON-BLANK CHARACTERS          * 36400013
*              SCANNED.                                               * 37100013
*   REGISTER 14- POINTS TO THE PARAMETER LIST DESCRIBED ABOVE.        * 37800013
*                                                                     * 38500013
*EXTERNAL ROUTINES-                                                   * 39200013
*   NONE.                                                             * 39900013
*                                                                     * 40600013
*EXITS-                                                               * 41300013
*   NORMAL- RETURN TO LOCATION POINTED TO BY REGISTER 3.              * 42000013
*   ERROR- IF A COUNT IS GIVEN AND END OF SEGMENT IS FOUND BEFORE     * 42700013
*              THIS COUNT HAS BEEN SATISFIED, BIT FIVE, INCOMPLETE    * 43400013
*              MESSAGE HEADER, IS SET IN THE ERROR HALFWORD (LCBERRST * 44100013
*              IS OR'ED WITH A X'04'), AND THE SCAN POINTER IS BACKED * 44800013
*              UP TO POINT TO THE END OF THE SEGMENT.  THE SAME ERROR * 45500013
*              INDICATION IS GIVEN IF VARIABLE LENGTH INDICATION IS   * 46200013
*              GIVEN AND END OF SEGMENT IS FOUND BEFORE THE NEXT      * 46900013
*              BLANK CHARACTER.                                       * 47600013
*                                                                     * 48300013
*TABLES/WORK AREAS-                                                   * 49000013
*   WORKWORD IS USED TO HOLD THE NON-BLANK CHARACTERS.                * 49700013
*                                                                     * 50400013
*ATTRIBUTES-                                                          * 51100013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 51800013
*                                                                     * 52500013
*NOTES-                                                               * 53200013
*   REGISTER  9- WORK REGISTER.  KEEPS COUNT OF CHARACTERS SCANNED.   * 53900013
*   REGISTER 10- WORK REGISTER.  HOLDS INCREMENT VALUE OF 1.          * 54600013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 55300013
*   REGISTER 12- WORK REGISTER.  USED TO TRANSFER THE CHARACTERS FROM * 56000013
*              THE HEADER TO WORKWORD.                                * 56700013
*   REGISTER 15- BASE REGISTER FOR THIS ROUTINE.                      * 57400013
*                                                                     * 58100013
*********************************************************************** 58800013
IECKSCAN START                                                          59500013
KREG     EQU   2                                                        60200013
RREG2    EQU   3                                                        60900013
LCBREG   EQU   4                                                        61600013
SPREG    EQU   5                                                        62300013
WREG1    EQU   9                                                        63000013
IREG     EQU   10                                                       63700013
WREG2    EQU   12                                                       64400013
RREG1    EQU   14                                                       65100013
SREG     EQU   15                                                       65800013
         USING *,SREG                                                   66500013
         USING IECKLCB0,LCBREG                                          67200013
         LA    IREG,1              LOAD INCREMENT VALUE OF ONE          67900013
         MVC   WORKWORD,BLANK      BLANK WORKWORD                       68600013
         SR    WREG1,WREG1         CLEAR                                69300013
         LA    KREG,WORKWORD       LOAD WORKWORD ADDR FOR EXTERN USE    70000013
PTR1     CH    WREG1,0(0,RREG1)    GET FIELD SIZE                       70700013
         BCR   8,RREG2             RETURN IF END                        71400013
PTR2     BXH   SPREG,IREG,HEADERR  BUMP SCAN POINTER--END OF SEGM TST   72100013
         CLI   0(SPREG),C' '       TEST FOR BLANK                       72800013
         BE    PTR2                IF YES,SCAN NXT HEADER CHAR          73500013
VARIFLD  CLI   0(SPREG),C' '       TEST FOR BLANK                       74200013
         BCR   8,RREG2             IF YES,DO END OF FLD RETURN TO SUBR  74900013
         IC    WREG2,0(0,SPREG)    ELSE PUT CHAR IN WORKWORD            75600013
         STC   WREG2,WORKWORD(WREG1)                                    76300013
         AR    WREG1,IREG          HAR COUNTER FOR VAR FLD              77000013
         CH    WREG1,H8            IS FIELD MAX SIZE                    77700013
         BCR   8,RREG2             IF END OF FLD RETURN TO CALLING SUBR 78400013
         CLI   1(RREG1),X'FF'      TST FOR VAR LNGTH FLD INDIC          79100013
         BNE   PTR1                BR IF NOT VARIABLE                   79800013
         BXLE  SPREG,IREG,VARIFLD  BUMP SCAN POINTER--END OF SEGM TST   80500013
HEADERR  OI    LCBERRST,X'04'      SET ERROR BIT                        81200013
         BCTR  SPREG,RREG2         RETURN                               81900013
         SPACE                                                          82600013
H8       DC    X'000800'                                                83300013
BLANK    DC    C' '                BLANK TO FILL WORKWORD               84000013
WORKWORD DC    C'        '         DEFINE STORAGE FOR WORK AREA         84700013
         EJECT                                                          85400013
         LCBD                                                           86100013
         END                                                            86800013
