         TITLE ' IGG0193R QTAM LINE GROUP OPEN EXECUTOR - LOAD 2'       00100013
*********************************************************************** 00120021
*                                                                     * 00140021
* STATUS - CHANGE LEVEL = 18      JANUARY 1971                        * 00160021
*                                                                     * 00180021
* FUNCTION - ANALYSIS OF THE DEVICE TYPE FIELD IS CONTINUED FOR       * 00200021
*    83B3'S, 115A'S, TWX'S, AND 2260 TERMINALS.  IF AN INVALID MODEL  * 00220021
*    TYPE IS SPECIFIED FOR AN ADAPTER, AN 093 ABEND IS ISSUED.  TESTS * 00240021
*    FOR THE POSSIBLE OPTIONAL FEATURES FOR EITHER A 83B3, 115A, TWX, * 00260021
*    OR 2260 ARE CHECKED.  IF INCORRECT OPTIONAL FEATURE BITS HAVE    * 00280021
*    BEEN SET, A 094 ABEND IS ISSUED.                                 * 00300021
*         TO THE MINIMUM SIZE OF AN LCB (112 BYTES) IS ADDED THE SIZE * 00320021
*    OF THE CHANNEL PROGRAM AREA FOR A PARTICULAR DEVICE.  A GETMAIN  * 00340021
*    IS ISSUED TO OBTAIN CORE FROM SUBPOOL 250 FOR ALL THE LCBS (AN   * 00360021
*    LCB FOR EACH LINE IN THE LINE GROUP).  THE DCB IS INITIALIZED    * 00380021
*    WITH THE ADDRESS OF THE FIRST LCB MINUS THE SIZE OF AN LCB IN    * 00400021
*    DCBLCBAD, THE SIZE OF THE LCB IN DCBEIOBX, IOB ADDRESS IN        * 00420021
*    DCBIOBAD, AND THE DEVICE TYPE IN DCBDEVTP.                       * 00440021
*         THE IOB IN EACH LCB IS INITIALIZED.  AFTER THE LCB IS       * 00460021
*    CLEARED TO ZEROES, THE ADDRESS OF LCBCPA IS STORED IN IOBSTART,  * 00480021
*    IOBUCBX IS SET ( STARTING WITH 0 AND INCREMENTING BY 1 FOR EACH  * 00500021
*    DEVICE EXTENT), AND DCB ADDRESS IS STORED IN IOBDCBPT.           * 00520021
*         THE CHANNEL PROGRAM AREA IS INITIALIZED.  FOR AN IBM 2702   * 00540021
*    CONTROL UNIT, THE FIRST CCW IS SET WITH THE CORRECT SAD COMMAND  * 00560021
*    (OBTAINED FROM UCB).  EXCEPT FOR 2701 WITH TYPE III ADAPTER      * 00580021
*    (2260), AND IF THERE IS NO AUTO CALL OR AUTO ANSWER FEATURE, A   * 00600021
*    CCW WITH AN ENABLE COMMAND CODE IS SET IN THE CHANNEL PROGRAM    * 00620021
*    AREA.  IF NON-DIAL TERMINALS AND A RESTART IS IN PROGRESS, A     * 00640021
*    WRITE BREAK COMMAND, FOR A TTY DEVICE, OR A READ SKIP COMMAND,   * 00660021
*    FOR OTHER DEVICES, IS SET IN THE CCW.  FOR DIAL LINES A NOP IS   * 00680021
*    SET IN THE CHANNEL PROGRAM AREA.  FOR AUTO POLL LINES AN AUTO    * 00700021
*    POLL FLAG (1 BIT) IS SET IN LCBFLAG2.                            * 00720021
*         FOR OUTPUT ONLY LINES, THE QEVENT SUBTASK ADDRESS IS STORED * 00740021
*    IN THE RECEIVE SCHEDULER IN THE LCB.  OTHERWISE, THE RECEIVE     * 00760021
*    SCHEDULER IS SET TO POINT TO ITSELF WITH QEVENT SUBTASK IN THE   * 00780021
*    LINK FIELD OF THE RECEIVE SCHEDULER.  DCBCPRI IS STORED IN       * 00800021
*    LCBCPRI FOR NON-DIAL LINES AND 0 FOR DIAL LINES.  THE PRIORITY OF* 00820021
*    THE ECB IN THE LCB IS SET TO X'E4'.  IOBPOLPT IS SET TO THE      * 00840021
*    ADDRESS OF LCBDLPTR.  LCBDLPTR IS ZERO AND WILL APPEAR AS THE END* 00860021
*    OF THE POLLING LIST.  A FLAG (X'FF') IS SET IN LCBCPA + 32 TO    * 00880021
*    INDICATE OPEN LINE.  LCBINCAM IS SET TO X'0700' SO THAT THE LINE * 00900021
*    WILL APPEAR CONNECTED.                                           * 00920021
*         THE CPFLAG IN THE FIXED AREA OF IGG019NG IS CHECKED FOR A   * 00940021
*    RESTART.  IF A RESTART IS IN PROGRESS, A SEARCH IS MADE OF THE   * 00960021
*    LCBS IN THE CHECK POINTED WORK AREA FOR THE SAME LINE NUMBER.    * 00980021
*    LCBCHDR, LCBTTIND, AND LCBNASEG ARE RESTORED AND LCBSTATE IS     * 01000021
*    MOVED TO LCBCPA + 40 TO BE TEMPORARILY SAVED.                    * 01020021
*         IF THE LINE IS TO BE OPENED IDLE, OR ON RESTART, THE LINE   * 01040021
*    WAS NOT ACTIVE AT CHECKPOINT TIME (LCBSTATE=0), THE 'NO STARTLN' * 01060021
*    CODE (X'FE' IN LCBCPA + 32) IS SET.  THE ADDRESS OF A DUMMY ECB  * 01080021
*    (LCBCPA + 36) IS STORED IN IOBECBPT FOR THE INITIAL SAD, ENABLE, * 01100021
*    OR NOP.                                                          * 01120021
*         THE ROUTINE LOOPS BACK TO INITIALIZE THE NEXT LCB, LOCATED  * 01140021
*    BY ADDING THE LENGTH OF AN LCB TO THIS LCB.  IF THERE IS ANOTHER * 01160021
*    DCB TO BE OPENED, A BRANCH IS MADE TO THE START OF THIS ROUTINE. * 01180021
*    OTHERWISE, THE ROUTINE EXITS VIA AN XCTL TO LINE GROUP EXECUTOR  * 01200021
*    LOAD 3, IGG0193T.                                                * 01220021
*                                                                     * 01240021
* ENTRY POINT - ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE BY AN   * 01260021
*         XCTL TO IGG0193R BY IGG0193N.  IT MAY ALSO BE RE-ENTERED    * 01280021
*         FROM A RELOOP PORTION OF THIS ROUTINE IF ANOTHER DCB IS TO  * 01300021
*         BE OPENED.                                                  * 01320021
*                                                                     * 01600013
*INPUT-  THE REGISTERS 5, 6, 7, AND 8 ARE THE INPUT, AS FOLLOWS,      * 01700013
*   5- THE ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST,      * 01800013
*   6- THE ADDRESS OF THE BEGINNING OF THE WHERE@TO@GO TABLE,         * 01900013
*   7- THE ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST,    * 02000013
*   8- THE ADDRESS OF THE CURRENT EXECUTOR S ENTRY IN THE WHERE-TO-GO * 02100013
*      TABLE.                                                         * 02200013
*   9-15 THE CONTENTS OF THE REGESTERS ARE PASSED FORWARD IN THE AREA * 02300013
*        DESIGNATED IN THE WTG TABLE                                  * 02400013
*                                                                     * 02500013
*                                                                     * 02600013
*OUTPUT-  THE REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES* 02700013
*   IN THE DCB PARAMETER LIST AND THE WHERE-TO TABLE. ONE IOB PER LINE* 02800013
*   WILL HAVE BEEN CONSTRUCTED IN SUBPOOL 250.  DCB FIELDS (DEVTP,    * 02900013
*   IOBAD, EIOBX,IFLGS,DEBAD,AND READ/WRITE WILL HAVE BEEN            * 03000013
*   INITIALIZED.  THIS EXECUTOR'S ENTRY (OR ENTRIES) IN THE WHERE-TO- * 03100013
*    GO TABLE WILL HAVE BEEN UPDATED TO IDENTIFY LOAD 3 (IGG0193T).   * 03200021
*                                                                     * 03300021
* EXTERNAL ROUTINES - NONE                                            * 03400021
*                                                                     * 03500013
*EXITS-NORMAL-  THIS ROUTINE EXITS VIA AN XCTL TO THE MODULE          * 03600013
*   IDENTIFIED BY THE NEXT NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE,   * 03700013
*   NAMELY IGG0193T (QTAM OPEN EXECUTOR - LOAD 3).                    * 03800013
*                                                                     * 03900013
*EXIT-ERRORS-                                                         * 04000013
*     -ERRORS-  THIS ROUTINE EXITS VIA ABEND FOR THE FOLLOWING        * 04100013
*   ERROR CONDITIONS-                                                 * 04200013
*   ABEND CODE ERROR CONDITION                                        * 04300013
*   00090000    A DEVICE OTHER THAN A COMMUNICATIONS DEVICE HAS BEEN  * 04400013
*               ALLOCATED TO THIS DCB.                                * 04500013
*   00091000    AN INVALID OR UNSUPPORTED CONTROL UNIT HAS BEEN       * 04600013
*               SPECIFIED                                             * 04700013
*   00092000    AN INVALID OR UNSUPPORTED TYPE OF TERMINAL CONTROL    * 04800013
*               OR ADAPTER HAS BEEN SPECIFIED                         * 04900013
*   00093000    AN INVALID OR UNSUPPORTED TERMINAL TYPE HAS BEEN      * 05000013
*               SPECIFIED.                                            * 05100013
*   00094000    AN INVALID OR UNSUPPORTED OPTIONAL FEATURE  OR MODE OF* 05200013
*               OPERATION  HAS BEEN SPECIFIED.                        * 05300013
*   00095000    2701, 2702, OR 2703 NOT SPECIFIED                     * 05400013
*                                                                     * 05500013
*TABLES/WORK AREAS- 1.DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH * 05600013
*  DCB SPECIFIED IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO    * 05700013
*  TABLE CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE * 05800013
*  DCB WHICH CORRESPONDS TO THIS ENTRY. 3. THE WHERE TO GO TABLE      * 05900013
*   POINTS TO A WORK AREA IN WHICH REGESTERS 9-15 ARE PASSED FORWARD  * 06000013
*   TO AND FROM THIS ROUTINE.                                         * 06100013
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 06300013
IGG0193R CSECT                                                          06400013
*3190290000,293000,434000,436400,439000                            000A 06450015
*2340301000-302000,352000-353000                                   6978 06480016
*2719142000,174300-174600,464300-464600,521000                     000C 06490017
*1202235200-235800,466000                                          000D 06492018
*1202340100-340300,340700                                         22437 06494018
*1202340400-340600                                                23144 06496018
*1990348100-348700                                                22437 06498018
*A001200-063000                                                         06499021
         SPACE 1                                                        06500013
RE       EQU   0                       WORK/PARAMREG                    06600013
RF       EQU   1                       WORK/PARAMREG                    06700013
RDCB     EQU   2                       DCB ADDRESS                      06800013
RBASE    EQU   3                       BASE REGISTER                    06900013
RCORE    EQU   4                       IOB ADDRESS                      07000013
RPAR     EQU   5                       START OF PARAMETER LIST          07100013
RWTG     EQU   6                       START OF WTG                     07200013
RPARC    EQU   7                       CURRENT ENTRY IN PARAMETER LIST  07300013
RWTGC    EQU   8                       CURRENT ENTRY IN WTG TABLE       07400013
RTIOT    EQU   9                       TIOT ADDRESS                     07500013
RUCB     EQU   10                      CURRENT UCB                      07600013
RDEB     EQU   11                      DEB ADDRESS                      07700013
RB       EQU   12                      WORK REG                         07800013
RC       EQU   13                      WORK REG                         07900013
RD       EQU   14                      WORK/PARAMREG                    08000013
RJ       EQU   15                      WORK/PARAMREG                    08100013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 08200013
LPS      EQU   0                                                        08300013
LCBSTATE EQU   0                                                        08400013
OLDCHDR  EQU   0                                                        08500013
OLDTTIND EQU   3                                                        08600013
NGAD     EQU   4                                                        08700013
DEVAD    EQU   4                                                        08800013
OLDSTATE EQU   5                                                        08900013
OLDNASEG EQU   6                                                        09000013
LCBSCHAD EQU   8                                                        09100013
LCBDEV   EQU   9                                                        09200013
LCBSZ    EQU   11                                                       09300013
LCBCPRI  EQU   12                                                       09400013
QTAMOUT  EQU   15                                                       09500013
LCBCHDR  EQU   16                                                       09600013
UCBFEA   EQU   17                                                       09700013
UCBADP   EQU   19                                                       09800013
LCBNASEG EQU   22                                                       09900013
LCBOFF   EQU   22                                                       10000013
WKAREA   EQU   24                                                       10100013
QTAMIDLE EQU   32                                                       10200013
CPSIZE   EQU   34                                                       10300013
LCBTTIND EQU   44                                                       10400013
LCBFLAG2 EQU   49                                                       10500013
ERPMIN   EQU   56            MINIMUM CCP SIZE IF ERP IS TO BE USED      10600013
CMDCHAIN EQU   X'40'                                                    10700013
QATTACH  EQU   72                                                       10800013
QEVENT   EQU   80                                                       10900013
TERM     EQU   156                CVT OFFSET TO ADDRESS OF THE TERM TBL 11000013
CPFLAG   EQU   304                                                      11100013
DXCCW12  EQU   X'1C8'                                                   11200013
         USING IECTIOB-48,RCORE                                         11300013
         USING IHADCB,RDCB                                              11400013
         USING IECTDEB,RDEB                                             11500013
         BALR  RBASE,0                                                  11600013
         USING *,RBASE                                                  11700013
         SR    RDCB,RDCB                                                11800013
         L     RJ,4(RWTGC)                                              11900013
         LM    9,15,0(RJ)          LOAD REGESTERS FROM LOAD 1           12000013
* TEST WILL BE PERFORMED ON MODEL TYPE FOR EACH TERMINAL ADAPTER        12100013
         B     MODELRT(RC)                                              12200013
*                                                                       12300013
*  BRANCH IS EXECUTED TO MODELRT INDEX BY THE CONTENTS OF UNITYREG      12400013
*                                                                       12500013
         SPACE 2                                                        12600013
MODELRT  B     TERMERR                                                  12700013
* THIS FIRST BRANCH IS TAKEN ON ZERO UNIT TYPE                          12800013
* THE FOLLOWING BRANCHES ARE TAKEN FOR A SPECIFIC TERMINAL ADAPTER      12900013
*                                 SPEC IN UNITYREG VALUE CD BITS 1-5    13000013
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  13100013
*                            VALUE CODES 1-3 PROCESSED IN LOAD 1.       13200013
*                                                                       13300013
         B     TYPE1              VALUE CD 1-IBM TERMINAL ADAPTER TYPE1 13400013
         B     TYPE2              VALUE CD 2-IBM TERMINAL ADAPTER TYPE  13500013
         B     IBMTEL             VALUE CD 3-IBM TERMINAL ADAPTER       13600013
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  13700013
*                                  CODES 4-8 PROCESSED IN LOAD 2.       13800013
*                                                                       13900013
         B     TELTYPE1           VALUE CD 4-IBM TELGRAPH ADAPTER TYPE  14000013
         B     TELTYPE2           VALUE CD 5-IBM TELGRAPH ADAPTER TYPE  14100013
         B     TYPE6              VALUE CD- 6 WORRLD TRADE TELETYPE000C 14200017
         B     TERMERR            VALUE CD 7-SYNC DATA ADAPTER    *NCS* 14300013
         B     TYPE3              VALUE CD 8-IBM TERMINAL ADAPTER TYPE3 14400013
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  14500013
TYPE1    B     IOBST1        PROCESSED BY LOAD 1.                       14600013
TYPE2    B     IOBST1        PROCESSED BY LOAD 1.                       14700013
IBMTEL   B     IOBST1        PROCESSED BY LOAD 1.                       14800013
TELTYPE1 TM    0(RB),DEVATT                                             14900013
         BO    D83B3                   ATT83B3 BRANCH  @   UNITYREG-4   15000013
         TM    0(RB),DEVWU                                              15100013
         BO    D115A                   WU115A  BRANCH  @   UNITYREG-6   15200013
* ANY OTHER DEVICE IN ERROR                                             15300013
         B     ADAPTYER                                                 15400013
TELTYPE2 TM    0(RB),DEVTWX                                             15500013
         BO    DTWX                    TWX  BRANCH CODETAB UNITYREG-5   15600013
* ANY OTHER DEVICE IN ERROR                                             15700013
*                                                                       15800013
D115A    LA    RDCB,2(0,0)             POINT TO 115A REGULAR            15900013
D83B3    TM    1(RB),REGMASK           TEST 83B3 REGULAR                16000013
         BZ    TELTY1                                                   16100013
         AR    RDCB,RD                 POINT TO 83B3TT POSITION         16200013
         TM    1(RB),TTMASK                                             16300013
         BO    TELTY1                                                   16400013
         B     SPFEAERR                                                 16500013
DTWX     TM    1(RB),AMASK             TEST FOR TWXA                    16600013
         BO    TELTY2                                                   16700013
         AR    RDCB,RD                 POINT TO TWXAA                   16800013
         TM    1(RB),AAMASK                                             16900013
         BO    TELTY2                                                   17000013
         AR    RDCB,RD       POINT TO TWXAC                             17100013
         TM    1(RB),ACMASK                                             17200013
         BO    TELTY2                                                   17300013
         B     SPFEAERR                                                 17400013
TYPE6    EQU   *                  ASSUME VALUE FOR DEVICE CODE     000C 17430017
         B     IOBST1                                              000C 17460017
TERMERR  L     1,ERR2                  TERMINAL ADAPTR TYPE 0 > 5       17500013
         ABEND (1)                                                      17600013
TYPE3    TM    0(RB),DEV2260                                            17700013
         BO    D2260              2260 BRANCH                           17800013
* ANY OTHER DEVICE ON IBM TERMINAL ADAPTER TYPE3 IS IN ERROR            17900013
ADAPTYER L     1,ERR3                                                   18000013
         ABEND (1)                                                      18100013
D2260    TM    1(RB),REGMASK                                            18200013
         BZ    IBM3                                                     18300013
SPFEAERR L     1,ERR4                                                   18400013
         ABEND (1)                                                      18500013
         SPACE 3                                                        18600013
* IOB                                                                   18700013
* DCBREG HAS 4BYTES THAT HAS HIGH ORDER BYTE USED BY QTAM               18800013
* 3 LOW ORDER BYTES OF ADDRESS OF DCB                                   18900013
* PARAMREG POINTS TO     HIGH ORDER POSITION OF FIELD THAT              19000013
* HAS HIGH ORDER BYTE FOR BTAM AND DCB ADDRESS                          19100013
         SPACE 2                                                        19200013
IBM3     LA    RDCB,CDIBM3-CDTEL2(RDCB)                                 19300013
TELTY2   LA    RDCB,CDTEL2-CDTEL1(RDCB)                                 19400013
TELTY1   LA    RTIOT,CDTEL1(RDCB)                                       19500013
IOBST1   SR    RE,RE                                                    19600013
         L     RDCB,0(RPARC,0)                                          19700013
         IC    RE,SZTABLE(RTIOT)        SET NORMAL SIZE                 19800013
         AH    RE,ONE12           ADD BASIC 112- IOB SIZE               19900013
         STC   RE,DCBEIOBX         IOB SIZE SENT TO DCB                 20000013
         LR    15,RE          STORE SIZE TEMPORARLY                     20100013
         SR    12,12         CLEAR EVEN REG. FOR MULT.ND                20200013
         SR    14,14         CLEAR MULTIPLIER REG.                      20300013
         LR    13,RE         LOAD SIZE INTO MULT.ND                     20400013
         IC    RD,DEBNMEXT       NUM. OF EXTENTS IN R14                 20500013
         MR    12,RD         MULT = EXT TIMES IOB SIZE                  20600013
         LA    RE,0(13)        LOAD PRODUCT IN R0                       20700013
         LR    RC,15         REPLACE ORIGINAL SIZE                      20800013
         O     RE,IOBPOOL              HIGH ORDER BYTE HAS SUB POOL NO  20900013
         GETMAIN R,LV=(0)                                               21000013
         LR    RCORE,RF                                                 21100013
         SR    RCORE,RC           ADDRESS                               21200013
         IC    RB,DCBLCBAD         SAVE THE PRIORITY                    21300013
         ST    RCORE,DCBLCBAD                                           21400013
         STC   RB,DCBLCBAD         RESTORE THE PRIORITY                 21500013
*                                 OVERLAY OF DCBDEVTP FIELD.            21600013
         LR    RB,RTIOT                                                 21700013
*                                 BY LOAD SECTION.                      21800013
         AR    RCORE,RC            ADD BACK BASIC SIZE POINT START IOB  21900013
         LA    RTIOT,IOBFLAG1      LOAD ADDR OF IOB                     22000013
         ST    RTIOT,DCBIOBAD      STORE IN DCB                         22100013
         STC   RB,DCBDEVTP         MOVE DEVICE TYPE OFFSET FOR LOAD DCB 22200013
         SR    RTIOT,RTIOT                                              22300013
* WE WILL CLEAR ONE IOB TEST NUMBER OF EXTENTS FOR ADDITIONAL IOBS      22400013
* WHEN COUNT IS ZERO TERMINATE IOB LOOP.                                22500013
         BCTR  RC,0               SUB ONE FOR THE EXECUTE INSTRUCTION   22600013
STARTLP  EX    RC,CLEAR           CLEAR JUST 1 IOB NO OF EXTENTS        22700013
         MVI   IOBCSW+4,X'0F'   INDICATE CHAN OPER COMPLETE             22800013
         LA    RB,LCBCPA(RCORE)                                         22900013
         ST      RB,IOBSTART      MOVE IN ADDRESS DESTROYING TOBSIOCC   23000013
         STC   RTIOT,IOBUCBX       ZERO FIRST TIME                      23100013
         LA    RTIOT,1(RTIOT)     INCREMENT RTIOT BY ONE                23200013
         ST    RDCB,IOBWGHT     STORE DCB ADDRESS AT IOBWGHT-IOBDCBPT   23300013
         MVI   IOBWGHT,X'00'   CLEAR OUT HIGH ORDER BYTE                23400013
         LA    RCORE,1(RCORE,RC)  BUMP FOR CLEAR OF NEXT IOB            23500013
         BCT   RD,STARTLP              CLEAR IOB ON POSITIVE NO EXTENT  23600013
         SPACE 2                                                        23700013
         L     RDEB,DCBDEBAD           ACCESS POINTER TO DEB            23800013
         L     RDEB,28(RDEB)           POINT TO APPENDAGE TABLE OF DEB  23900013
*                                 OR TRUE START OF DEB FOR DSECT.       24000013
         LA    RD,DEBUCBAD              POINT TO TABLE OF UCB           24100013
*                                  ADDRESSES.                           24200013
         L     RCORE,DCBLCBAD     CALCULATE ADDR OF FIRST IOB           24300013
         SR    RB,RB                                                    24400013
         IC    RB,DCBEIOBX                                              24500013
         AR    RCORE,RB                                                 24600013
         SR    RC,RC                    LOAD NUMBER OF EXTENTS TO BE    24700013
         IC    RC,DEBNMEXT         USED AS A LOOP COUNTER.              24800013
*                                                                       24900013
*      LOAD ADDRESSES OF QATTACH AND THE LPS QUEUE                      25000013
*                                                                       25100013
NEXTLINE L     RTIOT,16           ADDRESS OF THE CVT                    25200013
         L     RTIOT,TERM(RTIOT)  ADDRESS OF THE TERMINAL TABLE         25300013
         L     RTIOT,NGAD(RTIOT)  ADDRESS OF IGG019NG                   25400013
         L     RTIOT,LPS(RTIOT)   ADDRESS OF THE LPS QUEUE IN IGG019NG  25500013
*                                                                       25600013
*      BUILD NOP COMMAND IN CHANNEL PROGRAM AREA                        25700013
*                                                                       25800013
         L     RUCB,0(RD)         LOAD ADDRESS OF THE NEXT UCB          25900013
         LA    RF,LCBCPA-8(RCORE) ADDRESS OF FIRST COMMAND MINUS 8      26000013
         MVZ   DCBCPOLL(1),UCBADP(RUCB) MOVE DEVICE TYPE TO THE UCB     26100013
         MVI   8(RF),3            NOP COMMAND CODE                      26200013
         MVC   12(4,RF),SADENNOP  BUILD REST OF NOP COMMAND             26300013
*                                                                       26400013
* SET AUTOPOLL FLAG                                                     26500013
*                                                                       26600013
         TM    UCBFEA(RUCB),X'40'  DOES THE UCB SPECIFY AUTOPOLL        26700013
         BZ    *+8                 IF NO SKIP NEXT INSTRUCTION          26800013
         OI    LCBFLAG2(RCORE),X'01' IF YES TURN ON AUTOPOLL FLAG       26900013
*                                                                       27000013
*      TEST FOR CONTROL UNIT EQUAL 2702                                 27100013
*                                                                       27200013
         IC    RJ,UCBADP(RUCB)    LOAD CONTROL UNIT TYPE BITS           27300013
         N     RJ,ANDMASK         CLEAR ALL OTHER BITS FROM REGISTER    27400013
         BCT   RJ,NOT2702         BRANCH IF 2701 OR 2703-CODES 2 AND 3  27500013
*                                                                       27600013
*      CONTROL UNIT IS A 2702 SET UP CORRECT SAD COMMAND                27700013
*                                                                       27800013
         IC    RJ,UCBFEA(RUCB)    LOAD FEATURE BYTE FROM THE UCB        27900013
         N     RJ,ANDMASK         CLEAR EXTRANEOUS BITS FROM REGISTER   28000013
         IC    RJ,SADCCODE(RJ)    INSERT ACTUAL SAD COMMAND CODE        28100013
         STC   RJ,8(RF)           STORE IN CHANNEL PROGRAM AREA         28200013
         MVC   12(4,RF),SADENNOP  BUILD REST OF SAD COMMAND             28300013
         LA    RF,8(RF)           INCREMENT COMMAND POINTER             28400013
NOT2702  CLI   UCBADP(RUCB),X'82' 2701 WITH IBM TYPE 3 ADAPTER          28500013
         BE    TESTRSTR           BRANCH YES NO ENABLE REQUIRED         28600013
*                                                                       28700013
*      GENERATE ENABLE COMMAND IF NOT AUTO CALL OR AUTO ANSWER          28800013
*                                                                       28900013
         TM    UCBFEA(RUCB),X'90' TEST FOR AUTO CALL OR AUTO ANSWER     29100013
         BNZ   STARTLN            BRANCH IF AUTO CALL OR AUTO ANSWER    29200013
         MVI   8(RF),X'27'        SET COMMAND CODE FOR ENABLE           29400013
         MVC   12(4,RF),SADENNOP  BUILD REST OF ENABLE COMMAND          29500013
         OI    4(RF),CMDCHAIN     TURN ON COMMAND CHAIN IN PRIOR COMM.  29600013
         LA    RF,8(RF)           INCREMENT COMMAND POINTER             29700013
*                                                                       29800013
*      GENERATE READ SKIP OR BREAK COMMAND IF RESTART IN PROGRESS       29900013
*                                                                       30000013
TESTRSTR TM    CPFLAG(RTIOT),X'E2' IS A RESTART IN PROGRESS        6978 30100016
         BNO   STARTLN             BRANCH IF NO                    6978 30200016
         OI    4(RF),CMDCHAIN     TURN ON COMMAND CHAIN IN PRIOR COMM.  30300013
         MVC   8(8,RF),READSKIP   READ SKIP TO CHANNEL PROGRAM AREA     30400013
         TM    UCBADP(RUCB),X'B0' IS THIS A TTY DEVICE                  30500013
         BNZ   STARTLN            BRANCH IF TTY                         30600013
         MVC   8(8,RF),BREAK      REPLACE READ SKIP WITH BREAK COMMAND  30700013
         SPACE 3                                                        30800013
*       TEST QTAM BYTE FOR OUTPUT AND/OR IDLE                           30900013
*       IF OUTPUT PLACE LCBCPRI INFORMATION INTO LCBSCHAD               31000013
*       IF IDLE DO NOT START LINE                                       31100013
*             QTAM BYTE                                                 31200013
*   *    *    *    *    *    *    *    *    *                           31300013
*   *    *    *    *    *    *    *    *    *                           31400013
*   * *  *    *    *    *    *    *    *    *                           31500013
*   *    *    *    *    *    *    *    *    *                           31600013
*          2ND OPTION   *       1ST OPTION                              31700013
*                       *                                               31800013
*   1ST OPTION:  BIT CONFIG   NOTATION                                  31900013
*                 0000         INPUT                                    32000013
*                 0011         IN-OUT                                   32100013
*                 1111         OUTPUT                                   32200013
*                                                                       32300013
*   2ND OPTION    *010         IDLE                                     32400013
*                 *011         LEAVE                                    32500013
*                 *001         REREAD                                   32600013
*                 *000         DISPOSITION TAKEN FROM DD CARD           32700013
*                 * BIT ON INDICATES LAST WORD OF LIST                  32800013
*                                                                       32900013
*                                                                       33000013
         SPACE 3                                                        33100013
STARTLN  LA    RJ,QEVENT(RTIOT)   QEVENT SUBTASK ADDRESS                33200013
         ST    RJ,LCBSCHAD(RCORE) QEVENT SUBTAST IN TEH LCB             33300013
         TM    0(RPARC),QTAMOUT   LINE OPENED FOR OUTPUT ONLY           33400013
         BO    OUTONLY            BRANCH IF YES                         33500013
*                                                                       33600013
*      LINE OPENED FOR INPUT SET CPRI AND RECEIVE SCHEDULAR             33700013
*                                                                       33800013
         ST    RJ,LCBCPRI(RCORE)  QEVENT SUBTASK AFTER RECEIVE SCHEDULR 33900013
        MVI   LCBCPRI(RCORE),1   SET SEND PRIORITY (DEFAULT OPTION)000A 33920015
        CLI   DCBCPRI,0          IS DEFAULT OPTION REQUIRED        000A 33940015
        BE    *+10               BRANCH IF YES                     000A 33960015
         MVC   LCBCPRI(1,RCORE),DCBCPRI DCBCPRI TO THE LCB              34000013
         LA    RJ,LCBSTATE+8(RCORE) ADDRESS FO RECEIVE SCHEDULAR STCB   34100013
         ST    RJ,LCBSCHAD(RCORE) RECEIVE SCHEDULAR STCB TO THE LCB     34200013
OUTONLY  LA    RJ,LCBSTATE+X'2E'(RCORE)  POINT TO ZEROS FOR OPEN   000D 34300016
         MVI   LCBSCHAD(RCORE),X'12' SET RETURN CODE FOR RECEIVE SCH.   34400013
         ST    RJ,IOBPOLPT        SET POLL POINTER TO LOOK LIKE END OF  34500013
*                                 THE POLLING LIST                      34600013
         MVI   LCBSTATE+4(RCORE),X'E4' SET THE LCB PRIORITY             34700013
         MVI   LCBCPA+32(RCORE),X'FF' SET DO START LINE CODE            34800013
         TM    UCBFEA(RUCB),X'90'  IS THIS A DIAL LINE            22437 34810018
         BZ    NOTDIAL             NO, LEAVE LCBCPRI ALONE        22437 34820018
         MVI   LCBCPRI(RCORE),0    SET LCBCPRI TO 0 FOR DIAL      22437 34830018
         MVI   IOBINCAM,7          SET DIAL LINE TO LOOK          23144 34840018
*                                   CONNECTED IN CASE OF RESTART  23144 34850018
*                                   OR OPEN IDLE                  23144 34860018
NOTDIAL  EQU   *                                                  22437 34870018
*                                                                       34900013
*      IF RESTART LOCATE CHECK-POINTED DATA FOR THIS LCB                35000013
*                                                                       35100013
         TM    CPFLAG(RTIOT),X'E2' IS A RESTART IN PROGRESS        6978 35200016
         BNO   NORMAL              BRANCH IF NO                    6978 35300016
         L     RJ,CPFLAG(RTIOT)   LOAD ADDRESS OF THE CHECK-POINT RT.   35400013
         L     RTIOT,4(RWTGC)     ADDRESS OF OPEN WORK AREA             35500013
         MVC   0(2,RTIOT),DEVAD(RUCB) LINE ADDRESS TO TEMPORARY STORAGE 35600013
         NI    0(RTIOT),X'0F'     CLEAR UNWANTED BITS                   35700013
         L     RF,WKAREA(RJ)      ADDRESS OF CHECK POINT DATA           35800013
         AH    RF,LCBOFF(RJ)      ADDRESS OF SAVE LCB DATA              35900013
TRYAGAIN OC    0(LCBSZ,RF),0(RF)  TEST FOR END OF LCB DATA              36000013
         BZ    NORMAL             BRANCH END-LCB NOT CHECK POINTED      36100013
         NI    LCBDEV(RF),X'0F'   CLEAR UNWANTED BITS                   36200013
         CLC   LCBDEV(2,RF),0(RTIOT) COMPARE LINE ADDRESS               36300013
         BE    FOUNDLCB           GO RESTORE LCB FIELDS                 36400013
         LA    RF,LCBSZ(RF)       INCREMENT VARIABLE LCB POINTER        36500013
         B     TRYAGAIN                                                 36600013
FOUNDLCB MVC   LCBCHDR(3,RCORE),OLDCHDR(RF) RESTORE LCBCHDR             36700013
         MVC   LCBTTIND(2,RCORE),OLDTTIND(RF) RESTORE LCBTTIND          36800013
         MVC   LCBNASEG(3,RCORE),OLDNASEG(RF) RESTORE LCBNASEG          36900013
         MVC   LCBCPA+40(1,RCORE),OLDSTATE(RF) SAVE LCBSTATE FOR LOAD 3 37000013
         CLI   LCBCPA+40(RCORE),0 WAS THE LINE ACTIVE AT CHECK POINT    37100013
         BE    NOSTART            BRANCH IF LINE WAS NOT ACTIVE         37200013
         B     STOREECB           BRANCH IF LINE WAS ACTIVE             37300013
NORMAL   TM    0(RPARC),QTAMIDLE  IS THE LINE TO BE STARTED             37400013
         BNO   STOREECB           BRANCH IF LINE WILL BE STARTED        37500013
NOSTART  MVI   LCBCPA+32(RCORE),X'FE' SET NO START LINE CODE            37600013
*                                                                       37700013
*      STORE DUMMY ECB POINTER AND TEST FOR MORE LINES                  37800013
*                                                                       37900013
STOREECB LA    RJ,LCBCPA+36(RCORE) ADDRESS OF THE DUMMY ECB             38000013
         ST    RJ,IOBECBPT        STORE FOR IOS                         38100013
         ALR   RCORE,RB           ADDRESS FO THE NEXT LCB               38200013
         LA    RD,4(RD)           UP DATA THE UCB ADDRESS POINTER       38300013
         BCT   RC,NEXTLINE        BRANCH IF MORE LINES                  38400013
*                                                                       38500013
*      PREPARE REGISTERS FOR NEXT LOAD OF OPEN                          38600013
*                                                                       38700013
         SR    RD,RD                                                    38800013
         IC    RD,DEBNMEXT        LOAD NUMBER OF UCB'S                  38900013
         SLL   RD,2               ACTUAL SIZE OF THE UCB FIELD          39000013
         LA    RUCB,DEBUCBAD(RD)  ADDRESS OF ACCESS METHOD DEP. SECTION 39100013
         SR    RD,RD                                                    39200013
         IC    RD,DEBAMLNG                                              39300013
         AR    RUCB,RD            ADDRESS OF SUB ROUTINE ID SECTION     39400013
         SR    RD,RD              ZERO RD FOR THIRD LOAD                39500013
*                                                                       39600013
*      EXIT TO THE NEXT LOAD OF OPEN IGG0193T                           39700013
*                                                                       39800013
ENDLOD2  MVC   0(5,RWTGC),QTAMLOD3 SET UP ID FOR LOAD 3 OF OTAM         39900013
*                                  EXECUTOR.                            40000013
         L     RJ,4(RWTGC)              LOAD ADDRESS OF WORK AREA.      40100013
         STM   9,15,0(RJ)          SAVE REGESTERS FOR LOAD 2            40200013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURRENT WTG REGISTER. 40300013
         LA    RPARC,PLOFF(0,RPARC)     INCREMENT CURRENT PARAMETER     40400013
*                                  LIST REGISTER TO NEXT ENTRY.         40500013
         CLC   0(2,RWTGC),AMIDCNST      IF THE NEXT WTG ENTRY CALLS FOR 40600013
         BCR   8,RBASE             THIS EXECUTOR, RETURN TO BEGINNING.  40700013
         CLC   0(2,RWTGC),OPIDCNST      IF NOT, TEST FOR END OF TABLE.  40800013
         BNE   RELOOP              NOT END OF TABLE, RETURN TO CHECK    40900013
*                                  NEXT ENTRY.                          41000013
         LR    RPARC,RPAR               REINITIALIZE CURRENT WTG REG    41100013
         LA    RWTGC,WAOFF(0,RWTG) AND CURRENT PARAMETER LIST REG.      41200013
ZCHECK   CLI   0(RWTGC),X'00'                                           41300013
         BNE   XCTLRTNE            IF NOT ZERO, GO TO TRANSFER CONTROL  41400013
         LA    RWTGC,WGOFF(0,RWTGC) IF ZERO, GET NEXT ENTRY AND RETURN  41500013
         LA    RPARC,PLOFF(0,RPARC) TO ZCHECK.                          41600013
         B     ZCHECK                                                   41700013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 41800013
XCTLRTNE EQU   *                                                        41900013
         LA    RJ,DXCCW12(RJ)           POINT TO DOUBLE WORD LIST.      42000013
         MVC   6(2,RWTG),0(RWTGC)       MOVE ID TO NAME FIELD.          42100013
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR TO WTG TABLE.          42200013
         XCTL  DE=(RWTG),SF=(E,(15))                                    42300013
*    *    1050 AND 2740      *    *    *    *    *    *    *    *    *  42400013
SZTABLE  DC    HL1'72'                 1050R                            42500013
         DC    HL1'96'                 1050AP                           42600013
         DC    HL1'96'                 1050A                            42700013
         DC    HL1'96'                 1050AA                           42800013
         DC    HL1'96'                 1050AC                           42900013
         DC    HL1'80'                 2740 REGULAR                     43000013
         DC    HL1'80'                 2740 A                           43100013
         DC    HL1'80'                 2740 AA                          43200013
         DC    HL1'80'                 2740 AC                          43300013
         DC    HL1'88'                  2740 CCKAX                 000A 43400015
         DC    HL1'80'                 2740 CAAX                        43500013
         DC    HL1'88'                  2740 ACCHX                 000A 43600015
         DC    HL1'80'                 2740 AX                          43700013
         DC    HL1'80'                 2740 AAX                         43800013
         DC    HL1'88'                  ACX                        000A 43900015
         DC    HL1'80'                 2740 CCKA                        44000013
         DC    HL1'80'                 2740 CKAA                        44100013
         DC    HL1'80'                 2740 ACCK                        44200013
         DC    HL1'96'                 2740 APCS                        44300013
         DC    HL1'80'                 2740 CKS                         44400013
         DC    HL1'96'                 2740 APS                         44500013
         DC    HL1'80'                 2740 SC                          44600013
         DC    HL1'80'                 2740 CK                          44700013
*    *    OTHER IBM1         *    *    *    *    *    *    *    *    *  44800013
         DC    HL1'72'                 1060R                            44900013
         DC    HL1'96'                 1060 AP                          45000013
*    *    IBM2     *    *    *    *    *    *    *    *    *    *    *  45100013
         DC    HL1'80'                 1030R                            45200013
         DC    HL1'96'                 1030AP                           45300013
*    *    TEL1     *    *    *    *    *    *    *    *    *    *    *  45400013
         DC    HL1'72'                 83B3R                            45500013
         DC    HL1'72'                 83B3TT                           45600013
         DC    HL1'72'                 115A REGULAR                     45700013
         DC    HL1'72'                 115ATT                           45800013
*    *    TEL2     *    *    *    *    *    *    *    *    *    *    *  45900013
         DC    HL1'72'                 TWXA                             46000013
         DC    HL1'72'                 TWXAA                            46100013
         DC    HL1'72'                 TWXAC                            46200013
*    *    IBM3     *    *    *    *    *    *    *    *    *    *    *  46300013
         DC    HL1'80'                 2260 REGULAR                     46400013
*    *    WORLD TRADE TELETYPR                                     000C 46430017
         DC    HL1'64'                 WTTA                        000C 46460017
CLEAR    XC    0(1,RCORE),0(RCORE)                                      46500013
ONE12    DC    H'112'                                              000D 46600018
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 46700013
LAST2740 EQU   X'16'              NOTE 1050 AND 2740 CODES (0-16) ARE   46800013
CDIBM1   EQU   LAST2740+1               DEFINED ABOVE IN FETAB          46900013
CDIBM2   EQU   CDIBM1+2                                                 47000013
CDTEL1   EQU   CDIBM2+2                                                 47100013
CDTEL2   EQU   CDTEL1+4                                                 47200013
CDIBM3   EQU   CDTEL2+3                                                 47300013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 47400013
DEVATT   EQU   X'01'                                                    47500013
DEVWU    EQU   X'02'                                                    47600013
DEVTWX   EQU   X'01'                                                    47700013
DEV2260  EQU   X'01'                                                    47800013
*                                          OPTIONAL FEATURES BYTE CODES 47900013
REGMASK  EQU   X'FC'                                                    48000013
AMASK    EQU   X'90'                                                    48100013
ACMASK   EQU   X'80'                                                    48200013
TTMASK   EQU   X'20'                                                    48300013
AAMASK   EQU   X'10'                                                    48400013
BREAK    DC    X'0D00000220040040'                                      48500013
READSKIP DC    X'020000023008FFFF'                                      48600013
         DS    0F                                                       48700013
IOBPOOL  DC    X'FA000000'              SUBPOOL NUMBER FOR IOB          48800013
ERR2     DC    X'80092000'                                              48900013
ERR3     DC    X'80093000'                                              49000013
ERR4     DC    X'80094000'                                              49100013
ANDMASK  DC    X'00000003'                                              49200013
SADENNOP DC    X'20000001'                                              49300013
SADCCODE DC    X'13'                   SADZER CODE                      49400013
         DC    X'17'                   SADONE CODE                      49500013
         DC    X'1B'                   SADTWO CODE                      49600013
         DC    X'1F'                   SADTHREE CODE                    49700013
WAOFF    EQU   32                       OFFSET OF FIRST WTG ENTRY FROM  49800013
*                                  START OF WTG.                        49900013
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES.          50000013
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES.          50100013
         DS    0H                                                       50200013
ERPMINSZ DC    AL2(ERPMIN)                                              50300013
OPIDCNST DC    C'0S'                    ID OF LAST OPEN LOAD.           50400013
AMIDCNST DC    C'3R'          ID OF THIS MODULE                         50500013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 50600013
NENT     EQU   1                       NUMBER OF IDTTR'S                50700013
LENGTH   EQU   NENT*6+6                LENGTH OF IDTTR'S+2+4            50800013
NODBWDS  EQU   (LENGTH+7)/8            NO OF DBL WDS W/ PADDING         50900013
ORGIDTTR EQU   1024-NODBWDS*8          START OF IDTTR LIST              51000013
         ORG   IGG0193R+ORGIDTTR                                        51100013
QTAMLOD3 DC    C'3T'              ID FOR THIRD LOAD OF QTAM OPEN        51200013
         DC    X'00000000'             TTR AND L                        51300013
         SPACE 1                                                        51400013
IDEND    DC    X'0000'                  END OF IDTTRL TABLE.            51500013
         SPACE 1                                                        51600013
         CNOP  4,8                     PADDING                          51700013
LOADID   DC    C'019'                  OPEN SVC CODE                    51800013
         DC    YL1(X'80'-NODBWDS)                                       51900013
LCBCPA   EQU   96                                                       52000013
         DCBD  DSORG=CX,DEVD=WT                                    000C 52100017
         IECKQIOB                                                       52200013
        IECTDEBX                                                        52300013
         END                                                            52400013
