         TITLE 'IECKSEQN  QTAM SEQUENCE-IN (SEQIN)'                     00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*NAME-                                                                * 02400013
*   IECKSEQN   QTAM SEQUENCE-IN (SEQIN)                               * 03000013
*                                                                     * 03600013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04200013
*                                                                     * 04800013
*FUNCTION-                                                            * 05400013
*        IECKSEQN IS USED TO CHECK THE SEQUENCE NUMBER OF AN INCOMING * 06000013
*   MESSAGE.  IF THE NUMBER IS NOT IN SEQUENCE ACCORDING TO THE       * 06600013
*   TSEQUIN FIELD IN THE TERMINAL TABLE ENTRY, THE SEQUENCE ERROR BIT * 07200013
*   IN THE LCB IS SET ACCORDINGLY.  IF THE NUMBER IS TOO HIGH OR IN   * 07800013
*   CORRECT SEQUENCE, THE EXPECTED SEQUENCE NUMBER FROM THE TERMINAL  * 08400013
*   TABLE IS STORED IN THE LCBERRST FIELD OF THE LCB (LCB+40).  THE   * 09000013
*   EXPECTED SEQUENCE NUMBER IS INCREMENTED BY ONE FOR THE NEXT       * 09600013
*   MESSAGE BEFORE RETURNING TO THE NEXT LPS INSTRUCTION.             * 10200013
*        IECKSCAN IS USED TO FIND THE END OF THE SEQUENCE NUMBER IN   * 10800013
*   THE MESSAGE HEADER.  SCAN WILL RETURN THE ADDRESS OF THE WORKWORD * 11400013
*   CONTAINING THE CHARACTERS THAT WERE SCANNED, AND THE COUNT OF THE * 12000013
*   CHARACTERS SCANNED.  SEQIN WILL ASSUME THESE CHARACTERS TO BE     * 12600013
*   NUMERIC.  ONE AT A TIME THESE CHARACTERS WILL BE INSERTED INTO A  * 13200013
*   WORK REGISTER, STRIPPED OF THEIR ZONES, AND MULTIPLIED BY TEN.    * 13800013
*   THE LAST NUMBER IS MERELY ADDED TO THIS SUM WITHOUT               * 14400013
*   MULTIPLICATION.  THE RESULT IS THE CONVERTED INPUT SEQUENCE       * 15000013
*   NUMBER IN BINARY FORM.                                            * 15600013
*        THIS BINARY SUM IS COMPARED WITH THE EXPECTED INCOMMING      * 16200013
*   SEQUENCE NUMBER.  IF THIS SUM IS LOW, LCBERRST (LCB+40) IS OR'ED  * 16800013
*   WITH A X'10' TO SET THE SEQUENCE LOW BIT IN THE ERROR HALFWORD.   * 17400013
*   IF SUM IS HIGH, LCBERRST IS OR'ED WITH  X'20' TO SET THE          * 18000013
*   SEQUENCE HIGH ERROR BIT.                                          * 18600013
*        ON A HIGH OR EQUAL, THE BINARY SEQUENCE NUMBER FORMED IS     * 19200013
*   STORED IN THE MSNUMIN FIELD OF THE HEADER PREFIX.  THE EXPECTED   * 19800013
*   SEQUENCE NUMBER IS MOVED INTO THE LCBBRKCT FIELD OF THE LCB.      * 20400013
*   IT IS UPDATED BY ONE AND RETURNED TO THE TSEQUIN FIELD OF THE     * 21000013
*   TERMINAL TABLE.                                                   * 21600013
*        RETURN IS TO THE NEXT LPS INSTRUCTION.                       * 22200013
*                                                                     * 22800013
*ENTRY POINTS-                                                        * 23400013
*   IECKSEQN - THE EXPANSION OF THE SEQIN MACRO GENERATES A BALR TO   * 24000013
*        THIS POINT, USING REGISTER 15 AS THE ENTRY POINT REGISTER    * 24600013
*        AND REGISTER 14 AS THE RETURN REGISTER.                      * 25200013
*                                                                     * 25800013
*INPUT-                                                               * 26400013
*   REGISTER 14- RETURN ADDRESS                                       * 27000013
*        REGISTER 14 ALSO CONTAINS A POINTER TO THE NUMBER OF         * 27600013
*        CHARACTERS IN THE SEQUENCE NUMBER IN THE HEADER.  THIS       * 28200013
*        NUMBER IS USED BY IECKSCAN.                                  * 28800013
*   REGISTER 15- ENTRY POINT REGISTER.                                * 29400013
*                                                                     * 30000013
*OUTPUT-                                                              * 30600013
*   IF SEQUENCE NUMBER IS LOW, LOW SEQUENCE ERROR FLAG IS SET IN THE  * 31200013
*        ERROR HALFWORD.                                              * 31800013
*   IF SEQUENCE NUMBER IS CORRECT, BINARY SEQUENCE NO. IS IN HEADER   * 32400013
*        PREFIX AND EXPECTED SEQUENCE IS IN TERMINAL TABLE ENTRY.     * 33000013
*   IF SEQUENCE NUMBER IS HIGH, THE HIGH SEQUENCE BIT IS SET IN THE   * 33600013
*        ERROR HALFWORD, AS WELL AS ALL RESULTS FROM EQUAL COMPARE.   * 34200013
*                                                                     * 34800013
*EXTERNAL ROUTINES-                                                   * 35400013
*   IECKSCAN - USED TO SCAN THE HEADER FOR EITHER THE NUMBER OF       * 36000013
*        CHARACTERS SPECIFIED, OR THE END OF THE NEXT FIELD,          * 36600013
*        DEPENDING UPON WHAT THE CALLING ROUTINE SPECIFIES.           * 37200013
*                                                                     * 37800013
*EXITS-                                                               * 38400013
*   NORMAL - RETURN IS TO THE NEXT LPS INSTRUCTION BY BRANCHING       * 39000013
*        ON REGISTER 14.                                              * 39600013
*   ERROR - SAME AS ABOVE BUT WITH PROPER ERROR BIT SET IN THE        * 40200013
*        ERROR HALFWORD (LCB+40):                                     * 40800013
*        X'10' FOR LOW SEQUENCE NUMBER                                * 41400013
*        X'20' FOR HIGH SEQUENCE NUMBER.                              * 42000013
*                                                                     * 42600013
*TABLES/WORK AREAS-                                                   * 43200013
*   NONE                                                              * 43800013
*                                                                     * 44400013
*ATTRIBUTES-                                                          * 45000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 45600013
*                                                                     * 46200013
*NOTES-                                                               * 46800013
*   REGISTER 0- WORK REGISTER. CHARACTERS FROM SCAN'S WORK AREA WILL  * 47400013
*        BE INSERTED INTO THE LOW ORDER BYTE OF THIS REGISTER.        * 48000013
*   REGISTER  1- WORK REGISTER.  WILL HOLD A MASK FOR CLEARING A      * 48600013
*        HALFWORD.                                                    * 49200013
*   REGISTER  2- WORK REGISTER.  ON RETURNING FROM SCAN, THIS REGISTER* 49800013
*        WILL HOLD THE POINTER TO SCAN'S WORK AREA.                   * 50400013
*   REGISTER  3- SECOND LEVEL LINKAGE. WILL HOLD THE RETURN ADDRESS   * 51000013
*        WHEN LINKING TO SCAN.  LATER, IT WILL HOLD A MASK TO STRIP   * 51600013
*        ZONE BITS FROM CHARACTERS.                                   * 52200013
*   REGISTER  4- BASE FOR LCB.                                        * 52800013
*   REGISTER  7- BASE FOR THIS LPS.                                   * 53400013
*   REGISTER  8- BASE FOR TERMINAL TABLE.                             * 54000013
*   REGISTER  9- WORK REGISTER.  SCAN WILL RETURN THE NUMBER OF       * 54600013
*        CHARACTERS SCANNED IN THIS REGISTER.                         * 55200013
*   REGISTER 10- WORK REGISTER. WILL HOLD AN INCREMENT VALUE OF 1.    * 55800013
*   REGISTER 12- WORK REGISTER. BINARY SEQUENCE NUMBER WILL BE        * 56400013
*        ACCUMULATED HERE.                                            * 57000013
*                                                                     * 57600013
*********************************************************************** 58200013
IECKSEQN START                                                          58800013
*3410738000,900000                                                18912 59100017
*90351816000,852000                                                00PS 59200017
*90356819000,831000                                                00PS 59300017
DREG0    EQU   0                                                        59400013
DREG1    EQU   1                                                        60000013
KREG     EQU   2                                                        60600013
RREG2    EQU   3                                                        61200013
LCBREG   EQU   4                                                        61800013
MSREG    EQU   6                                                        62400013
LGREG    EQU   7                                                        63000013
TCREG    EQU   8                                                        63600013
WREG1    EQU   9                                                        64200013
IREG     EQU   10                                                       64800013
WREG2    EQU   12                                                       65400013
RREG1    EQU   14                                                       66000013
SREG     EQU   15                                                       66600013
         USING *,SREG                                                   67200013
         USING IECKPREF,MSREG                                           67800013
         USING IECKTERM,TCREG                                           68400013
         USING IECKLCB0,LCBREG                                          69000013
         LR    DREG0,SREG          SAVE BASE REG                        69600013
         L     SREG,4(0,LGREG)     GET SCAN ADDR                        70200013
         BALR  RREG2,SREG          LINKAGE TO SCAN SUBR                 70800013
         LR    SREG,DREG0          RESTORE BASE REG                     71400013
         LTR   WREG1,WREG1         TEST FOR HEADER ERROR                72000013
         BE    TOOLOW              IF YES ASSUME LOW SEQ                72600013
         LA    RREG2,15            MASK FOR CLEARING ZONE BITS          73200013
         L     DREG1,XFFFF    MASK FOR CLEARING WRAP VALUE        18912 73800017
         LA    WREG2,1(0,DREG1)    SET INITIAL WRAP VALUE               74400013
