         TITLE 'IECKSRCE  QTAM SOURCE (SOURCE)'                         00600013
*********************************************************************** 01200013
*                                                                     * 01800013
*NAME-                                                                * 02400013
*   IECKSRCE     QTAM SOURCE (SOURCE)                                 * 03000013
*                                                                     * 03600013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 04200013
*                                                                     * 04800013
*FUNCTION-                                                            * 05400013
*        DETERMINES THE VALIDITY OF THE SOURCE CODE FIELD OF AN       * 06000013
*   INCOMING MESSAGE HEADER.  THE ROUTINE LINKS TO THE SCAN ROUTINE   * 06600013
*   TO OBTAIN THE SOURCE CODE FROM THE HEADER.                        * 07200013
*        IF THE MESSAGE ORIGINATED FROM A NON-SWITCHED TERMINAL, THE  * 07800013
*   CONTENTS OF THE SOURCE FIELD ARE COMPARED WITH THE NAME OF THE    * 08400013
*   ORIGINATING TERMINAL (AS THE NAME APPEARS IN THE TERMINAL TABLE   * 09000013
*   ENTRY).  IF THE CHARACTERS MATCH, THE SOURCE CODE IS CONSIDERED   * 09600013
*   VALID.                                                            * 10200013
*        IF THE MESSAGE ORIGINATED FROM A SWITCHED TERMINAL, THE      * 10800013
*   CONTENTS OF THE SOURCE CODE FIELD ARE COMPARED WITH EACH TERMINAL * 11400013
*   ENTRY NAME IN THE TERMINAL TABLE, IN SUCCESSION, UNTIL A MATCH IS * 12000013
*   FOUND.  IF THE SOURCE CODE MATCHES ANY OF THE ENTRY NAMES IN THE  * 12600013
*   TERMINAL TABLE THAT IS IN THE SAME LINE GROUP AS THE LINE, IT IS  * 13200000
*   CONSIDERED VALID. IF NO MATCH IS FOUND AMONG ANY OF THE ENTRY     * 13800000
*   NAMES IN THE TABLE, THE CODE IS CONSIDERED INVALID.               * 14400000
*        IF THE SOURCE CODE IS VALID, THE ROUTINE PLACES ITS RELATIVE * 15000013
*   ADDRESS IN TTSKEY FIELD OF THE HEADER PREFIX IN THE BUFFER WHOSE  * 15600013
*   MESSAGE SEGMENT IS BEING OPERATED UPON.                           * 16200013
*        IF THE SOURCE CODE IS INVALID, THE ROUTINE SETS BIT 6        * 16800013
*   (INVALID SOURCE CODE) OF THE ERROR HALFWORD FOR THE LINE TO 1.    * 17400013
*        CONTROL RETURNS TO THE NEXT LPS INSTRUCTION.                 * 18000013
*                                                                     * 18600013
*ENTRY POINTS-                                                        * 19200013
*   IECKSRCE - EXPANSION OF SOURCE MACRO-INSTRUCTION GENERATES A      * 19800013
*              BALR TO THIS POINT, USING REGISTER 15 AS THE BRANCH    * 20400013
*              ADDRESS REGISTER AND REGISTER 14 AS THE RETURN         * 21000013
*              ADDRESS REGISTER.                                      * 21600013
*                                                                     * 22200013
*INPUT-                                                               * 22800013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 23400013
*   REGISTER  6- BUFFER ADDRESS                                       * 24000013
*   REGISTER  7- BASE REGISTER FOR THIS LPS.                          * 24600013
*   REGISTER  8- TERMINAL TABLE SOURCE ENTRY                          * 25200013
*   REGISTER 14- RETURN ADDRESS                                       * 25800013
*       REGISTER 14 ALSO POINTS TO A PARAMETER, A HALFWORD CONTAINING * 26400013
*       A SOURCE CODE FIELD-LENGTH INDICATOR.                         * 27000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 27600013
*                                                                     * 28200013
*OUTPUT-                                                              * 28800013
*   THE RELATIVE ADDRESS OF THE SOURCE CODE FIELD WILL BE PLACED IN   * 29400013
*                THE TTSKEY FIELD OF THE HEADER PREFIX.               * 30000013
*                                                                     * 30600013
*EXTERNAL ROUTINES-                                                   * 31200013
*   IECKSCAN - TO OBTAIN SOURCE CODE FROM HEADER.                     * 31800013
*                                                                     * 32400013
*EXITS-                                                               * 33000013
*   NORMAL- RETURN IS BY A BRANCH ON REGISTER 14 TO THE NEXT LPS      * 33600013
*   INSTRUCTION.                                                      * 34200013
*   ERROR- NONE.                                                      * 34800013
*                                                                     * 35400013
*TABLES/WORK AREAS-                                                   * 36000013
*   NONE.                                                             * 36600013
*                                                                     * 37200013
*ATTRIBUTES-                                                          * 37800013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 38400013
*                                                                     * 39000013
*NOTES-                                                               * 39600013
*   REGISTER  1- LOADED WITH THE ADDRESS OF TERMTBL BY THIS ROUTINE   * 40200013
*   REGISTER  2- POINTER TO COPY OF HEADER SOURCE CODE FIELD IN       * 40800013
*                IECKSCAN ROUTINE.                                    * 41400013
*   REGISTER  3- CONTAINS RETURN ADDRESS FOR IECKSCAN.                * 42000013
*   REGISTERS 9, 10, AND 12 ARE WORK REGISTERS.                       * 42600013
*                                                                     * 43200013
*********************************************************************** 43800013
IECKSRCE START                                                          44400013
*3170630000-636000                                                 000A 44700000
*1201772000-7728000                                               22437 44800000
* 642000                                                         A29210 44900000
DREG1    EQU   1                                                        45000013
KREG     EQU   2                                                        45600013
RREG2    EQU   3                                                        46200013
LCBREG   EQU   4                                                        46800013
MSREG    EQU   6                                                        47400013
LGREG    EQU   7                                                        48000013
TCREG    EQU   8                                                        48600013
WREG1    EQU   9                                                        49200013
WREG2    EQU   10                                                       49800013
IREG     EQU   12                                                       50400013
RREG1    EQU   14                                                       51000013
SREG     EQU   15                                                       51600013
DEBUCBAD EQU   32                                                       52200013
DCBDEBAD EQU   44                                                       52800013
QCBDCBPT EQU   17                                                  000A 53200000
         USING IECKPREF,MSREG                                           53400013
         USING IECKTERM,WREG2                                           54000013
         USING IECKLCB0,LCBREG                                          54600013
         L     SREG,4(0,LGREG)     GET SCAN ADDR                        55200013
         BALR  RREG2,SREG          LINKAGE TO SCAN SUBR                 55800013
         USING *,RREG2                                                  56400013
