         TITLE  'IGG0193O  QTAM OPEN DIRECT-ACCESS MESSAGE QUEUE'       00002021
*********************************************************************** 00004021
*                                                                     * 00006021
* STATUS - CHANGE LEVEL=20    JANUARY 1971                            * 00008021
*                                                                     * 00010021
* FUNCTION - THIS ROUTINE IS ENTERED FOR EITHER OPEN MESSAGE QUEUE    * 00012021
*    DATA SET OR CHECKPOINT DATA SET.  THE SIZE OF THE DEB IS CALCU-  * 00014021
*    LATED BY ADDING THE BASIC SIZE OF A DEB PLUS THE TOTAL NUMBER OF * 00016021
*    EXTENTS FOR THE VOLUMES TIMES 20.  A GETMAIN IS ISSUED FOR THE   * 00018021
*    DEB, AND THE BASIC DEB IS ZEROED.  THE LENGTH OF THE DEB IN      * 00020021
*    DOUBLE WORDS IS STORED IN DEBLNGTH (DEB + 32).  THE DEB IS INIT- * 00022021
*    IALIZED WITH THE TCB ADDRESS IN DEBTCBAD, DCB ADDRESS IN         * 00024021
*    DEBDCBAD, PROTECTION FLAG AND DEB ID IN DEBPROTG, PRIORITY INDI- * 00026021
*    CATOR IN DEBPRIOR, OPEN ATTRIBUTES IN DEBOPATB, NUMBER OF EXTENTS* 00028021
*    IN DEBAMLNG, AND THE DEB IS CHAINED INTO THE TCB.  EACH EXTENT IS* 00030021
*    BUILT CONTAINING THE UCB ADDRESS, FILE MASK, AND CYLINDER START  * 00032021
*    ADDRESS.                                                         * 00034021
*         BY CHECKING IF AN ADDRESS HAS BEEN STORED IN THE CVTTRMTB,  * 00036021
*    IT IS DETERMINED WHETHER A MESSAGE QUEUES DATA SET HAS BEEN      * 00038021
*    OPENED.  IF ONE HAS, AN 0A6 ABEND IS ISSUED SINCE THERE CAN BE   * 00040021
*    ONLY ONE MESSAGE QUEUES DATA SET.                                * 00042021
*         IF NOT CHECKPOINT, THE TERMINAL TABLE ADDRESS IS OBTAINED   * 00044021
*    FROM DCBBUFCB (ASSEMBLED) AND STORED IN THE CVTTRMTB (CVT + 9C). * 00046021
*    THE IMPLEMENTATION MODULE, IGG019NG, IS LOADED VIA THE LOAD MACRO* 00048021
*    USING A CONSTANT THAT CONTAINS THE LENGTH OF THE MODULE.  THIS   * 00050021
*    LENGTH-4 IS DETERMINED BY AN ORG STATEMENT IN IGG019NG.  THE     * 00052021
*    ADDRESS OF IGG019NG IS STORED INTO THE SECOND WORD OF THE TERM-  * 00054021
*    INAL TABLE.                                                      * 00056021
*         THE NUMBER OF BYTES REQUIRED FOR EACH RELATIVE RECORD IS    * 00058021
*    DETERMINED FOR EACH EXTENT FOR THE SPECIFIED DEVICE TYPE.  THE   * 00060021
*    NUMBER OF RECORDS PER EXTENT AND PER TRACK ARE STORED IN THE DEB * 00062021
*    EXTENTS.  THE ID FOR MODULE IGG0193U, THE NEXT LOAD OF MESSAGE   * 00064021
*    QUEUES OPEN, IS STORED IN THE WHERE-TO-GO TABLE.                 * 00066021
*         IF THE DATA SET BEING OPENED IS FOR CHECKPOINT, A TEST IS   * 00068021
*    MADE TO INSURE THAT THE DIRECT ACCESS DATA SET HAS BEEN OPENED.  * 00070021
*    IF A DIRECT ACCESS FOR MESSAGE QUEUES DATA SET HAS NOT BEEN      * 00072021
*    OPENED, AN 0A7 ABEND IS ISSUED.  THE CHECKPOINT/RESTART MODULE,  * 00074021
*    IGG019NH, IS LOADED VIA THE LOAD MACRO USING THE LENGTH SPECIFIED* 00076021
*    IN A CONSTANT.  THE LENGTH OF IGG019NH IS SET BY AN ORG STATEMENT* 00078021
*    IN IGG019NH.  THE DEB APPENDAGE ADDRESSES ARE SET TO IOS APPEN-  * 00080021
*    DAGE EXCEPT FOR DISK END APPENDAGE WHICH CONTAINS AN ADDRESS OF  * 00082021
*    THE APPENDAGE IN MODULE IGG019NH.  THE ADDRESS IN IGG019NH OF THE* 00084021
*    APPENDAGE IS THEN CHANGED TO CONTAIN THE ADDRESS OF THE TERMINAL * 00086021
*    TABLE.  THE ADDRESS OF IGG019NH IS STORED IN THE IMPLEMENTATION  * 00088021
*    MODULE AT LPS + 304.  THE CONSTANT AREA OF THE CHECKPOINT ROUTINE* 00090021
*    IS INITIALIZED WITH THE START ADDRESS OF THE SEEK FIELD, THE     * 00092021
*    TRACK LENGTH, AND THE OVERHEAD VALUE.  THE NUMBER OF TRACKS PER  * 00094021
*    EXTENT IS CALCULATED AND STORED IN THE DEB EXTENT.  THE ADDRESS  * 00096021
*    OF MODULE IGG0193V FOR THE NEXT LOAD FOR CHECKPOINT IS STORED IN * 00098021
*    THE WHERE-TO-GO TABLE.                                           * 00100021
*         IF THIS ROUTINE IS NEEDED FOR ANOTHER DCB, A BRANCH IS TAKEN* 00102021
*    TO THE START OF THIS ROUTINE.  UPON COMPLETION, CONTROL IS PASSED* 00104021
*    TO THE NEXT NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE VIA ZN XCTL. * 00106021
*                                                                     * 00108021
* ENTRY POINTS - ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE BY AN  * 00110021
*         XCTL FROM SYSTEM OPEN.                                      * 00112021
*                                                                     * 00114021
* INPUT-                                                              * 00116021
*    5- ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST          * 00118021
*    6- ADDRESS OF THE BEGINNING OF THE WHERE-TO-GO TABLE             * 00120021
*    7- ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00122021
*    8- ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO    * 00124021
*       TABLE.                                                        * 00126021
*                                                                     * 00128021
* OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES IN* 00130021
*    THE DCB PARAMETER LIST AND THE WHERE-TO-GO TABLE.                * 00132021
*                                                                     * 00134021
* EXTERNAL REFERENCES - NONE                                          * 00136021
*                                                                     * 00138021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA AN XCTL TO THE NEXT NON-ZERO  * 00140021
*    ENTRY IN THE WHERE-TO-GO TABLE.                                  * 00142021
*                                                                     * 00144021
* EXITS, ERROR -  THIS ROUTINE EXITS VIA A 0A6 ABEND IF MORE THAN ONE * 00146021
*         MESSAGE QUEUES DATA SET IS BEING OPENED.  THIS ROUTINE CAN  * 00148021
*         ALSO EXIT VIA A 0A7 ABEND IF THE CHECK POINT DATA SET IS    * 00150021
*         BEING OPENED BEFORE THE MESSAGE QUEUES DATA SET.            * 00152021
*                                                                     * 00154021
* TABLES/WORK AREAS-                                                  * 00156021
*    1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED * 00158021
*    IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO TABLE CONTAINS * 00160021
*    THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE DCB. 3. THE  * 00162021
*    WHERE-TO-GO TABLE POINTS TO A WORK AREA IN WHICH REGISTERS 9-15  * 00164021
*    ARE PASSED TO AND FROM THIS ROUTINE.                             * 00166021
*                                                                     * 00168021
* ATTRIBUTES-  RE-ENTRANT AND PRIVILEGED.                             * 00170021
*                                                                     * 00172021
* CHARACTER CODE DEPENDENCY- NONE                                     * 00174021
*                                                                     * 00176021
* NOTES- NONE                                                         * 00178021
*                                                                     * 00180021
*********************************************************************** 00182021
         TITLE 'IGG01930  QTAM OPEN DIRECT-ACCESS MESSAGE QUEUE'        00200013
