*********************************************************************** 00003021
*                                                                     * 00006021
* STATUS - CHANGE LEVEL=20        JANUARY 1971                        * 00009021
*                                                                     * 00012021
* FUNCTION-  THE SECOND LOAD OF THE DIRECT ACCESS OPEN RECEIVES       * 00015021
*    CONTROL THROUGH THE WHERE-TO-GO TABLE SET UP BY IGG0193O.  THE   * 00018021
*    TCB ADDRESS IS STORED AT DECIMAL 288 PAST THE LPS QUEUE IN MODULE* 00021021
*    IGG019NG.  THE HIGH ORDER BYTE IS SET TO X'FF' TO TURN ON THE    * 00024021
*    MASTER RECEIVE SWITCH.  THE MESSAGE PROCESSING PROGRAM CHAIN OF  * 00027021
*    DEB'S (292 PAST THE LPS QUEUE IN IGG019NG) IS ZEROED.  FOR EACH  * 00030021
*    TERMINAL TABLE ENTRY THAT IS NOT A DISTRIBUTION LIST, THE ROUTINE* 00033021
*    STORES THE ADDRESS OF THE DASD DESTINATION STCB (IECKMQ) IN THE  * 00036021
*    LINK FIELD AND PRIORITY IN THE SEND SCHEDULER OF THE QCB.  IF THE* 00039021
*    QCB IS FOR A PROCESS QUEUE THE DASD DESTINATION STCB ADDRESS IS  * 00042021
*    SET IN THE CHAIN POINTER OF THE STCB.  THE NEXT AVAILABLE RECORD * 00045021
*    ON THE DISK IS OBTAINED BY ADDING ONE TO THE VALUE ASSIGNED TO   * 00048021
*    THE LAST PROCESSED QCB.  THIS RELATIVE RECORD NUMBER IS STORED AT* 00051021
*    LABEL 'ADDRESS' IN MODULE IGG019NG.  THE ADDRESS OF THE FIRST    * 00054021
*    BUFFER IS STORED IN THE AVAILABLE BUFFER QCB TO START THE CHAIN. * 00057021
*    THE ADDRESS OF THE IOB FOR THE DISK, WHICH IS IN MODULE IGG019NG,* 00060021
*    IS STORED IN THE DCB FOR THE DISK,AND THE ADDRESS OF THE DISK DCB* 00063021
*    IS STORED IN THE IOB.  THE BUFFER SIZE IS STORED IN THE DISK CCW * 00066021
*    IN IGG019NG.  THE APPENDAGE LIST ADDRESS IS STORED IN THE DEB.   * 00069021
*    THIRTY-TWO BYTES, AFTER THE RECB, OF EACH BUFFER IS ZEROED.  A   * 00072021
*    SUBROUTINE, WITH ASSOCIATED RECB/STCB IN THIS ROUTINE, IS MOVED  * 00075021
*    INTO THE OPEN WORK AREA.  THE RECB IS QPOSTED TO ITSELF TO CAUSE * 00078021
*    THE SUBROUTINE TO BE ACTIVATED.  THE SUBROUTINE OBTAINS THE      * 00081021
*    ADDRESS OF IECKQQ01 ( OBTAINED FROM THE BASE REGISTER SET UP AS A* 00084021
*    RESULT OF THE QPOST) AND STORES THE ADDRESS IN 'QQPTR' IN MODULE * 00087021
*    IGG019NG.                                                        * 00090021
*         IF THE DSCBS IN THE CHAIN HAVE NOT BEEN FREED, A FREEMAIN IS* 00093021
*    ISSUED FOR EACH DSCB IN THE CHAIN.  THE CORE POINTER IN THE LAST * 00096021
*    DSCB OF THE FIRST VOLUME IS ZEROED.                              * 00099021
*         IF OPERATOR CONTROL HAS BEEN SPECIFIED IN THE TERMINAL TABLE* 00102021
*    AN ADDRESS CONSTANT IN THE IMPLEMENTATION MODULE IS CHANGED      * 00105021
*    FROM THE ADDRESS OF THE BUFFER RECALL/CLEANUP ROUTINE (IECKPR) TO* 00108021
*    THE ADDRESS OF OPERATOR AWARENESS ROUTINE.                       * 00111021
*         FOR ALL ENTRIES IN THE TERMINAL TABLE, THE POLLING LIST IS  * 00114021
*    EXAMINED. IF AN AUTOPOLL POLLING LIST (X'FF' THE STOP SCAN BYTE  * 00117021
*    IS FOUND), THE POLLING CHARACTERS AND INDEX BYTE, REPLACES THE   * 00120021
*    OFFSET VALUE IN THE POLLING LIST.  THE 7TH BIT OF THE 4TH BYTE OF* 00123021
*    THE LIST IS ZEROED TO INDICATE LIST HAS BEEN CONVERTED.          * 00126021
*         IF THE WHERE-TO-GO TABLE INDICATES THAT THIS ROUTINE IS RE- * 00129021
*    QUIRED AGAIN, THE PROGRAM IS ABNORMALLY ENDED (713 ABEND)        * 00132021
*    BECAUSE THERE IS ONLY ONE DCB FOR THE DIRECT ACCESS DEVICE FOR   * 00135021
*    MESSAGE QUEUES.                                                  * 00138021
*                                                                     * 00141021
* ENTRY POINTS- ENTRY WILL BE MADE TO THE FIRST BYTE OF THE MODULE BY * 00144021
*         AN 'XCTL' TO IGG0193U AS SPECIFIED BY IGG0193O, THE FIRST   * 00147021
*    LOAD OF OPEN.                                                    * 00150021
*                                                                     * 00153021
* INPUT-                                                              * 00156021
*    5- ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST          * 00159021
*    6- ADDRESS OF THE BEGINNING OF THE WHERE-TO-GO TABLE             * 00162021
*    7- ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00165021
*    8- ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO    * 00168021
*       TABLE.                                                        * 00171021
*                                                                     * 00174021
* OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES IN* 00177021
*    THE DCB PARAMETER LIST AND THE WHERE-TO-GO TABLE.                * 00180021
*                                                                     * 00183021
* EXTERNAL REFERENCES- NONE                                           * 00186021
*                                                                     * 00189021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA AN XCTL TO THE NEXT NON-ZERO  * 00192021
*    ENTRY IN THE WHERE-TO-GO TABLE.                                  * 00195021
*                                                                     * 00198021
* EXITS,ERROR- THIS ROUTINE EXITS VIA A 713 ABEND IF MORE THAN ONE    * 00201021
*    MESSAGE QUEUES DATA SET IS OPENED.                               * 00204021
*                                                                     * 00207021
* TABLES/WORK AREAS-                                                  * 00210021
*    1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED * 00213021
*    IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO TABLE CONTAINS * 00216021
*    THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE DCB. 3. THE  * 00219021
*    WHERE-TO-GO TABLE POINTS TO A WORK AREA IN WHICH REGISTERS 9-15  * 00222021
*    ARE PASSED TO AND FROM THIS ROUTINE.                             * 00225021
*                                                                     * 00228021
* ATTRIBUTES-  RE-ENTRANT AND PRIVILEGED.                             * 00231021
*                                                                     * 00234021
* CHARACTER CODE DEPENDENCY- NONE                                     * 00237021
*                                                                     * 00240021
* NOTES- NONE                                                         * 00243021
*                                                                     * 00246021
*********************************************************************** 00249021
         TITLE ' IGG0193U- QTAM OPEN DIRECT ACCESS LOAD 2 '             00300013
