     TITLE  'IECKSEQT QTAM SEQUENCE-OUT (SEQOUT)       QTAM III'        02000013
*********************************************************************** 02070018
*                                                                     * 02140018
*NAME-                                                                * 02210018
*   IECKSEQT     QTAM SEQUENCE OUT (SEQOUT)                           * 02280018
*                                                                     * 02350018
*STATUS-  CHANGE LEVEL= 19         JANUARY 1971                       * 02420021
*                                                                     * 02490018
*FUNCTION-                                                            * 02560018
*        IF THE SEQOUT MACRO APPEARS IN THE RCVHDR PORTION OF THE LPS,* 02570021
*   THE DESTINATION QCB IS CHECKED FOR BEING A PROCESS QCB. IF THIS IS* 02580021
*   NOT A PROCESS QCB, RETURN IS MADE TO THE NEXT LPS INSTRUCTION. IF * 02590021
*   A PROCESS QCB, LINKAGE IS MADE TO THE EXPAND ROUTINE, WHICH       * 02600021
*   EXPANDS THE HEADER TO CREATE A NEW FIELD.  IDLE CHARACTERS ARE    * 02610021
*   INSERTED INTO THIS FIELD.  THE VALUE OF THE SCAN POINTER IS STORED* 02620021
*   IN THE MSNUMOUT FIELD OF THE HEADER.  RETURN IS MADE TO THE NEXT  * 02630021
*   LPS INSTRUCTION.                                                  * 02640021
*        IF THE SEQOUT MACRO APPEARS IN THE SENDHR PORTION OF THE LPS,* 02650021
*   THE ROUTINE BRANCHES AND LINKS TO IECKEXPD TO SHIFT THE           * 02660021
*   CONTENTS OF THE HEADER LEFT FROM THE CURRENT POINT BY THE         * 02700018
*   NUMBER OF BYTES SPECIFIED IN THE PARAMETER OF THE MACRO.          * 02770018
*   THE BINARY OUTPUT SEQUENCE NUMBER IS RETRIEVED FROM THE HEADER    * 02840018
*   PREFIX, CONVERTED TO DECIMAL FORM, UNPACKED, AND INSERTED INTO    * 02910018
*   THE NEWLY CREATED HEADER FIELD.                                   * 02980018
*                                                                     * 03050018
*ENTRY POINTS-                                                        * 03120018
*   IECKSEQT - ENTERED FROM MACRO GENERATION BY STANDARD LINKAGE      * 03190018
*              CONVENTIONS.                                           * 03260018
*                                                                     * 03330018
*INPUT-                                                               * 03400018
*   REGISTER  6- ADDRESS OF MESSAGE BUFFER.                           * 03470018
*   REGISTER 14- RETURN ADDRESS                                       * 03540018
*          REGISTER 14 ALSO POINTS TO A PARAMETER LIST WHICH CONTAINS * 03610018
*   THE SIZE OF THE FIELD TO BE EXPANDED.  THIS PARAMETER IS USED     * 03680018
*   BY IECKEXPD.                                                      * 03750018
*   REGISTER 15- ADDRESS OF THIS ROUTINE.                             * 03820018
*                                                                     * 03890018
*OUTPUT-                                                              * 03960018
*   UNPACKED DECIMAL OUTPUT SEQUENCE NUMBER IS IN THE NEWLY-CREATED   * 04030018
*              FIELD OF THE HEADER.  REGISTER 10 POINTS TO THIS FIELD.* 04100018
*                                                                     * 04170018
*EXTERNAL ROUTINES-                                                   * 04240018
*   IECKEXPD - USED TO EXPAND HEADER TO MAKE ROOM FOR NEW FIELD.      * 04310018
*                                                                     * 04380018
*EXITS-                                                               * 04450018
*   NORMAL- RETURN IS TO NEXT LPS INSTRUCTION BY BRANCHING AROUND     * 04520018
*   2 BYTE CONSTANT CREATED BY THE MACRO EXPANSION.                   * 04590018
*   ERROR- NONE.                                                      * 04660018
*                                                                     * 04730018
*TABLES/WORK AREAS-                                                   * 04800018
*  SEQWORD IS USED TO RECEIVE CONVERTED DECIMAL DATA. DATA HERE IS    * 04870018
*        UNPACKED INTO THE HEADER FIELD.                              * 04940018
*                                                                     * 05010018
*ATTRIBUTES-                                                          * 05080018
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 05150018
*                                                                     * 05220018
*NOTES-                                                               * 05290018
*   REGISTER  0 IS USED AS A WORK REGISTER                            * 05360018
*   REGISTER  3 IS USED FOR SECOND LEVEL LINKAGE TO IECKEXPD.         * 05430018
*   REGISTER  9 IS USED AS A WORK REGISTER                            * 05500018
*                                                                     * 05570018
*********************************************************************** 05640018
IECKSEQT  START                                                         05710018
* 490000-550000                                                   M3139 05780018
* 520000-530000                                                  A29205 05880019
*A024200,025700-026600                                           S21016 05940021
DREG0  EQU 0                                                            06000013
RREG2  EQU 3                                                            08000013
LCBREG  EQU 4                                                           10000013
MSREG  EQU 6                                                            12000013
WREG1  EQU 9                                                            14000013
WREG2  EQU 10                                                           16000013
WREG3  EQU 12                                                           18000013
REG13 EQU  13                                                           20000013
RREG1  EQU 14                                                           22000013
SREG  EQU 15                                                            24000013
   USING   *,SREG                                                       26000013
   USING IECKPREF,MSREG                                                 28000013
     USING  IECKLCB0,LCBREG                                             30000013
          LR    DREG0,SREG             SAVE BASE REG                    32000013
          TM    0(LCBREG),X'04'     IS THIS AN OUTPUT OPERATION         34000013
          BO    SEQT                   BRANCH IF YES                    36000013
          L    WREG3,LCBDESTQ-1          NO, ACCESS DEST. QCB           38000013
          CLI    8(WREG3),0            IS THIS A PROCESS QCB            40000013
          BNE    2(0,RREG1)            NO, NO OP THIS MACRO AND RETURN  42000013
          L    SREG,=V(IECKEXPD)       ACCESS ADDR OF EXPAND ROUTINE    44000013
          BALR    RREG2,SREG           LINK TO EXPAND ROUTINE           46000013
          LR    SREG,DREG0             RESTORE  BASE REG                48000013
         LA    WREG3,1(WREG2)      PREPARE AND SAVE               M3139 49000018
         SR    WREG3,MSREG           ONE BYTE OFFSET TO           M3139 50000018
         STH   WREG3,MSNUMOUT        SEQ OUT FIELD IN MSG HDR     M3139 51000018
