         TITLE 'IGE0704E QTAM LINK ROUTINE'                             00600013
IGE0704E CSECT                                                          01200013
*********************************************************************** 01203021
*                                                                     * 01206021
* STATUS       CHANGE LEVEL=18      JANUARY 1971                      * 01209021
*                                                                     * 01212021
* FUNCTION - THIS MODULE IS USED TO CHECK THE RESULTS OF I/O INITIATED* 01215021
*    BY ERP.  LCBERRCT + 1 IS USED TO INDICATE THE REASON FOR ENTRY.  * 01218021
*    IF THE ROUTINE WAS ENTERED FOR OPEN OR RESTART (0C), LINKAGE IS  * 01221021
*    MADE TO MODULE IGE0404F.                                         * 01224021
*         IF THE ROUTINE WAS ENTERED FOR A DIAGNOSTIC WRITE/READ      * 01227021
*    RETURN (04), THE TP OP CODE IS USED TO DETERMINE THE OPERATION   * 01230021
*    FAILED.                                                          * 01233021
*         (1) FOR AN ENABLE RETURN, IF CSW INDICATES A STATUS OTHER   * 01236021
*    THAN CHANNEL END/DEVICE END, THE CONTROL UNIT FAILURE BIT (13) IS* 01239021
*    SET IN THE ERROR HALF-WORD OF THE LCB.  THE ORIGINAL SENSE, CSW, * 01242021
*    AND FAILING CSW ARE RESTORED FROM A SAVE AREA AT LCBCPA + 32.    * 01245021
*    'POST WITH MESSAGE' IS INDICATED IN LCBERRCT + 1 (0).  LINKAGE   * 01248021
*    IS MADE TO THE POST MODULE, IGE0504E.                            * 01251021
*         (2) FOR A DISABLE RETURN, THE CONTROL UNIT FAILURE BIT (13) * 01254021
*    IS SET IN THE ERROR HALFWORD OF THE LCB, AND THE SENSE IN THE LCB* 01257021
*    IS CLEARED.  ERROR EXCP IS ISSUED TO RESTART ON THE DIAGNOSTIC   * 01260021
*    WRITE BEFORE RETURNING TO IOS.                                   * 01263021
*         (3) FOR A DIAGNOSTIC READ FAILURE, THE STATUS IS CHECKED FOR* 01266021
*    ERRORS BEFORE RESTARTING.  IF THE UCB INDICATES A TELEGRAPH      * 01269021
*    ADAPTER, TYPE I, AND THE STATUS IS OTHER THAN CE/DE/UE, THE      * 01272021
*    'CONTROL UNIT FAILURE' BIT  (13) IS SET IN THE ERROR HALF-WORD OF* 01275021
*    THE LCB.  FOR OTHER DEVICES, IF THE STATUS IS OTHER THAN CE/DE   * 01278021
*    (ALONE), THE 'CONTROL UNIT FAILURE' BIT IS SET.                  * 01281021
*         (4) FOR A DIAGNOSTIC WRITE FAILURE, THE 'CONTROL UNIT       * 01284021
*    FAILURE' BIT (13) IS SET IN LCBERRST FIELD OF THE LCB.           * 01287021
*         FOR ALL DIAGNOSTIC READ OR WRITE FAILURES, THE DIAGNOSTIC   * 01290021
*    SENSE IS SAVED IN LCBSENSE + 1.  IF THE ENABLE HAS BEEN CHAINED, * 01293021
*    THE CHANNEL PROGRAM IS RESTARTED AT THE ENABLE CCW.  RETURN IS   * 01296021
*    MADE TO IOS.  IF THE ENABLE IS NOT NEEDED, LINKAGE IS MADE TO THE* 01299021
*    POST MODULE TO 'POST WITH MESSAGE', INDICATED BY LCBERRCT + 1 =0.* 01302021
*    THE MESSAGE IS SET UP BY RESTORING THE SENSE, CSW, AND CCW FROM  * 01305021
*    LCBCPA + 32.                                                     * 01308021
*         IF ENTRY WAS MADE FOR A READ SKIP/WRITE BREAK RETURN,       * 01311021
*    'POST WITH MESSAGE' (0) IS INDICATED IN LCBERRCT + 1.  IF ENTRY  * 01314021
*    WAS FOR READ SKIP, LINKAGE IS MADE TO READ SKIP RETURN ROUTINE,  * 01317021
*    IGE0004F.  IF ENTRY WAS FOR WRITE BREAK, THE STATUS OF THE CSW IS* 01320021
*    CHECKED.  IF OTHER THAN CE/DE OR CE/DE/UE WITH BUS OUT, THE ERROR* 01323021
*    IS POSTED WITH A MESSAGE.                                        * 01326021
*         IF CE/DE OR CE/DE/UE WITH BUS OUT, A CHECK IS MADE FOR TEXT * 01329021
*    TRANSFER IN THE SAVED FAILING CCW.  IF NO TEXT TRANSFER AND AN   * 01332021
*    INITIAL OPERATION THAT HAS NOT BEEN RETRIED TWICE, THE CHANNEL   * 01335021
*    PROGRAM IS RESTARTED ON THE WRITE BREAK.  IF THE RETRIES HAVE    * 01338021
*    FAILED OR IT IS NOT AN INITIAL OPERATION, THE ERROR IS POSTED    * 01341021
*    WITH MESSAGE.                                                    * 01344021
*         IF A TEXT TRANSFER, THE RETRY COUNTER IN LCBERRST IS        * 01347021
*    UPDATED.  IF ANOTHER RETRY IS TO BE DONE, TIME OUT IS SET IN     * 01350021
*    LCBSENSE FOR RESELECTION AND 'POST WITH NO MESSAGE' IS INDICATED.* 01353021
*    IF RETRY HAS FAILED, THE ERROR IS POSTED WITH MESSAGE.           * 01356021
*         TO 'POST WITH MESSAGE' THE SENSE FROM THE BREAK IS MOVED TO * 01359021
*    LCBSENSE + 1, THE ORIGINAL SENSE IN LCBSENSE, AND ORIGINAL CSW   * 01362021
*    IN LCBCSW.  LINKAGE IS MADE TO POST MODULE, IGE0504E.            * 01365021
*                                                                     * 01368021
* ENTRY POINTS -                                                      * 01371021
*         IGE0704E - CONTROL IS PASSED HERE BY IGE0004A.              * 01374021
*                                                                     * 01377021
* INPUT -                                                             * 01380021
*    REGISTER 1 - RQE ADDRESS                                         * 01383021
*    REGISTER 15 - ENTRY POINT                                        * 01386021
*                                                                     * 01389021
* OUTPUT -                                                            * 01392021
*    FOR ERROR EXCP, LCBSTART POINTS TO CCW TO RESTART WITH.          * 01395021
*    FOR BRANCHING TO EXIT ROUTINE, REGISTER 13 CONTAINS CODE FOR     * 01398021
*    NEXT MODULE TO CALL.                                             * 01401021
*                                                                     * 01404021
* EXTERNAL REFERENCES -                                               * 01407021
*         IOS SVC 15 ROUTINE                                          * 01410021
*         IOS SVC 3 ROUTINE                                           * 01413021
*                                                                     * 01416021
* EXITS, NORMAL -                                                     * 01419021
*         TO RESTART THE CHANNEL PROGRAM, AN SVC 15 IS EXECUTED       * 01422021
*         FOLLOWED BY AN SVC 3 TO RETURN TO IOS.                      * 01425021
*         TO XCTL TO THE NEXT ROUTINE, THE ROUTINE EXITS VIA A BRANCH * 01428021
*         REGISTER 14 WITH THE MODULE CODE IN REGISTER 13.            * 01431021
*                                                                     * 01434021
* EXITS, ERROR - NONE                                                 * 01437021
*                                                                     * 01440021
* TABLES / WORKAREAS - NONE                                           * 01443021
*                                                                     * 01446021
* ATTRIBUTES - SERIALLY REUSABLE, DISABLED, TRANSIENT, REFRESHABLE    * 01449021
*                                                                     * 01452021
* CHARACTER CODE DEPENDENCY - NONE                                    * 01455021
*                                                                     * 01458021
* NOTES - NONE                                                        * 01461021
*                                                                     * 01464021
*********************************************************************** 01467021
*1204558000                                                       20399 01500018
*A012030-014670                                                  S21016 01600021
*              REGISTER USAGE                                           02400013
         SPACE 2                                                        03000013