IGG0193U START                                                          00600013
*3190191000-195000                                                 000A 00700015
*3190237000                                                        00PS 00800015
*2010202000                                                        8059 00850016
*                                                                       00900013
*3411300600-302400                                                19562 01000017
* 625000-632000                                                  A29210 01100020
*C707000-711000                                                  A39111 01130021
*D774000                                                         A39111 01160021
*A000030-002490                                                  S21016 01180021
*D351000,A355000                                                 A59594 01190021
*      REGISTER USAGE                                                   01200013
*                                                                       01500013
RE       EQU   0                                                        01800013
RF       EQU   1                                                        02100013
RDCB     EQU   2                  DCB ADDRESS                           02400013
RBASE    EQU   3                  BASE REGISTER                         02700013
RCORE    EQU   4                  WORK AREA ADDRESS                     03000013
RPAR     EQU   5                  PARAMETER LIST ADDRESS                03300013
RWTG     EQU   6                  FRONT OF WHERE-TO-GO TABLE (WTG)      03600013
RPARC    EQU   7                  CURRENT ENTRY IN PARAMETER LIST       03900013
RWTGC    EQU   8                  CURRENT ENTRY IN WHERE-TO-GO TABLE    04200013
R9       EQU   9                  WORK REGISTER                         04500013
RUCB     EQU   10                                                       04800013
RDEB     EQU   11                 DEB ADDRESS                           05100013
RB       EQU   12                                                       05400013
RC       EQU   13                                                       05700013
RD       EQU   14                                                       06000013
RJ       EQU   15                                                       06300013
*                                                                       06600013
*                                                                       06900013
TTQUES   EQU   4                                                        07200013
CVT      EQU   16                                                       07500013
IOBDCBPR EQU   20                                                       07800013
CCWAD    EQU   40                                                       08100013
APVECT   EQU   24                                                       08400013
FMAT3EX  EQU   44                                                       08700013
QPOST    EQU   67                                                       09000013
DISKIOB  EQU   92                                                       09300013
FMAT1LN  EQU   104                                                      09600013
FMAT3LN  EQU   144                                                      09900013
TERM     EQU   156                                                      10200013
NASEG    EQU   196                                                      10500013
DISPATCH EQU   X'F8'                                                    10800013
TTBAS    EQU   249                                                      11100013
GETRET   EQU   280                                                      11400013
ADCON    EQU   320                                                      11700013
*                                                                       12000013
         USING IHADCB,RDCB                                              12300013
         USING IECTDEB+36,RDEB                                          12600013
         USING FORCORE,RCORE                                            12900013
         BALR  RBASE,0                                                  13200013
         USING *,RBASE                                                  13500013
         L     RCORE,4(RWTGC)     LOAD ADDRESS OF THE WORK AREA         13800013
         L     RDCB,0(RPARC)      LOAD THE DCB ADDRESS                  14100013
         L     RDEB,DCBDEBAD      ADDRESS OF THE DEB                    14400013
         L     RD,CVT             ADDRESS OF THE CVT                    14700013
         L     RC,TERM(RD)        ADDRESS OF THE TERM TABLE             15000013
         L     RF,TTQUES(RC)      ADDRESS OF MODULE IGG019NG            15300013
         L     RF,0(RF)                RF NOW HAS ADDRESS OF LPS QUEUE  15600013
         L     RB,0(RD)           TCB LIST POINTER                      15900013
         L     RB,4(RB)           CURRENT TCB ADDRESS                   16200013
         ST    RB,288(RF)         MSGCTL TCB ADDRESS TO IGG019NG        16500013
         MVI   288(RF),X'FF'      SET PRIORITY AND MASTER RECEIVE SW.   16800013
         XC    292(4,RF),292(RF)  ZERO MSG PROCESSING DEB CHAIN         17100013
         L     RE,208(0,RF)        GET MESSAGE QUEUE ADDRESS IN RE      17400013
         LA    RB,8(RC)                ADDRESS OF FIRST TERM ENTRY      17700013
