         TITLE 'IGG0193P  QTAM OPEN MESSAGE-PROCESS QUEUE'              00200013
IGG0193P START                                                          00400013
*********************************************************************** 00400921
*                                                                     * 00401821
* STATUS       CHANGE LEVEL= 18  JANUARY 1971                         * 00402721
*                                                                     * 00403621
* FUNCTION - THIS ROUTINE IS ENTERED FOR A QTAM MESSAGE PROCESSING DCB* 00404521
*    (DSORG=MQ).  IF THE TRMAD PARAMETER HAS NOT BEEN SPECIFIED, AN   * 00405421
*    0A0 ABEND IS ISSUED.  IF THE MESSAGE QUEUES DATA SET HAS NOT BEEN* 00406321
*    OPENED, AN 0A6 ABEND IS ISSUED.                                  * 00407221
*         IF THE DCB IS FOR A GET (DCBMACR=X'40'), THE DCBBUFRQ FIELD * 00408121
*    IS CHECKED FOR ZEROS.  IF ZERO HAS BEEN SPECIFIED, THE VALUE IS  * 00409021
*    SET TO 1.  IF DCBSOWA HAS NOT BEEN SPECIFIED, AN 0A1 ABEND IS    * 00409921
*    ISSUED.  THE DDNAME FOUND IN THE TIOT IS COMPARED TO THE TERMINAL* 00410821
*    ID'S IN THE TERMINAL TABLE.  IF THE DDNAME IS NOT FOUND AS AN    * 00411721
*    ENTRY IN THE TERMINAL TABLE, AN 0A2 ABEND IS ISSUED.  IF THE QCB * 00412621
*    FOR THIS DCB INDICATES THAT THIS DCB HAS ALREADY BEEN OPENED     * 00413521
*    (QCB + 4 = X'01'), AN 0A5 ABEND IS ISSUED.                       * 00414421
*         A GETMAIN IS ISSUED FROM SUBPOOL 254 FOR 144 BYTES FOR A    * 00415321
*    PROCESSING PROGRAM DEB.  THE CORE FOR THE DEB IS ZEROED AND THEN * 00416221
*    INITIALIZED WITH THE LENGTH IN DOUBLE WORDS IN DEBLNGTH, THE     * 00417121
*    'CCHHR' IN DEBDSCB + 2, DCB ADDRESS IN DEBDCBAD, TCB ADDRESS IN  * 00418021
*    DEBTCBAD, PROTECTION KEY AND DEBID IN DEBPROTG, PREVIOUS DEB     * 00418921
*    ADDRESS IN DEBDEBAD AND DEB ADDRESS IN THE TCB + 8 FOR CHAINING. * 00419821
*    THE DEB IS CHAINED INTO THE CHAIN OF QTAM DEB'S IN FIXED AREA OF * 00420721
*    IGG019NG.                                                        * 00421621
*         IF THE DCB IS FOR PUT (DCBMACR + 1 = X'40'), THE ADDRESS OF * 00422521
*    THE QPRIRTY QUEUE IS STORED IN THE STCB CHAIN POINTER OF THE QCB * 00423421
*    IN THE DEB.  THE LCBSTATE FIELD OF THE LCB IN THE DEB IS SET TO  * 00424321
*    X'18'.                                                           * 00425221
*         IF THE DCB IS FOR A GET (DCBMACR = X'40'), THE ASSOCIATED   * 00426121
*    DASD QCB IS FLAGGED AS BEING OPENED (QCB + 4 = X'01'). IN THE DEB* 00427021
*    THE FOLLOWING INFORMATION IS SAVED: QCB ADDRESS IN DEB + 8,      * 00427921
*    MESSAGE ADDRESS IN DEB + 17 AND DEB + 66.  THE ADDRESS OF THE BRB* 00428821
*    IN THE DEB IS PLACED IN DCBSEGAD FIELD OF THE DCB.  THE DEB IS   * 00429721
*    INITIALIZED WITH THE FOLLOWING: SIZE OF WORKAREA (DCBSOWA) TO    * 00430621
*    DEB + 64, DUMMY LAST ENTRY (IECKSTOP) TO DEB + 36 (QCB), ADDRESS * 00431521
*    OF LCB (DEB + 32) TO DEB + 60 (BRB), PRIORITY OF X'E0' PUT IN    * 00432421
*    BRB AT DEB + 52, DUMMY BUFFER IS INDICATED (X'07') AT DEB + 60,  * 00433321
*    ADDRESS OF DASD QCB IN BRB AT DEB + 56, TIC COMMAND X'08' IN BRB * 00434221
*    AT DEB + 56, ADDRESS OF QPRIORITY SUBTASK (QPRIRTY) IN QCB AT    * 00435121
*    DEB + 44, ADDRESS OF BRB (DEB + 48) IN DEB + 28, AND PRIORITY    * 00436021
*    (X'FE') IN BRB AT DEB + 52.  THE DASD QCB IN INITIALIZED WITH THE* 00436921
*    ADDRESS OF THE LCB AT DEB + 32 IN QCB + 12 AND THE ADDRESS OF THE* 00437821
*    GET SCHEDULER IN QCB + 8.                                        * 00438721
*         THE ADDRESS OF THE GET OR PUT MODULE IS OBTAINED ACCORDING  * 00439621
*    TO THE MODE (MESSAGE, RECORD, OR SEGMENT), AND THE GET OR PUT    * 00440521
*    MODULE IS LOADED VIA THE LOAD MACRO.  THE ADDRESS OF THE ROUTINE * 00441421
*    IS STORED IN DCBGET OR DCBPUT.  THE DEB IS SET TO INDICATE NON-  * 00442321
*    DIRECT ACCESS (2) IS DEBEXSCL, NUMBER OF SUBROUTINES LOADED (1)  * 00443221
*    IN DEBNMSUB, NO EXTENTS IS DEBNMEXT, LENGTH (92) IN BASIC PORTION* 00444121
*    IN DEBAMLNG, AND MODULE ID IN DEB + 124.                         * 00445021
*         IF THE OPEN MODULE IS NEEDED FOR ANOTHER DCB, A BRANCH IS   * 00445921
*    TAKEN TO THE BEGINNING OF THE ROUTINE.  OTHERWISE, THE ROUTINE   * 00446821
*    EXITS TO THE NEXT WHERE-TO-GO ENTRY.                             * 00447721
*                                                                     * 00448621
* ENTRY POINT - ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE FROM    * 00449521
*         SYSTEM OPEN.  IT MAY ALSO BE RE-ENTERED IF THE ROUTINE      * 00450421
*         DETERMINES THAT THERE IS ANOTHER DCB TO BE OPENED.          * 00451321
*                                                                     * 00452221
* INPUT-                                                              * 00453121
*    5- ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST          * 00454021
*    6- ADDRESS OF THE BEGINNING OF THE WHERE-TO-GO TABLE             * 00454921
*    7- ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00455821
*    8- ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO    * 00456721
*       TABLE.                                                        * 00457621
*                                                                     * 00458521
* OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES IN* 00459421
*    THE DCB PARAMETER LIST AND THE WHERE-TO-GO TABLE.                * 00460321
*                                                                     * 00461221
* EXTERNAL REFERENCES- NONE                                           * 00462121
*                                                                     * 00463021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA AN XCTL TO THE NEXT NON-ZERO  * 00463921
*    ENTRY IN THE WHERE-TO-GO TABLE.                                  * 00464821
*                                                                     * 00465721
* TABLES/WORK AREAS-                                                  * 00466621
*    1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED * 00467521
*    IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO TABLE CONTAINS * 00468421
*    THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE DCB. 3. THE  * 00469321
*    WHERE-TO-GO TABLE POINTS TO A WORK AREA IN WHICH REGISTERS 9-15  * 00470221
*    ARE PASSED TO AND FROM THIS ROUTINE.                             * 00471121
*                                                                     * 00472021
* EXITS, ERROR - THIS ROUTINE EXITS VIA AN ABEND FOR THE FOLLOWING    * 00472921
*         ERROR CONDITIONS:                                           * 00473821
*         800A0000 - THE TRMAD FIELD HAS NOT BEEN SPECIFIED FOR       * 00474721
*         PROCESS DCB.                                                * 00475621
*         800A1000 - THE SOWA FIELD HAS NOT BEEN SPECIFIED FOR        * 00476521
*         PROCESS DCB FOR GET.                                        * 00477421
*         800A2000 - THE DD NAME SPECIFIED IN THE NAME FIELD OF THE   * 00478321
*         DD STATEMENT IS NOT THE NAME OF A PROCESS ENTRY IN THE      * 00479221
*         TERMINAL TABLE.                                             * 00480121
*         800A5000 - AN OPEN WAS ISSUED FOR A DCB THAT HAD PREVIOUSLY * 00481021
*         BEEN OPENED.                                                * 00481921
*         800A6000 - THE MESSAGE QUEUES DATA SET HAS NOT BEEN OPENED  * 00482821
*         BEFORE PROCESS DCB IS TO BE OPENED.                         * 00483721
*                                                                     * 00484621
* ATTRIBUTES-  RE-ENTRANT AND PRIVILEGED.                             * 00485521
*                                                                     * 00486421
* CHARACTER CODE DEPENDENCY- NONE                                     * 00487321
*                                                                     * 00488221
* NOTES- NONE                                                         * 00489121
*                                                                     * 00490021
*********************************************************************** 00490921
*1202146400-147600                                                22752 00500018
*A004009-004909                                                  S21016 00550021
         USING IHADCB,RDCB                                              00600013
         USING FORCORE,RCORE                                            00800013
         USING IECKTERM,RC                                              01000013
         USING TCB,RTIOT                                                01200013
         USING IECTDEB+20,RDEB                                          01400013