TSTREG   EQU   1                       TWELVE STAR ADDRESS              03600013
UCBREG   EQU   2                       UNIT CONTROL BLOCK ADDRESS       04200013
DCBREG   EQU   3                       DATA CONTROL BLOCK ADDRESS       04800013
CCWREG   EQU   4                       ADDRESS OF CHANNEL COMMAND WORD  05400013
LCBREG   EQU   5                       LINE CONTROL BLOCK ADDRESS       06000013
W1       EQU   6                       WORK REGISTER                    06600013
W2       EQU   7                       WORK REGISTER                    07200013
W3       EQU   8                       WORK REGISTER                    07800013
W4       EQU   9                       WORK REGISTER                    08400013
LINKREG  EQU   13                      NAME OF NEXT ERP MODULE          09000013
RETREG   EQU   14                      RETURN REGISTER                  09600013
BASEREG  EQU   15                      BASE REGISTER                    10200013
         SPACE 2                                                        10800013
         USING *,BASEREG                                                11400013
         USING IECKLCB0,LCBREG                                          12000013
         L     LCBREG,X4(TSTREG)       IOB ADDRESS                      12600013
         SH    LCBREG,H48              ADJUST TO LCB                    13200013
         L     CCWREG,LCBCSW           FAILING CCW + 8                  13800013
         SH    CCWREG,H8               ADJUST TO FAILING CCW            14400013
         LH    UCBREG,X2(TSTREG)        UCB ADDRESS                     15000013
         L     RETREG,X10              CVT ADDRESS                      15600013
         SR    W1,W1                                                    16200013
         IC    W1,LCBERRCT+1           ENTRY INDEX BYTE                 16800013
         B     *(W1)                   DETERMINE ENTRY                  17400013
         B     LNDIAGWR                  DIAGNOSTIC WRITE/READ RETURN   18000013
         B     LNRDSKIP                  READ SKIP/WRITE BREAK RETURN   18600013
         LA    LINKREG,OPENLOD           SPECIAL OPEN AND CHECKPOINT    19200013
