         TITLE 'IGE0304E QTAM INTERVENTION REQUIRED MODULE'             00500013
IGE0304E CSECT                                                          01000013
*********************************************************************** 01002021
*                                                                     * 01004021
* STATUS-CHANGE LEVEL=18     JANUARY 1971                             * 01006021
*                                                                     * 01008021
* FUNCTION - AFTER ADJUSTING TO THE FAILING CCW, THE EOBLC RETRY      * 01010021
*    COUNTER IN LCBERRST IS ZEROED.  EXCEPT FOR 'SHOULD NOT OCCUR'    * 01012021
*    ERRORS AND TEXT TRANSFER, ONE IS ADDED TO THE ERROR COUNTER IN   * 01014021
*    THE LCB (LCBERRCT).  EXCEPT FOR 'SHOULD NOT OCCUR' ERRORS, CODE  * 01016021
*    FOR LER (X'02') IS SET IN LCBINCAM + 1.                          * 01018021
*         IF THE FAILING CCW IS A READ OR WRITE:                      * 01020021
*         (1) IF A READ RESPONSE TO AUTOPOLL, THE START OF THE POLLING* 01022021
*    LIST AND COUNT IS OBTAINED FROM THE CHANNEL PROGRAM AREA.  THE   * 01024021
*    POLLING LIST IS SEARCHED FOR INDEX BYTE EQUAL TO THE INDEX BYTE  * 01026021
*    POINTED TO BY THE FAILING CCW.  IF FOUND, THE DATA ADDRESS AND   * 01028021
*    COUNT ARE STORED IN THE FIRST POLL CCW IN THE CHANNEL PROGRAM    * 01030021
*    AREA.  IF NOT FOUND BY END OF LIST (X'FE'), NO CHANGE IS MADE.   * 01032021
*    IF THE RETRY HAS FAILED TWICE, 'POST WITH MESSAGE' (X'00') AND   * 01034021
*    'EXIT TO POST' (X'02') IS INDICATED IN LCBERRCT + 1.  LINKAGE IS * 01036021
*    MADE TO THE LINE ERROR RECORDING ROUTINE, IGE0204F.  IF THE RETRY* 01038021
*    HAS NOT BEEN TRIED TWICE, THE LCBSTART FIELD IS SET TO RETRY ON  * 01040021
*    THE FIRST CCW.  LINKAGE IS MADE TO THE LER ROUTINE BEFORE ISSUING* 01042021
*    THE EREXCP.                                                      * 01044021
*         (2) IF THE TP OP CODE INDICATES A TEXT TRANSFER, THE ERROR  * 01046021
*    COUNT IS STORED IN THE 2-BIT RETRY COUNTER IN THE ERROR HALFWORD.* 01048021
*    IF RETRY HAS FAILED TWICE, 'POST WITH MESSAGE' (X'00') IS        * 01050021
*    INDICATED IN LCBERRCT + 1.  IF RETRY HAS NOT FAILED TWICE, 'POST * 01052021
*    WITHOUT MESSAGE' (X'03') IS INDICATED IN LCBERRCT + 1.  'EXIT TO * 01054021
*    POST' (X'02') IS INDICATED IN LCBERRCT + 1, BEFORE LINKING TO    * 01056021
*    LINE ERROR RECORDING ROUTINE.                                    * 01058021
*         (3) IF A NONTEXT TRANSFER, TEST IS MADE FOR PERMANENT ERROR.* 01060021
*    IF RETRY HAS FAILED 2 TIMES, 'POST WITH MESSAGE' IS INDICATED.   * 01062021
*    IF RETRY HAS NOT FAILED TWICE, RESTART IS ON THE FIRST CCW.  FOR * 01064021
*    DIAL LINES, A DISABLE IS SET TO HANG UP THE TRANSMITTER.  'EXIT  * 01066021
*    TO POST' (X'02') IS INDICATED IN LCBERRCT + 1 BEFORE LINKING TO  * 01068021
*    LINE ERROR RECORDING ROUTINE.                                    * 01070021
*         IF THE FAILING CCW IS A PREPARE OR DIAL COMMAND, A TEST IS  * 01072021
*    MADE FOR PERMANENT ERROR.  IF THE RETRY HAS FAILED TWICE,'POST   * 01074021
*    WITH MESSAGE' (X'00') AND 'EXIT TO POST' (X'02') IS INDICATED IN * 01076021
*    LCBERRCT + 1.  LINKAGE IS MADE TO THE LINE ERROR RECORDING (LER) * 01078021
*    ROUTINE BEFORE LINKING TO POST MODULE.  IF THE RETRY HAS NOT     * 01080021
*    FAILED TWO TIMES, RESTART IS SET FOR THE FIRST CCW FOR A PREPARE * 01082021
*    COMMAND.  FOR DIAL LINES, A DISABLE CODE IS RESET IN FIRST CCW   * 01084021
*    AND 'POST WITHOUT MESSAGE' IS SET IN LCBERCCT + 1.  LINKAGE IS   * 01086021
*    MADE TO LER ROUTINE BEFORE LINKING TO POST MODULE.               * 01088021
*         IF THE FAILING CCW IS A POLL, THE FAILING POLLING LIST      * 01090021
*    ADDRESS AND COUNT ARE STORED IN THE FIRST POLL CCW IN THE CHANNEL* 01092021
*    PROGRAM.  IF RETRY HAS FAILED TWICE, 'POST WITH MESSAGE' IS      * 01094021
*    INDICATED.  IF RETRY HAS NOT FAILED TWICE, RESTART IS ON THE     * 01096021
*    FIRST CCW.  LINKAGE IS MADE TO LER BEFORE EREXCP.                * 01098021
*         IF A FAILING CCW IS NONE OF THE ABOVE, 'SHOULD NOT OCCUR'   * 01100021
*    (X'01') IS SET IN THE ERROR HALFWORD.  EXIT IS MADE TO POST WITH * 01102021
*    MESSAGE.                                                         * 01104021
*                                                                     * 01106021
* ENTRY POINTS -                                                      * 01108021
*         IGE0304E - CONTROL IS PASSED HERE BY IGE0004A.              * 01110021
*                                                                     * 01112021
* INPUT -                                                             * 01114021
*    REGISTER 1 - RQE ADDRESS                                         * 01116021
*    REGISTER 15 - ENTRY POINT                                        * 01118021
*                                                                     * 01120021
* OUTPUT -                                                            * 01122021
*    FOR ERROR EXCP, LCBSTART POINTS TO CCW TO RESTART WITH.          * 01124021
*    FOR BRANCHING TO EXIT ROUTINE, REGISTER 13 CONTAINS CODE FOR     * 01126021
*    NEXT MODULE TO CALL.                                             * 01128021
*                                                                     * 01130021
* EXTERNAL REFERENCES -                                               * 01132021
*         IOS SVC 15 ROUTINE                                          * 01134021
*         IOS SVC 3 ROUTINE                                           * 01136021
*                                                                     * 01138021
* EXITS, NORMAL -                                                     * 01140021
*         TO RESTART THE CHANNEL PROGRAM, AN SVC 15 IS EXECUTED       * 01142021
*         FOLLOWED BY AN SVC 3 TO RETURN TO IOS.                      * 01144021
*         TO XCTL TO THE NEXT ROUTINE, THE ROUTINE EXITS VIA A BRANCH * 01146021
*         REGISTER 14 WITH THE MODULE CODE IN REGISTER 13.            * 01148021
*                                                                     * 01150021
* EXITS, ERROR - NONE                                                 * 01152021
*                                                                     * 01154021
* TABLES / WORKAREAS - NONE                                           * 01156021
*                                                                     * 01158021
* ATTRIBUTES - SERIALLY REUSABLE, DISABLED, TRANSIENT, REFRESHABLE    * 01160021
*                                                                     * 01162021
* CHARACTER CODE DEPENDENCY - NONE                                    * 01164021
*                                                                     * 01166021
* NOTES - NONE                                                        * 01168021
*                                                                     * 01170021
*********************************************************************** 01172021
*1171310000-340000,505000-515000                                   5739 01200016
*83660270000,445000,520000                                        20800 01250017
*3411520000                                                       18921 01300017
*1203357000                                                       23168 01400018
*A010020-011720                                                  S21016 01450021
*              REGISTER USAGE                                           02000013
         SPACE 2                                                        02500013
