         TITLE 'IGE0604F QTAM ERP AUTOPOLL BUS OUT AND OVERRUN'         00700013
*********************************************************************** 00710021
*TITLE- IGE0604F QTAM ERP AUTOPOLL BUS OUT AND OVERRUN                  00720021
*                                                                     * 00730021
*STATUS - CHANGE LEVEL=18         JANUARY 1971                        * 00740021
*                                                                     * 00750021
*FUNCTION-  AFTER INITIALIZATION, THE ROUTINE TESTS FOR BUS-OUT OR    * 00760021
*   OVERRUN CHECKS.                                                   * 00770021
*        FOR OVERRUN CHECK, THE "SHOULD NOT OCCUR" BIT IS SET IN THE  * 00780021
*   ERROR HALFWORD AND A PERMANENT ERROR CONDITION EXISTS.            * 00790021
*        FOR BUS-OUT CHECK:                                           * 00800021
*   IF THE FAILING CCW IS A POLL OPERATION, THE ADDRESS OF THE        * 00810021
*   POLLING LIST AND THE LENGTH OF THE ENTRIES ARE OBTAINED. THE      * 00820021
*   NEW COUNT AND DATA ADDRESS ARE STORED IN THE POLL CCW. THE RETRY  * 00830021
*   COUNTER IS UPDATED, AND THE CONTROL UNIT FAILURE IS RECORDED. THE * 00840021
*   CHANNEL PROGRAM IS RETRIED WITH THE FIRST CCW.                    * 00850021
*   IF THE FAILING CCW IS A READ RESPONSE TO POLLING, THE ADDRESS OF  * 00860021
*   THE POLLING LIST AND THE LENGTH OF THE ENTRIES ARE OBTAINED. A    * 00870021
*   SEARCH IS MADE FOR THE CORRECT DATA ADDRESS AND COUNT FOR THE     * 00880021
*   POLL CCW. THE RETRY COUNTER IS UPDATED AND CONTROL UNIT FAILURE   * 00890021
*   IS RECORDED. THE CHANNEL PROGRAM IS RETRIED WITH THE FIRST CCW.   * 00900021
*        AFTER TWO RETRIES, A PERMANENT ERROR CONDITION EXISTS.       * 00910021
*   FOR A BUS-OUT THE CONTROL UNIT FAILURE IS SET IN THE ERROR        * 00920021
*   HALFWORD. AN INDICATION IS SET FOR OUTBOARD RECORDING.            * 00930021
*   LINKAGE IS MADE TO THE ERROR POST ROUTINE.                        * 00940021
*                                                                     * 00950021
*ENTRY POINTS-                                                        * 00960021
*        IGE0604F- CONTROL IS PASSED HERE FROM QTAM BUS OUT           * 00970021
*   AND OVERRUN MODULE WHEN AN AUTOPOLL OPERATION IS IN ERROR.        * 00980021
*                                                                     * 00990021
*INPUT-                                                               * 01000021
*   REGISTER 1 - RQE ADDRESS                                          * 01010021
*   REGISTER 15- ENTRY POINT                                          * 01020021
*                                                                     * 01030021
*OUTPUT-                                                              * 01040021
*   THE ERROR HALF WORD AND THE RETRY COUNTER ARE UPDATED AND         * 01050021
*   THE UNIT FAILURE IS RECORDED IN THE STATISTICAL DATA RECORDER.    * 01060021
*                                                                     * 01070021
*EXTERNAL REFERENCES-                                                 * 01080021
*        IOS SVC 15 ROUTINE (ERROR EXECUTE CHANNEL PROGRAM)           * 01090021
*        IOS SVC 3 ROUTINE (TO RETURN TO IOS)                         * 01100021
*                                                                     * 01110021
*EXITS, NORMAL-                                                       * 01120021
*        FOR A BUS-OUT CHECK ON A POLL OPERATION, OR AN               * 01130021
*   OVERRUN CHECK ON A READ RESPONSE TO POLLING, THE CHANNEL PROGRAM  * 01140021
*   IS RETRIED. RETURN IS MADE TO IOS.                                * 01150021
*        FOR OTHER CONDITIONS OR AFTER TWO RETRIES, LINKAGE IS MAD    * 01160021
*   TO THE ERROR POST ROUTINE.                                        * 01170021
*                                                                     * 01180021
*EXITS, ERROR- NONE                                                   * 01190021
*                                                                     * 01200021
*TABLES/WORKAREAS-  NONE                                              * 01210021
*                                                                     * 01220021
*ATTRIBUTES- SERIALLY REUSABLE, DISABLED, TRANSIENT, ONLY LOADABLE,   * 01230021
*   SUPERVISOR MODE, REFRESHABLE                                      * 01240021
*                                                                     * 01250021
* CHARACTER CODE DEPENDENCY - NONE                                    * 01260021
*                                                                     * 01270021
*********************************************************************** 01280021
*1204603000-608000,613000-618000                                  18204 01700018
*A007100-012800                                                  S21016 01900021
IGE0604F CSECT                                                          02300021
         SPACE 2                                                        02800013
