         TITLE 'QTAM ERP CHANNEL CHECK RECOVERY ROUTINE'                00200017
IGE0804F CSECT                                                          00400017
*A004000-031200                                                  S21016 00420021
*********************************************************************** 00440021
*                                                                     * 00460021
* STATUS       CHANGE LEVEL=18     JANUARY 1971                       * 00480021
*                                                                     * 00500021
* FUNCTION- THIS MODULE RECEIVES CONTROL FROM IGE0004A WHEN A CHANNEL * 00520021
*    CONTROL CHECK OR AN INTERFACE CONTROL CHECK OCCURS.  THE ERPIB   * 00540021
*    (ERROR RECOVERY PROCEDURE INTERFACE BYTE) IS LOCATED BY ACCESSING* 00560021
*    A POINTER TO THE PARAMETER TABLE A CVT + 16.  THE PARAMETER TABLE* 00580021
*    POINTS TO THE ERPIB TABLE.  IF NO ERPIB CAN BE FOUND FOR THIS    * 00600021
*    CHANNEL CHECK CONDITION (OCCURS WHEN MORE THAN FIVE CHANNEL      * 00620021
*    CHECKS ARE RECEIVED BEFORE AN ERPIB CAN BE CLEARED), EXIT IS MADE* 00640021
*    TO POST WITH ERROR.                                              * 00660021
*         THE PERTINENT INFORMATION (PROGRAM FLAGS, RETRY CODES, AND  * 00680021
*    TERMINATION CODES) FROM THE ERPIB FOR THE TP DEVICE IS SAVED IN  * 00700021
*    LCBRESTR AND THE ERPIB IS CLEARED.  IF THE ERPIB HAS THE 'NO     * 00720021
*    RETRY' FLAG SET,   A SYSTEM RESET HAS OCCURRRD SO EXIT IS MADE TO* 00740021
*    POST THE ERROR.  IF NOT A SIO, I/O, OR HIO INTERRUPT, AN INVALID * 00760021
*    INTERRUPT WAS RECEIVED; THEREFORE EXIT IS MADE TO POST THE ERROR.* 00780021
*         FOR A HIO INTERRUPT, THE VALIDITY OF THE CCW ADDRESS IN THE * 00800021
*    CSW IS CHECKED.  IF INVALID, THE NEXT CCW IN THE CHANNEL PROGRAM * 00820021
*    AREA IS USED.  AN I/O ERROR MESSAGE, IEA000I, IS SET UP WITH THE * 00840021
*    OP CODE, STATUS, SENSE, AND LINE NUMBER.  A WTO IS ISSUED TO     * 00860021
*    WRITE THE MESSAGE TO THE CONSOLE.  CHANNEL END, DEVICE END, AND  * 00880021
*    UNIT EXECPTION ARE SET  IN LCBCSW.  THE IOB FLAGS ARE SET TO     * 00900021
*    X'C2' TO INDICATE ERROR CORRECTED.  AN ERROR EXCP AND RETURN SVCS* 00920021
*    ARE ISSUED TO RETURN TO IOS.                                     * 00940021
*         FOR A VALID CSW ON A SIO OR I/O INTERRUPT, THE CCW IS CHECK-* 00960021
*    ED FOR VALIDITY.  IF AN INVALID CCW, EXIT IS MADE TO POST WITH   * 00980021
*    ERROR.  THE FOLLOWING ACTION IS TAKEN FOR THE RETRY CODE AND     * 01000021
*    TRANSACTION CODE IN THE ERPIB ACCORDING TO THE CONTROL UNIT.     * 01020021
*                                                                     * 01040021
*    TERM CODE*       0       *        1       *        2       *     * 01060021
*      E  O   *2701*2702*2703 * 2701 2702 2703 * 2701 2702 2703 *     * 01080021
*      T  D--------*----*-----*-----*----*-----*-----*----*-----*     * 01100021
*      R  E *1*  B *  A *  A  *   B *  B *  A  *   A *  A *  A  *     * 01120021
*      Y    *2*  B *  A *  A  *   A *  A *  B  *   A *  A *  A  *     * 01140021
*           *3*  B *  D *  B  *   D *  D *  D  *   C *  C *  C  *     * 01160021
*           *4*  B *  A *  A  *   B *  B *  B  *   A *  A *  A  *     * 01180021
*           *5*  E *  D *  E  *   E *  D *  E  *   E *  C *  E  *     * 01200021
*          6&7*  C *  C *  C  *   C *  C *  C  *   C *  C *  C  *     * 01220021
*          ------------------------------------------------------     * 01240021
*                                                                     * 01260021
*        THE DECISIONS ARE MADE VIA BXLE'S AND A BRANCH TABLE.        * 01280021
*    THE ACTION TAKEN IS THE FOLLOWING:                               * 01300021
*         A- ONE IS ADDED TO THE RETRY COUNTER IN LCBERRCT FIELD.  IF * 01320021
*    THE RETRY COUNT IS 3, EXIT IS MADE TO POST WITH ERROR.  IF THE   * 01340021
*    RETRY COUNT IS LESS THAN 3, THE SDR TABLE IS UPDATED FOR A       * 01360021
*    CONTROL UNIT FAILURE, AND LCBSENSE IS ZEROED.  IF THE FAILING CCW* 01380021
*    IS A DIAL, ENABLE, OR DISABLE, LCBSTART IS SET TO THE FIRST CCW; * 01400021
*    OTHERWISE LEFT AT FAILING CCW.  AN ERROR EXCP IS ISSUED TO       * 01420021
*    RESTART THE CHANNEL PROGRAM ON THE CCW IN LCBSTART FOLLOWED BY A * 01440021
*    RETURN SVC.                                                      * 01460021
*         B- THE 'SHOULD NOT OCCUR' BIT IS SET IN THE ERROR HALFWORD  * 01480021
*    OF THE LCB.  THE ERROR EXCP IS ISSUED FOLLOWED BY A RETURN SVC.  * 01500021
*         C- THE 'OBR RECORDING' FLAG IS SET IN THE LCBCSW, AND LINK. * 01520021
*    AGE IS MADE TO THE ERROR POST MODULE, IGE0504E.                  * 01540021
*         D- IF THE FAILING CCW IS A READ-                            * 01560021
*             FOR A DIAL OR ENABLE, ONE IS ADDED TO THE RETRY COUNTER * 01580021
*         IN LCBERRCT.  IF THE RETRY COUNTER IS 3, EXIT IS MADE TO    * 01600021
*         POST THE ERROR.  IF THE RETRY COUNTER IS LESS THAN 3, THE   * 01620021
*         SDR TABLE IS UPDATED BY THE SENSE INFORMATION. LCBSENSE IS  * 01640021
*         SET TO ZERO BEFORE ERROR EXCP IS ISSUED WITH LCBSTART POINT-* 01660021
*         ING TO THE THIRD CCW.                                       * 01680021
*             FOR A TEXT TRANSFER, ONE IS ADDED TO THE RETRY COUNTER  * 01700021
*         IN LCBERRCT.  IF THE RETRY COUNT IS 3, THE ERROR COUNT IS   * 01720021
*         ADDED TO THE TWO-BIT COUNTERS IN THE ERROR HALFWORD OF THE  * 01740021
*         LCB.  EXIT IS INDICATED TO POST WITH ERROR.  IF THE RETRY   * 01760021
*         COUNT IS LESS THAN 3, THE SDR TABLE IS UPDATED BY THE SENSE * 01780021
*         INFORMATION,AND THEN LCBSENSE IS ZEROED.  IF THE RESIDUAL   * 01800021
*         COUNT IS EQUAL TO ORIGINAL COUNT (INDICATING NO DATA HAS    * 01820021
*         BEEN SENT), AN ERROR EXCP IS ISSUED WITH THE FAILING CCW IN * 01840021
*         LCBSTART SO THAT EOBLC WILL RETRY.  IF THE RESIDUAL COUNT   * 01860021
*         IS NOT EQUAL TO THE ORIGINAL COUNT, THE ERROR COUNT IS      * 01880021
*         ADDED TO THE TWO-BIT COUNTER IN THE ERROR HALFWORD. EXIT IS * 01900021
*         MADE TO POST THE ERROR WITH NO MESSAGE INDICATED IN LCBERRCT* 01920021
*         + 1.                                                        * 01940021
*             OTHERWISE, ONE IS ADDED TO THE RETRY COUNT IN LCBERRCT. * 01960021
*         IF THE RETRY COUNTER IS 3, EXIT IS MADE TO POST THE ERROR.  * 01980021
*         IF THE RETRY COUNTER IS LESS THAN 3, THE SDR TABLE IS UP-   * 02000021
*         DATED BY THE SENSE INFORMATION.  LCBSENSE IS SET TO 0 BEFORE* 02020021
*         AN ERROR EXCP IS ISSUED WITH LCBSTART SET TO THE FIRST CCW  * 02040021
*         IN THE CHANNEL PROGRAM.                                     * 02060021
*         IF THE FAILING CCW IS A POLL OR DIAL COMMAND, ONE IS ADDED  * 02080021
*    TO THE RETRY COUNTER IN LCBERRCT.  IF THE RETRY COUNTER IS 3,    * 02100021
*    EXIT IS MADE TO POST THE ERROR. IF THE RETRY COUNTER IS LESS THAN* 02120021
*    3, THE SDR TABLE IS UPDATED BY THE SENSE INFORMATION. LCBSENSE IS* 02140021
*    ZEROED BEFORE AN ERROR EXCP IS ISSUED WITH LCBSTART SET TO THE   * 02160021
*    FIRST CCW IN THE CHANNEL PROGRAM.                                * 02180021
*         IF THE FAILING CCW IS NOT A POLL, READ, OR DIAL, THE 'SHOULD* 02200021
*    NOT OCCUR' BIT IS SET IN THE ERROR HALFWORD. ERROR EXCP IS ISSUED* 02220021
*    FOLLOWED BY A RETURN SVC.                                        * 02240021
*         E- IF THE SENSE BYTE IN THE LCB IS ZERO, THE CSW IS CHECKED.* 02260021
*    IF A CHANNEL DATA CHECK IS INDICATED, EXIT IS MADE TO POST THE   * 02280021
*    ERROR.  OTHERWISE, THE 'SHOULD NOT OCCUR' BIT IS SET IN THE ERROR* 02300021
*    HALFWORD.  AN ERROR EXCP IS ISSUED FOLLOWED BY A RETURN SVC.     * 02320021
*         IF THE SENSE IS NOT ZERO, THE SENSE IS CHECKED.  FOR EQUIP- * 02340021
*    MENT CHECK, EXIT IS MADE TO POST THE ERROR.  FOR LOST DATA, THE  * 02360021
*    ACTION TAKEN IS THE SAME AS FOR ACTION D.  IF A TIME OUT OR DATA * 02380021
*    CHECK, THE ACTION TAKEN IS THE SAME AS D FOR READ CCW. OTHERWISE,* 02400021
*    THE 'SHOULD NOT OCCUR' BIT IS SET IN THE ERROR HALFWORD OF THE   * 02420021
*    LCB. AN ERROR EXCP IS ISSUED,FOLLOWED BY A RETURN SVC.           * 02440021
*                                                                     * 02460021
* ENTRY POINT-                                                        * 02480021
*         IGE0804F- CONTROL IS PASSED HERE BY IGE0004A.               * 02500021
*                                                                     * 02520021
* INPUT -                                                             * 02540021
*    REGISTER 1 - RQE ADDRESS                                         * 02560021
*    REGISTER 15 - ENTRY POINT                                        * 02580021
*                                                                     * 02600021
* OUTPUT -                                                            * 02620021
*    FOR ERROR EXCP, LCBSTART POINTS TO CCW TO RESTART WITH.          * 02640021
*    FOR BRANCHING TO EXIT ROUTINE, REGISTER 13 CONTAINS CODE FOR     * 02660021
*    NEXT MODULE TO CALL.                                             * 02680021
*                                                                     * 02700021
* EXTERNAL REFERENCES -                                               * 02720021
*         IOS SVC 15 ROUTINE                                          * 02740021
*         IOS SVC 3 ROUTINE                                           * 02760021
*         WTO SVC 35                                                  * 02780021
*                                                                     * 02800021
* EXITS, NORMAL -                                                     * 02820021
*         TO RESTART THE CHANNEL PROGRAM, AN SVC 15 IS EXECUTED       * 02840021
*         FOLLOWED BY AN SVC 3 TO RETURN TO IOS.                      * 02860021
*         TO XCTL TO THE NEXT ROUTINE, THE ROUTINE EXITS VIA A BRANCH * 02880021
*         REGISTER 14 WITH THE MODULE CODE IN REGISTER 13.            * 02900021
*                                                                     * 02920021
* EXITS, ERROR - NONE                                                 * 02940021
*                                                                     * 02960021
* TABLES / WORKAREAS - NONE                                           * 02980021
*                                                                     * 03000021
* ATTRIBUTES - SERIALLY REUSABLE, DISABLED, TRANSIENT, REFRESHABLE    * 03020021
*                                                                     * 03040021
* CHARACTER CODE DEPENDENCY - NONE                                    * 03060021
*                                                                     * 03080021
* NOTES - NONE                                                        * 03100021
*                                                                     * 03120021
*********************************************************************** 03140021
         EJECT                                                          03600017