*                                                                       01600013
* MASKS TO TEST PARAMETER LIST                                          01800013
INP      EQU   X'7F'                                                    02000013
OUTP     EQU   X'8F'                                                    02200013
DISP     EQU   X'0'                                                     02400013
*                                                                       02600013
*                                                                       02800013
MESSM    EQU   X'04'                                                    03000013
RECRDM   EQU   X'02'                                                    03200013
SEGM     EQU   X'08'                                                    03400013
*                                                                       03600013
RE       EQU   0                                                        03800013
RF       EQU   1                                                        04000013
RDCB     EQU   2                                                        04200013
RBASE    EQU   3                                                        04400013
RCORE    EQU   4                                                        04600013
RPAR     EQU   5                                                        04800013
RWTG     EQU   6                                                        05000013
RPARC    EQU   7                                                        05200013
RWTGC    EQU   8                                                        05400013
RC       EQU    9                                                       05600013
RUCB     EQU   10                                                       05800013
RDEB     EQU   11                                                       06000013
RB       EQU   12                                                       06200013
RTIOT    EQU   13                                                       06400013
RD       EQU   14                                                       06600013
RJ       EQU   15                                                       06800013
*                                                                       07000013
         BALR  RBASE,0                                                  07200013
         USING *,RBASE                                                  07400013
         SR    RF,RF               CLEAR RF                             07600013
         L     RDCB,0(0,RPARC)     LOAD CURRENT DCB ADDR                07800013
         NC    DCBTRMAD+1(3),DCBTRMAD+1  TERMTBL ENTRY SPECIFIED        08000013
         BNZ   TRMADOK                 BRANCH IF TRMAD SUPPLIED         08200013