*              REGISTER USAGE                                           03500013
TSTREG   EQU   1                       TWELVE START ADDRESS             04200013
UCBREG   EQU   2                       UNIT CONTROL BLOCK ADDRESS       04900013
DCBREG   EQU   3                       DATA CONTROL BLOCK ADDRESS       05600013
CCWREG   EQU   4                       ADDRESS OF CHANNEL COMMAND WORD  06300013
LCBREG   EQU   5                       LINE CONTROL BLOCK ADDRESS       07000013
W1       EQU   6                       WORK REGISTER                    07700013
W2       EQU   7                       WORK REGISTER                    08400013
W3       EQU   8                       WORK REGISTER                    09100013
W4       EQU   9                       WORK REGISTER                    09800013
W5       EQU   10                      WORK REGISTER                    10500013
W6       EQU   11                      WORK REGISTER                    11200013
W7       EQU   12                      WORK REGISTER                    11900013
LINKREG  EQU   13                      NAME OF NEXT ERP MODULE          12600013
RETREG   EQU   14                      ADDRESS OF CUT OR LINK ROUTINE   13300013
BASEREG  EQU   15                                                       14000013
         SPACE 2                                                        14700013
         USING *,BASEREG                                                15400013
         USING IECKLCB0,LCBREG                                          16100013
         L     LCBREG,X4(TSTREG)       IOB ADDRESS                      16800013
         SH    LCBREG,H48              ADJUST TO LCB                    17500013
         L     DCBREG,LCBDCBPT         DCB ADDRESS                      18200013
         L     CCWREG,LCBCSW           FAILING CCW +8                   18900013
         SH    CCWREG,H8               ADJUST TO FAILING CCW            19600013
         LH    UCBREG,X2(TSTREG)       UCB ADDRESS                      20300013
         L     RETREG,X10              CUT ADDRESS                      21000013
         CLI   X0(CCWREG),X9           POLL CCW                         21700013
         BNE   AURDRSP                   NO, READ RESPONSE TO POLL      22400013
         TM    LCBSENSE,X20            BUS OUT CHECK                    23100013
         BZ    AUSNO                     NO, SHOULD NOT OCCUR           23800013
         BAL   W2,AUPOLSUB             GET POLL LIST ADDRESS            24500013
         AH    W4,LCBCSW+6             ADD RESIDUAL COUNT TO WIDTH      25200013
         AH    W6,X6(CCWREG)           ADD ORIGINAL COUNT TO ADDRESS    25900013
         SR    W6,W4                   SUBTRACT WIDTH AND RESIDUAL      26600013
*                                        COUNT FROM ADDRESS             27300013
AUCOM    STH   W4,LCBCPA+14            STORE NEW COUNT                  28000013
         ST    W6,LCBCPA+8             STORE NEW DATA ADDRESS           28700013
         MVI   LCBCPA+8,X9             RESTORE POLL OP CODE             29400013
         B     AUCKCNT                 START CHANNEL PROGRAM            30100013
AURDRSP  TM    LCBSENSE,X20            BUS OUT CHECK                    30800013
         BO    AUSNO                     CHOULD NOT OCCUR               31500013
         BAL   W2,AUPOLSUB             GET  POLL LIST ADDRESS           32200013
         LR    W7,W3                   SAVE POLLING LIST ADDRESS        32900013
AULOOP   CLI   X1(W7),XFE              END OF LIST                      33600013
         BE    AUCKCNT                 YES RESTART WITH OLD POLL        34300013
         AR    W7,W4                   BUMP TO NEXT ENTRY               35000013
         CLC   X0(1,W6),X0(W7)         INDEX BYTE COMPARE               35700013
         BNE   AULOOP                  NO, CHECK FOR END OF LIST        36400013
         BCTR  W4,0                    REDUCE ENTRY SIXE BY ONE         37100013
         SR    W7,W4                   W7 = ADDRESS OF POLL CHARS       37800013
         LR    W6,W7                   SET FOR COMMON CODE              38500013
         LH    W4,LCBCPA+38            COUNT OF 2ND POLL CCW            39200013
         SLR   W3,W7                   1ST - MATCH (NEGATIVE)           39900013
         LA    W4,X1(W3,W4)            W4 = NEW COUNT                   40600013
         B     AUCOM                   USE COMMON CODE                  41300013