*              REGISTER USAGE                                      00PS 03800017
TSTREG   EQU   1                       TWELVE STAR ADDRESS         00PS 04000017
UCBREG   EQU   2                       UNIT CONTROL BLOCK ADDRESS  00PS 04200017
LCBREG   EQU   3                       LINE CONTROL BLOCK ADDRESS  00PS 04400017
W1       EQU   4                                                   00PS 04600017
W2       EQU   5                                                   00PS 04800017
W3       EQU   6                                                   00PS 05000017
CCWREG   EQU   7                                                   00PS 05200017
W5       EQU   8                                                   00PS 05400017
W6       EQU   9                                                   00PS 05600017
W7       EQU   10                                                  00PS 05800017
W8       EQU   11                                                  00PS 06000017
W9       EQU   12                                                  00PS 06200017
LINKREG  EQU   13                      NEXT MODULE NAME            00PS 06400017
RETREG   EQU   14                      RETURN REGISTER             00PS 06600017
BASEREG  EQU   15                      BASE REGISTER               00PS 06800017
         EJECT                                                     00PS 07000017
         USING IECKLCB0,LCBREG                                     00PS 07200017
         USING *,BASEREG                                           00PS 07400017
         L     LCBREG,4(TSTREG)        IOB ADDRESS                 00PS 07600017
         SH    LCBREG,LCBSZ              BACK UP TO LCB            00PS 07800017
         LH    UCBREG,2(TSTREG)        UCB ADDRESS                 00PS 08000017
         L     RETREG,16               CVT ADDRESS                 00PS 08200017
         SPACE 2                                                        08400017
