 TITLE 'IGG0193N  QTAM LINE GROUP OPEN EXECUTOR - LOAD 1'               00100013
*********************************************************************** 00170021
*                                                                     * 00240021
*STATUS- CHANGE LEVEL=20          JANUARY 1971                        * 00310021
*                                                                     * 00400013
* FUNCTION - THE PRIMARY FUNCTION OF THIS ROUTINE IS TO OBTAIN THE DEB* 00420021
*    AND ANALYZE THE UCB INFORMATION.  IF THE DCBDEVTP FIELD OF THE   * 00440021
*    DCB CONTAINS A X'FF', INDICATING 'STRAM', THE WHERE-TO-GO TABLE  * 00460021
*    IS SET FOR THE 'STRAM' MODULE BEFORE EXITING VIA AN XCTL.        * 00480021
*         THE TIOT IS ACCESSED TO OBTAIN THE LENGTH NEEDED FOR THE DEB* 00500021
*    EXTENTS.  THE SIZE OF THE DEVICE ENTRY FOR THE DEB EXTENTS IS    * 00520021
*    CALCULATED.  THE SIZE OF THE DEVICE ENTRY FOR EACH CONCATENTED DD* 00540021
*    STATEMENTS IS TOTALED.  THE MINIMUM SIZE OF THE DEB (87) IS ADDED* 00560021
*    TO THE AMOUNT FOR EXTENTS, AS A PARAMETER FOR GETMAIN MACRO.  THE* 00580021
*    CORE FOR THE DEB IS OBTAINED FROM SUBPOOL 254.  THE DEB IS ZEROED* 00600021
*    AND THEN INITIALIZED WITH THE NUMBER OF EXTENTS IN DEBNMEXT, TCB * 00620021
*    ADDRESS IN DEBTCBAD, START OF DEB IN DEBAPPAD, DCB ADDRESS IN    * 00640021
*    DEBDCBAD, X'00' IN DCBDEVTP, PROTECTION TAG FROM THE TCB TO      * 00660021
*    DEBPROTG, LENGTH IN DOUBLE WORDS IN DEBLNGTH, AND DEB ADDRESS IN * 00680021
*    TCB TO DEBDEBAD TO CHAIN THE DEB INTO THE TCB.  THE DIAL-OUT     * 00700021
*    CALL QUEUE IS INITIALIZED BY STORING THE ADDRESS OF THE DEB      * 00720021
*    PREFIX INTO THE FIRST TWO WORDS OF THE DEB PREFIX.  THESE 2 WORDS* 00740021
*    ARE NOT USED FOR I/O BY QTAM.  THE DEB ADDRESS IS STORED INTO THE* 00760021
*    DCBDEBAD FIELD OF THE DCB.  IF THE NUMBER OF BUFFERS REQUESTED IN* 00780021
*    DCBBUFRQ IS LESS THAN 2, DCBBUFRQ IS SET TO TWO.  THE ADDRESSES  * 00800021
*    OF THE UCBS IN THE TIOT ARE MOVED INTO THE DEB EXTENTS.          * 00820021
*         IF THE DIRECT ACCESS DEVICE FOR MESSAGE QUEUES HAS NOT BEEN * 00840021
*    OPENED, AN ABEND IS ISSUED WITH AN 0A6 COMPLETION CODE.  OTHER-  * 00860021
*    WISE THE APPENDAGE ADDRESSES IN THE FIXED AREA OF IGG019NG ARE   * 00880021
*    STORED IN THE DEB APPENDAGE AREA.                                * 00900021
*         ANALYSIS OF THE DEVICE TYPE FIELD OF THE UCB IS DONE FOR    * 00920021
*    EACH UCB ADDRESS IN THE DEB.  IF COMMUNICATION EQUIPMENT (X'40'  * 00940021
*    IN THIRD BYTE) HAS NOT BEEN SPECIFIED, AN 090 ABEND IS ISSUED.   * 00960021
*    IF THE CONTROL UNIT SPECIFIED IS NOT 2701,2702, OR 2703, AN 091  * 00980021
*    ABEND IS ISSUED.  IF ONE OF THE 8 ADAPTER TYPES IS NOT SPECIFIED,* 01000021
*    AN 092 ABEND IS ISSUED.  FOR EACH ADAPTER TYPE, THE POSSIBLE     * 01020021
*    MODEL TYPES ARE CHECKED.  IF AN INVALID MODEL TYPE IS SPECIFIED, * 01040021
*    AN 093 ABEND IS ISSUED.  IF A WORLD TRADE TELETYPE ADAPTER IS    * 01060021
*    SPECIFIED AND THE MODEL TYPE IS NOT FOR WTTA TERMINALS, AN 092   * 01080021
*    ABEND IS ISSUED.  ALSO FOR WORLD TRADE ADAPTERS, IGG019QB IS     * 01100021
*    LOADED FOR WTTA APPENDAGES.  THE ADDRESS OF IGG019QB IS STORED IN* 01120021
*    THE APPENDAGE TABLE OF THE DEB.  THE WTTA DEVICE CODE POINTER IS * 01140021
*    SET IN THE DCBDEVTP FIELD OF THE DCB.  THE 'WRU' BITS FROM THE   * 01160021
*    LPSTART MACRO EXPANSION ARE MOVED INTO THE DCB.                  * 01180021
*         TESTS FOR THE POSSIBLE OPTIONAL FEATURE BITS FOR THE 1060,  * 01200021
*    2740, 1050, AND 1030 ARE MADE.  AN 094 ABEND IS ISSUED FOR       * 01220021
*    INCORRECT OPTIONAL BITS.  THE DEVICE CODE FOR SELECTING THE      * 01240021
*    DEVICE I/O MODULE FOR A TERMINAL TYPE IS SET IN THE DCBDEVTP     * 01260021
*    FIELD OF THE DCB.                                                * 01280021
*    IF THIS ROUTINE IS NEEDED FOR ANOTHER DCB, A BRANCH IS TAKEN TO  * 01300021
*    THE START OF THIS ROUTINE.  UPON COMPLETION, CONTROL IS PASSED   * 01320021
*    TO THE NEXT NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE VIA AN XCTL. * 01340021
*                                                                     * 01360021
* ENTRY POINTS- ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE BY AN   * 01380021
*         XCTL FROM SYSTEM OPEN.  IT ALSO MAY BE RE-ENTERED FROM A    * 01400021
*         RELOOP PORTION OF THIS ROUTINE IF THERE IS ANOTHER DCB TO BE* 01420021
*         OPENED.                                                     * 01440021
*                                                                     * 01460021
*                                                                     * 01600013
*INPUT-  THE REGISTERS 5, 6, 7, AND 8 ARE THE INPUT, AS FOLLOWS,      * 01700013
*   5- THE ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST,      * 01800013
*   6- THE ADDRESS OF THE BEGINNING OF THE WHERE@TO@GO TABLE,         * 01900013
*   7- THE ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST,    * 02000013
*   8- THE ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO * 02100013
*      TABLE.                                                         * 02200013
*OUTPUT-  THE REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES* 02300013
*   IN THE DCB PARAMETER LIST AND THE WHERE-TO TABLE.  A DEB WILL  *    02400013
*   HAVE BEEN CONSTRUCTED IN SUBPOOL 254, AND IOB'S (ONE PER LINE)    * 02500013
*   WILL HAVE BEEN CONSTRUCTED IN SUBPOOL 250.  DCB FIELDS (DEVTP,    * 02600013
*   IOBAD, EIOBX,IFLGS,DEBAD,AND READ/WRITE WILL HAVE BEEN            * 02700013
*   INITIALIZED.  THIS EXECUTOR'S ENTRY (OR ENTRIES) IN THE WHERE-TO- * 02800013
*    GO TABLE WILL HAVE BEEN UPDATED TO IDENTIFY LOAD 2 (IGG0193R).   * 02870021
*                                                                     * 02940021
* EXTERNAL REFERENCES - NONE                                          * 03010021
*                                                                     * 03100013
*EXITS-NORMAL-  THIS ROUTINE EXITS VIA AN XCTL TO THE MODULE          * 03200013
*   IDENTIFIED BY THE NEXT NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE,   * 03300013
*    NAMELY IGG0193R (QTAM OPEN - LOAD 2).                            * 03380021
*                                                                     * 03460021
* EXITS, ERROR - THIS ROUTINE EXITS VIA ABEND FOR THE FOLLOWING:      * 03540021
*                                                                     * 03620021
*   ERROR CONDITIONS-                                                 * 03700013
*   ABEND CODE ERROR CONDITION                                        * 03800013
*   00090000    A DEVICE OTHER THAN A COMMUNICATIONS DEVICE HAS BEEN  * 03900013
*               ALLOCATED TO THIS DCB.                                * 04000013
*   00091000    AN INVALID OR UNSUPPORTED CONTROL UNIT HAS BEEN       * 04100013
*               SPECIFIED                                             * 04200013
*   00092000    AN INVALID OR UNSUPPORTED TYPE OF TERMINAL CONTROL    * 04300013
*               OR ADAPTER HAS BEEN SPECIFIED                         * 04400013
*   00093000    AN INVALID OR UNSUPPORTED TERMINAL TYPE HAS BEEN      * 04500013
*               SPECIFIED.                                            * 04600013
*   00094000    AN INVALID OR UNSUPPORTED OPTIONAL FEATURE (OR MODE OF* 04700013
*               OPERATION) HAS BEEN SPECIFIED.                        * 04800013
*                                                                     * 04900013
*TABLES/WORK AREAS- THE WHERE-TO-GO TABLE CONTAINS THE ID AND TTR     * 05000013
*       OF THE OPEN EXECUTOR LOAD 2. THE DCB PARAMETER LIST CONTAINS  * 05100013
*       THE ADDRESS OF EACH DCB SPECIFIED IN THE OPEN MACRO. THE        05200013
*       COMMUNICATION VECTOR TABLE IS A RESIDENT VECTOR LIST USED     * 05300013
*       TO LOCATE THE TIOT,WHICH IS NEEDED IN DEB CONSTRUCTION.       * 05400013
*                                                                     * 05500013
*ATTRIBUTES-THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS         * 05600013
*       ENABLED, PRIVILEGED, AND REENTRANT.                           * 05700013
*                                                                     * 05800013
*NOTES- THIS ROUTINE INITIATES THE OPEN PROCESSING FOR                * 05900013
*  TELECOMMUNICATIONS. IT CONSTRUCTS THE IOB AND BEGINS                 06000013
*  A DEVICE TYPE ANALYSIS OF THE TELECOMMUNICATION DEVICE FOUND IN    * 06100013
*  UCB. UPON COMPLETION OF THIS MODULE CONTROL IS PASSED ON TO THE    * 06200013
*  SECOND OPEN MODULE THROUGH THE WHERE-TO-GO TABLE ENTRY.            * 06300013
*                                                                     * 06400013
*********************************************************************** 06500021
IGG0193N CSECT                                                          06600013
         SPACE 1                                                        06700013
*2719296000,358040-358800,471200-471800,508000                     000C 06730017
*2719517300-517600,523000                                          000C 06760017
*3411162500                                                       19567 06780017
* 482000                                                         A36519 06790020
*A358530-358540                                                  A25045 06795021
*A001700-014600,028700-030100,033800-036200                      S21016 06797021
RE       EQU   0                       WORK/PARAMREG                    06800013
RF       EQU   1                       WORK/PARAMREG                    06900013
RDCB     EQU   2                       DCB ADDRESS                      07000013
RBASE    EQU   3                       BASE REGISTER                    07100013
RCORE    EQU   4                       IOB ADDRESS                      07200013
RPAR     EQU   5                       START OF PARAMETER LIST          07300013
RWTG     EQU   6                       START OF WTG                     07400013
RPARC    EQU   7                       CURRENT ENTRY IN PARAMETER LIST  07500013
RWTGC    EQU   8                       CURRENT ENTRY IN WTG TABLE       07600013
RTIOT    EQU   9                       TIOT ADDRESS                     07700013
RUCB     EQU   10                      CURRENT UCB                      07800013
RDEB     EQU   11                      DEB ADDRESS                      07900013
RB       EQU   12                      WORK REG                         08000013
RC       EQU   13                      WORK REG                         08100013
RD       EQU   14                      WORK/PARAMREG                    08200013
RJ       EQU   15                      WORK/PARAMREG                    08300013
CVTTCBPT EQU   0                                                        08400013
LPS      EQU   0                                                        08500013
DEV1030  EQU   X'01'                                                    08600013
DEV1050  EQU   X'01'                                                    08700013
DEV1060  EQU   X'02'                                                    08800013
DEV2740  EQU   X'04'                                                    08900013
NGAD     EQU   4                                                        09000013
CURNTTCB EQU   X'04'                                                    09100013
TCBTIO   EQU   12                                                       09200013
CVT      EQU   16                                                       09300013
CVTAPP   EQU   20                      OFFSET OF IOS APPENDAGE TBL      09400013
TCBPKF   EQU   28                                                       09500013
TPDEVCCD EQU   X'40'                                                    09600013
APMASK   EQU   X'40'                                                    09700013
REGMASK  EQU   X'FC'                                                    09800013
TERMTBL  EQU   156                                                      09900013
APPAD    EQU   176                                                      10000013
GETRET   EQU   280                                                      10100013
DISPATCH EQU   X'F8'                                                    10200013
DXCCW    EQU   X'170'         REGESTER SAVE AREA                        10300013
DXCCW12  EQU   X'1C8'                                                   10400013
         USING IHADCB,RDCB                                              10500013
         USING IECTDEB,RDEB                                             10600013
         BALR  RBASE,0             START OF DCBD MACRO                  10700013
         USING *,RBASE                                                  10800013
*                                                                       10900013
*      EXECUTE SUBTASK CAUSEING QQ01 BASE TO BE STORED IN IGG019NG      11000013
*                                                                       11100013
         L     RCORE,4(RWTGC)     ADDRESS OF THE OPEN WORK AREA         11200013
RESTART  L     RDCB,0(RPARC)      ADDRESS OF THE DCB                    11300013
         TM    DCBDEVTP,X'FF'      TEST FOR STRAM                       11400013
         BC    14,DEBSTART         IF NOT STRAM, CONTINUE PROCESSING.   11500013
         MVC   0(5,RWTGC),STRAMID  SET STRAM ID                         11600013
         B     BYPASS              BYPASS BTAM PROCESSING.              11700013
* DEB                                                                   11800013
DEBSTART SR    RCORE,RCORE                   CLEAR REGISTERS            11900013
         SR    RB,RB                                                    12000013
* LOCATE DDNAME                                                         12100013
* LOCATION 16 CONTAINS POINTER TO COMMUNICATION VECTOR TABLE            12200013
* CVTTCBPT CONTAINS POINTER TO THE TCB TABLE                            12300013
* CURNTTCB CONTAINS POINTER TO THE FIRST TASK CONTROL BLOCK             12400013
         L     RC,16(0,0)                    ACCESS POINTER TO COM V.T. 12500013
         L     RC,CVTTCBPT(0,RC)         ACC.POINTER TO TCB TABLE       12600013
         L     RC,CURNTTCB(0,RC)         POINT TO CURRENT TCB           12700013
         L     RTIOT,TCBTIO(0,RC)     LOAD PTR TO TASK I/O TABLE        12800013
* TCBTIO EQUALS 12 AND POINTS TO STARTING POS OF TIOT                   12900013
         AH    RTIOT,DCBTIOT                ADD OFFSET TO ACCESS POINT  13000013
*                                       TO TIOT LENGTH FIELD START      13100013
         LR    RD,RTIOT         EQUATE TO LENGTH POS OF TIOT            13200013
*  RTIOT WILL BE NEEDED TO POINT TO FIRST TIOT.                         13300013
         SR    RF,RF                                                    13400013
DDBLKLP  LA    RCORE,1(0,RCORE)       INCR FOR EACH CONC DDNAME         13500013
         IC    RF,0(RD,0)              PICK UP LENGTH OF TIOT           13600013
         AR    RD,RF               ADD LENGTH FOR NEXT TIOT             13700013
         SH    RF,SIXTEEN          L-16 EQUAL AMOUNT OF UCB'S           13800013
         AR    RB,RF               ACCUMULATE UCB'S FOR NO OF EXTENTS   13900013
         NC    0(4,RD),0(RD)                 ZERO TEST ON START OF TIOT 14000013
         BZ    EOTS                                                     14100013
         CLI   4(RD),X'40'             TEST BLANK DDNAME                14200013
         BE    DDBLKLP         IF CONCATENATED GET UCBS FOR GETMAIN     14300013
EOTS     LA    RE,MINSIZE2(RB)          ADD THE MINIMUM DEB SIZE        14400013
GETDEB   SRL   RE,3                                                     14500013
         LR    RD,RE                    RD NOW CONTAINS THE DEB SIZE IN 14600013
*                                  NUMBER OF DOUBLE WORDS.              14700013
         SLL   RE,3                     RE NOW CONTAINS THE DEB SIZE IN 14800013
*    NUMBER OF BYTES, AND IS THE PARAMETER REGISTER FOR GETMAIN.        14900013
         O     RE,DEBPOOL               PLACE SUBPOOL NUMBER IN HIGH    15000013
*                                  ORDER BYTE OF PARAMETER REGISTER.    15100013
         GETMAIN R,LV=(0)                                               15200013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 15300013
MINSIZE2 EQU   87                       THE MINIMUM DEB SIZE FOR BUFFER 15400013
*    POOL MANAGEMENT SUPPORT - IT INCLUDES A 4 BYTE ACCESS METHOD       15500013
*    SECTION AND 2 BYTES OF SUBROUTINE ID IN ADDITION TO THE MINSIZE1   15600013
*    REQUIREMENT.                                                       15700013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 15800013
         LR    RDEB,RF                  LOAD ADDRESS OF STORAGE AREA    15900013
*    INTO RDEB FOR USE OF ROUTINE THAT CLEARS STORAGE.                  16000013
         LR    RJ,RE                    LOAD DEB SIZE FOR USE OF THE    16100013
*                                  CLEAR STORAGE ROUTINE.               16200013
         LA    RJ,0(RJ)            CLEAR HIGH ORDER BYTE          19567 16250017
CLEARL   CH    RJ,HWC256                IF THE DEB SIZE IS LESS THAN OR 16300013
         BNH   EXMODIFY            EQUAL TO 256, GO TO EXECUTE THE      16400013
*    CLEAR DEB INSTRUCTION WITH A LENGTH EQUAL TO THE SIZE MINUS ONE.   16500013
         LA    RDCB,255                 DCB REGISTER TEMPORARILY        16600013
*    DESTROYED FOR USE AS LENGTH REGISTER IN EXECUTE INSTRUCTION.       16700013
         EX    RDCB,CLEARDEB            CLEAR 256 BYTES OF DEB.         16800013
         SH    RJ,HWC256                DECREMENT SIZE                  16900013
         AH    RDEB,HWC256                   INCREMENT ADDRESS          17000013
         B     CLEARL                             AND RELOOP.           17100013
EXMODIFY BCTR  RJ,0               SUB ONE FOR THE EXECUTE               17200013
         EX    RJ,CLEARDEB                  BASIC SIZE OR LAST SIZE OF  17300013
*                                       DEB IS CLEARED TO ZERO          17400013
         LR    RDEB,RF                      RE-INITIALIZE DEB POSITION  17500013
         L     RDCB,0(RPARC,0)              RE-INITIALIZE DCB POSITION  17600013
         SRL   RB,2                DIVIDE UCB'S BY 4                    17700013
         STC   RB,DEBNMEXT         MOVE IN DEB NO. OF EXTENTS           17800013
         ST    RC,DEBNMSUB     MOVE IN DEBTCBAD OVERLAY DEBNMSUB        17900013
         ST    RF,DEBEXSCL                                              18000013
         LA    RF,20(RF)          ACCESS DEB PREFIX                000A 18020015
         ST    RF,0(RF)           INITIALIZE FOR DIAL-OUT CALL QUEUe00A 18040015
         ST    RF,4(RF)           INITIALIZE DUMMY END ELEMENT     000A 18060015
         MVI   4(RF),X'FF'        IDENTIFY DUMMY END ELEMENT       000A 18080015
* MOVE IN EXSCL FIELD AND APPAD-ADDRESS OF APPENDAGE BLOCK              18100013
*                                  CHAIN OF DEBS, AND STORE IN DEB.     18200013
         MVI   DEBEXSCL,X'02'   MOVE IN 2 FOR NON-DIRECT ACCESS DEVICE  18300013
* MOVE OF DEBEXSCL COMPLETES 4 BYTE FIELD OF DEBEXSCL AND DEBAPPAD      18400013
         MVC   DEBOPATB(1),0(RPARC)                                     18500013
         L     RF,8(RC)                 LOAD ADDRESS OF FIRST DEB IN    18600013
*                                  CHAIN OF DEB'S OFF TASK CONTROL      18700013
*                                  BLOCK.                               18800013
         ST    RF,DEBAMLNG              STORE ADDRESS IN THIS DEB TO    18900013
*                                  MAKE IT FIRST ON CHAIN.              19000013
         MVI   DCBDEVTP,X'00'     MOVE THE SIZE OF THE ACCESS           19100013
*                                  METHOD SECTION INTO THE DEB.         19200013
         LA    RF,DEBNMSUB              ACCESS ADDRESS OF BASIC DEB.    19300013
         ST    RF,8(RC)                 STORE DEB ADDRESS IN TASK       19400013
*                                  CONTROL BLOCK.                       19500013
         ST    RF,DCBIFLGS              STORE DEB ADDRESS IN DCB.       19600013
         ST    RDCB,DEBPROTG                                            19700013
         CLI   DCBBUFRQ,X'02'     BUFFER REQUESTS LESS THAN TWO         19800013
         BC    10,*+8             BRANCH IF NO                          19900013
         MVI   DCBBUFRQ,X'02'      SET TO TWO                           20000013
         MVC   DEBPROTG(1),TCBPKF(RC)   MOVE PROTECTION TAG FROM TCB    20100013
         OI    DEBPROTG,X'0F'           TO DEB AND OR IN DEB ID.        20200013
         STC   RD,DEBLNGTH       MOVE IN DOUBLE WORDS OF DEB            20300013
         LA    RJ,DEBUCBAD                  PLACE DEB-UCB START IN REG  20400013
DEBMOVE1 SR    RF,RF                         CLEAR                      20500013
         IC    RF,0(0,RTIOT)          BRING IN INITIAL TIOT             20600013
* START OF TIOT                                                         20700013
         SH    RF,SEVNTEEN         AMOUNT OF UCBS TO MOVE PLUS 1 FOR EX 20800013
         EX    RF,UCBMOVE                                               20900013
         LA    RJ,1(RJ,RF)                  INCREASE DEB POS BY LENGTH  21000013
         LA    RTIOT,17(RTIOT,RF)                                       21100013
* 17 DISPLACEMENT EQUALS 16 FROM LENGTHREG,1 FROM LENGTHREG AND         21200013
* LENGTHREG TO POINT TO NEXT TIOT.                                      21300013
         BCT   RCORE,DEBMOVE1                                           21400013
*                                                                       21500013
*      SET APPENDAGE ADDRESSES IN THE DEB                               21600013
*                                                                       21700013
         L     RC,CVT                  LOAD COMM. VECT. TBL ADDRESS.    21800013
         L     RC,TERMTBL(RC)     ADDRESS OF THE TERMINAL TABLE         21900013
         LTR   RC,RC              IS THE DIRECT ACCESS DEVICE OPEN      22000013
         BNZ   DAOPEN                                                   22100013
         L     1,ERR5             ABEND CODE DIRECT ACCESS NOT OPEN     22200013
         ABEND (1)                                                      22300013
DAOPEN   L     RC,NGAD(RC)        ADDRESS OF IGG019NG                   22400013
         L     RC,LPS(RC)         ADDRESS OF THE LPS QUEUE IN IGG019NG  22500013
         MVC   DEBEOEA(16),APPAD(RC) APPENDAGE ADDRESS TO THE DEB       22600013
         MVC   DEBXCEA(4),DEBCEA                                        22700013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 22800013
*FOLLOWING IS 4 BYTE DEVICE TYPE FIELD OF UCB                           22900013
* DEVICE TYPE ANALYSIS FOLLOWS                                          23000013
* IOS   - MODEL* OPTIONAL * DEVICE* UNIT*                               23100013
*       -      *          *       *     *                               23200013
* FLAGS - CODE *  FEATURES*  CLASS* TYPE*                               23300013
         SR    RC,RC                                                    23400013
         SR    RTIOT,RTIOT             RTIOT WILL CONTAIN DEVICE CODE   23500013
*                                      DEVCDREG SET TO ZERO FOR 1050R   23600013
         L     RB,DEBUCBAD           STORE ADDRESS OF UCB               23700013
*                                                                       23800013
*                   TEST ALL UCB DEVICE CODES IN THIS LINE GROUP        23900013
*                        IF ERROR EXISTS (GENERR) THE SYSTEM MUST BE    24000013
*                          CORRECTED AND REGENERATED.                   24100013
         SR    RJ,RJ               CLEAR RJ (INDEX TO UCB POINTER)      24200013
         SR    RF,RF                                                    24300013
         LA    RE,4                SET INCREMENT REGESTER TO L'DEBUCBAD 24400013
         IC    RF,DEBNMEXT         SET NUMBER OF EXTENTS                24500013
         BCTR  RF,0                REDUCE BY 1                          24600013
         SLL   RF,2                SET LOC OF LAST UCB                  24700013
         B     BUMPUCB             ENTER LOOP                           24800013
NEXTUCB  L     RCORE,DEBUCBAD(RJ)                                       24900013
         MVC   0(4,RWTGC),16(RB)   MOVE FIRST UCB DEVICE CODE TO WORK   25000013
         XC    0(4,RWTGC),16(RCORE) COMPARE ALL BITS                    25100013
         NC    0(4,RWTGC),HOLDMASK REMOVE IRELEVENT BITS                25200013
         BC    4,GENERR            TEST NON-ZERO                        25300013
BUMPUCB  BXLE  RJ,RE,NEXTUCB       INCREMENT RJ BY RE (4),COMPARE TO RF 25400013
         AH    RB,SIXTEEN          BUMP TO GET DEVICE TYPE POS OF UCB   25500013
         IC    RC,3(RB)                                                 25600013
         CLI   2(RB),TPDEVCCD                                           25700013
         BE    UCBPT1                                                   25800013
* TELECOMMUNICATION ERROR FOLLOWS-SHOULD BE CODE 40                     25900013
         L     1,ERR0                                                   26000013
         ABEND (1)                                                      26100013
* UNIT TYPE-2701-2702 TEST                                              26200013
UCBPT1   TM    3(RB),X'03'                                              26300013
         BC    5,UCBPT2       BRANCH IF 2701,2702 OR 2703               26400013
* CONTROL UNIT ERROR-NO SPECIFICATION OF 2701,2702, OR 2703             26500013
         L     1,ERR1                                                   26600013
         ABEND (1)                                                      26700013
UCBPT2   SRL   RC,4           CLEAR OUT LOW ORDER 2701,2702,2703 BITS   26800013
         CH    RC,HWC8                                                  26900013
         BH    TERMERR                                                  27000013
* UNIT TYPE WILL BE USED AS POINTER TO LOCATE SPECIFIC TERMINAL ADAPTER 27100013
         SLL   RC,2                                                     27200013
         SR    RDCB,RDCB              INITIALIZE FOR TYPE TEST          27300013
         LA    RD,1(0,0)              REG USED AS INCREMENT FACTOR 1    27400013
* TEST WILL BE PERFORMED ON MODEL TYPE FOR EACH TERMINAL ADAPTER        27500013
         B     MODELRT(RC)                                              27600013
*                                                                       27700013
*  BRANCH IS EXECUTED TO MODELRT INDEX BY THE CONTENTS OF UNITYREG      27800013
*                                                                       27900013
         SPACE 2                                                        28000013
MODELRT  B     TERMERR                                                  28100013
* THIS FIRST BRANCH IS TAKEN ON ZERO UNIT TYPE                          28200013
* THE FOLLOWING BRANCHES ARE TAKEN FOR A SPECIFIC TERMINAL ADAPTER      28300013
*                                 SPEC IN UNITYREG VALUE CD BITS 1-5    28400013
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  28500013
*                            VALUE CODES 1-3 PROCESSED IN LOAD 1.       28600013
*                                                                       28700013
         B     TYPE1              VALUE CD 1-IBM TERMINAL ADAPTER TYPE1 28800013
         B     TYPE2              VALUE CD 2-IBM TERMINAL ADAPTER TYPE  28900013
         B     IBMTEL             VALUE CD 3-IBM TERMINAL ADAPTER       29000013
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  29100013
*                                  CODES 4-8 PROCESSED IN LOAD 2.       29200013
*                                                                       29300013
         B     ENDLOD1            VALUE CD 4-IBM TELGRAPH ADAPTER TYPE1 29400013
         B     ENDLOD1            VALUE CD 5-IBM TELGRAPH ADAPTER TYPE2 29500013
         B     TYPE6              VALUE CD 6-WORLD TRADE TELETYPE  000C 29600017
         B     TERMERR            VALUE CD 7-SYNC DATA ADAPTER    *NCS* 29700013
         B     ENDLOD1            VALUE CD 8-IBM TERMINAL ADAPTER TYPE3 29800013
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  29900013
TYPE1    TM    0(RB),DEV2740                                            30000013
         BO    D2740              2740 BRANCH                           30100013
         TM    0(RB),DEV1060                                            30200013
         BO    D1060                   1060 BRANCH CODETAB UNITYREG-1   30300013
IBMTEL   TM    0(RB),DEV1050                                            30400013
         BO    D1050                   1050 BRANCH CODETAB UNITYREG-3   30500013
*                                            ANY OTHER UCB CODE FOR IBM 30600013
*                                 TERMINAL ADAPTER AND TYPE1 IS ERROR   30700013
         B     ADAPTYER                                                 30800013
TYPE2    TM    0(RB),DEV1030                                            30900013
         BO    D1030                   1030 BRANCH CODETAB UNITYREG-2   31000013
* ANY OTHER UCB CODE FOR IBM TERMINAL ADAPTER TYPE2 IS IN ERROR         31100013
ADAPTYER L     1,ERR3                                                   31200013
         ABEND (1)                                                      31300013
TERMERR  L     1,ERR2                  TERMINAL ADAPTR TYPE 0 > 5       31400013
         ABEND (1)                                                      31500013
GENERR   EQU   TERMERR       * * * * TEMP CODE-REPLACE * * * *          31600013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 31700013
*                                       OPTIONAL FEATURE TEST FOLLOWS   31800013
*                                      INDICATIONG DEVICE TYPE WITH OPT 31900013
*                                      FEATURES,REGULAR DEVICE OR OPT   32000013
*                                      DEVICE FEATURE ERROR.            32100013
*                                       OPTIONAL FEATURE BIT CODES-     32200013
*                                      0-AUTOMATIC CALL-AC              32300013
*                                      1-AUTOMATIC POLL-AP              32400013
*                                      2-TERMINAL-TERMINAL-TT           32500013
*                                      3-AUTO ANSWERING-AA              32600013
*                                      0AND3 BIT INDICATE COMBINATION   32700013
*                                      AC AND AA OR CODE A              32800013
*                                       BIT CODES                       32900013
*                                         0    1    2    3    *AC-0-8   33000013
*                                       XXXXXXXXXXXXXXXXXXX   AP-1-4    33100013
*                                       X   XX   XX   XX   X   TT-2-2   33200013
*                                       XXXXXXXXXXXXXXXXXXXX  *AA-3-1   33300013
*                                         8    4    2    1    *A-03-9   33400013
D1060    TM    1(RB),REGMASK                                            33500013
         BZ    IBM1                                                     33600013
         AR    RDCB,RD                                                  33700013
         TM    1(RB),APMASK                                             33800013
         BO    IBM1                                                     33900013
         B     SPFEAERR                                                 34000013
         SPACE 2                                                        34100013
D2740   LA    RDCB,SWITCH2-SWITCH1     SET SWITCH FOR 2740              34200013
D1050   LR    RD,RDCB                  FREE RDCB                        34300013
         L     RDCB,DEBDCBAD-1          RESTORE DCB ADDRESSABILITY      34400013
         LA    RE,X'1F'                 INITIALIZE MASK FOR 2740        34500013
         IC    RTIOT,1(RB)             GET SPECIAL FEATURES BITS        34600013
         SRL   RTIOT,2                 DROP 2 LOW ORDER BITS            34700013
         STC   RTIOT,DCBDEVTP          STORE INTO DCB                   34800013
         TR    DCBDEVTP(1),FETAB       TRANSLATE FEATURE BITS TO CODE   34900013
         IC    RTIOT,DCBDEVTP           GET TRANSLATED BYTE             35000013
         B     SWITCH1(RD)                                              35100013
SWITCH1  SRL   RTIOT,5                  1050 ONLY - SHIFT OUT 2740 BITS 35200013
         LA    RE,X'07'                SET MASK FOR 1050                35300013
SWITCH2  NR    RTIOT,RE                 REMOVE UNWANTED BITS            35400013
         STC   RTIOT,DCBDEVTP           STORE FINAL RESULTS             35500013
         CLR   RTIOT,RE                 TEST FOR ALL BITS ON -INVALID-  35600013
         BE    SPFEAERR                                                 35700013
         B     ENDLOD1                                                  35800013
TYPE6    TM    0(RB),DEVWTTA           IS IT A WTTA                000C 35804017
         BNO   TERMERR                 NO,ERROR                    000C 35808017
         MVC   6(2,RWTG),WTTA          LOAD MODULE ID IN WORKAREA  000C 35812017
         MVC   14(3,RWTG),WTTA+2       TTR TO THE WORKAREA         000C 35816017
         MVC   22(7,RWTG),WTATTRIB     MOVE CORRECT CONTAB         000C 35820017
         LR    RE,RWTG                 GET ADDRESS OF NAME         000C 35824017
         L     RD,CVT                  GET CVT ADDRESS             000C 35828017
         L     RF,84(RD)               GET ADDRESS OF SVCLIB DCB   000C 35832017
         LOAD  DE=(0),DCB=(1)          LOAD IGG019QB               000C 35836017
         LR    RF,RE                   SAVE IGG019QB ADDRESS       000C 35840017
         MVC   8(8,RF),DEBPCIA         SET QTAM APPEND.IN IGG019QB 000C 35844017
         STM   RE,RF,DEBPCIA           CHANGE PCI CE APP. ADDRESS  000C 35848017
         ST    RF,DEBXCEA              AND ABNORMAL END APP. IN DEB000C 35852017
         LA    RF,24(RF)          COMPUTE PCI APP ENTRY ADDR     A25045 35853021
         ST    RF,DEBPCIA         SET IT AS PCI APPENDAGE ADDR   A25045 35854021
         L     RDCB,DEBDCBAD-1         RESTORE BASE OF DCB         000C 35856017
         LA    RTIOT,WTTADVTP          GET WTTA DEVICE CODE        000C 35860017
         STC   RTIOT,DCBDEVTP          AND SET IT IN DCB           000C 35864017
         L     RF,DCBCLPS         GET LPS ADDRESS                  000C 35868017
         OC    DCBBQFLG(1),10(RF) SET IN DCB THE WRU BITS IF ANY   000C 35872017
         MVC   22(7,RWTG),TRANSCOD     RESTORE WTG TABLE           000C 35876017
         B     ENDLOD1                                             000C 35880017
         SPACE 2                                                        35900013
*                        1050 2740 CONFIG    DISCRIPTION                36000013
FETAB    DS    0F                                                       36100013
*                                  001111                               36200013
*                                  890123                               36300013
*                                                                       36400013
         DC    X'05'      REG REG  000000    NO SPECIAL FEATURES        36500013
         DC    X'FF'               000001                               36600013
         DC    X'F5'           SC  000010    STATION CONTROL            36700013
         DC    X'FF'               000011                               36800013
         DC    X'67'      AA   AA  000100    AUTO-ANSWER                36900013
         DC    X'ED'          AAX  000101    AA & XCONTROL              37000013
         DC    X'FF'               000110                               37100013
         DC    X'FF'               000111                               37200013
         DC    X'F6'          CK   001000    CHECKING                   37300013
         DC    X'FF'               001001                               37400013
         DC    X'F3'          CKS  001010    CHECKING & SCONTROL        37500013
         DC    X'FF'               001011                               37600013
         DC    X'F0'          CKAA 001100    CHECKING & AA              37700013
         DC    X'EA'          CAAX 001101    CHECKING , AA & XCONTROL   37800013
         DC    X'FF'               001110                               37900013
         DC    X'FF'               001111                               38000013
         DC    X'3F'      AP       010000    AUTO POLL                  38100013
         DC    X'FF'               010001                               38200013
         DC    X'F4'          APS  010010    NCS/AUTOPOLL & STATION CTL 38300013
         DC    X'FF'               010011                               38400013
         DC    X'FF'               010100                               38500013
         DC    X'FF'               010101                               38600013
         DC    X'FF'               010110                               38700013
         DC    X'FF'               010111                               38800013
         DC    X'FF'               011000                               38900013
         DC    X'FF'               011001                               39000013
         DC    X'F2'          APCS 011010    NCS/AP & CHECKING W/SCTL   39100013
         DC    X'FF'               011011                               39200013
         DC    X'FF'               011100                               39300013
         DC    X'FF'               011101                               39400013
         DC    X'FF'               011110                               39500013
         DC    X'FF'               011111                               39600013
         DC    X'88'      AC   AC  100000    AUTO CALL                  39700013
         DC    X'EE'          ACX  100001    AUTO CALL W/ TRANS. CTL    39800013
         DC    X'FF'               100010                               39900013
         DC    X'FF'               100011                               40000013
         DC    X'46'      A    A   100100    AUTO CALL & AUTO ANSWER    40100013
         DC    X'EC'           AX  100101    AC & AA W/ XCONTROL        40200013
         DC    X'FF'               100110                               40300013
         DC    X'FF'               100111                               40400013
         DC    X'F1'          ACCK 101000    AC & CHECKING              40500013
         DC    X'EB'          ACCKX101001    AC & CHECKING W/ XCONTROL  40600013
         DC    X'FF'               101010                               40700013
         DC    X'FF'               101011                               40800013
         DC    X'EF'          CCKAA101100    AC, CHECKING & AA          40900013
         DC    X'E9'          CCKAX101101    AC, AA, CHECKING & XCONTRL 41000013
         DC    X'FF'               101110                               41100013
         DC    X'FF'               101111                               41200013
         DC    X'FF'               110000                               41300013
         DC    X'FF'               110001                               41400013
         DC    X'FF'               110010                               41500013
         DC    X'FF'               110011                               41600013
         DC    X'FF'               110100                               41700013
         DC    X'FF'               110101                               41800013
         DC    X'FF'               110110                               41900013
         DC    X'FF'               110111                               42000013
         DC    X'FF'               111000                               42100013
         DC    X'FF'               111001                               42200013
         DC    X'FF'               111010                               42300013
         DC    X'FF'               111011                               42400013
         DC    X'FF'               111100                               42500013
         DC    X'FF'               111101                               42600013
         DC    X'FF'               111110                               42700013
         DC    X'FF'               111111                               42800013
*                                      A TEST OF IBMTYPE2 DEVICES       42900013
D1030    TM    1(RB),REGMASK                                            43000013
         BZ    IBM2                    REGULAR INDICATES NO OPTL BIT ON 43100013
         AR    RDCB,RD                 POINT TO 1030AP POSITION         43200013
         TM    1(RB),APMASK                                             43300013
         BO    IBM2                                                     43400013
SPFEAERR L     1,ERR4                                                   43500013
         ABEND (1)                                                      43600013
         SPACE 3                                                        43700013
IBM1     LA    RTIOT,CDIBM1(RDCB)                                       43800013
         B     ENDLOD1                                                  43900013
IBM2     LA    RTIOT,CDIBM2(RDCB)                                       44000013
*                                                                       44100013
*      TRANSFER CONTROL TO SECOND LOAD OF OPEN- IGG0193R                44200013
*                                                                       44300013
ENDLOD1  MVC   0(5,RWTGC),BTAMLOD2      SET UP ID FOR LOAD 2 OF BTAM    44400013
BYPASS   L     RJ,4(RWTGC)              LOAD ADDRESS OF WORK AREA.      44500013
         STM   9,15,0(RJ)          SAVE REGESTERS FOR LOAD 2            44600013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURRENT WTG REGISTER. 44700013
         LA    RPARC,PLOFF(0,RPARC)     INCREMENT CURRENT PARAMETER     44800013
*                                  LIST REGISTER TO NEXT ENTRY.         44900013
         CLC   0(2,RWTGC),AMIDCNST      IF THE NEXT WTG ENTRY CALLS FOR 45000013
         BE    RESTART            BRANCH IF THIS EXECUTOR               45100013
         CLC   0(2,RWTGC),OPIDCNST      IF NOT, TEST FOR END OF TABLE.  45200013
         BNE   RELOOP              NOT END OF TABLE, RETURN TO CHECK    45300013
*                                  NEXT ENTRY.                          45400013
         LR    RPARC,RPAR               REINITIALIZE CURRENT WTG REG    45500013
         LA    RWTGC,WAOFF(0,RWTG) AND CURRENT PARAMETER LIST REG.      45600013
ZCHECK   CLI   0(RWTGC),X'00'                                           45700013
         BNE   XCTLRTNE            IF NOT ZERO, GO TO TRANSFER CONTROL. 45800013
         LA    RWTGC,WGOFF(0,RWTGC) IF ZERO, GET NEXT ENTRY AND RETURN  45900013
         LA    RPARC,PLOFF(0,RPARC) TO ZCHECK.                          46000013
         B     ZCHECK                                                   46100013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 46200013
XCTLRTNE EQU   *                                                        46300013
         LA    RJ,DXCCW12(RJ)           POINT TO DOUBLE WORD LIST.      46400013
         MVC   6(2,RWTG),0(RWTGC)       MOVE ID TO NAME FIELD.          46500013
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR TO WTG TABLE.          46600013
         XCTL  DE=(RWTG),SF=(E,(15))                                    46700013
WAOFF    EQU   32                       OFFSET OF FIRST WTG ENTRY FROM  46800013
*                                  START OF WTG.                        46900013
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES.          47000013
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES.          47100013
DEVWTTA  EQU   1                                                   000C 47120017
WTTADVTP EQU   35                                                  000C 47140017
WTATTRIB DC    X'0A680004E00400'                                   000C 47160017
TRANSCOD DC    X'C3780004000400'       TRANSIENT ATTRIBUTES        000C 47180017
OPIDCNST DC    C'0S'                    ID OF LAST OPEN LOAD.           47200013
AMIDCNST DC    C'3N'          ID OF THIS MODULE                         47300013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 47400013
         CNOP  0,4                          FULL WORD BOUNDRY           47500013
DEBPOOL  DC    X'FE000000'             254 SUBPOOL NUMBER               47600013
ERR0     DC    X'80090000'                                              47700013
ERR1     DC    X'80091000'                                              47800013
ERR2     DC    X'80092000'                                              47900013
ERR3     DC    X'80093000'                                              48000013
ERR4     DC    X'80094000'                                              48100013
ERR5     DC    X'800A6000'         DIRECT ACCESS NOT OPEN        A36519 48200020
HWC8     DC    H'8'                                                     48300013
SIXTEEN  DC    H'16'                                                    48400013
SEVNTEEN DC    H'17'                                                    48500013
HWC256   DC    H'256'                                                   48600013
CLEARDEB XC    0(1,RDEB),0(RDEB)            CLEAR FROM START OF DEB     48700013
UCBMOVE  MVC   0(1,RJ),16(RTIOT)            MOVE UCB FROM TIOT TO DEB   48800013
*                                      FOLLOWING TABLE IS USED FOR      48900013
*                                 - VECTOR DIRECTORY WITH LOAD OF       49000013
*                                 VECTOR LIST, AND SIZE DETERMINATION   49100013
*                                 OF IOB.                               49200013
LAST2740 EQU   X'16'              NOTE 1050 AND 2740 CODES (0-16) ARE   49300013
CDIBM1   EQU   LAST2740+1               DEFINED ABOVE IN FETAB          49400013
CDIBM2   EQU   CDIBM1+2                                                 49500013
CDTEL1   EQU   CDIBM2+2                                                 49600013
CDTEL2   EQU   CDTEL1+4                                                 49700013
CDIBM3   EQU   CDTEL2+3                                                 49800013
HOLDMASK DS    0F              BITS   FIELD                             49900013
         DC    BL.4'1111'     00-03   IOSFLAGS                          50000013
         DC    BL.4'1111'     04-07   MODEL CODE                        50100013
         DC    BL.6'111111'   08-13   OPTIONAL FEATURES                 50200013
         DC    BL.2'00'       14-15   SAD COMMAND      (MAY DIFFER)     50300013
         DC    BL.8'11111111' 16-23   DEVICE CLASS     SHOULD = 40      50400013
         DC    BL.4'1111'     24-27   ADAPTER TYPE                      50500013
         DC    BL.4'0000'     28-31   CONTROL UNIT     (MAY DIFFER)     50600013
         SPACE 3                                                        50700013
NENT     EQU   3                       NUMBER OF IDTTR'S           000C 50800017
LENGTH   EQU   NENT*6+6                LENGTH OF IDTTR'S+2+4            50900013
NODBWDS  EQU   (LENGTH+7)/8            NO OF DBL WDS W/ PADDING         51000013
ORGIDTTR EQU   1024-NODBWDS*8          START OF IDTTR LIST              51100013
         SPACE 1                                                        51200013
         ORG   IGG0193N+ORGIDTTR                                        51300013
BTAMLOD2 DC    C'3R'              ID FOR SECOND OPEN LOAD MOD           51400013
         DC    X'00000000'             TTR AND L                        51500013
STRAMID  DC    C'3W'                                                    51600013
         DC    X'00000000'                                              51700013
WTTA     DC    C'QB'                   ID FOR WTTA LINE APPENDAGE  000C 51730017
         DC    X'00000000'             TTR AND L                   000C 51760017
IDEND    DC    X'0000'                  END OF IDTTRL TABLE.            51800013
         SPACE 1                                                        51900013
         CNOP  4,8                     PADDING                          52000013
LOADID   DC    C'019'                  OPEN SVC CODE                    52100013
         DC    YL1(X'80'-NODBWDS)                                       52200013
         DCBD  DSORG=CX,DEVD=WT                                    000C 52300017
        IECTDEBX                                                        52400013
         END                                                            52500013
