         TITLE 'IECKTYPE  QTAM MESSAGE TYPE (MSGTYPE)'                  01000013
*********************************************************************** 02000013
*                                                                     * 03000013
*NAME-                                                                * 04000013
*   IECKTYPE     QTAM MESSAGE TYPE (MSGTYPE)                          * 05000013
*                                                                     * 06000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 07000013
*                                                                     * 08000013
*FUNCTION-                                                            * 09000013
*        THIS ROUTINE LINKS TO THE SCAN ROUTINE TO LOCATE THE NEXT    * 10000013
*   FIELD IN THE MESSAGE HEADER.  THIS CHARACTER IS COMPARED WITH THE * 11000013
*   CHARACTER GIVEN AS THE OPERAND OF THE MSGTYPE MACRO-INSTRUCTION.  * 12000013
*   IF THE TWO CHARACTERS ARE IDENTICAL, THE INSTRUCTIONS BETWEEN THIS* 13000013
*   MSGTYPE MACRO AND THE NEXT MSGTYPE MACRO OR THE NEXT DELIMITER    * 14000013
*   MACRO INSTRUCTION ARE EXECUTED.                                   * 15000013
*        IF THE TWO CHARACTERS ARE NOT IDENTICAL, THE INSTRUCTIONS    * 16000013
*   BETWEEN THE MSGTYPE MACRO PERFORMING THE TEST AND THE NEXT        * 17000013
*   MSGTYPE MACRO OR DELIMITER ARE NOT EXECUTED.  THE SCAN POINTER IS * 18000013
*   RESET TO ITS POSITION PRIOR TO THE COMPARISON.  IN THIS INSTANCE, * 19000013
*   CONTROL PASSES TO THE NEXT MSGTYPE OR DELIMITER MACRO.            * 20000013
*                                                                     * 21000013
*ENTRY POINTS-                                                        * 22000013
*   IECKTYPE - EXPANSION OF MSGTYPE MACRO GENERATES A BALR TO THIS    * 23000013
*        POINT.  REGISTER 15 IS THE ENTRY POINT    REGISTER, AND      * 24000013
*        REGISTER 14 IS THE RETURN ADDRESS REGISTER.                  * 25000013
*                                                                     * 26000013
*INPUT-                                                               * 27000013
*   REGISTER  1- CONTAINS ADDRESS OF NEXT MSGTYPE INSTRUCTION.        * 28000013
*   REGISTER 14- RETURN ADDRESS                                       * 29000013
*        REGISTER 14 ALSO POINTS TO A PARAMETER LIST CONSISTING OF    * 30000013
*          1) A HALFWORD BINARY 1, INDICATING SINGLE BYTE LENGTH,AND  * 31000013
*          2) THE CHARACTER SPECIFIED IN THE MACRO STATEMENT.         * 32000013
*   REGISTER 15- ENTRY POINT.                                         * 33000013
*                                                                     * 34000013
*OUTPUT-                                                              * 35000013
*   NONE.                                                             * 36000013
*                                                                     * 37000013
*EXTERNAL ROUTINES-                                                   * 38000013
*   IECKSCAN - TO LOCATE NEXT FIELD IN THE MESSAGE HEADER.            * 39000013
*                                                                     * 40000013
*EXITS-                                                               * 41000013
*   NORMAL- IDENTICAL CHARACTERS - BRANCH ON REGISTER 14 TO NEXT LPS  * 42000013
*        INSTRUCTION.                                                 * 43000013
*           NON-IDENTICAL CHARACTERS - BRANCH ON REGISTER 1 TO NEXT   * 44000013
*           MSGTYPE MACRO OR DELIMITER.                               * 45000013
*   ERROR- NONE.                                                      * 46000013
*                                                                     * 47000013
*TABLES/WORK AREAS-                                                   * 48000013
*   NONE.                                                             * 49000013
*                                                                     * 50000013
*ATTRIBUTES-                                                          * 51000013
*   SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM MODE.       * 52000013
*                                                                     * 53000013
*NOTES-                                                               * 54000013
*   REGISTER  0- USED AS WORK REGISTER TO SAVE SCAN POINTER.          * 55000013
*   REGISTER  2- USED AS WORK REGISTER.  WILL CONTAIN ADDRESS OF NEXT * 56000013
*        NON-BLANK CHARACTER AS RETURNED BY SCAN.                     * 57000013
*   REGISTER  3- RETURN REGISTER FROM SCAN SUBROUTINE.                * 58000013
*   REGISTER 15- ADDRESS OF THIS ROUTINE AND OF SCAN ROUTINE.         * 59000013
*                                                                     * 60000013
*********************************************************************** 61000013
IECKTYPE START                                                          62000013
*3170702000-780000                                                 00PS 62500015
DREG0    EQU   0                                                        63000013
DREG1    EQU   1                                                        64000013
KREG     EQU   2                                                        65000013
RREG2    EQU   3                                                        66000013
SPREG    EQU   5                                                        67000013
LGREG    EQU   7                                                        68000013
RREG1    EQU   14                                                       69000013
SREG     EQU   15                                                       70000013
R9       EQU   9                                                   00PS 70200015
TWOREG   EQU   10                                                  00PS 70400015
WREG     EQU   12                                                  00PS 70600015
*                                                                  00PS 70800015
* SCAN OFF CHARACTERS INTO WORK AREA, REGISTER 14 POINTS TO FIELD  00PS 71000015
*   SIZE                                                           00PS 71200015
         LR    DREG0,SPREG         SAVE SCAN POINTER               00PS 71400015
         L     SREG,4(LGREG)       GET SCAN ROUTINE ADDRESS        00PS 71600015
         BALR  RREG2,SREG          LINK TO SCAN ROUTINE            00PS 71800015
*                                                                  00PS 72000015
* COMPUTE RETURN ADDRESS FOR EQUAL COMPARE                         00PS 72200015
*                                                                  00PS 72400015
         LH    RREG2,0(RREG1)      GET FIELD SIZE                  00PS 72600015
         LR    R9,RREG2            SAVE FIELD SIZE FOR COMPARE     00PS 72800015
         LA    RREG2,1(RREG2)     INCREMENT FIELD SIZE BY ONE      00PS 73000015
         SRL   RREG2,1            DIVIDE BY 2                      00PS 73200015
         SLL   RREG2,1            MULTIPLY BY 2                    00PS 73400015
         LA    RREG2,2(RREG1,RREG2) ADD RETURN ADDRESS PLUS TWO    00PS 73600015
*                                                                  00PS 73800015
* COMPARE MESSAGE TYPE CHARACTERS AND RETURN                       00PS 74000015
*                                                                  00PS 74200015
         BALR WREG,0                                               00PS 74400015
         USING *,WREG                                              00PS 74600015
         BCTR  R9,0                SUBTRACT ONE FOR COMPARE        00PS 74800015
         EX    R9,CMPR             WERE MESSAGE CHARACTERS FOUND   00PS 75000015
         BCR   8,RREG2            IF YES RETURN TO NEXT INSTRUCTION00PS 75200015
         LR    SPREG,DREG0         ELSE RESTORE SCAN POINTER       00PS 75400015
         BR    DREG1             AND GO TO NEXT MSGTYPE INSTRUCTION00PS 75600015
CMPR     CLC   2(1,RREG1),0(KREG)                                  00PS 75800015
         END                                                            78000013