* THE FOLLOWING SUBROUTINE IS USED TO FIND THE POLLING LIST AND THE     42000013
* LENGTH OF THE POLLING LIST ENTRIES. REGISTERS ON EXIT ARE             42700013
* W3 - ADDRESS OF THE POLLING LIST                                      43400013
* W4 - LENGTH OF EACH ENTRY (2 OR 3 BYTES)                              44100013
* W6 - OP CODE AND DATA ADDRESS OF FAILING CCW                          44800013
* W7 - FLAGS, TP OP CODE AND COUNT OF F AILING CCW                      45500013
AUPOLSUB LM    W6,W7,X0(CCWREG)        FAILING CCW TO W6 AND W7         46200013
         L     W3,LCBCPA+32            POLL LIST ADDRESS FROM POLL CCW  46900013
         BCTR  W3,0                    BACK UP TO CHECK ENTRY SIZE      47600013
         LA    W4,X3                   ASSUME 3 BYTE ENTRIES            48300013
         TM    X0(W3),X20              CHECK LENGTH OF ENTRIES          49000013
         BCR   1,W2                    THREE, RETURN                    49700013
         BCTR  W4,W2                   DECREMENT COUNT AND RETURN       50400013
AUCKCNT  SR    W3,W3                                                    51100013
         IC    W3,LCBERRCT             ERP RETRY COUNTER                51800013
         AH    W3,LCBERRST             ADD ERROR HALF WORD              52500013
         LA    W3,X1(W3)               ADD ONE                          53200013
         NI    LCBERRST+1,XFC          CLEAR EOBLC RETRY COUNT          53900013
         STC   W3,LCBERRCT             STORE COMBINED COUNT             54600013
         NI    LCBERRCT,X3             ONLY RETRY BITS                  55300013
         CLI   LCBERRCT,X3             HAS RETRY FAILED                 56000013
         BE    AUPERM                    YES, POST                      56700013
         LA    W1,LCBCPA               RESTART FIRST CCW                57400013
         ST    W1,LCBSTART-1           INITIALIZE IOBSTART              58100013
         L     W2,X70(RETREG)          SDR UPDATE ROUTINE               58800013
         SR    W3,W3                                                    59500013
         IC    W3,X9(UCBREG)           INDEX TO TABLE ENTRY             60200013
         LR    W5,W2               GET STAT TAB START ADR         18204 60300018
LOOP1    CH    UCBREG,0(0,W5)      DEV. SUPPORTED BY THIS SECTION 18204 60400018
         BC    4,LOOP2             YES, INCR. ADJUSTED CORRECTLY  18204 60500018
         LA    W5,2(0,W5)          INCR. TO NEXT CTL ENTRY        18204 60600018
         LA    W3,256(0,W3)        INCR. STAT INDEX TO NEXT SECT. 18204 60700018
         BC    15,LOOP1            LOOP TO CHECK THIS SECTION     18204 60800018
LOOP2    MH    W3,H10              ADJUST ENTRY PTR BY ENTRY LEN. 18204 61300018
         AR    W2,W3                                              18204 61800018
         OC    X8(1,W2),LCBSENSE       RECORD CONTROL UNIT FAILURE      62300013
         MVI   LCBSENSE,X0             CLEAR SENSE                      63000013
         SVC   EREXCP                  ERROR EXECUTE CHANNEL PROGRAM    63700013
         SVC   RETURN                  RETURN                           64400013
AUSNO    OI    LCBERRST,X1             SET SHOULD NOT OCCUR BIT         65100013
AUPERM   TM    LCBSENSE,X20            BUS OUT                          65800013
         BZ    *+8                     NO                               66500013
         OI    LCBERRST+1,X4           SET CONTROL UNIT FAILURE         67200013
         OI    LCBCSW,X1               INDICATE OBR RECORDING           67900013
         LH    LINKREG,POSTMOD         NAME OF NEXT MODULE IS POST      68600013
         L     RETREG,X2C(RETREG)      LINK ROUTINE ADDRESS             69300013
         BR    RETREG                  LINK TO NEXT MODULE              70000013
         EJECT                                                          70700013
*                                                                       71400013
*        CONSTANTS                                                      72100013
*                                                                       72800013
X0       EQU   0                                                        73500013
X1       EQU   1                                                        74200013
X2       EQU   2                                                        74900013
X3       EQU   3                                                        75600013
X4       EQU   4                                                        76300013
X6       EQU   6                                                        77000013
X8       EQU   8                                                        77700013
X9       EQU   9                                                        78400013
X10      EQU   16                                                       79100013
X20      EQU   32                                                       79800013
X2C      EQU   44                                                       80500013
X40      EQU   64                                                       81200013
X70      EQU   112                                                      81900013
XFC      EQU   252                                                      82600013
XFE      EQU   254                                                      83300013
EREXCP   EQU   15                                                       84000013
RETURN   EQU   3                                                        84700013
H8       DC    AL2(8)                                                   85400013
H10      DC    AL2(10)                                                  86100013
H48      DC    AL2(48)                                                  86800013
POSTMOD  DC    AL2(5045)                                                87500013
         EJECT                                                          88200013
         LCBD  QTAM=3                                                   88900013
         END                                                            89600013