*                                                                       08400013
*      SYSTEM ABEND                                                     08600013
*                                                                       08800013
         L     RF,ERR0                 ABEND CODE FOR NO TRMAD SPEC.    09000013
         ABEND (1)                                                      09200013
*                                                                       09400013
*                                                                       09600013
*                                                                       09800013
* GET TERMINAL NAME FROM TCB                                            10000013
*                                                                       10200013
TRMADOK  L     RD,CVTABLE              LOAD CVT ADDRESS                 10400013
         L     RC,CVTTRMTB(RD)     GET ADDR OF TERMTBL                  10600013
         LTR   RC,RC               HAS DIRECT ACCESS DEVICE BEEN OPENED 10800013
*  OPEN TELECOMMUNICATIONS DIRECT ACCESS DEVICE LOADS CVT WITH          11000013
*                  ADDRESS OF TERMTBL                                   11200013
         BC    7,DK01OK            YES CONTINUE                         11400013
*                                                                       11600013
*      SYSTEM ABEND                                                     11800013
*                                                                       12000013
         L     RF,ERR6                 ABEND CODE FOR DA NOT OPEN       12200013
         ABEND (1)                                                      12400013
*                                                                       12600013
*                                                                       12800013
*                                                                       13000013
DK01OK   EQU   *                                                        13200013
         L     RTIOT,CVTTCBAD(RD)  ACCESS POINTER TO TCB TABLE.         13400013
         L     RTIOT,CURNTTCB(RTIOT) POINT TO CURRENT TCB               13600013
         LR    RDEB,RTIOT          SAVE POINTER TO TCB                  13800013
         L     RTIOT,12(RTIOT)     GET ADDR OF TIOT FROM TCB.           14000013
         AH    RTIOT,DCBTIOT       DCB TIOT OFFSET.                     14200013
         TM    DCBMACR,X'40'                                            14400013
         BZ    FOUND               IF ZERO PUT IS SPECIFIED.            14600013
         CLI   DCBBUFRQ,X'00'      WAS BUFFER REQUEST SPECIFIED   22752 14640018
         BNE   OK                  IF YES CONTINUE                22752 14680018
         MVI   DCBBUFRQ,X'01'      SET TO ONE IF NOT SPECIFIED    22752 14720018