W8       EQU   0                                                        03000013
TSTREG   EQU   1                       TWELVE STAR ADDRESS              03500013
UCBREG   EQU   2                       UNIT CONTROL BLOCK ADDRESS       04000013
DCBREG   EQU   3                       DATA CONTROL BLOCK ADDRESS       04500013
CCWREG   EQU   4                       ADDRESS OF CHANNEL COMMAND WORD  05000013
LCBREG   EQU   5                       LINE CONTROL BLOCK ADDRESS       05500013
W1       EQU   6                       WORK REGISTER                    06000013
W2       EQU   7                       WORK REGISTER                    06500013
W3       EQU   8                       WORK REGISTER                    07000013
W4       EQU   9                       WORK REGISTER                    07500013
W5       EQU   10                      WORK REGISTER                    08000013
W6       EQU   11                  WORK REGISTER                        08500013
W7       EQU   12                  WORK REGISTER                        09000013
LINKREG  EQU   13                      NAME OF NEXT ERP MODULE          09500013
RETREG   EQU   14                      RETURN REGISTER                  10000013
BASEREG  EQU   15                      BASE REGISTER                    10500013
         SPACE 2                                                        11000013
         USING *,BASEREG                                                11500013
         USING IECKLCB0,LCBREG                                          12000013
         L     LCBREG,X4(TSTREG)       IOB ADDRESS                      12500013
         SH    LCBREG,H48              ADJUST TO LCB                    13000013
         L     CCWREG,LCBCSW           FAILING CCW+8                    13500013
         SH    CCWREG,H8               FAILING CCW                      14000013
         LH    UCBREG,X2(TSTREG)       UCB ADDRESS                      14500013
         LA    W5,IRLERB               SET FOR LINE ERROR RECORDING     15000013
         SR    W1,W1                                                    15500013
         IC    W1,LCBERRCT             ERP RETRY COUNTER                16000013
         AH    W1,LCBERRST             ADD ERROR HALF WORD              16500013