*                             LOCATE AND CLEAR ERPIB               00PS 08600017
         SPACE 1                                                        08800017
         L     W1,116(RETREG)          POINTER TO PARAMETER TABLE  00PS 09000017
         L     W1,0(W1)                POINTER TO ERPIB TABLE      00PS 09200017
         L     W1,0(W1)                WI= ADDRESS OF ERPIB TABLE  00PS 09400017
LOOP     CH    UCBREG,2(W1)        IS THIS THE ERPIB FOR OUR UNIT  00PS 09600017
         BE    FOUND                     BRANCH YES                00PS 09800017
         CLI   0(W1),255               IS THERE A NEXT ENTRY       00PS 10000017
         LA    W1,8(W1)                STEP TO NEXT ERPIB ENTRY    00PS 10200017
         BNE   LOOP                      BRANCH YES TO CHECK ENTRY 00PS 10400017
         SPACE 2                                                        10600017
         SPACE 2                                                        12800017
*        SAVE PROGRAM FLAGS, RETRY AND TERMINATION CODES AND CLEAR 00PS 13000017
*        THE ERPIB.                                                00PS 13200017
         SPACE 2                                                        13400017
FOUND    MVC   LCBRESTR(4),4(W1)       MOVE PERTINENT ERPIB        00PS 13600017
*                                        INFORMATION TO LCB        00PS 13800017
         XC    0(8,W1),0(W1)           CLEAR ERPIB                 00PS 14000017
         TM    LCBRESTR,1              NO RETRY FLAG SET           00PS 14200017
         BO    POST               BRANCH IF YES                    00PS 14400018
         TM    LCBRESTR+3,X'C0'        DID A SYSTEM RESET OCCUR    00PS 14600017
         BO    POST               BRANCH YES,POST ERROR            00PS 14800018
         TM    LCBRESTR,X'C0'          VALID CSW STORED (SIO OR I/O00PS 15000017
*                                        INTERRUPT)                00PS 15200017
         BNZ   CKRETRY                 BRANCH YES, CHECK RETRY CODE00PS 15400017
         TM    LCBRESTR,X'10'          DID A HIO CAUSE INTERRUPT   00PS 15600017
         BZ    POST               BRANCH NO,INVALID INTERRUPT      00PS 15800018
         SPACE 2                                                        16000017