OK       EQU   *                                                  22752 14760018
         LH    RF,DCBSOWA                                               14800013
         LTR   RF,RF                                                    15000013
         BNZ   SOWAOK                  BRANCH SOWA SUPPLIED             15200013
*                                                                       15400013
*      SYSTEM ABEND                                                     15600013
*                                                                       15800013
         L     RF,ERR1                 ABEND CODE SOWA NOT SUPPLIED     16000013
         ABEND (1)                                                      16200013
*                                                                       16400013
*                                                                       16600013
*                                                                       16800013
SOWAOK   L     RF,0(RC)                LAST TERM ENTRY ADDRESS          17000013
         SR    RUCB,RUCB                                                17200013
         IC    RUCB,4(RC)          GET LNTH OF TERMID FIELD FOR COMP    17400013
         BCTR  RUCB,0              DECREMENT.                           17600013
         LA    RC,8(RC)            GET ADDRESS OF FIRST ENTRY           17800013
         SR    RCORE,RCORE                                              18000013
LOOKUP   EX    RUCB,COMPID                                              18200013
         BE    TESTOPEN           BRANCH IF FOUND                       18400013
* TEST FOR END OF TERMINAL TABLE ADDR                                   18600013
         CR    RC,RF               COMP ENTRY ADDR TO END OF TABLE ADDR 18800013
         BC    4,NOTEND                BRANCH NOT END OF TERM TABLE     19000013
*                                                                       19200013
*      SYSTEM ABEND                                                     19400013
*                                                                       19600013
         L     RF,ERR2                 ABEND CODE DD NAME NOT FOUND     19800013
         ABEND (1)                                                      20000013
*                                                                       20200013
*                                                                       20400013
*                                                                       20600013
*                                                                       20800013
* NOT THIS ENTRY STEP TO NEXT TABLE ENTRY                               21000013
*                                                                       21200013
NOTEND   IC    RCORE,TNTRYSZE          LOAD SIZE OF THIS ENTRY          21400013
         LA    RC,0(RCORE,RC)      GET ADDRESS OF NEXT ENTRY.           21600013
         B     LOOKUP                                                   21800013
*                                                                       22000013
COMPID   CLC   TIODD(1,RTIOT),TERMID COMP TIOT DDNAME TO TERMTBL ENTRY  22200013
TESTOPEN L     RCORE,TQCBADDR-1   ADDRESS OF THE QCB                    22400013
         TM    4(RCORE),1         IS THIS QUEUE ALREADY OPEN            22600013
         BZ    FOUND              BRANCH IF NOT OPEN                    22800013
         L     RF,ERR7            ABEND ERROR CODE                      23000013
         ABEND (1)                                                      23200013
