         TITLE 'IECKTRNS  QTAM TRANSLATE (TRANS)'                       01000013
*********************************************************************** 02000013
*                                                                     * 03000013
*NAME-                                                                * 04000013
*   IECKTRNS     QTAM TRANSLATE (TRANS)                               * 05000013
*                                                                     * 06000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 07000013
*                                                                     * 08000013
*FUNCTION-                                                            * 09000013
*        THIS ROUTINE TRANSLATES MESSAGE SEGMENTS FROM ONE CODE TO    * 10000013
*   ANOTHER.  THE NUMBER OF CHARACTERS TRANSLATED IS COMPUTED BY      * 11000013
*   SUBTRACTING THE ADDRESS OF THE FIRST BYTE TO BE TRANSLATED        * 12000013
*   FROM THE ADDRESS OF THE END OF THE SEGMENT.                       * 13000013
*                                                                     * 14000013
*ENTRY POINTS-                                                        * 15000013
*   IECKTRNS - EXPANSION OF THE TRANS MACRO GENERATES A BALR TO THIS  * 16000013
*        POINT, USING REGISTER 15 AS THE BRANCH ADDRESS REGISTER, AND * 17000013
*        REGISTER 14 AS THE RETURN ADDRESS REGISTER.                  * 18000013
*                                                                     * 19000013
*INPUT-                                                               * 20000013
*   REGISTER  1- CONTAINS THE ADDRESS OF THE TRANSLATION CODE TABLE   * 21000013
*        NAMED IN THE OPERAND OF THE MACRO.                           * 22000013
*   REGISTER  4- ADDRESS OF THE LCB                                   * 23000013
*   REGISTER  6- ADDRESS OF MESSAGE BUFFER.                           * 24000013
*   REGISTER 11- POINTER TO LAST BYTE IN SEGMENT                      * 25000013
*   REGISTER 14- RETURN ADDRESS                                       * 26000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE                              * 27000013
*                                                                     * 28000013
*OUTPUT-                                                              * 29000013
*   THE SPECIFIED CHARACTERS WILL BE TRANSLATED TO THE SPECIFIED CODE.* 30000013
*                                                                     * 31000013
*EXTERNAL ROUTINES-                                                   * 32000013
*   NONE.                                                             * 33000013
*                                                                     * 34000013
*EXITS-                                                               * 35000013
*   NORMAL- RETURN IS TO THE NEXT LPS INSTRUCTION BY BRANCHING ON     * 36000013
*           REGISTER 14.                                              * 37000013
*   ERROR- IF NO CHARACTERS ARE TO BE TRANSLATED, RETURN IS TO THE    * 38000013
*        NEXT LPS INSTRUCTION WITH NO TRANSLATION TAKING PLACE.       * 39000013
*                                                                     * 40000013
*TABLES/WORK AREAS-                                                   * 41000013
*   NONE.                                                             * 42000013
*                                                                     * 43000013
*ATTRIBUTES-                                                          * 44000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 45000013
*                                                                     * 46000013
*NOTES-                                                               * 47000013
*   REGISTER  9- WORK REGISTER.                                       * 48000013
*   REGISTER 10- WORK REGISTER.                                       * 49000013
*   REGISTER 12- USED AS WORK REGISTER.  USED TO CALCULATE THE        * 50000013
*        ADDRESS OF THE FIRST BYTE TO BE TRANSLATED.  CONTAINS        * 51000013
*        RELATIVE ADDRESS OF BYTE WITH RESPECT TO BEGINNING OF        * 52000013
*        THE BUFFER.                                                  * 53000013
*                                                                     * 54000013
*********************************************************************** 55000013
IECKTRNS START                                                          56000013
DREG1    EQU   1                                                        57000013
LCBREG   EQU   4                                                        58000013
MSREG    EQU   6                                                        59000013
WREG1    EQU   9                                                        60000013
WREG2    EQU   10                                                       61000013
EOSREG   EQU   11                                                       62000013
IREG     EQU   12                                                       63000013
RREG1    EQU   14                                                       64000013
SREG     EQU   15                                                       65000013
         USING *,SREG                                                   66000013
         USING IECKLCB0,LCBREG                                          67000013
         USING IECKPREF,MSREG                                           68000013
         LH    IREG,LCBTRST        GET REL ADDR OF FIRST CHAR TO TRANS  69000013
         TM    MSTATUS,X'01'       TEST FOR TEXT SEGMENT                70000013
         BC    8,USETRST           IF HEADER,IREG IS SET OK             71000013
         TM    MSTATUS,X'20'       IS EOB BIT ON                        72000013
         BC    1,USETRST           IF YES,IREG IS SET OK                73000013
         LA    IREG,TXSTRT-MSEGSZE GET REL ADDR OF FIRST CHAR TO TRANS  74000013
USETRST  LA    WREG2,8(MSREG,IREG)  GET ADDR OF FIRST BYTE TO TRANS     75000013
         LR    WREG1,EOSREG        GET ENDOF SEGMENT                    76000013
         SR    WREG1,WREG2         SUBTRACT START TO GET COUNT          77000013
         BCR   4,RREG1           EXIT IF NO CHARACTERS                  78000013
         EX    WREG1,CONV          EXECUTE TRANSLATE                    79000013
         BR    RREG1               RETURN TO LPS                        80000013
         SPACE                                                          81000013
CONV     TR    0(1,WREG2),0(DREG1)                                      82000013
         EJECT                                                          83000013
         LCBD                                                           84000013
         EJECT                                                          85000013
         PREFIXD                                                        86000013
         END                                                            87000013