*                                        W1 NOW CONTAINS ERROR HALF     17000013
*                                        WORD WITH COMBINED COUNT       17500013
         LA    W1,X1(W1)               ADD ONE                          18000013
         NI    LCBERRST+1,XFC           ZERO EOBLC COUNTER              18500013
         CLI   X0(CCWREG),X2           FAILING CCW A READ OR WRITE      19000013
         BNH   IRTEST                  YES, CHECK FOR TEXT TRANSFER     19500013
         CLI   X0(CCWREG),X6           PREPARE COMMAND                  20000013
         BE    IRCKCNT                                                  20500013
         CLI   X0(CCWREG),X29          DIAL COMMAND                     21000013
         BE    IRCKCNT                 BRANCH IF DIAL                   21500013
         CLI   X0(CCWREG),X9       POLL CCW                             22000013
         BE    IRPOLL              YES                                  22500013
         OI    LCBERRST,X1             INDICATE SHOULD NOT OCCUR ERROR  23000013
         LA    W5,IRBRIN               SET FOR NO LINE ERROR RECORDING  23500013
IRMSG    MVI   LCBERRCT+1,X0           POST WITH MESSAGE                24000013
         B     IRPOST             INDICATE PERM ERROR AND RETURN  20800 27000017
IRRETRY  ST    W8,LCBSTART-1           INITIALIZE IOBSTART              30500013
         BALR  W5,W5                   BRANCH TO IRLERB IF LINE ERROR   34500013
*                                        RECORDING REQUIRED, ELSE       35000013
*                                        RETURN TO NEXT INSTRUCTION     35500013
         SVC   EREXCP                  ERROR EXECUTE CHANNEL PROG.23168 35700018
         SVC   RETURN                  NO, RETURN                       36000013
IRBRIN   BR    W5                      RETURN TO INSTRUCTION AFTER      36500013
*                                        BALR                           37000013
IRLERB   MVI   LCBINCAM+1,X2            SET CODE FOR LER                37500013
         LA    LINKREG,LERBMOD         NAME OF LINE ERROR RECORDING     38000013
*                                        MODULE                         38500013
IRLINK   L     RETREG,X10              CUT ADDRESS                      39000013
         L     RETREG,X2C(RETREG)      LINK ROUTINE ADDRESS             39500013
         BR    RETREG                  LINK TO NEXT MODULE              40000013
IRTEST   CLI   X5(CCWREG),XA       AUTOPOLL READ RESPONSE               40500013
         BE    IRRDPOLL            YES                                  41000013
         TM    X5(CCWREG),X30          TEXT TRANSFER CCW                41500013
         BZ    IRCKCNT                 NO,  CHECK IF PERMANENT          42000013
         STH   W1,LCBERRST              STORE UPDATED HALF WORD         42500013
         TM    LCBERRST+1,X3            HAS RETRY FAILED                43000013
         BO    IRMSG                    YES, PERMANENT ERROR            43500013
         MVI   LCBERRCT+1,X3           ELSE POST WITHOUT MESSAGE        44000013
         B     IRPOST                                             20800 44500017
IRPOST   OI    LCBERRCT+1,X2           SET TO EXIT TO POST              45000013
         BALR  W5,W5                   BRANCH TO IRLERB IF LINE ERROR   45500013
*                                        RECORDING REQUIRED, ELSE       46000013
*                                        RETURN TO NEXT INSTRUCTION     46500013
IRPERM   LH    LINKREG,POSTMOD         NO, LINK TO POST MODULE          47000013
         B     IRLINK                                                   47500013
IRCKCNT  STC   W1,LCBERRCT              STORE UPDATED COUNT             48000013
         NI    LCBERRCT,X3              ONLY RETRY BITS                 48500013
         CLI   LCBERRCT,X3              HAS RETRY FAILED                49000013
         BNL   IRMSG                   YES, POST WITH MESSAGE           49500013
         LA    W8,LCBCPA               ASSUME RESTART AT FIRST CCW      50000013
         TM    LCBCPA+8,X20            SECOND CCW A DIAL/ENABLE         50500013
         BZ    IRRETRY                 NO, RETRY AT FIRST               51000013
         MVI   LCBCPA,X2F              RESET DISABLE OP CODE            51500013
         B     IRPOST                                             20800 52000017