IGG0193O START                                                          00400013
*3190352000                                                        00PS 00500015
*1210352000                                                        00PS 00550016
*1210516000                                                        5645 00570016
*2719352000                                                        000C 00580017
*3412352000                                                        00PS 00640017
*0367353000                                                        00PS 00720017
*0367353000                                                        00PS 00750017
* 332200-333400,344000,733000                                    A27847 00770019
* 352000                                                         A31036 00780020
*C352000                                                         A33039 00790020
* 733000                                                         A36519 00795020
*C516000                                                         A39110 00797021
*A000000-004900                                                  S21016 00798021
*C352000                                                         A59550 00799021
*C352000                                                         A65111 00799421
*C516000                                                         A65129 00799821
* REGISTER USAGE                                                        00800013
*                                                                       01000013
RE       EQU   0         WORK REG                                       01200013
RF       EQU   1         WORK REG                                       01400013
RDCB     EQU   2         CURRENT DCB                                    01600013
RBASE    EQU   3         BASE OF THIS ROUTINE                           01800013
RCORE    EQU   4         WORK AREA ADDR                                 02000013
RPAR     EQU   5         PARAMETER LIST ADDR                            02200013
RWTG     EQU   6        FRONT OF WHERE-TO-GO (WTG) TABLE                02400013
RPARC    EQU   7         CURRENT ENTRY IN PARAMETER LIST                02600013
RWTGC    EQU   8         CURRENT ENTRY IN WTG                           02800013
RTIOT    EQU   9         TIOT ADDR                                      03000013
R9       EQU   9         WORK REG                                       03200013
RUCB     EQU   10        CURRENT UCB ADDR                               03400013
RDEB     EQU   11        DEB ADDR                                       03600013
RB       EQU   12        WORK REG                                       03800013
RC       EQU   13        WORK REG                                       04000013
RD       EQU   14        WORK REG                                       04200013
RJ       EQU   15        WORK/PARAMETER REG                             04400013
EXUCB    EQU   0                                                        04600013
DSCC     EQU   2                                                        04800013
F3SKIP   EQU   1                                                        05000013
F1NEX    EQU   3                                                        05200013
UCBLN    EQU   4                                                        05400013
EXBB     EQU   4                                                        05600013
F3FIRST  EQU   4                                                        05800013
EXCC     EQU   6                                                        06000013
DSEXSZ   EQU   10                                                       06200013
F3NEX    EQU   13                                                       06400013
DEBEXSZ  EQU   16                                                       06600013
FM3EXTRA EQU   44                                                       06800013
*                                                                       07000013
         USING IHADCB,RDCB                                              07200013
         USING IECTDEB,RDEB                                             07400013
         USING TCB,RC                                                   07600013
         USING FORCORE,RCORE                                            07800013