*                                                                       57000013
*                                                                       59400013
         SR    WREG2,WREG2                                              60000013
         IC    WREG2,LCBUCBX       GET RELATIVE LINE NUMBER-1           60600013
         SLL   WREG2,2             MULTIPLY BY FOUR AND SAVE            61200013
         L     WREG1,LCBDCBPT      GET DCB ADDRESS                      61800013
         L     WREG1,DCBDEBAD(WREG1) GET DEB ADDRESS                    62400013
         AR    WREG1,WREG2        BUMP TO APPROPRIATE UCB ADDRESS  000A 63000000
         L     WREG1,DEBUCBAD(WREG1) GET ADDRESS OF UCB            000A 63600000
         TM    17(WREG1),X'90'     IS THIS A DIAL LINE           A29210 64200000
         BZ    *+8                 BRANCH IF NO                         64800013
         L     TCREG,=V(TERMTBL)   SET TCREG TO BEGINNING OF TERMTBL    65400013
*                                                                       66000013
         L     DREG1,=V(TERMTBL)                                        66600013
         SR    WREG1,WREG1         CLEAR REG                            67200013
         IC    WREG1,4(0,DREG1)    GET MAX SIZE OF TERM NAME            67800013
         BCTR  WREG1,0             ADJUST COUNT                         68400013
         LA    WREG2,0(0,TCREG)    STORE TCREG                          69000013
         LA    IREG,8              CLEAR INCR REG                       69600013
         CLR   WREG2,DREG1        IS MSG FROM A DIAL LINE               70200000
         BE    DIALUP              IF YES,BRANCH                        70800013
         EX    WREG1,TERMCK        EXECT TST FOR VALID SOURCE TERM      71400013
         BE    2(0,RREG1)          AND RETURN                           72000013
SOURCERR OI    LCBERRST,X'02'      IF YES,SET SOURCE ERROR BIT          72600013
         B     2(0,RREG1)          AND RETURN                           73200013
COMPAR2  CL    WREG2,0(0,DREG1)    ELSE TEST FOR END OF TABLE           73800013
         BC    8,SOURCERR          IF EOT GO SET ERROR                  74400013
DIALUP   AR    WREG2,IREG          INDEX NEXT ENTRY                     75000013
         IC    IREG,TNTRYSZE       GET ENTRY SIZE                       75600013
         EX    WREG1,TERMCK        EXECT TST FOR TERM ENTRY             76200013
         BNE   COMPAR2             GO TEST NEXT ENTRY                   76800013
         L     WREG1,TQCBADDR-1   LOAD ADDRESS OF TERMINAL'S QCB   000A 76880000
         CLC   LCBDCBPT+1(3),QCBDCBPT(WREG1) COMPARE               000A 76960000
*              THE DCB FIELDS IN THE LCB AND QCB                   000A 77040000
         BNE   SOURCERR           BRANCH IF NOT IN SAME LINE GROUP 000A 77120000
         LR    TCREG,WREG2         PUT SOURCE ENTRY INTO TC REG         77400013
         SR    WREG2,DREG1         GET RELATIVE ADDR OF SOURCE ENTRY    78000013
         STH   WREG2,TTSKEY        STORE IN HEADER PREFIX               78600013
         STH   WREG2,LCBTTIND      SET REL TERM TBL ADDR OF TERM IN LCB 79200013
         B     2(0,RREG1)          RETURN                               79800013
         SPACE                                                          80400013
TERMCK   CLC   TERMID(1),0(KREG)   COMPARE TERMID TO HEADER SOURCE FLD  81000013
         EJECT                                                          81600013
         PREFIXD                                                        82200013
         EJECT                                                          82800013
         TERMTBLD                                                       83400013
         EJECT                                                          84000013
         LCBD                                                           84600013
         END                                                            85200013