*                                                                       23400013
* PROCESS ENTRY FOUND IN TERMINAL TABLE                                 23600013
*                                                                       23800013
FOUND    MVC   DCBDEBAD+1(3),TQCBADDR   TQCBADDR TO DCB TEMPORAIRLY     24000013
         LA    RE,144                  BYTES NEEDED FOR THE DEB         24200013
         O     RE,POOLNUM          PUT POOL NUMBER IN HIGH ORDER        24400013
         GETMAIN R,LV=(0)                                               24600013
*                                                                       24800013
*                                                                       25000013
*  CLEAR  CORE GOTTEN FROM SVC MACRO                                    25200013
*                                                                       25400013
         XC    0(144,RF),0(RF)         CLEAR THE DEB                    25600013
         AH    RE,SEVEN            BUMP TO NEXT DOUBLE WORD.            25800013
         SSM   *+1                DISABLE INTERRUPTS                    26000013
SAVLEN   SRL   RE,3                DIVIDE BY EIGHT.                     26200013
         L     RCORE,4(0,RWTGC)                                         26400013
         LR    RD,RDEB             CURRENT TCB ADDRESS.                 26600013
         LA    RDEB,0(RF)          SET DEB BASE REGISTER.               26800013
         STC   RE,DEBLNGTH         SET NUMBER OF DOUBLE WORDS.          27000013
         MVC   DEBWKARA+3(5),DXCCW7                                     27200013
         ST    RDCB,DEBDCBAD-1     STORE DCB ADDRESS IN DEB.            27400013
         ST    RD,DEBTCBAD-1       STORE CURRENT TCB ADDRESS.           27600013
         MVZ  DEBPROTG(1),TCBPKF(RD)   PLACE PROTECTION KEY INTO DEB    27800013
         OI    DEBPROTG,OPMDEBID   SET DEBID FIELD TO X'F'.             28000013
         L     RF,8(RD)            CHAIN THIS DEB.                      28200013
         ST    RF,DEBDEBAD-1                                            28400013
         LR    RUCB,RDEB           SAVE DEB BASE.                       28600013
         LA    RDEB,DEBNMSUB       POINT TO START OF BASIC DEB.         28800013
         ST    RDEB,8(RD)          UPDATE TCB DEB ADDRESS.              29000013
         L     RD,CVTABLE(0,0)     GET ADDRESS OF COMM VECT TABLE       29200013
         L     RD,CVTTRMTB(0,RD)   GET ADDRESS OF TRMTBL                29400013
         L     RTIOT,TTQUES(RD)    GADDRESS OF DK01                     29600013
*                                                                       29800013
*      CHAIN DEB TO CHAIN OF PROCESS DEBS                               30000013
*                                                                       30200013
         L     RF,0(RTIOT)             ADDRESS OF LPS QUEUE             30400013
         MVC   21(3,RDEB),293(RF)      LAST DEB POINTER TO NEW DEB      30600013
         ST    RDEB,292(RF)            NEW POINTER TO HEAD OF CHAIN     30800013