CQGP     BALR  RBASE,0                                                  08000013
         USING *,RBASE                                                  08200013
         L     RDCB,0(RPARC)      ADDRESS OF THE DCB                    08400013
         L     RCORE,4(RWTGC)     ADDRESS OF THE OPEN WORK AREA         08600013
*                                                                       08800013
*      COUNT TOTAL NUMBER OF EXTENTS                                    09000013
*                                                                       09200013
         SR    RC,RC                                                    09400013
         SR    RB,RB                                                    09600013
CTLOOP   IC    RB,DSCNOEXT        NUMBER OF EXTENTS ON THIS VOLUME      09800013
         AR    RC,RB              ADD TO PREVIOUS COUNT                 10000013
         L     RCORE,DSCCORE      ADDRESS OF THE NEXT DSCB              10200013
         LTR   RCORE,RCORE        END OF DSCB CHAIN                     10400013
         BZ    ENDDSCBS           BRANCH IF YES                         10600013
FORMTEST CLI   DSCFMTID,C'1'      IS THIS A FORMAT 1 DSCB               10800013
         BE    CTLOOP             BRANCH IF FORMAT 1                    11000013
         L     RCORE,DSCCORE+FM3EXTRA LOAD ADDRESS OF THE NEXT DSCB     11200013
         LTR   RCORE,RCORE        END OF DSCB CHAIN REACHED             11400013
         BNZ   FORMTEST           BRANCH NO TO TEST FORMAT OF THIS DSCB 11600013
ENDDSCBS L     RCORE,4(RWTGC)     RELOAD POINTER TO THE WORK AREA       11800013
*                                                                       12000013
*      COMPUTE SIZE REQUIRED FOR THE DEB                                12200013
*                                                                       12400013
         LR    RJ,RC              COPY COUNT OF EXTENTS                 12600013
         MH    RJ,OPK20           NUMBER OF EXTENTS TIMES 20            12800013
         LA    RE,BASESZ(RJ)      TOTAL SIZE OF THE DEB                 13000013
*                                                                       13200013
*      NOW COMPUTE NUMBER OF DOUBLE WORDS                               13400013
*                                                                       13600013
         SRL   RE,3               DIVIDE BY EIGHT                       13800013
         LR    RB,RE              SAVE DOUBLE WORD COUNT                14000013
*                                                                       14200013
*      GET MAIN FOR THE DEB                                             14400013
*                                                                       14600013
         SLL   RE,3               ACTUAL COUNT OF BYTES FOR GET MAIN    14800013
         O     RE,SUBPOOL         OR IN SUBPOOL ID                      15000013
         GETMAIN R,LV=(0)                                               15200013
         LR    RDEB,RF             SET DEB BASE REG.                    15400013
         XC    0(68,RDEB),0(RDEB) ZERO BASIC PART OF THE DEB            15600013
         LA    RF,DEBNMSUB         ACCESS POINTER TO BASIC DEB.         15800013
         ST    RF,DCBDEBAD         STORE DEB ADDR IN DCB.               16000013
         STC   RB,DEBLNGTH         STORE NUMBER OF DOUBLE WRDS FOR DEB. 16200013
         ST    RB,DEBWKARA        ZERO THE FIRST THREE BYTES            16400013
         MVC   DEBWKARA+3(5),DXCCW7                                     16600013
         STC   RC,DEBNMEXT        COUNT OF EXTENTS TO THE DEB           16800013
*                                                                       17000013
         L     RD,CVTABLE(0,0)     GET ADDRESS OF COMM VECT TABLE       17200013
         L     RC,CVTTCBAD(RD)     LOAD POINTER TO LIST OF TCBS.        17400013
         L     RC,4(RC)            LOAD CURRENT TCB.                    17600013
         LA    RC,0(RC)            CLEAR HIGH ORDER BYTE.               17800013
         ST    RC,DEBTCBAD-1       STORE POINTER TO TCB IN DEB.         18000013
         MVI   DEBNMSUB,X'01'      INDICATE ONE SBRTNE LOADED.          18200013
         ST    RDCB,DEBDCBAD-1     DCB ADDR. PLACED IN DEB.             18400013
         MVC   DEBPROTG(1),TCBPRTK    PROTECTION TAG OF TCB             18600013
         OI    DEBPROTG,OPMDEBID   INSERT DEBID.                        18800013
         MVC   DEBPRIOR(1),TCBPRTY   PRIORITY INDICATOR                 19000013
         MVC   DEBOPATB(1),OPPATRUB(RPARC)  OPEN ATTRIBUTES             19200013
         L     RF,8(RC)            ADDR OF 1ST DEB IN CHAIN.            19400013
         LA    RF,0(RF)            CLEAR HIGH ORDER BYTE.               19600013
         ST    RF,DEBDEBAD-1       STORE IN DEB CHAIN SLOT.             19800013