TLOOP    MH    WREG2,H10           MULTIPLY PREVIOUS ACCUMULATION BY 10 75000013
         IC    DREG0,0(0,KREG)     GET CHARACTER                        75600013
         NR    DREG0,RREG2         CLEAR ZONES                          76200013
         BZ    TEST                TEST FOR ZERO                        76800013
         NR    WREG2,DREG1         CLEAR WRAP VALUE                     77400013
         AR    WREG2,DREG0         ADD DIGIT                            78000013
TEST     AR    KREG,IREG           GET NEXT SCAN CHARACTER              78600013
         BCT   WREG1,TLOOP         RETURN IF NOT END                    79200013
         NR    DREG1,WREG2         CLEAR NON WRAP VALUE                 79800013
         SRL   WREG2,16            CLEAR WRAP INCREMENT                 80400013
         AR    WREG2,DREG1         GET WRAP VALUE                       81000013
         STH   DREG1,LCBBRKCT     AND SAVE IN LCB                  00PS 81600017
         STH   DREG1,MSNUMIN       SAVE IN BUFFER PREFIX           00PS 81900017
         CH    WREG2,TSEQUIN       IS MSG NUM INSEQ                     82200013
         BE    GOOD                                                     82800013
         MVC   MSNUMIN(2),XFFFF    CLEAR OUT MSNUMIN IF WRONG      00PS 83100017
NONSEQ   BC    4,TOOLOW            BRANCH IF NUMBER TOO LOW             83400013
         OI    LCBERRST,X'20'      SET SEQ HIGH ERROR BIT               84000013
         B     2(0,RREG1)          RETURN                               84600013
GOOD     MVC   LCBBRKCT,TSEQUIN    STORE EXPECTED SEQUENCE NO.     00PS 85200017
         AR    DREG1,IREG          INCREMENT SEQUENCE                   85800013
         STH   DREG1,TSEQUIN       STORE FOR NEXT MESSAGE               86400013
         B     2(0,RREG1)          RETURN                               87000013
         SPACE                                                          87600013
TOOLOW   OI    LCBERRST,X'10'      SET SEQ LOW ERROR BIT                88200013
         B     2(0,RREG1)          RETURN                               88800013
         SPACE                                                          89400013
XFFFF    DC    F'65535'                                           18912 90000017
H10      DC    H'10'                                                    90600013
         EJECT                                                          91200013
         PREFIXD                                                        91800013
         EJECT                                                          92400013
         TERMTBLD                                                       93000013
         EJECT                                                          93600013
         LCBD                                                           94200013
         END                                                            94800013
