*********************************************************************** 00006021
*                                                                     * 00012021
*STATUS - CHANGE LEVEL=18         JANUARY 1971                        * 00018021
*                                                                     * 00024021
*FUNCTION- AFTER INITIALIZING, THE ROUTINE INDICATES A DATA CHECK UP- * 00030021
*   DATE FOR THE LINE ERROR RECORDING MODULE IN LCBINCAM + 1 (X'01'). * 00036021
*        IF THE FAILING CCW IS A READ:                                * 00042021
*   FOR A TEXT TRANSFER AND NO PERMANENT ERROR, LINKAGE IS MADE TO THE* 00048021
*   LINE ERROR RECORDING ROUTINE FOR DATA CHECK UPDATE WITH AN INDICA-* 00054021
*   TION FOR NO MESSAGE.                                              * 00060021
*   FOR NO TEXT TRANSFER:                                             * 00066021
*        (A)IF A READ TWX ID RESPONSE, THE START OF THE RETRY CHANNEL * 00072021
*   PROGRAM IS SET SO AS TO DISABLE AND REDIAL BEFORE THE RETRY. LINK-* 00078021
*   AGE IS MADE TO LINE ERROR RECORDING FOR DATA CHECK UPDATE.        * 00084021
*        (B)IF A READ RESPONSE TO AUTOPOLLING, LINKAGE IS MADE TO THE * 00090021
*   TIME-OUT AND DATA CHECK FOR AUTOPOLL MODULE.                      * 00096021
*        (C)IF A SWITCHED CONNECTION, THE ROUTINE SETS UP FOR A RETRY * 00102021
*   AFTER THE DISABLE-DIAL OR DISABLE-ENABLE SEQUENCE. LINKAGE IS MADE* 00108021
*   TO THE LINE ERROR RECORDING ROUTINE FOR DATA CHECK UPDATE.        * 00114021
*        (D)OTHERWISE, RETRY IS SET TO START WITH THE FIRST CCW, AND  * 00120021
*   LINKAGE IS MADE TO THE LINE ERROR RECORDING MODULE.               * 00126021
*        IF THE FAILING CCW IS A WRITE:                               * 00132021
*   FOR A TYPE I ADAPTER, THE ACTION TAKEN IS THE SAME AS FOR A READ. * 00138021
*   FOR A WTTA ADAPTER, LINKAGE IS MADE TO THE LINE ERROR RECORDING   * 00144021
*   ROUTINE WITH A PERMANENT ERROR INDICATED.                         * 00150021
*   FOR OTHER ADAPTERS, THE ROUTINE INDICATES NO LINKAGE TO THE LINE  * 00156021
*   ERROR RECORDING ROUTINE AND THE 'SHOULD NOT OCCUR' BIT IN THE     * 00162021
*   ERROR HALFWORD OF THE LCB. A PERMANENT ERROR CONDITION EXISTS.    * 00168021
*        IF THE FAILING CCW IS A POLL, LINKAGE IS MADE TO THE TIMEOUT * 00174021
*   AND DATA CHECK FOR AUTOPOLL MODULE.                               * 00180021
*        IF THE FAILING CCW IS A BREAK FOR WTTA ADAPTER, IT IS TREATED* 00186021
*   AS A PERMANENT ERROR.                                             * 00192021
*        IF RETRY HAS FAILED TWO TIMES, THEN IT IS CONSIDERED A       * 00198021
*   PERMANENT ERROR.                                                  * 00204021
*   ON A 2701 CONTROL UNIT,                                           * 00210021
*        (A)IF THE LER ROUTINE IS REQUIRED, AN INDICATION (X'04')     * 00216021
*   FOR DIAGNOSTIC WRITE/READ IS SET IN LCBERRCT + 1 AND LINKAGE IS   * 00222021
*   MADE TO THE LER ROUTINE.                                          * 00228021
*        (B)IF THE LER ROUTINE IS NOT REQUIRED, LINKAGE IS MADE TO    * 00234021
*   THE DIAGNOSTIC WRITE/READ ROUTINE.                                * 00240021
*   OTHERWISE IF LER IS REQUIRED, POST WITH MESSAGE IS INDICATED IN   * 00246021
*   LCBERRCT + 1 FOR LER. IF NO LER IS REQUIRED, LINKAGE IS MADE TO   * 00252021
*   THE POST MODULE TO POST WITH MESSAGE.                             * 00258021
*                                                                     * 00264021
*ENTRY POINTS-                                                        * 00270021
*         IGE0104E - CONTROL IS PASSED HERE BY IGE0004A.              * 00276021
*                                                                     * 00282021
*INPUT-                                                               * 00288021
*   REGISTER 1 - RQE ADDRESS                                          * 00294021
*   REGISTER 15- ENTRY POINT                                          * 00300021
*                                                                     * 00306021
* OUTPUT -                                                            * 00312021
*    FOR ERROR EXCP - LCBSTART POINTS TO THE CCW TO RESTART WITH.     * 00318021
*    FOR BRANCHING TO XCTL ROUTINE, REGISTER 13 CONTAINS CODE FOR NEXT* 00324021
*    MODULE TO CALL.                                                  * 00330021
*                                                                     * 00336021
*EXTERNAL REFERENCES-                                                 * 00342021
*        IOS SVC 15 ROUTINE (ERROR EXECUTE CHANNEL PROGRAM)           * 00348021
*        IOS SVC 3 ROUTINE (TO RETURN TO IOS)                         * 00354021
*EXITS, NORMAL-                                                       * 00360021
*         TO RESTART THE CHANNEL PROGRAM, AN SVC 15 IS EXECUTED       * 00366021
*    FOLLOWED BY AN SVC 3 TO RETURN TO IOS.                           * 00372021
*         TO XCTL TO THE NEXT ROUTINE, THE ROUTINE EXITS VIA A BRANCH * 00378021
*    REGISTER 14 WITH THE MODULE CODE IN REGISTER 13.                 * 00384021
*                                                                     * 00390021
*EXITS, ERROR- NONE                                                   * 00396021
*                                                                     * 00402021
*TABLES/WORKAREAS-  NONE                                              * 00408021
*                                                                     * 00414021
*ATTRIBUTES- SERIALLY REUSABLE, DISABLED, TRANSIENT, ONLY LOADABLE,   * 00420021
*   SUPERVISOR MODE, REFRESHABLE                                      * 00426021
*                                                                     * 00432021
* CHARACTER CODE DEPENDENCY - NONE                                    * 00438021
*                                                                     * 00444021
* NOTES - NONE                                                        * 00450021
*                                                                     * 00456021
*********************************************************************** 00462021
         TITLE 'IGE0104E QTAM ERP DATA CHECK MODULE'                    00500013