*                                                                       20000013
         LA    RF,DEBNMSUB                                              20200013
         ST    RF,TCBDEBAD                                              20400013
*                                                                       20600013
         L     RC,TCBTIO           USE TIOT ADDR PLUS                   20800013
         AH    RC,DCBTIOT          DCB TIOT OFFSET                      21000013
*                                                                       21200013
*      PREPARE FOR SCAN OF DSCB'S TO BUILD DEB EXTENTS                  21400013
*                                                                       21600013
         SR    RE,RE                                                    21800013
         SR    RDCB,RDCB                                                22000013
         IC    RDCB,DSCNOEXT      COUNT OF EXTENTS FIRST VOLUME         22200013
         IC    RE,DEBNMEXT        TOTAL NUMBER OF EXTENTS TO BE BUILT   22400013
         LR    RB,RE              COPY NUMBER OF EXTENTS                22600013
         SLL   RB,2               NULTIPLY BY 4 FOR ACCESS METHODE LN.  22800013
         STC   RB,DEBAMLNG        STORE IN THE DEB                      23000013
         LA    RUCB,DEBUCBAD      SET POINTER TO FIRST EXTENT           23200013
         LA    RJ,TIOEFSRT-4(RC)  POINTER TO FIRST UCB ADDRESS IN TIOT  23400013
*                                                                       23600013
*      PREPARE FOR THE NEXT DSCB                                        23800013
*                                                                       24000013
NEXTDSCB LA    RF,DSCEXTYP        SET POINTER TO FIRST DSCB EXTENT      24200013
*                                 FIELD ASSUMING FORMAT 1 DSCB          24400013
         LA    RB,F1NEX           SET TO NUMBER OF EX. FORMAT 1         24600013
         SR    R9,R9              ZERO THE FORMAT 3 INDEX               24800013
         CLI   DSCFMTID,C'1'      TEST FOR FORMAT1 DSCB                 25000013
         BE    FORMAT1            BRANCH IF FORMAT 1                    25200013
         LA    RB,F3NEX           SET INDEX TO FORMAT 3 NUMBER EXTENTS  25400013
         LA    RF,F3FIRST(RCORE)  FIRST DSCB EXTENT (FORMAT 3)          25600013
         LA    R9,FM3EXTRA        SET THE FORMAT 3 INDEX                25800013
         B     CHECKCT                                                  26000013
FORMAT1  LA    RJ,UCBLN(RJ)       INCREMENT UCB POINTER TO NEXT UCB     26200013
         IC    RDCB,DSCNOEXT      NUMBER OF EXTENTS ON THIS VOLUME      26400013
*                                                                       26600013
*      ASSURE RB NOT GREATER THAN REMAINING EXTENTS THIS VOLUME         26800013
*                                                                       27000013
CHECKCT  CR    RB,RDCB                                                  27200013
         BNH   REDUCE             BRANCH RB LESS THAN OR EQUAL          27400013
         LR    RB,RDCB            SET RB TO REMAINING COUNT             27600013
REDUCE   SR    RDCB,RB            REDUCE COUNT OF REMAINING EXTENTS     27800013
*                                                                       28000013
*      BUILD THE NEXT EXTENT ON THE DEB                                 28200013
*                                                                       28400013
MOVEUCB  MVC   EXUCB(4,RUCB),0(RJ) UCB ADDRESS TO THE EXTENT            28600013
         MVI   EXUCB(RUCB),X'C0'  ALLOW ANY WRITE SEEK                  28800013
         XC    EXBB(2,RUCB),EXBB(RUCB) ZERO THE BB BYTES                29000013
         MVC   EXCC(8,RUCB),DSCC(RF) CCHH-CCHH TO THE EXTENT            29200013
         LA    RF,DSEXSZ(RF)      INCREMENT DSCB EXTENT POINTER         29400013
         BCT   RE,MOREEX          BRANCH IF MORE EXTENTS TO BUILD       29600013
         B     EXBUILT            BRANCH ALL EXTENTS ARE BUILT          29800013
MOREEX   LA    RUCB,DEBEXSZ(RUCB) INCREMENT THE DEB EXTENT POINTER      30000013
         BCT   RB,SAMEDSCB        BRANCH IF MORE EXTENTS THIS DSCB      30200013
         B     GETNEXT            BRANCH TO GET NEXT DSCB               30400013
SAMEDSCB CLI   0(RF),C'3'         IS THE NEXT EXTENT THE FIFTH EXTENT   30600013
*                                 OF A FORMAT 3 DSCB                    30800013
         BNE   MOVEUCB            BRANCH IF NOT TO BUILD NEXT EXTENT    31000013
         LA    RF,F3SKIP(RF)      SKIP TO THE NEXT EXTENT               31200013
         B     MOVEUCB                                                  31400013
GETNEXT  L     RCORE,DSCCORE(R9)  ADDRESS OF THE NEXT DSCB              31600013
         B     NEXTDSCB                                                 31800013
EXBUILT  L     RCORE,4(RWTGC)     RESET THE WORK AREA POINTER           32000013
         L     RDCB,0(RPARC)      RESET ADDRESS OF THE DCB              32200013