*                                                                       31000013
*                                                                       31200013
         TM    DCBMACR+1,X'40'                                          31400013
         BO    MQOUT               IF PUT IS ON GO TO OUTPUT.           31600013
         L     RF,DCBDEBAD        LOAD ADDRESS OF THE PROCESS QUEUE     31800013
         OI    4(RF),1            FLAG QCB AS BEING OPEN                32000013
         ST    RF,8(RDEB)         SAVE QCB ADDRESS FOR CLOSE            32200013
         MVC   66(3,RDEB),1(RF)   SAVE FIRST MESSAGE ADDRESS            32400013
         MVC   17(3,RDEB),1(RF)   SAVE FIRST MESSAGE ADDRESS            32600013
         LA  RF,48(0,RDEB)         INITIALIZE DEBSEGAD 1ST TIME ONLY    32800013
         ST  RF,DCBSEGAD               WITH ADDRESS OF DUMMY BRB        33000013
         MVC   64(2,RDEB),DCBSOWA                                       33200013
         LA    RF,72(RTIOT)            ADDRESS OF IECKSTOP              33400013
         ST    RF,36(0,RDEB)                                            33600013
         L     RC,DCBDEBAD        QUEUE ADDR FROM TEMPORARY.            33800013
         LA    RF,32(RDEB)         SET ADDR TO DEBUCBAD.                34000013
         ST    RF,60(RDEB)                                              34200013
         MVI   52(RDEB),X'E0'     SET PRIORITY IN BRB                   34400013
         MVI   60(RDEB),7          SET CODE TO INDICATE DUMMY BUFFER    34600013
         ST    RF,12(RC)                                                34800013
         L     RF,0(RTIOT)             ADDRESS OF LPS QUEUE             35000013
        L     RF,276(RF)              GETSCH ADDRESS                    35200013
         ST    RF,8(RC)            STORE GET SCHEDULER ADDRESS IN QCB   35400013
         LA    RF,2(RC)            GET ADDRESS OF QCB+2                 35600013
         ST    RF,56(0,RDEB)       STORE IT IN DEB                      35800013
         MVI   56(RDEB),8          PUT TIC COMMAND IN DUMMY BRB IN DEB  36000013
         L     RTIOT,0(RTIOT)      GET ADDR OF LPS QUEUE FROM IGG019NG  36200013
         LA    RF,QPRITY(RTIOT)    GET ADDR OF QPRIRTY QUEUE FROM NG    36400013
         ST    RF,44(0,RDEB)       STORE QPRIRTY QCB ADDR IN DUMMY QCB  36600013
*                                                                       36800013
         LA    RF,48(RDEB)         GET ADDRESS OF DUMMY BRB JUST BUILT  37000013
         ST    RF,28(RDEB)         STORE IT IN DEB                      37200013
         MVI   52(RDEB),254        INITIALIZE REQUEST BLOCK PRIORITY    37400013
         TM    DCBRECFM,MESSM      TEST FOR MESSAGE MODE                37600013
         BC    1,MESS                    BRANCH IF YES                  37800013
         TM    DCBRECFM,RECRDM     TEST FOR RECORD MODE                 38000013
         BC    1,REC                     BRANCH IF YES                  38200013
*                                                                       38400013
*  ASSUME SEGMENT MODE IF NONE SPECIFIED                                38600013
*                                                                       38800013
SEG      LA    RC,MQGPR            LOAD ADDR OF GET SEGMENT INDICATOR   39000013
         B     KLDROUT             GO TO LOAD                           39200013
MESS     LA    RC,MQGG             LOAD ADDR OF GET MESSAGE INDICATOR   39400013
         B     KLDROUT             GO TO LOAD                           39600013
REC      LA    RC,MQGR             LOAD ADDR OF GET RECORD INDICATOR    39800013
         B     KLDROUT            GO TO LOAD                            40000013
*                                                                       40200013
*                                                                       40400013
*                                                                       40600013
MQOUT    EQU   *                                                        40800013
         L     RTIOT,0(RTIOT)      GET ADDR OF LPS QUEUE FROM IGG019NG  41000013
         LA    RF,QPRITY(RTIOT)    GET ADDR OF QPRIRTY QUEUE.           41200013
         ST    RF,40(0,RDEB)       STORE QPRIRTY QCB ADDR               41400013
         MVI   40(RDEB),X'18'          SET LCB STATE                    41600013
         TM    DCBRECFM,MESSM      TEST FOR MESSAGE MODE                41800013
         BC    1,PMESS            BRANCH IF YES                         42000013
         TM    DCBRECFM,RECRDM     TEST FOR RECORD MODE                 42200013
         BC    1,PRECRD            BRANCH IF YES                        42400013
* ASSUME SEG MODE                                                       42600013
PSEG     LA    RC,MQPS             LOAD ADDR OF PUT SEGMENT INDICATOR   42800013
         B     KLDROUT             GO TO LOAD                           43000013