QLOOP    L     R9,0(0,RB)          GET ADDRESS OF QCB FOR FIRST ENTRY   18000013
         CLI   8(R9),X'02'         IS IT A DISTRIBUTION LIST            18300013
         BE    DISTLST             BRANCH IF DISTRIBUTION LIST          18600013
         LR    RF,R9               GET ADDR OF QCB FOR FIRST ENTRY      18900013
         IC    R9,12(RF)          SAVE PRIORITY FROM QCB           000A 19100015
         ST    RE,12(RF)     STORE MESSAGE QUEUE ADDRESS IN QCB    000A 19300015
         STC   R9,12(RF)          RESTORE PRIORITY IN QCB          000A 19500015
         BH    DISTLST                                                  19800013
         ST    RE,8(0,RF)                                               20100013
         MVI   8(RF),X'00'         SET OFFSET TO ZERO              8059 20200016
DISTLST  EQU   *                                                        20400013
         SR    R9,R9               CLEAR R9                             20700013
         CL    RB,0(RC)                LAST ENTRY IN TERM TABLE         21000013
         BNL   OUT                 IF LAST CONTINUE                     21300013
         IC    R9,0(0,RB)          PREPARE TO LOOK AT NEXT ENTRY        21600013
         LA    RB,0(R9,RB)         BUMP TO NEXT ENTRY IN TERMTBL        21900013
         B     QLOOP               RELOOP                               22200013