LNLINK   L     RETREG,X2C(RETREG)        RESTART ENTRY                  19800013
         BR    RETREG                  LINK TO NEXT MODULE              20400013
LNDIAGWR EQU   *                                                        21000013
         NI    X5(CCWREG),XF            USE LOW ORDER FOUR BITS OF TP   21600013
         IC    W1,X5(CCWREG)              OP CODE TO DETERMINE ENDING   22200013
         B     *+4(W1)                    CCW ************************  22800013
         B     DWRDIS                     0 - DISABLE FAILED            23400013
         B     DWRDWR                     4 - DIAGNOSTIC WRITE FAILED   24000013
         B     DWRDRD                     8 - ENDING CONDITIONS ON      24600013
*                                             DIAGNOSTIC READ, COULD BE 25200013
*                                             NORMAL.                   25800013
         LA    W3,XC00                 CHANNEL END DEVICE END           26400013
         CH    W3,LCBCSW+4             ANY OTHER BITS ON                27000013
         BE    *+8                     NO, FREE OF ERRORS               27600013
         OI    LCBERRST+1,X4           INDICATE CU FAILED               28200013
DWRESTR  MVC   LCBSENSE(1),LCBCPA+32    RESTORE SENSE BYTE              28800013
         MVC   LCBCSW+1(7),LCBCPA+33    RESTORE CSW                     29400013
         L     CCWREG,LCBCSW            RESTORE POINTER TO ORIGINAL     30000013
         SH    CCWREG,H8                  FAILING CCW                   30600013
         MVC   X0(8,CCWREG),LCBCPA+40   RESTORE ORIGINAL FAILING CCW    31200013
         MVI   LCBERRCT+1,X0           INDICATE NORMAL POST/MESSAGE     31800013
LNPOST   LH    LINKREG,POSTLOD                                          32400013
         B     LNLINK                                                   33000013
DWRDIS   OI    LCBERRST+1,X4           INDICATE CU FAILED               33600013
         LA    W1,LCBCPA                ADDRESS OF DIAGNOSTIC WRITE     34200013
DWEXCP   ST    W1,LCBSTART-1            INITIALIZE IOBSTART             34800013
         MVI   LCBSENSE,X0              CLEAR SENSE BYTE                35400013
         SVC   EREXCP                   ERROR ECECUTE CHANNEL PROGRAM   36000013
         SVC   RETURN                   RETURN                          36600013
DWRDRD   MVC   LCBRESTR(1),X13(UCBREG)  DEVICE TYPE                     37200013
         NI    LCBRESTR,XF0             CHECK ADAPTER TYPE FOR          37800013
         LA    W3,XC00                 CHANNEL END DEVICE END           38400013
         CLI   LCBRESTR,X40               TELEGRAPH TYPE I ADABTER      39000013
         BE    DWTEST                  CHECK FOR UNIT EXCEPTION         39600013
         CH    W3,LCBCSW+4             CHECK FOR ERRORS                 40200013
         BE    *+8                     NO ERRORS                        40800013
DWRDWR   OI    LCBERRST+1,X4           INDICATE CU FAILED               41400013
*                                         FAILURE                       42000013
         MVC   LCBSENSE+1(1),LCBSENSE   SAVE DIAGNOSTIC SENSE BYTE      42600013
         TM    LCBCPA+12,XC0            IS ENABLE REQUIRED              43200013
         BZ    DWRESTR                  NO, LINK TO POST WITH MESSAGE   43800013
         LA    W1,LCBCPA+16             ADDRESS OF ENABLE CCW           44400013
         B     DWEXCP                   EXECUTE ENABLE                  45000013
DWTEST   LA    W3,X100(W3)             ADD UNIT EXCEPTION               45600013
         CH    W3,LCBCSW+4             CHECK FOR ERRORS                 46200013
         BE    DWRDWR+4                 TEST IF ENABLE REGUIRED         46800013
         B     DWRDWR                   ALL ELSE IS ERRONEOUS           47400013