*                                                                       32400013
*      TEST FOR OPEN OF THE CHECKPOINT DEVICE                           32600013
*                                                                       32800013
         CLC   TIOTDD(8,RC),CKPTDDNM COMPARE CHECK POINT DD NAME        33000013
         BE    OPENCP             BRANCH IF OPEN CHECK POINT            33200013
*                                                                A27847 33220019
         NC    CVTTRMTB(4,RD),CVTTRMTB(RD)  HAS MESSAGE QUEUES   A27847 33240019
*                                 DATA SET BEEN OPENED           A27847 33260019
         BZ    CONTINU            BRANCH IF NO                   A27847 33280019
         L     RF,ERRAB           LOAD ABEND CODE                A27847 33300019
         ABEND (1)                                               A27847 33320019
*                                                                A27847 33340019
*********************************************************************** 33400013
*                                                                     * 33600013
*      START OF CODE FOR THE DASD DATASET ONLY                        * 33800013
*                                                                     * 34000013
*********************************************************************** 34200013
CONTINU  L     RC,DCBBUFCB        GET TERMTBL ADDR FROM DCB      A27847 34400019
         ST    RC,CVTTRMTB(0,RD)   STORE TERMTBL ADDR IN CVT            34600013
         LA    R9,DK01            ADDRESS OF ID FOR MODULE IGG019NG     34800013
         BAL   RB,LOADSUB         GO LOAD MODULE IGG019NG               35000013
         DC    X'0A68001E180400'                                 A65111 35200021
         AL    RE,TTQUES(RC)      TERM NAME LENGTH TO HIGH ORDER BYTE   35400013
         ST    RE,TTQUES(RC)      STORE NG ADDRESS AND TERM NAME LNG.   35600013
         SPACE 2                                                        35800013
*                                                                       36000013
*  RELATIVE RECORD ADDRESSING, ADD RELATIVE EXTENTS TO END OF THE DEB.  36200013
*                                                                       36400013
*  DETERMINE THE TRUE LENGTH (BYTES) REQUIRED FOR INTERMEDIATE AND      36600013
*  LAST RECORD ON A TRACK FOR THIS DEVICE.                              36800013
*                                                                       37000013
         SR    RE,RE                                                    37200013
         IC    RE,DEBNMEXT                                              37400013
*                                                                       37600013
         STM   5,10,DXCCW1             SAVE REGS IN DCB WORK AREA       37800013
         LA    RD,16(RUCB)        POSITION RD TO FIRST RELATIVE EXTENT  38000013
         L     5,CVTABLE(0,0)          FIND DIRECT ACCESS DEVICE TABLE  38200013
         L     5,CVTDADT(0,5)          REG.5 POINTS TO DADT             38400013
OLOOP    L     R9,DEBUCBAD        ADDRESS OF THE UCB FOR THIS EXTENT    38600013
NEWEXT   L     7,DEBUCBAD     LOCAT DEVICE TYPE TO MATCH UCB            38800013
         IC    RJ,UCBTYPCD(0,7) IN THE TABLE BY USING TYPE CODE         39000013
         N     RJ,FULLWDF       AS AN OFFSET TO AN OFFSET BYTE          39200013
         IC    RJ,0(RJ,5)       IN THE FRONT OF THE TABLE.              39400013
         LA    6,0(RJ,5)        REG 6 POINT TO THE TABLE ENTRY          39600013
*                                                                       39800013
         SR    RB,RB                                                    40000013
         IC    RB,OVERK(0,6)                                            40200013
         IC    RJ,OVERL(0,6)                                            40400013
         SR    RJ,RB                                                    40600013
         LH    10,DCBBUFL                                               40800013
         AR    RJ,10         RJ HAS SIZE OF LAST RECORD                 41000013
         MH    10,TOLER(0,6) CALC 1.049(KEY LENGTH + DATA LENGTH)       41200013
         SRL   10,9                                                     41400013
         SR    R9,R9         DEVELOPE OVERHEAD FOR                      41600013
         IC    R9,OVERI(0,6)   INTERMEDIATE RECORDS                     41800013
         SR    R9,RB                                                    42000013
         AR    10,R9        R 10 HAS TRUE SIZE OF INTERM RECORDS        42200013
*                                                                       42400013
* DETERMINE NO. OF RECORDS THAT WILL FIT ON EACH TRACK                  42600013
*                                                                       42800013
RECTRK   SR    8,8           CLEAR REGS                                 43000013
         LH    RB,TRKL(0,6)   LOAD TRACK LENGTH IN BYTES                43200013
         SR    RB,RJ                   SUBTRACT SIZE OF LAST RECORD     43400013
TRYINT   LA    8,1(0,8)      UP RECORD COUNT BY ONE                     43600013
         SR    RB,10         SUBTRACT LENGTH OF AN INTER. RECORD        43800013
         BC    10,TRYINT      AND REPEAT THE LOOP IF NOT NEGATIVE       44000013
         LA    RJ,DUMEXIT         SET DUMMY RETURN ADDRESS              44200013
