         TITLE 'IECKTIME  QTAM TIMESTAMP (TIMESTMP)'                    00900013
*********************************************************************** 01800013
*                                                                     * 02700013
*NAME-                                                                * 03600013
*       IECKTIME     QTAM TIME STAMP (TIMESTMP)                       * 04500013
*STATUS-  CHANGE LEVEL 001                                OS QTAM II  * 05400013
*                                                                     * 06300013
*                                                                     * 07200013
*FUNCTION-                                                            * 08100013
*       OBTAINS THE CURRENT TIME IN PACKED DECIMAL FORMAT (VIA A      * 09000013
*   TIME MACRO), UNPACKS IT, AND INSERTS A SPECIFIED PORTION OF THE   * 09900013
*   TIME INFORMATION IN THE MESSAGE HEADER.  THE TIME IS INSERTED IN  * 10800013
*   A FIELD CREATED BY THE EXPAND ROUTINE.  THE MAXIMUM FIELD SIZE    * 11700013
*   IS NINE CHARACTERS IN THE FORMAT BHH.MM.SS, WHERE B=BLANK,        * 12600013
*   HH=HOURS, MM=MINUTES, AND SS=SECONDS.  THE SCAN POINTER WILL      * 13500013
*   POINT TO THE LAST CHARACTER IN THE TIME.  LESSER FIELD SIZES      * 14400013
*   HAVE A SIMILAR FORMAT, TRUNCATED FROM THE RIGHT.                  * 15300013
*                                                                     * 16200013
*ENTRY POINTS-                                                        * 17100013
*   IECKTIME - EXPANSION OF THE TIMESTMP MACRO GENERATES A BALR TO    * 18000013
*        THIS LOCATION, USING REGISTER 15 AS THE BRANCH ADDRESS       * 18900013
*        REGISTER AND REGISTER 14 AS THE RETURN ADDRESS REGISTER.     * 19800013
*                                                                     * 20700013
*INPUT-                                                               * 21600013
*   REGISTER 14-                                                      * 22500013
*        REGISTER 14 SERVES AS A PARAMETER REGISTER FOR IECKEXPD.  THE* 23400013
*        PARAMETER LIST PASSED CONSISTS OF ONE ITEM- A HALFWORD       * 24300013
*        CONTAINING, IN BINARY, THE LENGTH OF THE TIME INFORMATION    * 25200013
*        FIELD TO BE INSERTED INTO THE MESSAGE HEADER.                * 26100013
*   REGISTER 15- ENTRY POINT REGISTER FOR EXPAND SUBROUTINE.          * 27000013
*                                                                     * 27900013
*OUTPUT-                                                              * 28800013
*   THE TIME WILL BE INSERTED INTO THE HEADER IF THERE IS ENOUGH SPACE* 29700013
*                                                                     * 30600013
*EXTERNAL ROUTINES-                                                   * 31500013
*   IECKEXPD - TO EXPAND THE HEADER TO ALLOW FOR INSERTION OF TIME    * 32400013
*        DATA.                                                        * 33300013
*                                                                     * 34200013
*EXITS-                                                               * 35100013
*   NORMAL- RETURN IS TO THE NEXT LPS INSTRUCTION BY BRANCHING ON THE * 36000013
*        CONTENTS OF REGISTER 3 PAST THE MACRO GENERATED CONSTANT.    * 36900013
*   ERROR- NONE.                                                      * 37800013
*                                                                     * 38700013
*TABLES/WORK AREAS-                                                   * 39600013
*   TIMEWORD - TIME RETURNED FROM SUPERVISOR IS STORED HERE FOR USE   * 40500013
*        BY UNPK INSTRUCTION.                                         * 41400013
*                                                                     * 42300013
*ATTRIBUTES-                                                          * 43200013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 44100013
*                                                                     * 45000013
*NOTES-                                                               * 45900013
*   REGISTER  0- USED AS WORK REGISTER.  WILL CONTAIN TIME RETURNED   * 46800013
*        FROM SUPERVISOR BY TIME MACRO.                               * 47700013
*   REGISTER  2- BASE REGISTER.                                       * 48600013
*   REGISTER  3- RETURN ADDRESS FROM EXPAND SUBROUTINE AND TO THE     * 49500013
*        NEXT LPS INSTRUCTION.                                        * 50400013
*   REGISTER  9- WORK REGISTER.                                       * 51300013
*   REGISTER 10- CONTAINS BEGINNING OF FIELD INSERTED ON RETURN FROM  * 52200013
*        IECKEXPD.  CONTAINS END OF FIELD INSERTED ON RETURN TO LPS.  * 53100013
*   REGISTER 12- USED AS WORK REGISTER.                               * 54000013
*                                                                     * 54900013
*********************************************************************** 55800013
IECKTIME START                                                          56700013
DREG0    EQU   0                                                        57600013
TMREG    EQU   0                                                        58500013
TREG     EQU   2                                                        59400013
RREG2    EQU   3                                                        60300013
WREG1    EQU   9                                                        61200013
WREG2    EQU   10                                                       62100013
IREG     EQU   12                                                       63000013
RREG1    EQU   14                                                       63900013
SREG     EQU   15                                                       64800013
         BALR  TREG,0                                                   65700013
         USING *,TREG                                                   66600013
         L     SREG,=V(IECKEXPD)                                        67500013
         BALR  RREG2,SREG          LINK TO EXPAND SUBR                  68400013
         LR    RREG2,RREG1         SAVE RETURN REG                      69300013
         TIME  DEC                 OBTAIN TIME AND DATE FROM SUPERVISOR 70200013
         ST    TMREG,TIMEWORD      PUT TIME INTO WORKWORD      HHMMSSTH 71100013
         UNPK  TIMEWORD(9),TIMEWORD(5)  UNPACK TIME DATA                72000013
         LA    IREG,TIMEWORD       GET WORKWORD ADDR                    72900013
SPACER   LH    DREG0,TWO           SPEC NUM OF CHARS BETWEEN PERIODS    73800013
EDIT     MVC   1(1,WREG2),0(IREG)  MOVE FIRST(NXT) BYTE TO TIME FLD     74700013
         LA    WREG2,1(0,WREG2)    INCR TIME FIELD POINTER              75600013
         LA    IREG,1(0,IREG)      INCR WORKWORD POINTER                76500013
         BCT   WREG1,*+8           IF NOT END OF FIELD,CONTINUE         77400013
         B     2(0,RREG2)          RETURN                               78300013
         BCT   DREG0,EDIT          TEST FOR PERIOD INSERTION            79200013
         MVI   1(WREG2),X'4B'      INSERT PERIOD INTO TIME              80100013
         LA    WREG2,1(0,WREG2)    INCR TIME FIELD POINTER              81000013
         BCT   WREG1,SPACER        IF NOT END OF FIELD,CONTINUE         81900013
         B     2(0,RREG2)          RETURN                               82800013
         SPACE                                                          83700013
TIMEWORD DS    1D                                                       84600013
         DS    1H                                                       85500013
TWO      DC    X'0002'             CONSTANT                             86400013
TIME     DC    X'21452233'         STORED TIME OF DAY                   87300013
         DS    0F                                                       88200013
         END                                                            89100013