IGE0104E CSECT                                                          01000013
*83660580000                                                      20800 01200017
*1203387000                                                       23168 01300018
*2719247000-253000,270000,340700-344200                            000C 01600017
*2719662000-666000,762000,797000                                   000C 01700017
*3410245000                                                        00PS 01800017
*A000060-004620                                                  S21016 01900021
*              REGISTER USAGE                                           02000013
         SPACE 2                                                        02500013
W8       EQU   0                                                        03000013
TSTREG   EQU   1                       TWELVE STAR ADDRESS              03500013
UCBREG   EQU   2                       UNIT CONTROL BLOCK ADDRESS       04000013
DCBREG   EQU   3                       DATA CONTROL BLOCK ADDRESS       04500013
CCWREG   EQU   4                       ADDRESS OF CHANNEL COMMAND WORD  05000013
LCBREG   EQU   5                       LINE CONTROL BLOCK ADDRESS       05500013
W1       EQU   6                       WORK REGISTER                    06000013
W2       EQU   7                       WORK REGISTER                    06500013
W3       EQU   8                       WORK REGISTER                    07000013
W4       EQU   9                       WORK REGISTER                    07500013
W5       EQU   10                      WORK REGISTER                    08000013
W6       EQU   11                  WORK REGISTER                        08500013
W7       EQU   12                  WORK REGISTER                        09000013
LINKREG  EQU   13                      NAME OF NEXT ERP MODULE          09500013
RETREG   EQU   14                                                       10000013
BASEREG  EQU   15                      BASE REGISTER                    10500013
         SPACE 2                                                        11000013
         USING *,BASEREG                                                11500013
         USING IECKLCB0,LCBREG                                          12000013
         L     LCBREG,X4(TSTREG)        IOB ADDRESS                     12500013
         SH    LCBREG,H48               ADJUST TO LCB                   13000013
         L     CCWREG,LCBCSW            CCW+8                           13500013
         SH    CCWREG,H8                ADJUST TO FAILING CCW           14000013
         LH    UCBREG,X2(TSTREG)        UCB ADDRESS                     14500013
         LA    W5,DCLERB               FOR LINE ERROR RECORDING         15000013
         LA    W8,LCBCPA               ASSUME RESTART AT FIRST CCW      15500013
         LA    LINKREG,LERBMOD         ASSUME LER IS NEXT LOAD          16000013
         SR    W1,W1                                                    16500013
         IC    W1,LCBERRCT             ERP RETRY COUNTER                17000013
         AH    W1,LCBERRST             ADD ERROR HALF WORD              17500013