*                                                                       44400013
*      THIS CODE IS USED AS A SUB ROUTINE BY THE OPEN CHECK POINT       44600013
*      PORTION OF THIS MODULE                                           44800013
*                                                                       45000013
NMTRKS   LH    R9,DEBUCBAD+10     ENDING CC                             45200013
         SH    R9,DEBUCBAD+6       MINUS STARTING CC                    45400013
         MH    R9,2(0,6)           TIMES NO. TRACKS PER CYLINDER        45600013
         AH    R9,DEBUCBAD+12      PLUS ENDING TT                       45800013
         SH    R9,DEBUCBAD+8       MINUS STARTING TT                    46000013
         LA    R9,1(0,R9)          PLUS 1                               46200013
         STH   R9,DEBUCBAD+14      EQUALS TRACKS PER EXTENT             46400013
         BR    RJ                 RETURN TO CHECK POINT PORTION OR      46600013
*                                 BRANCH TO THE NEXT INSTRUCTION        46800013
DUMEXIT  LR    9,8                MULTIPLY RECORDS PER TRACK            47000013
         MH    R9,DEBUCBAD+14      BY TRACKS PER EXTENT.                47200013
         ST    9,0(0,RD)     STORE RECORDS PER EXTENT                   47400013
         STC   8,0(0,RD)     STORE RECORDS PER TRACK                    47600013
         LA    RD,4(0,RD)    INCREMENT BOTH                             47800013
         LA    RDEB,16(0,RDEB)  EXTENT POINTERS                         48000013
         BCT   RE,OLOOP                                                 48200013
*                                                                       48400013
RSTOR    LM    5,10,DXCCW1         RESTORE REGS                         48600013
STDCBREL MVC   0(2,RD),DK01        STORE SUBROUTINE ID                  48800013
         MVC   0(5,RWTGC),DALOAD2 ID AND TTR TO THE WHERE TO GO TABLE   49000013
         B     ENDLOAD                                                  49200013
*********************************************************************** 49400013
*                                                                     * 49600013
*      START OF CODE FOR THE CHECK POINT DATASET ONLY                 * 49800013
*                                                                     * 50000013
*********************************************************************** 50200013
OPENCP   NC    CVTTRMTB(4,RD),CVTTRMTB(RD) HAS DA DATA SET BEEN OPENED  50400013
         BNZ   DAOPEN             BRANCH IF YES                         50600013
         L     RF,ABCODE          LOAD ABEND CODE                       50800013
         ABEND (1)                                                      51000013
DAOPEN   LA    R9,IDNH            ADDRESS OF ID FOR MODULE IGG019NH     51200013
         BAL   RB,LOADSUB         GO LOAD MODULE IGG019NH               51400013
         DC    X'CA680004900400'                                 A65129 51600021
*                                                                       51800013
*      STORE ADDRESS OF IGG019NH IN THE IMPLEMENTATION MODULE AND THE   52000013
*      TERMINAL TABLE ADDRESS IN IGG019NH                               52200013
*                                                                       52400013
         L     R9,IOSAPPAD-1(RD)  POINTER TO IOS APPENDAGE VECTOR       52600013
         MVC   DEBEOEA(20),0(R9)  APPENDAGE ADDRESS TO THE DEB          52800013
         ST    RDEB,DEBAPPAD-1    SET DEB APPENDAGE VECTOR POINTER      53000013
         LR    RC,RE              SAVE ADDRESS OF THE CHECK POINT LOAD  53200013
         MVC   DEBCEA(4),TERMTBL(RC) SET TO USE CHANNEL END IN IGG019NH 53400013
         L     R9,CVTTRMTB(RD)    ADDRESS OF THE TERM TABLE             53600013
         ST    R9,TERMTBL(RC)     TERM TABLE ADDRESS TO IGG019NH        53800013
         L     R9,TTQUES(R9)      ADDRESS OF IGG019NG                   54000013
         L     R9,0(R9)           ADDRESS OF THE LPS QUEUE              54200013
         ST    RC,CPAD(R9)        STORE ADDRESS OF IGG019NH             54400013
         MVC   SEEKAD+3(4,RC),DEBUCBAD+4 START ADDR. TO THE SEEK FIELD  54600013
         MVC   DISKDCB+1(3,RC),DEBDCBAD DCB ADDRESS TO THE IOB          54800013
*                                                                       55000013
*      LOAD ADDRESS OF THE ENTRY IN THE DIRECT ACCESS DEVICE TABLE FOR  55200013
*      THIS DEVICE                                                      55400013
*                                                                       55600013
         L     RJ,CVTDADT(RD)     ADDRESS OF THE DADT                   55800013
         L     R9,DEBUCBAD        ADDRESS OF THE UCB                    56000013
         IC    RB,UCBTYPCD(R9)    LOAD DEVICE TYPE BYTE                 56200013
         N     RB,FULLWDF         CLEAR UNUSED BITS                     56400013
         IC    RB,0(RB,RJ)        INDEX BYTE INTO THE DADT              56600013
         LR    RF,6               SAVE CONTENTS OF REGISTER 6           56800013
         LA    6,0(RB,RJ)         ADDRESS OF THE CORRECT ENTRY FOR      57000013
*                                 THIS DEVICE                           57200013
*                                                                       57400013
*      STORE TRACK LENGTH AND OVERHEAD VALUE IN MODULE IGG019NH         57600013
*                                                                       57800013
         MVC   TRKLN(2,RC),TRKL(6) TRACK LENGTH TO IGG019NH             58000013
         MVC   OVERHD+1(1,RC),OVERI(6) OVERHEAD VALUE TO IGG019NH       58200013
