*********************************************************************** 00800013
*                                                                     * 01600013
*NAME-                                                                * 02400013
*   IECKSKPS     QTAM SKIP CHARACTER SET (SKIP)                       * 03200013
*                                                                     * 04000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04800013
*                                                                     * 05600013
*FUNCTION-                                                            * 06400013
*        LOCATE A GIVEN CHARACTER SEQUENCE IN THE HEADER SEGMENT.     * 07200013
*   IECKSCAN(SCAN) IS USED TO LOCATE THE NEXT NON-BLANK CHARACTER.    * 08000013
*   SKIP COMPARES THE REQUIRED NUMBER OF CHARACTERS WITH THE          * 08800013
*   DESIRED CHARACTER SEQUENCE.  IF THEY ARE THE SAME, SKIP RETURNS   * 09600013
*   TO THE NEXT LPS INSTRUCTION.  IF NOT EQUAL, SKIP GOES BACKTO SCAN * 10400013
*   TO GET THE NEXT NON-BLANK CHARACTER.  THIS CONTINUES UNTIL        * 11200013
*   THE DESIRED SEQUENCE IS FOUND, OR UNTIL END OF SEGMENT IS REACHED.* 12000013
*   IF END OF SEGMENT IS FOUND, FIRST MULTIPLE DESTINATION ROUTING    * 12800013
*   IS CANCELLED, THE SCAN POINTER IS RESET TO THE END OF THE         * 13600013
*   SEGMENT, AND CONTROL RETURNS TO THE NEXT LPS INSTRUCTION.         * 14400013
*                                                                     * 15200013
*ENTRY POINTS-                                                        * 16000013
*   IECKSKPS - EXPANSION OF THE SKIP MACRO GENERATES A BRANCH AND     * 16800013
*              LINK TO THIS POINT IF A CHARACTER SEQUENCE IS GIVEN    * 17600013
*              AS THE OPERAND OF THE SKIP MACRO.                      * 18400013
*                                                                     * 19200013
*INPUT-                                                               * 20000013
*   REGISTER  2- POINTS TO WORKAREA CONTAINING THE NEXT FIELD IN THE  * 20800013
*              HEADER SEGMENT PASSED FROM IECKSCAN.                   * 21600013
*   REGISTER  4- ADDRESS OF LCB.                                      * 22400013
*   REGISTER  5- POINTER TO BYTE BEFORE CURRENT FIELD IN HEADER       * 23200013
*        SEGMENT                                                      * 24000013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 24800013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 25600013
*   REGISTER 14- RETURN ADDRESS                                       * 26400013
*        REGISTER 14 ALSO POINTS TO A PARAMETER LIST CONSISTING OF:   * 27200013
*              1.  A HALFWORD CONTAINING THE LENGTH OF THE CHARACTER  * 28000013
*              SEQUENCE TO BE FOUND, AND                              * 28800013
*              2.  A CHARACTER CONSTANT CONTAINING THE CHARACTER      * 29600013
*              TO BE FOUND.                                           * 30400013
*   REGISTER 15- ADDRESS OF THIS ROUTINE.                             * 31200013
*                                                                     * 32000013
*OUTPUT-                                                              * 32800013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 33600013
*   REGISTER  5- POINTS TO THE LAST CHARACTER OF THE DESIRED          * 34400013
*               CHARACTER SEQUENCE, OR THE LAST CHARACTER OF THE      * 35200013
*               HEADER SEGMENT IF THE SPECIFIED CHARACTER SET WAS     * 36000013
*               NOT FOUND.                                            * 36800013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 37600013
*   REGISTER  9- WORK REGISTER.                                       * 38400013
*                 IF THE NUMBER OF CHARACTERS DESIRED IS ODD,         * 39200013
*               REGISTER 9 WILL CONTAIN THAT NUMBER. IF THE           * 40000013
*               NUMBER IS EVEN, REGISTER 9 WILL CONTAIN THE           * 40800013
*               NEXT HIGHEST ODD NUMBER, I.E., REGISTER 9 WILL ALWAYS * 41600013
*               CONTAIN AN ODD NUMBER.                                * 42400013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 43200013
*                                                                     * 44000013
*EXTERNAL ROUTINES-                                                   * 44800013
*   IECKSCAN - SKIP BRANCHES AND LINKS TO SCAN (USING REGISTER 3 AS   * 45600013
*              THE RETURN REGISTER) TO GET THE ADDRESS OF THE NEXT    * 46400013
*              NON-BLANK CHARACTER IN THE SEGMENT.                    * 47200013
*                                                                     * 48000013
*EXITS-                                                               * 48800013
*   NORMAL- RETURN TO THE NEXT LPS INSTRUCTION IS ACCOMPLISHED BY     * 49600013
*   BRANCHING AROUND CONSTANTS GENERATED BY THE SKIP MACRO.           * 50400013
*   ERROR- NONE.                                                      * 51200013
*                                                                     * 52000013
*TABLES/WORK AREAS-                                                   * 52800013
*   NONE.                                                             * 53600013
*                                                                     * 54400013
*ATTRIBUTES-                                                          * 55200013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 56000013
*                                                                     * 56800013
*NOTES-                                                               * 57600013
*   REGISTER  0- USED AS A WORK REGISTER TO HOLD THE SCAN POINTER.    * 58400013
*   REGISTER  1- USED FOR BASE REGISTER FOR IECKSKPC                  * 59200013
*   REGISTER  3- USED AS A SECOND LEVEL RETURN REGISTER FOR           * 60000013
*              RETURNING FROM SCAN.                                   * 60800013
*   REGISTER  9- USED AS A WORK REGISTER.                             * 61600013
*   REGISTER 10- USED AS A WORK REGISTER                              * 62400013
*                                                                     * 63200013
*********************************************************************** 64000013
IECKSKPS START                                                          64800013
DREG0    EQU   0                                                        65600013
DREG1    EQU   1                                                        66400013
KREG     EQU   2                                                        67200013
RREG2    EQU   3                                                        68000013
LCBREG   EQU   4                                                        68800013
SPREG    EQU   5                                                        69600013
LGREG    EQU   7                                                        70400013
WREG1    EQU   9                                                        71200013
IREG     EQU   10                                                       72000013
EOSREG   EQU   11                                                       72800013
RREG1    EQU   14                                                       73600013
SREG     EQU   15                                                       74400013
         USING IECKLCB0,LCBREG                                          75200013
         BALR  DREG1,0             SAVE BASE REG                        76000013
         USING *,DREG1                                                  76800013
         LA    DREG0,1(0,SPREG)    STORE SCAN POINTER                   77600013
         L     SREG,4(0,LGREG)     GET SCAN ADDR                        78400013
         BALR  RREG2,SREG          LINKAGE TO SCAN SUBR                 79200013
         LH    WREG1,0(0,RREG1)    GET FIELD SIZE                       80000013
         SR    WREG1,IREG          ADJUST COUNT                         80800013
         EX    WREG1,MATCH         WAS SET FOUND                        81600013
         BC    8,RETURN            IF YES,RETURN                        82400013
         LR    SPREG,DREG0         ELSE INCR STORED SCAN PTR ONE BYTE   83200013
         TM    LCBERRST,X'04'      TEST FOR SCAN ERROR                  84000013
         BCR   8,DREG1             IF NOT RETURN TO TRY AGAIN           84800013
ERROR    MVI   LCBMPLRT,0          AND CANCEL MULTIPLE ROUTING          85600013
         LR    SPREG,EOSREG        RESET SCAN TO END OF BUFFER          86400013
RETURN   OR    WREG1,IREG          INCREMENT COUNT IF ODD               87200013
         USING CALL+1,RREG1                                             88000013
         B     RETLOC(WREG1)                                            88800013
         SPACE                                                          89600013
MATCH    CLC   2(1,RREG1),0(KREG)  COMPARE INSTRUCT                     90400013
CALL     DSECT                                                          91200013
SIZE     DS    H                                                        92000013
CHAR     DS    C                                                        92800013
RETLOC   DS    0H                                                       93600013
         EJECT                                                          94400013
         LCBD                                                           95200013
         END                                                            96000013