PMESS    LA    RC,MQPG             LOAD ADDR OF PUT MESSAGE INDICATOR   43200013
         B     KLDROUT             GO TO LOAD                           43400013
PRECRD   LA    RC,MQPR             LOAD ADDR OF PUT RECORD INDICATOR    43600013
         MVI   72(RDEB),3         SET FLAG FOR PUT RECORD TO INDICATE   43800013
*                                 HEADER RECORD EXPECTED                44000013
KLDROUT  EQU   *                                                        44200013
         ST    RDEB,DCBDEBAD       PUT DEB ADDRESS IN DCB               44400013
         LR    RDEB,RUCB           RESTORE DEB BASE.                    44600013
         MVC   6(2,RWTG),0(RC)     LOAD WHERE-TO-GO TABLE               44800013
         MVC   14(3,RWTG),2(RC)                                         45000013
         SR    RE,RE               CLEAR RE                             45200013
         IC    RE,5(RC)                                                 45400013
         SLL   RE,3                                                     45600013
         ST    RE,24(RWTG)                                              45800013
         MVC   25(2,RWTG),26(RWTG)                                      46000013
         MVC   27(2,RWTG),25(RWTG)                                      46200013
         MVC   22(2,RWTG),CONTAB                                        46400013
         LR    RE,RWTG             GET ADDR OF NAME IN REG0.            46600013
         L     RF,CVTABLE(0,0)     GET ADDR OF CVT                      46800013
         L     RF,84(0,RF)         GET ADDRESS OF SVCLIB DCB            47000013
         LOAD  DE=(0),DCB=(1)      LOAD GET OR PUT MODULE               47200013
         IC    RF,DCBGET           SAVE DCBOFLGS                        47400013
         ST    RE,DCBGET           STORE SUBR ADDR IN DCB.              47600013
         STC   RF,DCBGET           SAVE DCBOFLGS                        47800013
         MVI   DEBEXSCL,X'02'      SET CODE FOR NON-DIRECT ACCESS.      48000013
         MVI   DEBNMSUB,X'01'      SET UP COUNT OF NUMBER SBRTNES LODED 48200013
         MVI   DEBNMEXT,X'00'      THERE ARE NO EXTENTS IN THIS DEB.    48400013
         MVI   DEBAMLNG,92         THERE ARE 92 BYTES BELOW THE BASIC   48600013
***********************         WARNING         *******************     48800013
*       NUMBER OF EXTENTS MUST BE EQUAL TO 0                         *  49000013
*      AND THE ACCESS METHOD LNTH MUST EQUAL THE NUMBER OF           *  49200013
*      BYTES USED BELOW THE BASIC DEB SO THAT SYSTEM CLOSE           *  49400013
*      CAN CALCULATE THE OFFSET TO SBRTN ID SECTION                  *  49600013
         MVC   140(2,RDEB),0(RC)   MOVE SBRTNE ID TO END OF TOTAL DEB.  49800013
         MVC   22(7,RWTG),CONATB2                                       50000013
         XC    0(2,RWTGC),0(RWTGC)   CLEAR ID,EXECUTOR COMPLETE         50200013
*                                                                       50400013
*          THIS IS AN OPEN PROVIDED SECTION OF CODE THAT SETS UP XCTL   50600013
*********************************************************************   50800013
         SSM   CONFF              ENABLE INTERRUPTS                     51000013
         L     RCORE,4(RWTGC)                                           51200013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURR WTG ENTRY        51400013
         LA    RPARC,PLOFF(0,RPARC)     INCR CURR ENTRY IN PARAM LIST   51600013
         CLC   0(2,RWTGC),AMIDCNST      SAME MODULE REQUIRED            51800013
         BCR   8,RBASE                  IF YES BRANCH TO BEGINNING      52000013
         CLC   0(2,RWTGC),OPIDCNST      END OF WTG TABLE                52200013
         BC    7,RELOOP                 NO CHECK NEXT ENTRY             52400013
*                                                                       52600013
         LR    RPARC,RPAR                                               52800013
         LA    RWTGC,WAOFF(0,RWTG)      REINITIALIZE WTG LIST PTR       53000013