*                                                                       58400013
*      EXECUTE SUB ROUTINE TO STORE NUMBER OF TRACKS IN THE DEB         58600013
*                                                                       58800013
         BAL   RJ,NMTRKS          GO STORE TRACKS FOR THIS EXTENT       59000013
         LR    6,RF               RESTORE CONTENTS OF REGISTER 6        59200013
*                                                                       59400013
*      SUB ROUTINE ID AND EXTENT SCALE TO THE DEB                       59600013
*                                                                       59800013
         SR    R9,R9                                                    60000013
         IC    R9,DEBNMEXT        NUMBER OF EXTENTS                     60200013
         MH    R9,OPK20           TIMES 20                              60400013
         LA    R9,DEBUCBAD(R9)    SUB ROUTINE ID SECTION                60600013
         MVC   0(2,R9),IDNH       SUBROUTINE ID TO THE DEB              60800013
         MVI   DEBEXSCL,4         SET THE EXTENT SCALE                  61000013
*                                                                       61200013
*      PRESET REGISTERS FOR NEXT LOAD (IGG0193V)                        61400013
*                                                                       61600013
         L     RD,CVTTRMTB(RD)    ADDRESS OF THE TERMINAL TABLE         61800013
         L     RE,0(RD)           REGISTER  0    LAST TERM ENTRY ADDR.  62000013
         LA    RF,QLEN            REGISTER  1                           62200013
         SR    R9,R9              REGISTER  9                           62400013
         SR    RUCB,RUCB          REGISTER 10                           62600013
         SR    RB,RB              REGISTER 12                           62800013
         LA    RJ,LCBLEN          REGISTER 15                           63000013
*                                                                       63200013
*      SAVE REGISTERS FOR LOAD2 (MODULE IGG0193V) AND EXIT              63400013
*                                                                       63600013
         MVC   0(5,RWTGC),CPLOAD2 ID AND TTR TO THE WHERE TO GO TABLE   63800013
         STM   9,1,0(RCORE)       STORE REGISTERS FOR THE NEXT LOAD     64000013
*********************************************************************** 64200013
*                                                                       64400013
*          THIS IS AN OPEN PROVIDED SECTION OF CODE THAT SETS UP XCTL   64600013
*                                                                       64800013
*********************************************************************   65000013
*                                                                       65200013
ENDLOAD  MVC   22(7,RWTG),CONTAB2                                       65400013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURR WTG ENTRY        65600013
         LA    RPARC,PLOFF(0,RPARC)     INCR CURR ENTRY IN PARAM LIST   65800013
         CLC   0(2,RWTGC),AMIDCNST      SAME MODULE REQUIRED            66000013
         BCR   8,RBASE            BACK TO START OF THIS MODULE          66200013
         CLC   0(2,RWTGC),OPIDCNST      END OF WTG TABLE                66400013
         BC    7,RELOOP                 NO CHECK NEXT ENTRY             66600013
*                                                                       66800013
         LR    RPARC,RPAR                                               67000013
         LA    RWTGC,WAOFF(0,RWTG)      REINITIALIZE WTG LIST PTR       67200013
ZCHEK    CLI   0(RWTGC),0               IS THIS ENTRY ZERO              67400013
         BC    7,TCTLRTN                IF NOT TRANSFER CONTROL         67600013
*                                                                       67800013
         LA    RWTGC,WGOFF(0,RWTGC)     GET NEXT ENTRY                  68000013
         LA    RPARC,PLOFF(0,RPARC)                                     68200013
         BC    15,ZCHEK                                                 68400013
*                                                                       68600013
*  CONTRO IS TRANSFERRED TO THE NEXT EXECUTOR OF THE FIRST              68800013
*  DCB WHICH IS NOT COMPLETED.                                          69000013
*                                                                       69200013
TCTLRTN  EQU   *                                                        69400013
         LA    RJ,DXCCW12                                               69600013
         MVC   6(2,RWTG),0(RWTGC)  MOVE EXECUTOR ID TO PARAMETER LIST   69800013
         MVC   14(3,RWTG),2(RWTGC) MOVE TTR TO WTG TABLE                70000013
         XCTL  DE=(RWTG),SF=(E,(15))                                    70200013
WAOFF    EQU   32                                                       70400013
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES           70600013
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES           70800013
OPIDCNST DC    C'0S'                                                    71000013
AMIDCNST DC    C'3O'                                                    71200013
LOADSUB  MVC   6(2,RWTG),0(R9)    LOAD MODULE ID TO THE WORKAREA        71400013
         MVC   14(3,RWTG),2(R9)   TTR TO THE WORK AREA                  71600013
         MVC   22(7,RWTG),0(RB)   MOVE CORRECT CONTAB TO WORKAREA       71800013
         LR    RE,RWTG             GET ADDRESS OF NAME IN REG 0         72000013
         L     RF,84(RD)          LOAD ADDRESS OF SVCLIB DCB            72200013
         LOAD  DE=(0),DCB=(1)      LOAD DK01                            72400013
         B     8(RB)              RETURN TO THE CALLER                  72600013
         DS    0F                                                       72800013