*              FOR HIO CAUSED CHANNEL ERRORS, WRITE ERROR MESSAGE  00PS 16200017
*              AND PASS NORMAL INTERRUPT TO LINE END APPENDAGE     00PS 16400017
         SPACE 1                                                        16600017
         BAL   W9,CCWADD          VERIFY CCW ADDRESS               00PS 16800017
         LA    CCWREG,LCBCPA+8    INVALID, USE SECOND              00PS 17000017
         BAL   W9,MESSAGE              WRITE ERROR MESSAGE         00PS 17200017
         LA    CCWREG,8(CCWREG)   ADD 8 TO INITIALIZE (REDUNDANT   00PS 17400017
*                                   IF CCW ADDRESS IS VALID        00PS 17600017
         ST    CCWREG,LCBCSW      SET FOR LINE END                 00PS 17800017
         MVC   LCBCSW+4(2),CEDEUX      SET CHANNEL END DEVICE END  00PS 18000017
*                                        UNIT EXCEPTION            00PS 18200017
GOOD     NI    LCBFLAG1,X'DB'          INDICATE ERROR CORRECTED    00PS 18400017
         SVC   15                      ERROR EXCP                  00PS 18600017
         SVC   3                       RETURN                      00PS 18800017
POST     OI    LCBCSW,1                SET OBR RECORDING FLAG      00PS 19000017
*                            LINK TO ERROR POST  'IGE0504E'        00PS 19200017
         LH    LINKREG,POSTMOD         NAME OF POST MODULE         00PS 19400017
         L     RETREG,44(RETREG)       ADDRESS OF LINK ROUTINE     00PS 19600017
         BR    RETREG                                              00PS 19800017
         SPACE 2                                                        20000017
*        CSW STORED AS RESULT OF SIO OR AN I/O INTERRUPT           00PS 20200017
*                                                                  00PS 20400017
CKRETRY  BAL   W9,CCWADD          VERIFY CCW ADDRESS VALIDITY      00PS 20600017
         B    POST                INVALID, POST ERROR              00PS 20800018
         TM    LCBRESTR+2,X'10'        IS RETRY CODE VALID         00PS 21000017
         BZ    POST               BRANCH NO                        00PS 21200018
         LA    W5,3               PLACE CONTROL UNIT TYPE IN       00PS 21400017
         N     W5,16(UCBREG)       REGISTER                        00PS 21600017
*                                     2701 = 2 = X'0010'           00PS 21800017
*                                     2702 = 1 = X'0001'           00PS 22000017
*                                     2703 = 3 = X'0011'           00PS 22200017
         BCTR  W5,0               DECREMENT BY ONE                 00PS 22400017
         SLL   W5,2               MULTIPLY BY FOUR                 00PS 22600017
*                                 REGISTER NOW CONTAINS FOR        00PS 22800017
*                                     2701 - 4                     00PS 23000017
*                                     2702 - 0                     00PS 23200017
*                                     2703 - 8                     00PS 23400017
         LA    W8,7               INITALIZE FOR RETRY CODE         00PS 23600017
         N     W8,LCBRESTR          ONLY RETRY CODE REMAINS        00PS 23800017
         LA    W7,1               SET UP INCREMENT VALUE FOR BXLE'S00PS 24000017
         SR    W6,W6              INITIALIZE FIRST OPERAND OF BXLE'00PS 24200017
         MVI   LCBRESTR+1,X'C0'   SET CONDITION CODE TO REFLECT    00PS 24400017
         NC    LCBRESTR+1(1),LCBRESTR+3  THE TERMINATION CODE      00PS 24600017
         CLI   LCBRESTR+1,X'40'  TERMINATION CODE OF=CONDITION CODE00PS 24800017
*                                        X'00'           4 - LOW   00PS 25000017
*                                        X'01'           8 - EQUAL 00PS 25200017
*                                        X'02'           2 - HIGH  00PS 25400017
         SPACE 2                                                        25600017
         BXLE  W6,W7,TS001        BRANCH IF RETRY CODE NOT X'000'  00PS 25800017
         B     POST               POST ERROR IF CODE=0             00PS 26000018
TS001    BXLE  W6,W7,TS010        BRANCH IF RETRY CODE NOT X'001'  00PS 26200017
         BH    RETRY                BRANCH TO RETRY IF TERMINATION 00PS 26400017
*                                   CODE IS 2                      00PS 26600017
         BE    CK000A(W5)         BRANCH TERMINATION CODE 1        00PS 26800017
         B     CK000B(W5)         BRANCH TERMINATION CODE 0        00PS 27000017
TS010    BXLE  W6,W7,TS011        BRANCH IF RETRY CODE NOT X'010'  00PS 27200017
         BH    RETRY                BRANCH TERMINATION CODE 2      00PS 27400017
         BL    CK000B(W5)           BRANCH TERMINATION CODE 0      00PS 27600017
         B     CK000C(W5)           BRANCH TERMINATION CODE 1      00PS 27800017
         SPACE 2                                                        28000017
TS011    BXLE  W6,W7,TS100        BRANCH IF RETRY CODE NOT X'011'  00PS 28200017
C02C011  BH    POST               BRANCH TERMINATION CODE=2        00PS 28400018
*                                   REQUIRES A SIO TO ALLOW AN     00PS 28600017
*                                   EQUIPMENT CHECK INTERRUPT THEN 00PS 28800017
*                                   ATTEMPT RECOVERY               00PS 29000017
         BE    LOSTD              BRANCH TERMINATION CODE 1        00PS 29200017
         B     *+4(W5)            DETERMINE CONTROL UNIT TYPE      00PS 29400017
         B     LOSTD              2702                             00PS 29600017
         B     SNO                2701                             00PS 29800017
*                                 2703                             00PS 30000017
LOSTD    EQU   *                                                   00PS 30200017
         CLI   0(CCWREG),X'29'    FAILING CCW A DIAL               00PS 30400017
         BNE   CKREAD             BRANCH NO, CHECK FOR A READ      00PS 30600017
         B     FRETR              BRANCH YES TO COMMON CODE        00PS 30800017
         SPACE 2                                                        31000017
TS100    BXLE  W6,W7,TS101        BRANCH IF RETRY CODE NOT X'100'  00PS 31200017
         BE    SNO                  BRANCH TERMINATION CODE 1      00PS 31400017
         BH    RETRY                BRANCH TERMINATION CODE 2      00PS 31600017
         B     CK000B(W5)           BRANCH TERMINATION CODE 0      00PS 31800017
         SPACE 2                                                        32000017
TS101    BXLE  W6,W7,POST         BRANCH IF RETRY CODE NOT X'101'  00PS 32200018
*                                 TO POST WITH ERROR               00PS 32400018
         LTR   W5,W5              IS CONTROL UNIT A 2702           00PS 32600017
         BNZ   AYB1               BRANCH IF NOT 2702               00PS 32800017
         CLI   LCBRESTR+1,X'40'   RESET THE COND CODE              00PS 33000017
         B     C02C011          BANCH -2702 USE CODE 011           00PS 33200017
AYB1      EQU   *                                                  00PS 33400017
         CLI   LCBSENSE,0         IS SENSE BYTE ZERO               00PS 33600017
         BNE   CKEQCK               BRANCH NO                      00PS 33800017
         TM    LCBCSW+5,8         IS CHANNEL DATA CHECK            00PS 34000017
         BO    POST               BRANCH YES, POST WITH ERROR      00PS 34200018
         B     SNO                ELSE BRANCH TO SHOULD NOT OCCUR  00PS 34400017
CKEQCK   TM    LCBSENSE,X'10'     IS EQUIPMENT CHECK SET           00PS 34600017
         BO    POST               BRANCH YES                       00PS 34800018
         TM    LCBSENSE,2         IS LOST DATA SET                 00PS 35000017
         BO    LOSTD                BRANCH YES                     00PS 35200017
         TM    LCBSENSE,5         TIME OUT OR DATA CHECK SET       00PS 35400017
         BZ    SNO                  BRANCH NO                      00PS 35600017
CKREAD   CLI   0(CCWREG),2        FAILING CCW A READ               00PS 35800017
         BE    CKTEXT               BRANCH YES                     00PS 36000017
         CLI   0(CCWREG),9        FAILING CCW A POLL               00PS 36200017
         BNE   SNO                  BRANCH NO                      00PS 36400017
FRETR    BAL   W9,CKCOUNT         CHECK RETRY COUNT                00PS 36600017
         B     POST               BRANCH IF RETRY COUNT AT MAX     00PS 36800018
         B     FIRST              RETRY WITH FIRST CCW             00PS 37000017
CKTEXT   TM    5(CCWREG),X'30'    TEXT TRANSFER CCW                00PS 37200017
         BNZ   SERHLF             BRANCH YES                       00PS 37400017
         TM    LCBCPA+8,X'20'     IS SECOND CCW A DIAL OR ENABLE   00PS 37600017
         BZ    FRETR              BRANCH NO                        00PS 37800017
         LA    CCWREG,LCBCPA+16   RESTART AT THIRD CCW             00PS 38000017
         BAL   W9,CKCOUNT         CHECK RETRY COUNT                00PS 38200017
         B     POST               POST ERROR                       00PS 38400018
         B     EREXCP             RETRY SELECTION SEQUENCE         00PS 38600017
SERHLF   BAL   W9,CKCOUNT         CHECK RETRY COUNT                00PS 38800017
         B     SETNO+4                                             00PS 39000017
         CLC   6(2,CCWREG),LCBCSW+6  IS RESIDUAL COUNT = ORIGINAL  00PS 39200017
         BE    EREXCP             BRANCH YES, RETRY CCW            00PS 39400017
*                                 SET SO EOBLC WILL RETRY          00PS 39600017
SETNO    MVI   LCBERRCT+1,1       SET NO MESSAGE INDICATOR         00PS 39800017
         AH    W7,LCBERRST       ADD ERROR HALF WORD TO RETRY COUNT00PS 40000017
         STH   W7,LCBERRST        RESTORE                          00PS 40200017
         B     POST                 TO IGE0504E                    00PS 40400017
CK000C   B     RETRY              2702 ENTRY                       00PS 40600017
         B     RETRY              2701 ENTRY                       00PS 40800017
CK000A   B     SNO                2702 ENTRY FROM CK000A BRANCH AND00PS 41000017
*                                 2701 ENTRY FROM CK000C BRANCH    00PS 41200017
         B     SNO                2701 ENTRY FROM CK000A BRANCH    00PS 41400017
*                                 2703 N5L98 FROM CK000C BRANCH    00PS 41600017
CK000B   B     RETRY              2703 ENTRY FROM CK000A BRANCH AND00PS 41800017
*                                 2702 ENTRY FROM CK000B BRANCH    00PS 42000017
         B     SNO                2701 ENTRY                       00PS 42200017
         B     RETRY              2703 ENTRY                       00PS 42400017
         SPACE 2                                                        42600017
*              SHOULD NOT OCCUR ERRORS                             00PS 42800017
         SPACE 1                                                        43000017
SNO       EQU   *                                                  00PS 43200017
         OI    LCBERRST,1         INDICATE SHOULD NOT OCCUR ERROR  00PS 43400017
EREXCP   ST    CCWREG,LCBSTART-1  INITIALIZE START ADDRESS         00PS 45800017
         SVC   15                 ERROR EXECUTE CHANNEL PROGRAM    00PS 46000017
         SVC   3                  RETURN                           00PS 46200017
         SPACE 2                                                        46400017
*                THE FOLLOWING ROUTINE WILL SET UP TO RETRY THE    00PS 46600017
*              FAILING CCW.                                        00PS 46800017
         SPACE 2                                                        47000017
RETRY    EQU   *                                                   00PS 47200017
         BAL   W9,CKCOUNT         CHECK RETRY COUNT                00PS 47400017
         B     POST               PERMANENT ERROR, POST            00PS 47600018
         CLI   0(CCWREG),X'27'    IS FAILING CCW A DIAL,ENABLE OR  00PS 47800017
         BL    EREXCP               BRANCH NO                      00PS 48000017
FIRST    LA    CCWREG,LCBCPA      RESTART AT FIRST                 00PS 48200017
*                                   DISABLE                        00PS 48400017
         B     EREXCP             ERROR EXECUTE CHANNEL PROGRAM    00PS 48600017
*                THE FOLLOWING SUBROUTINE CHECKS THE VALIDITY OF   00PS 48800017
*              CCW ADDRESS IN THE CSW. IF THE CCW ADDRESS IS VALID,00PS 49000017
*              THE ENDING CCW ADDRESS+8 WILL BE PLACED IN CCWREG,  00PS 49200017
*              RETURN IS MADE TO +4. IF THE CCW ADDRESS IS INVALID 00PS 49400017
*              RETURN IS MADE TO +0 WITH THE INVALID ADDRESS IN    00PS 49600017
*              CCWREG.                                             00PS 49800017
*                                                                  00PS 50000017
CCWADD   L     CCWREG,LCBSTART-1  LAST CCW FOR WHICH SIO ISSUED    00PS 50200017
         TM    LCBRESTR,X'80'     DID A SIO STORE A CSW            00PS 50400017
         BO    4(W9)                BRANCH YES TO VALID RETURN     00PS 50600017
         L     CCWREG,LCBCSW      CCW ADDRESS STORED IN CSW        00PS 50800017
         SH    CCWREG,H8          BACK UP TO FAILING CCW           00PS 51000017
         TM    LCBRESTR+2,4       IS IT VALID                      00PS 51200017
         BZ    4(W9)                BRANCH YES TO VALID RETURN     00PS 51400017
         BR    W9                 BRANCH NOT VALID.                00PS 51600017
         SPACE 2                                                        51800017
MESSAGE  UNPK  BUF+23(3),0(2,CCWREG)   UNPACK OP CODE              00PS 52000017
         UNPK  BUF+26(5),LCBCSW+4(3)          STATUS               00PS 52200017
         UNPK  BUF+33(5),LCBSENSE(3)          SENSE                00PS 52400017
         TR    BUF+18(17),TABLE-240    TRANSLATE TO HEX            00PS 52600017
         MVI   BUF+17,C','             SET COMMAS                  00PS 52800017
         MVI   BUF+21,C','                                         00PS 53000017
         MVI   BUF+24,C','                                         00PS 53200017
         MVI   BUF+29,C','                                         00PS 53400017
         MVC   BUF+19(3),13(UCBREG)    LINE #                      00PS 53600017
         LR    W2,TSTREG               SAVE RB                     00PS 53800017
         LA    TSTREG,MSG              MESSAGE ADDRESS TO REG 1    00PS 54000017
         LR    W5,BASEREG              SAVE BASE                   00PS 54200017
         WTO   MF=(E,(1))              WRITE MESSAGE               00PS 54400017
         LR    TSTREG,W2               RESTORE RB                  00PS 54600017
         LR    BASEREG,W5              RESTORE BASE                00PS 54800017
         BR    W9                      RETURN                      00PS 55000017
         SPACE 2                                                        55200017
*               THIS SUBROUTINE ADDS ONE TO THE RETRY COUNTER IN   00PS 55400017
*         THE LCB. IF COUNT IS 3 EXIT IS TO POST PERMANENT ERROR.  00PS 55600017
CKCOUNT  SR    W7,W7                                               00PS 55800017
         IC    W7,LCBERRCT        PICK UP RETRY COUNT              00PS 56000017
         LA    W7,1(W7)           ADD ONE                          00PS 56200017
         STC   W7,LCBERRCT        STORE BACK                       00PS 56400017
         CLI   LCBERRCT,3         HAVE WE TRIED THREE TIMES        00PS 56440018
         BCR   11,W9              YES, RETURN                      00PS 56480018
         L     W2,X70(RETREG)     SDR UPDATE ROUTINE               00PS 56520018
         SR    W3,W3                                               00PS 56560018
         IC    W3,X9(UCBREG)      INDEX TO TABLE ENTRY             00PS 56600018
         LR    W5,W2              GET STAT TAB START ADDRESS       00PS 56640018
LOOP1    CH    UCBREG,0(0,W5)     DEV. SUPPORTED BY THIS SECTION   00PS 56680018
         BL    LOOP2              YES, INCR, ADJUSTED CORRECTLY    00PS 56720018
         LA    W5,2(0,W5)         INCR. TO NEXT CTL ENTRY          00PS 56760018
         LA    W3,256(0,W3)       INCR. STAT INDEX TO NEXT SECTION 00PS 56800018
         B     LOOP1              LOOP TO CHECK THIS SECTION       00PS 56840018
LOOP2    MH    W3,H10             ADJUST ENTRY PTR BY ENTRY LENGTH 00PS 56880018
         AR    W2,W3                                               00PS 56920018
         OC    8(1,W2),LCBSENSE   RECORD CONTROL UNIT FAILURE      00PS 56960018
         MVI   LCBSENSE,0         CLEAR SENSE BYTE                 00PS 57000018
         B     4(W9)              RETURN                           00PS 57040018
LCBSZ    DC    AL2(48)                                             00PS 57200017
H8       DC    AL2(8)                                              00PS 57400017
WTO      EQU   253                                                 00PS 57600017
X70      EQU   112                                                 00PS 57650018
X9       EQU   9                                                   00PS 57700018
H10      DC    AL2(10)                                             00PS 57750018
CEDEUX   DC    X'0D00'                                             00PS 57800017
         DS    0F                                                  00PS 58000017
MSG      DC    X'00280000'                                         00PS 58200017
BUF      DC    C'IEA000I '                                         00PS 58400017
         DC    C'  I/O ERR'                                        00PS 58600017
         DC    CL19' '                                             00PS 58800017
TABLE    DC    C'0123456789ABCDEF'                                 00PS 59000017
POSTMOD  DC    AL2(5045)                                           00PS 59200017
         EJECT                                                          59400017
IECKLCB0 DSECT                                                          59600017
LCB   EQU   IECKLCB0                                               00PS 59800017
LCBSTATE  DS  XL1                                                  00PS 60000017
LCBENDOP    DS  AL3                                                00PS 60200017
LCBCECB   DS   XL1                                                 00PS 60400017
LCBRCADD   DS  AL3                                                 00PS 60600017
LCBSCHAD   DS  A                                                   00PS 60800017
LCBCPRI   DS   FL1                                                 00PS 61000017
LCBSCHLK  DS  AL3                                                  00PS 61200017
LCBCHDR  DS AL3                                                    00PS 61400017
LCBCSEG   DS  AL3                                                  00PS 61600017
LCBNASEG  DS  AL3                                                  00PS 61800017
LCBCORCE   DS AL3                                                  00PS 62000017
LCBMSGPR  DS FL1                                                   00PS 62200017
LCBDESTQ DS AL3                                                    00PS 62400017
LCBMPLRT  DS AL1                                                   00PS 62600017
LCBCLPCI DS AL3                                                    00PS 62800017
LCBCLCCW DS  A                                                     00PS 63000017
LCBERRST DS XL2                                                    00PS 63200017
LCBBRKCT  DS  H                                                    00PS 63400017
LCBTTIND  DS H                                                     00PS 63600017
LCBDLPTR  DS H                                                     00PS 63800017
LCBFLAG1  DS XL1                                                   00PS 64000017
LCBFLAG2  DS XL1                                                   00PS 64200017
LCBSENSE  DS  H                                                    00PS 64400017
LCBECBPT   DS A                                                    00PS 64600017
LCBCSW   DS   D                                                    00PS 64800017
LCBSIOCC DS  XL1                                                   00PS 65000017
LCBSTART  DS AL3                                                   00PS 65200017
LCBWGHT  DS  0XL1                                                  00PS 65400017
LCBDCBPT  DS  A                                                    00PS 65600017
LCBRESTR  DS  A                                                    00PS 65800017
LCBINCAM  DS  H                                                    00PS 66000017
LCBERRCT  DS  H                                                    00PS 66200017
LCBUCBX  DS  FL1                                                   00PS 66400017
LCBPTEMP  DS  FL1                                                  00PS 66600017
LCBTRST   DS  H                                                    00PS 66800017
LCBPOLCT   DS  FL1                                                 00PS 67000017
LCBPOLPT  DS  AL3                                                  00PS 67200017
LCBERCCW    DS  D                                                  00PS 67400017
LCBCPA   DS  0D                                                    00PS 67600017
         END                                                            67800017