*                                        W3 NOW CONTAINS ERROR HALF     18000013
*                                        WORD WITH COMBINED COUNT       18500013
         LA    W1,X1(W1)               ADD ONE                          19000013
         NI    LCBERRST+1,XFC           ZERO EOBLC COUNTER              19500013
         CLI   X0(CCWREG),X2           FAILING CCW A READ               20000013
         BE    DCTEXT                  YES CHECK TEXT TRANSFER          20500013
         BH    DCKPOLL                 NOT WRITE, CHECK POLL            21000013
         CLI   X0(CCWREG),X1           IS THIS A WRITE OP CODE          21500013
         BE    *+12                    YES                              22000013
         TM    LCBCECB,X1              IS THIS A READ OPERATION         22500013
         BO    DCTXTER                 YES                              23000013
         EX    0,DCTRLUNT              YES, CHECK ADAPTER TYPE          23500013
         NI    LCBERCCW+7,XF0          MASK OUT CONTROL UNIT            24000013
         CLI   LCBERCCW+7,X40  TELETYPE I ADAPTER                  00PS 24300017
         BE    DCTEXT                  YES                         000C 24700017
         CLI   LCBERCCW+7,X60          WTTA ADAPTER                000C 24900017
         BNE   DCSNO                   NO,SHOULD NOT OCCUR         000C 25100017
         B     DCTXTER                 BRANCH IF YES               000C 25300017
DCTEXT   TM    X5(CCWREG),X30          TEXT TRANSFER INDICATED BY TP    25500013
*                                        OP CODE                        26000013
         BNZ   DCTXTER                 YES                              26500013
         CLI   X5(CCWREG),X7           READ TWX/WTTA ID RESPONSE   000C 27000017
         BE    DCFIRST                 YES, MUST HANG UP(DISABLE) AND   27500013
*                                        REDIAL TO RETRY                28000013
         CLI   X5(CCWREG),XA       AUTOPOLL READ RESPONSE               28500013
         BE    DCRDPOLL            YES                                  29000013
         TM    LCBCPA+8,X20            IS THE SECOND CCW A DIAL OR      29500013
*                                        ENABLE COMMAND, INDICATES A    30000013
*                                        SWITCHED CONNECTION            30500013
         BZ    DCFIRST                 NO, RETRY AT FIRST CCW           31000013
         LA    W8,LCBCPA+16            IF SWITCHED CONNECTION, RETRY    31500013
*                                        AFTER THE DISABLE-DIAL OR      32000013
DCFIRST  STC   W1,LCBERRCT             STORE UPDATED COUNT              32500013
         NI    LCBERRCT,X3              ONLY RETRY BITS                 33000013
         CLI   LCBERRCT,X3              HAS RETRY FAILED                33500013
         BNL   DCTRLUNT                 YES, PERMANENT ERROR            34000013
         EX    0,DCTRLUNT              CHECK ADAPTER TYPE          000C 34070017
         NI    LCBERCCW+7,XF0          MASK OUT CONTROL UNIT BITS  000C 34140017
         CLI   LCBERCCW+7,X60          WTTA ADAPTER                000C 34210017
         BNE   DCEXCP                  NO                          000C 34280017
         SH    CCWREG,H8               PREPARE RESTART FOR WTTA    000C 34350017
         LR    W8,CCWREG               ON WRITE WRU CCW            000C 34420017
DCEXCP   ST    W8,LCBSTART-1           INITIALIZE IOBSTART              34500013
         BALR  W5,W5                   IF LINE ERROR RECORDING          37500013
*                                        REQUIRED GO TO DCLERB ELSE,    38000013
*                                        RETURN VIA W5                  38500013
         SVC   EREXCP                  ERROR EXECUTE CHANNEL PROG.23168 38700018
         SVC   RETURN                  RETURN                           39000013
DCPERM  MVI   LCBERRCT+1,X2           INDICATE LINE ERROR RECORDING TO  40000013
*                                        EXIT TO POST AND POST TO WRITE 40500013
*                                        MESSAGE                        41000013
         BALR  W5,W5                   IF LINE ERROR RECORDING          41500013
*                                        REQUIRED GO TO DCLERB ELSE,    42000013
*                                        RETURN VIA W5                  42500013
         LA    LINKREG,POSTMOD(LINKREG) NAME OF POST MODULE             43000013
         B     DCLINK                                                   43500013
