         TITLE 'IGE0004E QTAM III AUTOPOLL TIME OUT AND DATA CHECK'     00800013
*                                                                     * 00820018
*STATUS- CHANGE LEVEL 003                                             * 00840018
*                                                                     * 00860018
*FUNCTION- AFTER ADJUSTING TO THE FAILING CCW, THE ROUTINE TESTS THE  * 00880018
*   CCW.  FOR A POLL CCW, THE POLLING LIST ADDRESS AND ENTRY SIZE ARE * 00900018
*   ACCESSED.  THE NEW COUNT, OBTAINED BY ADDING THE RESIDUAL COUNT   * 00920018
*   TO THE ENTRY SIZE, IS PLACED IN THE POLL CCW.  THE DATA ADDRESS   * 00940018
*   FOR THE POLL CCW IS OBTAINED BY SUBTRACTING THE NEW COUNT FROM THE* 00960018
*   ORIGINAL COUNT AND ADDING THAT TO THE POLLING LIST ADDRESS.       * 00980018
*        FOR A READ RESPONSE CCW, THE POLLING LIST ADDRESS AND ENTRY  * 01000018
*   SIZE ARE ACCESSED. THE POLLING LIST IS SEARCHED FOR AN ENTRY WITH * 01020018
*   THE INDEX BYTE THE SAME AS THE ONE STORED.  THE NEW COUNT,OBTAINED* 01040018
*   BY SUBTRACTING THE LIST ADDRESS FOR THE ENTRY FROM THE LIST       * 01060018
*   ADDRESS OF THE POLL CCW AND ADDING THE COUNT IN THE SECOND POLL   * 01080018
*   CCW, IS PLACED IN THE FIRST POLL CCW. THE DATA ADDRESS FOR THE    * 01100018
*   POLL CCW IS THE ADDRESS FOUND IN THE ENTRY OF THE LIST.           * 01120018
*        THE IOB IS SET TO RESTART ON THE FIRST CCW OF THE CHANNEL    * 01140018
*   PROGRAM. IF THE RETRY HAS FAILED TWO TIMES, EITHER TIMEOUT IS SET * 01160018
*   IN THE ERROR HALFWORD AND IN LCBINCAM OR DATA CHECK IS SET IN     * 01180018
*   LCBINCAM. ON A DATA CHECK FOR A 2701 CONTROL UNIT, THE DIAGNOSTIC * 01200018
*   WRITE/READ EXIT IS SET.  ALSO FOR A PERMANENT ERROR LCBERRCT+1 IS * 01220018
*   SET TO INDICATE POST WITH MESSAGE.                                * 01240018
*        EXIT FROM THE ROUTINE IS TO THE LINE ERROR RECORDING WHICH   * 01260018
*   DOES THE EXCP TO RESTART THE CHANNEL PROGRAM.                     * 01280018
*                                                                     * 01300018
*ENTRY POINTS-                                                        * 01320018
*        IGE0004E- CONTROL IS PASSED HERE BY IGE0104E AND IGE0204E    * 01340018
*                                                                     * 01360018
*INPUT-                                                               * 01380018
*   REGISTER 1 - RQE ADDRESS                                          * 01400018
*   REGISTER 15- ENTRY POINT                                          * 01420018
*                                                                     * 01440018
*OUTPUT-                                                              * 01460018
*   BRANCHES TO THE LINK ROUTINE WITH REGISTER 13 CONTAINING THE CODE * 01480018
*   FOR THE LINE ERROR RECORDING ROUTINE. LCBERRCT+1=X'02' FOR MESSAGE* 01500018
*   FOR TIMEOUT ERRORS LCBINCAM+1=X'03' AND THE TIMEOUT BIT IS SET IN * 01520018
*   THE ERROR HALF WORD.                                              * 01540018
*   FOR DATA CHECK ERRORS LCBINCAM+1=X'01'. IF A 2701 CONTROL UNIT,   * 01560018
*   LCBINCAM+1=X'04'.                                                 * 01580018
*                                                                     * 01600018
*EXTERNAL REFERENCES- NONE                                            * 01620018
*                                                                     * 01640018
*EXITS,NORMAL-                                                        * 01660018
*        EXIT IS MADE BY A BRANCH TO THE LINKAGE ROUTINE POINTED TO BY* 01680018
*   CVT+44 WITH REGISTER 13 CONTAINING 2046 TO INDICATE LINKAGE       * 01700018
*   TO IGE0204F.                                                      * 01720018
*                                                                     * 01740018
*EXITS,ERROR- NONE                                                    * 01760018
*                                                                     * 01780018
*TABLES/WORKAREAS- NONE                                               * 01800018
*                                                                     * 01820018
*ATTRIBUTES- SERIALLY REUSABLE,DISABLED,TRANSIENT,ONLY LOADABLE,      * 01840018
*   SUPERVISOR MODE,REFRESHABLE                                       * 01860018
*                                                                     * 01880018
* 288000,416000                                                   24943 01900018
*              REGISTER USAGE                                           02400013
         SPACE 2                                                        03200013