*                                                                       22500013
*      COMPUTE NEXT AVAILABLE RECORD ON THE DISK                        22800013
*                                                                       23100013
OUT      LH    R9,2(RF)           LOAD QUEUE NUMBER LAST PROCESSED Q    23400013
         LA    RF,1(R9)           ADD ONE AND LOAD RF              00PS 23700015
         L     RC,TTQUES(RC)           ADDRESS OF IGG019NG              24000013
         L     RC,0(0,RC)          GET ADDR OF LPS QUEUE FROM IGG019NG  24300013
         LR    RJ,RC                   SAVE POINTER TO LPS QUEUE IN THE 24600013
*                                         QTAM IMPLEMENTATION MODULE    24900013
         MVC   TTBAS(3,RC),DCBBUFCB+1                                   25200013
         ST    RF,NASEG(0,RC)      STORE RELATIVE RECORD NUMBER IN      25500013
*                                     ADDRESS OF NEXT AVAILABLE SEGMENT 25800013
         MVC   49(3,RC),DCBEODAD+1    MOVE IECKRQ ADDRESS TO QUEUE      26100013
         L     RF,DCBEODAD         GET ADDRESS OF AVRQ                  26400013
         LH    RE,16(0,RF)         GET BUFFER SIZE                      26700013
         L     RF,0(0,RF)          GET ADDRESS OF BUFFER                27000013
         ST    RF,24(0,RC)         STORE ADDRESS OF IECKBUFF IN QUEUE   27300013
         MVI   24(RC),1            RESTORE CODE                         27600013
         LA    RC,DISKIOB(0,RC)    INCREMENT TO IOB ADDRESS             27900013
         ST    RC,DCBIOBAD         STORE IOB ADDR IN DCB                28200013
         ST    RDCB,IOBDCBPR(0,RC) STORE DCB ADDR IN IOB                28500013
         LA    RC,CCWAD(0,RC)      INCREMENT TO CCW LIST                28800013
         STH   RE,22(0,RC)                                              29100013
         LA    RC,APVECT(0,RC)     INCREMENT TO ADDR OF APPENDAGE LIST  29400013
         ST    RC,DEBAPPAD-1       STORE APPENDAGE LIST ADDRESS IN DEB  29700013
         MVI   DEBEXSCL,4         SET EXTENT SCALE IN THE DEB           30000013
CLEARBUF XC    8(32,RF),8(RF)      CLEAR OUT BUFFER PREFIX        19562 30060017
         L     RF,4(RF)            GET NEXT BUFFER ADDRESS        19562 30120017
         CLI   4(RF),X'FF'         IS IT DUMMY END ELEMENT        19562 30180017
         BNE   CLEARBUF            BRANCH NO TO CLEAR PREFIX      19562 30240017
*                                                                       30300013
*      EXECUTE SUBTASK TO CAUSE QQ01 BASE TO BE STORED IN IGG019NG      30600013
*                                                                       30900013
         MVC   DXCCW1+4(30),SUBTASK MOVE SUBTASK TO THE OPEN WORK AREA  31200013
         LA    RB,DXCCW1+8        COMPUT THE STCB ADDRESS               31500013
         ST    RB,DXCCW1+8        STORE THE STCB ADDRESS                31800013
         MVI   DXCCW1+8,2         MOVE IN STCB RETURN CODE              32100013
         LA    RF,DXCCW1          LOAD ELEMENT ADDRESS FOR POST         32400013
         LR    RDCB,RF            COPY ADDRESS FOR POST                 32700013
         SVC   QPOST                                                    33000013