* THE FOLLOWING SUBROUTINE IS USED TO FIND THE POLLING LIST AND THE     52500013
* LENGTH OF THE POLLING LIST ENTRIES. REGISTERS ON EXIT ARE             53000013
* W3 - ADDRESS OF THE POLLING LIST                                      53500013
* W4 - LENGTH OF EACH ENTRY (2 OR 3 BYTES)                              54000013
* W6 - OP CODE AND DATA ADDRESS OF FAILING CCW                          54500013
* W7 - FLAGS, TP OP CODE AND COUNT OF F AILING CCW                      55000013
IRPOLSUB LM    W6,W7,X0(CCWREG)        FAILING CCW TO W6 AND W7         55500013
         L     W3,LCBCPA+32            POLL LIST ADDRESS FROM POLL CCW  56000013
         BCTR  W3,0                    BACK UP TO CHECK ENTRY SIZE      56500013
         LA    W4,X3                   ASSUME 3 BYTE ENTRIES            57000013
         TM    X0(W3),X20              CHECK LENGTH OF ENTRIES          57500013
         BCR   1,W2                    THREE, RETURN                    58000013
         BCTR  W4,W2                   DECREMENT COUNT AND RETURN       58500013
IRPOLL   BAL   W2,IRPOLSUB             GET POLL LIST ADDRESS            59000013
         AH    W4,LCBCSW+6             ADD RESIDUAL COUNT TO WIDTH      59500013
         AH    W6,X6(CCWREG)           ADD ORIGINAL COUNT TO ADDRESS    60000013
         SR    W6,W4                   SUBTRACT WIDTH AND RESIDUAL      60500013
*                                        COUNT FROM ADDRESS             61000013
IRCOM    STH   W4,LCBCPA+14            STORE NEW COUNT                  61500013
         ST    W6,LCBCPA+8             STORE NEW DATA ADDRESS           62000013
         B     IRCKCNT                 START CHANNEL PROGRAM            62500013
IRRDPOLL BAL   W2,IRPOLSUB             GET  POLL LIST ADDRESS           63000013
         LR    W7,W3                   SAVE POLLING LIST ADDRESS        63500013
IRLOOP   CLI   X1(W7),XFE              END OF LIST                      64000013
         BE    IRCKCNT                 YES RESTART WITH OLD POLL        64500013
         AR    W7,W4                   BUMP TO NEXT ENTRY               65000013
         CLC   X0(1,W6),X0(W7)         INDEX BYTE COMPARE               65500013
         BNE   IRLOOP                  NO, CHECK FOR END OF LIST        66000013
         BCTR  W4,0                    REDUCE ENTRY SIXE BY ONE         66500013
         SR    W7,W4                   W7 = ADDRESS OF POLL CHARS       67000013
         LR    W6,W7                   SET FOR COMMON CODE              67500013
         LH    W4,LCBCPA+38            COUNT OF 2ND POLL CCW            68000013
         SLR   W3,W7                   1ST - MATCH (NEGATIVE)           68500013
         LA    W4,X1(W3,W4)            W4 = NEW COUNT                   69000013
         B     IRCOM                   USE COMMON CODE                  69500013
         EJECT                                                          70000013
*                                                                       70500013
*        CONSTANTS                                                      71000013
*                                                                       71500013
X0       EQU   0                                                        72000013
X1       EQU   1                                                        72500013
X2       EQU   2                                                        73000013
X3       EQU   3                                                        73500013
X4       EQU   4                                                        74000013
X5       EQU   5                                                        74500013
X6       EQU   6                                                        75000013
X9       EQU   9                                                        75500013
XA       EQU   10                                                       76000013
X10      EQU   16                                                       76500013
X11      EQU   17                                                       77000013
X20      EQU   32                                                       77500013
X29       EQU  41                                                       78000013
X2C      EQU   44                                                       78500013
X2F      EQU   47                                                       79000013
X30      EQU   48                                                       79500013
X40      EQU   64                                                       80000013
X90      EQU   144                                                      80500013
XFC      EQU   252                                                      81000013
XFE      EQU   254                                                      81500013
H8       DC    AL2(8)                                                   82000013
H48      DC    AL2(48)                                                  82500013
LERBMOD  EQU   2046                    NAME OF LINE ERROR REC MODULE    83000013
POSTMOD  DC    AL2(5045)               NAME OF POST MODULE              83500013
EREXCP   EQU   15                                                       84000013
RETURN   EQU   3                                                        84500013
         EJECT                                                          85000013
         LCBD  QTAM=3                                                   85500013
         END                                                            86000013