ZCHEK    CLI   0(RWTGC),X'00'      IS THIS ENTRY COMPLETE               53200013
         BC    7,TCTLRTN                IF NOT TRANSFER CONTROL         53400013
*                                                                       53600013
         LA    RWTGC,WGOFF(0,RWTGC)     GET NEXT ENTRY                  53800013
         LA    RPARC,PLOFF(0,RPARC)                                     54000013
         BC    15,ZCHEK                                                 54200013
*                                                                       54400013
TCTLRTN  EQU   *                                                        54600013
         LA    RJ,DXCCW12                                               54800013
         MVC   6(2,RWTG),0(RWTGC)                                       55000013
         MVC   14(3,RWTG),2(RWTGC)                                      55200013
         XCTL  DE=(RWTG),SF=(E,(15))                                    55400013
*                                                                       55600013
*                                                                       55800013
         DS    0F                                                       56000013
POOLNUM  DC    X'FE000000'                                              56200013
SEVEN    DC    H'7'                                                     56400013
AMIDCNST DC    C'3P'                                                    56600013
OPIDCNST DC    C'0S'                                                    56800013
CONTAB   DC    X'CB780004000400'                                        57000013
CONATB2  DC    X'C3780004000400'   XCTL ATTRIBUTES                      57200013
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES           57400013
WAOFF    EQU   32                       OFFSET OF                       57600013
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES           57800013
*                                                                       58000013
ERR0     DC    X'800A0000'                                              58200013
ERR1     DC    X'800A1000'                                              58400013
ERR2     DC    X'800A2000'                                              58600013
ERR6     DC    X'800A6000'                                              58800013
ERR7     DC    X'800A5000'                                              59000013
CONFF    DC    X'FF'                                                    59200013
         ORG   IGG0193P+968                                             59400013
MQGPR    DC    C'NA'                                                    59600013
         DC    XL4'0'                                                   59800013
MQGG     DC    C'NB'                                                    60000013
         DC    XL4'0'                                                   60200013
MQGR     DC    C'NC'                                                    60400013
         DC    XL4'0'                                                   60600013
MQPS     DC    C'ND'                                                    60800013
         DC    XL4'0'                                                   61000013
MQPG     DC    C'NE'                                                    61200013
         DC    XL4'0'                                                   61400013
MQPR     DC    C'NF'                                                    61600013
         DC    XL4'0'                                                   61800013
XCTLEND  DC    XL2'0'                                                   62000013
         ORG   IGG0193P+1020                                            62200013
LOADID   DC    C'019'                                                   62400013
         DC    X'79'                                                    62600013
*                                                                       62800013
CVTABLE  EQU   16            LOCATION OF POINTER TO COMM VECTOR TABLE   63000013
CVTTCBAD EQU   0                                                        63200013
CURNTTCB EQU   4                                                        63400013
CVTTRMTB EQU   156                                                      63600013
TCBPKF     EQU     28                                                   63800013
*                                                                       64000013
TTQUES   EQU   4                                                        64200013
QRET     EQU   96                                                       64400013
QPRITY   EQU   X'104'                                                   64600013
*                                                                       64800013
         EJECT                                                          65000013
TCB      DSECT                                                          65200013
TCBPRB   DS    F                                                        65400013
TCBPIE   DS    F                                                        65600013
TCBDEBAD DS    F                                                        65800013
TCBTIO   DS    F                                                        66000013
         EJECT                                                          66200013
*                                                                       66400013
TIODD    EQU   4                                                        66600013
DEBSIZE  EQU   88                                                       66800013
OPMDEBID EQU   X'0F'               IDENTIFIER FOR A DEB                 67000013
         IECTDEBX                                                       67200013
         EJECT                                                          67400013
         DCBD  DSORG=(MQ)                                               67600013
         EJECT                                                          67800013
         TERMTBLD                                                       68000013
         EJECT                                                          68200013
FORCORE  DSECT                                                          68400013
         IECDSECT                                                       68600013
         END                                                            68800013