DCBRIN   BR    W5                      RETURN TO INSTRUCTION FOLLOWING  44000013
*                                        BALR FOR LINE ERROR RECORDING  44500013
DCTXTER  STH   W1,LCBERRST              STORE UPDATED HALF WORD         45000013
         TM    LCBERRST+1,X3            HAS RETRY FAILED                45500013
         BO    DCPERM                   Y&ST -&R-A-&-T &RR--            46000013
         MVI   LCBERRCT+1,X1           INDICATE LINE ERROR RECORDING TO 46500013
*                                        POST WITHOUT MESSAGE           47000013
**********************************************************************  47500013
* "NOTE : FOLLOWING CODE IS EXECUTED WITHOUT A BASE REGISTER            48000013
*   WHEN ENTERED VIA BALR                                               48500013
DCLERB   MVI   LCBINCAM+1,X1           INDICATE DATA CHECK UP DATE FOR  49000013
*                                        LINE ERROR RECORDING           49500013
DCLINK   L     RETREG,X10              CVT ADDRESS                      50000013
         L     RETREG,X2C(RETREG)      ADDRESS OF LINK ROUTINE          50500013
         BR    RETREG                  LINK TO NEXT MODULE              51000013
**********************************************************************  51500013
DCSNO    LA    W5,DCBRIN               SET SO NO LINE ERROR RECORDING   52000013
         OI    LCBERRST,X1             INDICATE SHOULD NOT OCCUR ERROR  52500013
DCTRLUNT MVC   LCBERCCW+7(1),D19(UCBREG) CTRL UNIT TYPE TO WORK AREA    53000013
         NI    LCBERCCW+7,X0F          MASK OUT ADAPTER TYPE            53500013
         CLI   LCBERCCW+7,X2           CONTROL UNIT A 2701              54000013
         BNE   DCPERM             NOT 2701, INDICATE PERM ERROR   20800 58000017
DCDIAGWR MVI   LCBERRCT+1,X4           INDICATE LINE ERROR RECORDING TO 63000013
*                                        EXIT TO DIAGNOSTIC WRITE/READ  63500013
         BALR  W5,W5                   IF LINE ERROR RECORDING          64000013
*                                        REQUIRED GO TO DCLERB ELSE,    64500013
*                                        RETURN VIA W5                  65000013
         LA    LINKREG,DIAGLOD         NAME OF DIAGNOSTIC WRITE/READ    65500013
         B     DCLINK                    MODULE                         66000013
DCKPOLL  CLI   X0(CCWREG),XD           IS IT A BREAK CCW           000C 66200017
         BE    DCTRLUNT                YES                         000C 66400017
         CLI   X0(CCWREG),X9           IS OT A POLL CCW            000C 66600017
         BNE   DCSNO                   NO, SHOULD NOT OCCUR             67000013
DCRDPOLL LA    LINKREG,POLMOD      POLL MODULE                          67500013
         STH   W1,LCBERRCT         ERROR HALF WORD                      68000013
         B     DCLINK                                                   68500013
         EJECT                                                          69000013
*                                                                       69500013
*        CONSTANTS                                                      70000013
*                                                                       70500013
         SPACE 2                                                        71000013
X0       EQU   0                                                        71500013
X1       EQU   1                                                        72000013
X2       EQU   2                                                        72500013
X3       EQU   3                                                        73000013
X4       EQU   4                                                        73500013
X5       EQU   5                                                        74000013
X6       EQU   6                                                        74500013
X7       EQU   7                                                        75000013
X9       EQU   9                                                        75500013
XA       EQU   10                                                       76000013
XD       EQU   13                                                  000C 76200017
X0F      EQU   15                                                       76500013
X10      EQU   16                                                       77000013
X20      EQU   32                                                       77500013
X2C      EQU   44                                                       78000013
X2F      EQU   47                                                       78500013
X30      EQU   48                                                       79000013
X40      EQU   64                                                       79500013
X60      EQU   96                                                  000C 79700017
X90      EQU   144                                                      80000013
XF0      EQU   240                                                      80500013
XFC      EQU   252                                                      81000013
XFE      EQU   254                                                      81500013
D17      EQU   17                                                       82000013
D19      EQU   19                                                       82500013
H8       DC    AL2(8)                                                   83000013
H48      DC    AL2(48)                                                  83500013
EREXCP   EQU   15                                                       84000013
RETURN   EQU   3                                                        84500013
POLMOD   EQU   45                                                       85000013
DIAGLOD  EQU   1046                    NAME OF DIAG W/R MODULE          85500013
LERBMOD  EQU   2046                    NAME OF LINE ERROR REC MODULE    86000013
POSTMOD  EQU   2999                    NAME OF POST MODULE              86500013
         SPACE 2                                                        87000013
         EJECT                                                          87500013
         LCBD  QTAM=3                                                   88000013
         END                                                            88500013