*                                                                       33300013
*      FREE CORE FOR ALL SECONDARY DSCB'S                               33600013
*                                                                       33900013
         SR    RC,RC              ZERO THE FORMAT 3 INDEX               34200013
         LR    RB,RBASE           SET THE FIRST TIME SWITCH             34500013
STILLFST LR    R9,RCORE           SAVE ADDRESS OF THIS DSCB             34800013
         L     RCORE,DSCCORE(RC)  POINTER TO THE NEXT DSCB              35400013
         LTR   RCORE,RCORE         TEST FOR END OF DSCB CHAIN    A59594 35500021
         BZ    ALLFREE            BRANCH IF END-ALL DSCB'S FREE         35700013
NEXTDSCB SR    RC,RC              ZERO THE FORMAT 3 INDEX               36000013
         LA    RE,FMAT1LN         LOAD LENGTH OF FORMAT 1 DSCB          36300013
         CLI   DSCFMTID,C'1'      TEST FOR FORMAT 1 DSCB                36600013
         BE    FORMAT1            BRANCH IF FORMAT 1                    36900013
         LA    RE,FMAT3LN         LENGTH OF A FORMAT 3 DSCB             37200013
         LA    RC,FMAT3EX         SET THE FORMAT 3 INDEX                37500013
         LTR   RB,RB              TEST THE FIRST TIME SWITCH            37800013
         BNZ   STILLFST           BRANCH STILL FIRST SET OF DSCB'S      38100013
FORMAT1  SR    RB,RB              ZERO THE FIRST TIME SWITCH            38400013
         LR    RF,RCORE           COPY ADDRESS FOR FREE MAIN            38700013
         L     RCORE,DSCCORE(RC)  LOAD POINTER TO THE NEXT DSCB         39000013
         FREEMAIN R,LV=(0),A=(1)                                        39300013
         LTR   RCORE,RCORE        TEST FOR END OF THE DSCB CHAIN        39600013
         BNZ   NEXTDSCB           BRANCH NOT END OF CHAIN               39900013
*                                                                       40200013
*      ZERO POINTER IN LAST DSCB OF THE FIRST VOLUME                    40500013
*                                                                       40800013
ALLFREE  L     RJ,4(RWTGC)        POINTER TO THE FIRST DSCB             41100013
         SR    RF,RF              ZERO THE FORMAT 3 INDEX               41400013
         SR    RB,RB                                                    41700013
         LR    RCORE,R9           ADDRESS OF LAST DSCB FOR FIRST VOLUME 42000013
         CLI   DSCFMTID,C'1'      IS THIS A FORMAT 1 DSCB               42300013
         BE    ONE                BRANCH IF FORMAT 1                    42600013
         LA    RF,FMAT3EX         SET THE FORMAT 3 INDEX                42900013
ONE      ST    RB,DSCCORE(RF)     ZERO DSCB CORE POINTER                43200013
         LR    RCORE,RJ           REST POINTER TO THE WORK AREA         43500013
         L     RB,CVT              GET CVT ADDRESS                      43800013
         L     RB,TERM(RB)         GET TERMTBL ADDRESS                  44100013
         SH    RB,FOUR             GET ADDRESS OF TERMTBL-4             44400013
         L     RC,0(RB)            GET ADDRESS OF OPCTL MACRO           44700013
         LA    RC,0(RC)            CLEAR HIGH ORDER BYTE                45000013
         LTR   RC,RC               IS OPERATOR CONTROL SPECIFIED        45300013
         BZ    NOOPCTL             IF NOT, DON'T CHANGE ADCON IN NG     45600013
         L     RB,8(RB)            GET ADDRESS OF IGG019NG              45900013
         L     RB,0(RB)            GET ADDRESS OF LPS PORTION           46200013
         MVC   ADCON(4,RB),4(RC)   CHANGE ADCON FROM A(IECKPR) TO       46500013