LOOP     MVI   1(WREG2),X'17'     INSERT IDLE CHARACTER IN FIELD A29205 52000019
         LA    WREG2,1(WREG2)     ADD ONE TO AREA                A29205 53000019
         BCT   WREG1,LOOP          LOOP FOR ENTIRE FIELD          M3139 55000018
          B    2(0,RREG1)              RETURN TO MAINLINE LPS           56000013
SEQT  EQU *                                                             58000013
          L    SREG,=V(IECKEXPD)                                        60000013
          BALR   RREG2,SREG            LINK TO EXPAND SUBR              62000013
          LR    SREG,DREG0             RESTORE BASE REG                 64000013
          LH    DREG0,MSNUMOUT         GET BINARY SEQ NO FROM HDR PRFX  66000013
          CVD    DREG0,SEQWORD         CPNVERT BINARY SEQ NO TO DECIMAL 68000013
          OI    SEQWORD+7,X'0F'        DELETE SIGN                      70000013
          BCTR    WREG1,0              DECR COUNT FIELD BY ONE          72000013
         SLL    WREG1,4                ALIGN FIELD SIZE                 74000013
          EX    WREG1,UNPAK1           EXEC UNPACK SEQ NO INTO HDR FLD  76000013
          B    2(0,RREG1)              RETURN                           78000013
        SPACE                                                           80000013
UNPAK1  UNPK  1(1,WREG2),SEQWORD       UNPACK SEQ NO INTO HDR FIELD     82000013
SEQWORD  DS  1D                                                         84000013
      DS  0F                                                            86000013
      EJECT                                                             88000013
      PREFIXD                                                           90000013
      EJECT                                                             92000013
          LCBD                                                          94000013
      END                                                               96000013