CKPTDDNM DC    C'TPCHKPNT'                                              73000013
ABCODE   DC    X'800A7000'                                              73200013
ERRAB    DC    X'800A6000'         DIRECT ACCESS NOT OPEN        A36519 73300020
SUBPOOL  DC    X'FE000000'                                              73400013
FULLWDF  DC    F'15'                                                    73600013
OPK20    DC    H'20'                                                    73800013
CONTAB2  DC    X'C3780004000400'                                        74000013
NENT     EQU   4                                                        74200013
LEN      EQU   NENT*6+6           LENGTH OF ID'S AND TTRS               74400013
WDS      EQU   (LEN+7)/8          NUMBER OF DOUBLE WORDS WITH PADDING   74600013
ORG      EQU   1024-WDS*8         START OF TTR LIST                     74800013
         ORG   IGG0193O+ORG                                             75000013
DALOAD2  DC    C'3U'                                                    75200013
         DC    XL4'0000'                                                75400013
CPLOAD2  DC    C'3V'                                                    75600013
         DC    XL4'0000'                                                75800013
IDNH     DC    C'NH'                                                    76000013
         DC    XL4'0000'                                                76200013
DK01     DC    C'NG'                                                    76400013
TTRL     DC    XL4'0000'                                                76600013
XCTLEND  DC    XL2'0'                                                   76800013
         CNOP  4,8                                                      77000013
LOADID   DC    C'019'                                                   77200013
         DC    YL1(X'80'-WDS)                                           77400013
*                                                                       77600013
* DIRECT ACCESS DEVICE TABLE DEFINITION                                 77800013
TRKL     EQU   4             TRACK LENGTH                               78000013
OVERI    EQU   6             OVERHEAD-INTERMEDIATE RECORDS              78200013
OVERL    EQU   7                     -LAST RECORD ON A TRACK            78400013
OVERK    EQU   8                     -TO BE SUB TRACTED IF NO KEYS      78600013
TOLER    EQU   10            TOLERANCE FACTOR                           78800013
*                                                                       79000013
CVTABLE  EQU   16            POINTER  TO COMM VECTOR TABLE              79200013
CVTTCBAD EQU   0             OFFSET TO TCB ADDR                         79400013
CVTDADT  EQU   64                      DIRECT ACCESS DEVICE TABLE ADDR  79600013
CVTTRMTB EQU   156                                                      79800013
*                                                                       80000013
TTQUES   EQU   4                                                        80200013
DISKIOB  EQU   92                                                       80400013
CCWAD    EQU   40                                                       80600013
APVECT   EQU   24                                                       80800013
NASEG    EQU   196                 ADDR OF RELATIVE RECORD NUMBER       81000013
TTBAS    EQU   249                                                      81200013
IECKMQ   EQU   3178                                                     81400013
*                                                                       81600013
OPMEXSCL EQU   4              DEB EXTENT SIZE SCALE                     81800013
OPPATRUB EQU   0              OFFSET TO ATTRIBUTE BYTE                  82000013
OPMDEBID EQU   X'0F'          IDENTIFIER FOR A DEB                      82200013
*                                                                       82400013
LCBLEN   EQU   11                                                       82600013
QLEN     EQU   11                                                       82800013
TRKLN    EQU   38                                                       83000013
OVERHD   EQU   36                                                       83200013
SEEKAD   EQU   80                                                       83400013
TERMTBL  EQU   116                                                      83600013
TIOTDD   EQU   4                                                        83800013
IOBDCBPR EQU   20                                                       84000013
DISKDCB  EQU   68                                                       84200013
CPAD     EQU   304                                                      84400013
IOSAPPAD EQU   21                                                       84600013
BASESZ   EQU   77                                                       84800013
*                                                                       85000013
*                                                                       85200013
********* CONTROL BLOCK DEFINITIONS *********************************** 85400013
*                                                                       85600013
UCBTYPCD EQU   19                                                       85800013
*                                                                       86000013
TIOEFSRT EQU   16                                                       86200013
*                                                                       86400013
         EJECT                                                          86600013
         IECTDEBX                                                       86800013
         EJECT                                                          87000013
*                                                                       87200013
*                                                                       87400013
TCB      DSECT                                                          87600013
TCBPRB   DS    F                                                        87800013
TCBPIE   DS    F                                                        88000013
TCBDEBAD DS    F                                                        88200013
TCBTIO   DS    F                                                        88400013
TCBCOMM  DS    F                                                        88600013
TCBTTRN  DS    F                                                        88800013
TCBMSS   DS    F                                                        89000013
TCBPRTK  DC    X'00'                                                    89200013
TCBFLAG  DC    AL3(0)                                                   89400013
TCBLODPT DS    F                                                        89600013
TCBJLB   DS    F                                                        89800013
TCBINACT DS    F                                                        90000013
TCBSIZE  DS    H                                                        90200013
TCBPRTY  DS    H                                                        90400013
TCBTIME  DS    F                                                        90600013
*                                                                       90800013
         EJECT                                                          91000013
         DCBD  DSORG=(CQ,DA)                                            91200013
         EJECT                                                          91400013
*           DEFINITION OF CORE WORK AREA FOR THE DCB                    91600013
FORCORE  DSECT                                                          91800013
         IECDSECT                                                       92000013
         END                                                            92200013