*                                     A(IECKOPAW)                       46800013
NOOPCTL  EQU   *                                                        47100013
*                                                                       47400013
* THIS ROUTINE CONVERTS AUTOPOLL POLLING LISTS. AUTOPOLL POLLING LISTS  47700013
* GENERATED BY THE EXPANSION OF THE POLL MACRO CONTAIN OFFSETS OF THE   48000013
* TERM ENTRIES RELATIVE TO THE TERMINAL TABLE. THIS ROUTINE REPLACES    48300013
* THOSE OFFSETS WITH POLLING CHARACTERS AND SEQUENTIAL INDEX BYTES.     48600013
*                                                                       48900013
RGTTB    EQU   1                                                        49200013
RGTRM    EQU   2                                                        49500013
RGENT    EQU   9                                                        49800013
RGWK1    EQU   12                                                       50100013
RGWK2    EQU   13                                                       50400013
RGSIZ    EQU   14                                                       50700013
RGINX    EQU   15                                                       51000013
TRMTB    EQU   156                                                      51300013
QRLN     EQU   16                                                       51600013
QDCB     EQU   17                                                       51900013
QTRM8    EQU   8                                                        52200013
DCBCPOL  EQU   56                                                       52500013
*                                                                       52800013
* LOCATE FIRST ENTRY IN TERMINAL TABLE                                  53100013
*                                                                       53400013
AUTOPOLL L     RGTTB,16            LOAD ADDRESS OF CVT                  53700013
         L     RGTTB,TRMTB(RGTTB)  LOAD ADDRESS OF TERMINAL TABLE       54000013
         LA    RGTRM,8(RGTTB)      LOAD ADDRESS OF FIRST TERM ENTRY     54300013
         B     APN                                                      54600013
*                                                                       54900013
* GET NEXT TERM ENTRY AND TEST FOR END                                  55200013
*                                                                       55500013
APNXTERM SR    RGWK1,RGWK1                                              55800013
         IC    RGWK1,0(RGTRM)      GET SIZE OF CURRENT ENTRY            56100013
         AR    RGTRM,RGWK1         ADJUST RGTRM TO NEXT ENTRY           56400013
APN      C     RGTRM,0(RGTTB)      IS ADDRESS OF NEXT ENTRY GREATER     56700013
         BH    THRU                 THAN LAST. IF YES EXIT.             57000013
*                                                                       57300013
* OBTAIN ADDRESS OF POLLING LIST ASSOCIATED WITH TERM ENTRY             57600013
*                                                                       57900013
         L     RGWK1,0(RGTRM)      LOAD QCB ADDRESS                     58200013
         CLI   QTRM8(RGWK1),X'68'  IS THIS A DESTINATION QCB            58500013
         BNE   APNXTERM            IF NO GO TO NEXT TERM ENTRY          58800013
         SR    RGWK2,RGWK2                                              59100013
         IC    RGWK2,QRLN(RGWK1)   GET RELATIVE LINE NO FROM QCB        59400013
         SLA   RGWK2,2             MUTIPLY BY 4 TO GET RELATIVE OFFSET  59700013
*                                  TO DCBCPOLL                          60000013
         AL    RGWK2,QDCB-1(RGWK1) ADD ADDRESS OF DCB                   60300013
         L     RGENT,DCBCPOL-4(RGWK2) RGENT POINTS TO POLLING LIST      60600013
*                                  FOR THE TERMINAL POINTED TO BY RGTRM 60900013
*                                                                       61200013
* DETERMINE IF THIS IS AN AUTOPOLL POLLING LIST                         61500013
*                                                                       61800013
         SR    RGWK2,RGWK2                                              62100013
         IC    RGWK2,0(RGENT)      GET SIZE OF  POLLING LIST            62400013
         LR    RGINX,RGENT         GET STARTING ADDRESS FOR SCAN A29210 62500020