IGE0004E CSECT                                                          04000013
TSTREG   EQU   1                       TWELVE STAR ADDRESS              04800013
UCBREG   EQU   2                       UNIT CONTROL BLOCK ADDRESS       05600013
DCBREG   EQU   3                       DATA CONTROL BLOCK ADDRESS       06400013
CCWREG   EQU   4                       ADDRESS OF CHANNEL COMMAND WORD  07200013
LCBREG   EQU   5                       WORK REGISTER                    08000013
W1       EQU   6                       WORK REGISTER                    08800013
W2       EQU   7                       WORK REGISTER                    09600013
W3       EQU   8                       WORK REGISTER                    10400013
W4       EQU   9                       WORK REGISTER                    11200013
W6       EQU   11                      WORK REGISTER                    12000013
W7       EQU   12                      WORK REGISTER                    12800013
LINKREG  EQU   13                      NAME OF NEXT ERP MODULE          13600013
RETREG   EQU   14                                                       14400013
BASEREG  EQU   15                      BASE REGISTER                    15200013
         SPACE 2                                                        16000013
         USING *,BASEREG                                                16800013
         USING IECKLCB0,LCBREG                                          17600013
         L     LCBREG,X4(TSTREG)        IOB ADDRESS                     18400013
         SH    LCBREG,H48                 ADJUST TO LCB                 19200013
         L     CCWREG,LCBCSW            FAILING CCW+8                   20000013
         SH    CCWREG,H8                  ADJUST TO FAILING CCW         20800013
         CLI   X0(CCWREG),X9           IS THIS A POLLCCW                21600013
         BNE   TORDPOLL                NO, READ RESPONSE TO AUTOPOLL    22400013
         BAL   W2,TOPOLSUB             GET POLL LIST ADDRESS            23200013
         AH    W4,LCBCSW+6             ADD RESIDUAL COUNT TO WIDTH      24000013
         AH    W6,X6(CCWREG)           ADD ORIGINAL COUNT TO ADDRESS    24800013
         SR    W6,W4                   SUBTRACT WIDTH AND RESIDUAL      25600013
*                                        COUNT FROM ADDRESS             26400013
TOCOM    STH   W4,LCBCPA+14            STORE NEW COUNT                  27200013
         ST    W6,LCBCPA+8             STORE NEW DATA ADDRESS           28000013
XXX      MVC   LCBERRCT(1),LCBERRCT+1   RETRY COUNT              A24943 28800018
         MVI   LCBERRCT+1,X0           CLEAR LINK BYTE                  29600013
         NI    LCBERRCT,X3             ONLY  RETRY BITS                 30400013
         CLI   LCBERRCT,X3             HAS RETRY FAILED                 31200013
         BE    TOSWT                   YES                              32000013
         LA    W1,LCBCPA               RESTART AT FIRST                 32800013
         ST    W1,LCBSTART-1           INITIALIZE IOBSTART              33600013
         LR    W2,TSTREG               SAVE RB POINTER                  34400013
TOLERB   L     RETREG,X10              CVT ADDRESS                      36000013
         L     RETREG,X2C(RETREG)      LINK ROUTINE ADDRESS             36800013
         LA    LINKREG,LERBMOD         NAME OF LINE ERROR RECORDING     37600013
         BR    RETREG                  LINK                             38400013
TORDPOLL BAL   W2,TOPOLSUB             GET  POLL LIST ADDRESS           39200013
         LR    W7,W3                   SAVE POLLING LIST ADDRESS        40000013
