*********************************************************************** 01000013
*                                                                     * 02000013
*NAME-                                                                * 03000013
*   IECKSKPC     QTAM SKIP CHARACTER COUNT (SKIP)                     * 04000013
*                                                                     * 05000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 06000013
*                                                                     * 07000013
*FUNCTION-                                                            * 08000013
*        THIS ROUTINE SKIPS THE SCAN POINTER OVER A SPECIFIED         * 09000013
*   NUMBER OF NON-BLANK CHARACTERS. ALL CHARACTERS BYPASSED ARE       * 10000013
*   COMPLETELY IGNORED. AT THE END OF THE OPERATION, THE SCAN         * 11000013
*   POINTER POINTS TO THE LAST NON-BLANK CHARACTER SKIPPED.           * 12000013
*                                                                     * 13000013
*ENTRY POINTS-                                                        * 14000013
*   IECKSKPC - EXPANSION OF THE SKIP MACRO GENERATES A BRANCH TO      * 15000013
*              THIS POINT WHEN A NUMBER OF CHARACTERS IS SPECIFIED    * 16000013
*              AS THE OPERAND.  LINKAGE IS BY STANDARD LINKAGE        * 17000013
*              CONVENTIONS.                                           * 18000013
*                                                                     * 19000013
*INPUT-                                                               * 20000013
*   REGISTER  5- POINTER TO BYTE BEFORE CURRENT CHAR IN SEGMENT       * 21000013
*   REGISTER 14- RETURN ADDRESS                                       * 22000013
*   REGISTER 14 IS ALSO A POINTER TO A HALF-WORD PARAMETER, THE       * 23000013
*              NUMBER OF NON-BLANK CHARACTERS TO BE SKIPPED.          * 24000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE.                             * 25000013
*                                                                     * 26000013
*OUTPUT-                                                              * 27000013
*   REGISTER  5- THE SCAN POINTER WILL HAVE BEEN UPDATED BY THE NUMBER* 28000013
*              OF CHARACTERS SPECIFIED.  IF THE SCAN POINTER REACHES  * 29000013
*              THE END OF THE SEGMENT BEFORE EXHAUSTING THE SPECIFIED * 30000013
*              COUNT,BIT 5, INCOMPLETE MESSAGE HEADER, IS SET IN      * 31000013
*              THE ERROR HALFWORD, LCBERRST (LCB ADDRESS+40).         * 32000013
*                                                                     * 33000013
*EXTERNAL ROUTINES-                                                   * 34000013
*   NONE.                                                             * 35000013
*                                                                     * 36000013
*EXITS-                                                               * 37000013
*   NORMAL- RETURN IS TO THE NEXT LPS INSTRUCTION BY BRANCHING        * 38000013
*   ON REGISTER 14.                                                   * 39000013
*   ERROR- IF THE SCAN POINTER SKIPS PAST THE END OF THE SEGMENT,     * 40000013
*   THE INCOMPLETE HEADER BIT IN THE ERROR HALFWORD WILL BE SET,      * 41000013
*   THAT IS, THE CONTENTS OF LCBERRST (LCB+40) WILL BE OR'ED WITH A   * 42000013
*   X'04' TO SET THE ERROR BIT.                                       * 43000013
*                                                                     * 44000013
*TABLES/WORK AREAS-                                                   * 45000013
*   NONE.                                                             * 46000013
*                                                                     * 47000013
*ATTRIBUTES-                                                          * 48000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 49000013
*                                                                     * 50000013
*NOTES-                                                               * 51000013
*   REGISTER  9- USED AS A WORK REGISTER.                             * 52000013
*   REGISTER 10- USED AS A WORK REGISTER.                             * 53000013
*                                                                     * 54000013
*********************************************************************** 55000013
IECKSKPC START                                                          56000013
LCBREG   EQU   4                                                        57000013
SPREG    EQU   5                                                        58000013
WREG1    EQU   9                                                        59000013
IREG     EQU   10                                                       60000013
RREG1    EQU   14                                                       61000013
SREG     EQU   15                                                       62000013
         USING *,SREG                                                   63000013
         USING IECKLCB0,LCBREG                                          64000013
         LH    WREG1,0(0,RREG1)    GET FIELD SIZE                       65000013
         LA    IREG,1              GET INCREMENT VALUE                  66000013
SKPCHAR  BXH   SPREG,IREG,HEADERR2 BUMP SCAN POINTER--END OF SEGM TST   67000013
         CLI   0(SPREG),X'40'      TEST FOR BLANK                       68000013
         BC    8,SKPCHAR           IF YES POINT TO NXT CHAR             69000013
         BCT   WREG1,SKPCHAR       DECR COUNT TO SKIP                   70000013
         B     2(0,RREG1)          RETURN                               71000013
         SPACE                                                          72000013
HEADERR2 OI    LCBERRST,X'04'      SET ERROR BIT                        73000013
         BCT   SPREG,2(0,RREG1)    RETURN                               74000013
         EJECT                                                          75000013
         LCBD                                                           76000013
         END                                                            77000013