SCAN     CLI   0(RGINX),X'FE'      TEST FOR SCAN STOP BYTE       A29210 62600020
         BE    CONVERT             FOUND, GO TO CONVERT LIST     A29210 62700020
         LA    RGINX,1(RGINX)      BUMP TO NEXT BYTE IN LIST     A29210 62800020
         BCT   RGWK2,SCAN          GO SCAN NEXT BYTE             A29210 62900020
         B     APNXTERM            NOT AUTOPOLL, LOOK AT NEXT    A29210 63000020
*                                    TERMTABLE ENTRY             A29210 63100020
CONVERT  EQU   *                                                 A29210 63200020
*                                                                       63900013
* EXPANSION OF POLL MACRO SETS BIT 7 OF BYTE 4 OF AUTOPOLL POLLING LIST 64200013
* TO ONE.  WHEN LIST IS CONVERTED THE BIT IS TURNED OFF.                64500013
*                                                                       64800013
         TM    4(RGENT),X'01'      HAS THIS LIST BEEN CONVERTED         65100013
         BZ    APNXTERM            IF YES GO TO NEXT TERM ENTRY         65400013
         NI    4(RGENT),X'FE'      IF NO TURN OFF BIT                   65700013
*                                                                       66000013
* INITIALIZE FOR POLLING LIST CONVERSION AND TEST FOR COMPLETION        66300013
*                                                                       66600013
         LA    RGINX,1             SET INDEX VALUE TO ONE               66900013
         SR    RGSIZ,RGSIZ                                              67200013
         IC    RGSIZ,4(RGENT)      GET BYTE CONTAINING WIDTH OF POLLING 67500013
*                                  CHARACTER AND INDEX CHARACTER        67800013
         SRL   RGSIZ,5             SHIFT OUT OTHER INFO                 68100013
         BCTR  RGSIZ,0             DECREMENT BY ONE                     68400013
         LA    RGENT,5(RGENT)      SET RGENT TO FIRST OFFSET            68700013
*                                                                       69000013
APCONT   CLI   0(RGENT),X'FE'      TEST FOR SCAN STOP BYTE              69300013
         BE    APNXTERM            IF END GO TO NEXT TERM ENTRY         69600013
*                                                                       69900013
* REPLACE THE OFFSET TO THE TERM TABLE WITH THE TERMINALS POLLING CHARS 70200013
*                                                                       70500013
          IC   RGWK1,0(RGENT)     INSERT FIRST OFFSET ADDRESS    A39111 70700021
         SLL   RGWK1,8            SHIFT FOR SECOND BYTE          A39111 70900021
         IC    RGWK1,1(RGENT)     OFFSET TO TERMINAL ENTRY       A39111 71100021
         AR    RGWK1,RGTTB         ADD TERM TABLE BASE                  71400013
         SR    RGWK2,RGWK2                                              71700013
         IC    RGWK2,4(RGTTB)      PICK UP SIZE OF TERMINAL ID FIELD    72000013
         IC    RGWK2,9(RGWK2,RGWK1) GET OFFSET TO ADDRESSING CHARACTERS 72300013
         LA    RGWK1,2(RGWK1,RGWK2) INCREMENT BY 2 TO GET OFFSET TO     72600013
*                                  POLLING CHARACTERS                   72900013
         MVC   0(2,RGENT),0(RGWK1) MOVE POLLING CHARACTERS FROM         73200013
*                                  TERMINAL TABLE TO POLLING LIST       73500013
*                                                                       73800013
* STORE INDEX BYTE IN POLLING LIST                                      74100013
*                                                                       74400013
         STC   RGINX,0(RGENT,RGSIZ)                                     74700013
*                                                                       75000013
* INCREMENT REGISTERS FOR NEXT OFFSET CONVERSION                        75300013
*                                                                       75600013
         LA    RGINX,1(RGINX)      INCREMENT INDEX BY 1                 75900013
         LA    RGENT,1(RGENT,RGSIZ) ADD WIDTH TO ENTRY POINTER          76200013
         B     APCONT              CONTINUE                             76500013
*                                                                       76800013
HW3      DC    H'3'                                                     77100013
THRU     EQU   *                                                        77700013
*********************************************************************** 78000013
*                                                                     * 78300013
*      THIS IS AN OPEN PROVIDED SECTION OF CODE THAT SETS UP XCTL     * 78600013
*                                                                     * 78900013
*********************************************************************** 79200013
         XC    0(2,RWTGC),0(RWTGC) CLEAR TO INDICATE COMPLECTION        79500013