LNRDSKIP MVI   LCBERRCT+1,X0           INDICATE NORMAL POST/MESSAGE     48000013
         CLI   LCBERCCW,XD             WRITE BREAK CCW                  48600013
         BNE   LNREAD                  NO, MUST BE READ SKIP            49200013
         LA    W1,LCBCPA               INITIALIZE                       49800013
LNLOOP   LA    W1,X8(W1)               BUMP TO NEXT CCW                 50400013
         CLI   X0(W1),X8               NEXT CCW A TIC                   51000013
         BNE   LNLOOP                  NO TRY NEXT                      51600013
         LA    W3,XC00                 CHECK FOR CHANNEL END            52200013
         CH    W3,LCBCSW+4               DEVICE END ALONE               52800013
         BE    LNBKOK2                 YES, EOB OR NORMAL RESPONSE      53400013
         LA    W3,X100(W3)             SET TO CHECK FOR CHANNEL END     54000013
         CH    W3,LCBCSW+4               DEVICE END UNIT CHECK          54600013
         BE    LNBKOK                  YES, CHECK SENSE                 55200013
LNRESTR  MVC   LCBSENSE+1(1),LCBSENSE  SAVE SENSE FROM OPERATION  20399 55800018
         MVC   LCBSENSE(1),X8(W1)      RESTORE ORIGINAL SENS BYTE       56400013
         MVC   LCBCSW+1(7),X9(W1)      RESTORE ORIGINAL CSW             57000013
         B     LNPOST                  LINK TO POST                     57600013
LNBKOK   CLI   LCBSENSE,X20            BUS OUT CHECK IS OK              58200013
         BNE   LNRESTR                 ALL ELSE IS ERROR                58800013
LNBKOK2  L     CCWREG,X8(W1)           LOAD SAVED FAILING CCW ADDRESS   59400013
         SH    CCWREG,H8               ADJUST TO FAILING CCW            60000013
         TM    X5(CCWREG),X30          TEST FOR TEXT TRANSFER           60600013
         BZ    LNONTXT                 NON TEXT CCW                     61200013
         OC    LCBERRST+1(1),LCBERRCT  SET RETRY COUNTER FOR EOBLC      61800013
         CLI   LCBERRCT,X3             RETRY FAILED                     62400013
         BNL   LNRESTR                 YES, RESTORE                     63000013
         OI    LCBSENSE,X1             INDICATE RESELECTION NEEDED      63600013
         MVI   LCBERRCT+1,X1           INDICATE POST NO MWSSAGE         64200013
         B     LNRESTR                                                  64800013
LNONTXT  CLI   LCBCECB,X2              COMPARE TO INITIAL TYPE PRGM     65400013
         BH    LNRESTR                 NOT INITIAL CHANNEL PROGRAM      66000013
         CLI   LCBERRCT,X3             RETRY FAILED                     66600013
         BNL   LNRESTR                 YES, RESTORE                     67200013
         LA    W1,LCBCPA               SET TO RESTART WITH 1ST CCW      67800013
         B     DWEXCP                  EXECUTE CHANNEL PROGRAM          68400013
LNREAD   LA    LINKREG,RDSKMOD         NAME OF READ SKIP RETURN LOAD    69000013
         B     LNLINK                  LINK TO NEXT MODULE              69600013
         EJECT                                                          70200013
*                                                                       70800013
*              CONSTANTS                                                71400013
*                                                                       72000013
         SPACE 2                                                        72600013
X0       EQU   0                                                        73200013
X1       EQU   1                                                        73800013
X2       EQU   2                                                        74400013
X3       EQU   3                                                        75000013
X4       EQU   4                                                        75600013
X5       EQU   5                                                        76200013
X8       EQU   8                                                        76800013
X9       EQU   9                                                        77400013
XD       EQU   13                                                       78000013
XF       EQU   15                                                       78600013
X10      EQU   16                                                       79200013
X13      EQU   19                                                       79800013
X20      EQU   32                                                       80400013
X2C      EQU   44                                                       81000013
X30      EQU   48                                                       81600013
X40      EQU   64                                                       82200013
XC0      EQU   192                                                      82800013
XF0      EQU   240                                                      83400013
X100     EQU   256                                                      84000013
XC00     EQU   3072                                                     84600013
H8       DC    AL2(8)                                                   85200013
H48      DC    AL2(48)                                                  85800013
RDSKMOD  EQU   46                                                       86400013
OPENLOD  EQU   4046                                                     87000013
POSTLOD  DC    AL2(5045)                                                87600013
RETURN   EQU   3                                                        88200013
EREXCP   EQU   15                                                       88800013
         EJECT                                                          89400013
         LCBD  QTAM=3                                                   90000013
         END                                                            90600013