TOLOOP   CLI   X1(W7),XFE              END OF LIST                      40800013
         BC    8,XXX              YES RESTART WITH OLD POLL      A24943 41600018
         AR    W7,W4                   BUMP TO NEXT ENTRY               42400013
         CLC   X0(1,W6),X0(W7)         INDEX BYTE COMPARE               43200013
         BNE   TOLOOP                  NO, CHECK FOR END OF LIST        44000013
         BCTR  W4,0                    REDUCE ENTRY SIXE BY ONE         44800013
         SR    W7,W4                   W7 = ADDRESS OF POLL CHARS       45600013
         LR    W6,W7                   SET FOR COMMON CODE              46400013
         LH    W4,LCBCPA+38            COUNT OF 2ND POLL CCW            47200013
         SLR   W3,W7                   1ST - MATCH (NEGATIVE)           48000013
         LA    W4,X1(W3,W4)            W4 = NEW COUNT                   48800013
         B     TOCOM                   USE COMMON CODE                  49600013
* THE FOLLOWING SUBROUTINE IS USED TO FIND THE POLLING LIST AND THE     50400013
* LENGTH OF THE POLLING LIST ENTRIES. REGISTERS ON EXIT ARE             51200013
* W3 - ADDRESS OF THE POLLING LIST                                      52000013
* W4 - LENGTH OF EACH ENTRY (2 OR 3 BYTES)                              52800013
* W6 - OP CODE AND DATA ADDRESS OF FAILING CCW                          53600013
* W7 - FLAGS, TP OP CODE AND COUNT OF F AILING CCW                      54400013
TOPOLSUB LM    W6,W7,X0(CCWREG)        FAILING CCW TO W6 AND W7         55200013
         L     W3,LCBCPA+32            POLL LIST ADDRESS FROM POLL CCW  56000013
         BCTR  W3,0                    BACK UP TO CHECK ENTRY SIZE      56800013
         LA    W4,X3                   ASSUME 3 BYTE ENTRIES            57600013
         TM    X0(W3),X20              CHECK LENGTH OF ENTRIES          58400013
         BCR   1,W2                    THREE, RETURN                    59200013
         BCTR  W4,W2                   DECREMENT COUNT AND RETURN       60000013
TOSWT    TM    LCBSENSE,X1         TIME OUT                             60800013
         BZ    DCTRLUNT            NO, DATA CKECK                       61600013
         MVI   LCBINCAM+1,X3       TIME OUT UPDATE                      62400013
         OI    LCBERRST+1,X40          SET ERROR                        63200013
TOPOST   MVI   LCBERRCT+1,X2           POST WITH MESSAGE                64000013
         B     TOLERB                                                   64800013
DCTRLUNT MVI   LCBINCAM+1,X1       DATA CHECK UPDATE                    65600013
         LH    UCBREG,X2(TSTREG)   UCB ADDRESS                          66400013
         MVC   LCBERCCW+7(1),19(UCBREG)                                 67200013
         NI    LCBERCCW+7,XF       DEVICE TYPE                          68000013
         CLI   LCBERCCW+7,X2                                            68800013
         BNE   TOPOST              NO DIAG W/R                          69600013
         MVI   LCBERRCT+1,X4       EXIT TO DIAG W/R                     70400013
         B     TOLERB                                                   71200013
         EJECT                                                          72000013
*                                                                       72800013
*        CONSTANTS                                                      73600013
*                                                                       74400013
X0       EQU   0                                                        75200013
X1       EQU   1                                                        76000013
X2       EQU   2                                                        76800013
X3       EQU   3                                                        77600013
X4       EQU   4                                                        78400013
X9       EQU   9                                                        79200013
XF       EQU   15                                                       80000013
X10      EQU   16                                                       80800013
X2C      EQU   44                                                       81600013
X40      EQU   64                                                       82400013
X6       EQU  6                                                         83200013
X20      EQU   32                                                       84000013
XFE     EQU   254                                                       84800013
EREXCP   EQU   15                                                       85600013
LERBMOD  EQU   2046                                                     86400013
H8       DC    AL2(8)                                                   87200013
H48      DC    AL2(48)                                                  88000013
         EJECT                                                          88800013
         LCBD  QTAM=3                                                   89600013
         END                                                            90400013