RELOOP   LA    RWTGC,WGOFF(RWTGC) INCREMENT CURRENT WTG ENTRY           79800013
         LA    RPARC,PLOFF(RPARC) INCREMENT CURRENT PARAMETER LIST ENT. 80100013
         CLC   0(2,RWTGC),AMIDCNST SAME EXECUTOR REQUIRED               80400013
         BC    7,NOABEND          NO GO CHECK FOR END OF TABLE          80700013
         L     1,ABCODE           LOAD ABEND CODE                       81000013
         ABEND (1)                                                      81300013
NOABEND  CLC   0(2,RWTGC),OPIDCNST END OF WTG TABLE                     81600013
         BC    7,RELOOP           NO GO CHECK NEXT ENTRY                81900013
         LR    RPARC,RPAR         RESET PARAMETER LIST ADDRESS          82200013
         LA    RWTGC,WAOFF(RWTG)  RESET WHERE-TO-GO TABLE POINTER       82500013
ZCHEK    CLI   0(RWTGC),0         IS THIS ENTRY ZERO                    82800013
         BC    7,XCTLRTN          NO BRANCH TO XCTL ROUTINE             83100013
         LA    RWTGC,WGOFF(RWTGC) ADDRESS OF THE NEXT ENTRY             83400013
         LA    RPARC,PLOFF(RPARC)                                       83700013
         BC    15,ZCHEK                                                 84000013
*                                                                       84300013
*      TRANSFER CONTROL TO THE NEXT EXECUTOR OF FIRST INCOMPLETE DCB    84600013
*                                                                       84900013
XCTLRTN  LA    RJ,DXCCW12                                               85200013
         MVC   6(2,RWTG),0(RWTGC) EXECUTOR ID TO PARAMETER LIST         85500013
         MVC   14(3,RWTG),2(RWTGC) TTR TO THE WHERE-TO-GO TABLE         85800013
         XCTL  DE=(RWTG),SF=(E,(15))                                    86100013
         DS    0F                                                       86400013
ABCODE   DC    X'00713000'                                              86700013
WAOFF    EQU   32                                                       87000013
PLOFF    EQU   4                                                        87300013
WGOFF    EQU   8                                                        87600013
OPIDCNST DC    C'0S'                                                    87900013
AMIDCNST DC    C'3U'                                                    88200013
FOUR     DC    H'4'                                                     88500013
         DS    0F                                                       88800013
SUBTASK  DC    X'FE'                                                    89100013
         DC    AL3(0)                                                   89400013
         DC    A(0)                                                     89700013
         DC    H'8'                                                     90000013
         L     RBASE,0(RC)        ADDRESS FO THE LPS QUEUE              90300013
         L     RBASE,GETRET(RBASE) GETRET ADDRESS IN IGG019NG           90600013
         SH    RBASE,4(RDCB)      BACK UP 8 BYTES TO QQPTR ADCON        90900013
         ST    RB,0(RBASE)        STORE QQ01 BASE IN IGG019NG           91200013
         B     DISPATCH-2(RB)     EXIT TO DISPATCH IN IECKQQ01          91500013
NENT     EQU   1                                                        91800013
LEN      EQU   NENT*6+6                                                 92100013
WDS      EQU   (LEN+7)/8                                                92400013
ORG      EQU   1024-WDS*8                                               92700013
         ORG   IGG0193U+ORG                                             93000013
         DC    C'NH'                                                    93300013
         DC    XL4'0000'                                                93600013
         DC    XL2'0000'                                                93900013
         CNOP  4,8                                                      94200013
LOADID   DC    C'019'                                                   94500013
         DC    YL1(X'80'-WDS)                                           94800013
         IECTDEBX                                                       95100013
         DCBD  DSORG=(CQ,DA)                                            95400013
FORCORE  DSECT                                                          95700013
         IECDSECT                                                       96000013
         END   IGG0193U                                                 96300013
