*********************************************************************** 00001021
*                                                                     * 00002021
* STATUS CHANGE LEVEL 13   JANUARY 1971                                 00003021
*                                                                     * 00004021
* FUNCTION- THE SIZE OF THE CHECKPOINT RECORDS IS CALCULATED.  THE    * 00005021
*    TERMINAL TABLE IS SCANNED TO ACCESS ALL THE CONTROL INFORMATION  * 00006021
*    TO BE COUNTED.  THE SIZE OF THE WORK AREA IS CALCULATED BY ADDING* 00007021
*    THE TOTAL SIZE OF THE TERMINAL TABLE, SIZE OF EACH POLLING LIST, * 00008021
*    11 BYTES FOR EACH DESTINATION QCB, 14 BYTES FOR EACH PROCESS QCB,* 00009021
*    11 BYTES FOR EACH LCB, AND 8 BYTES FOR CONTROL INFORMATION.      * 00010021
*    THE OFFSET TO EACH TYPE OF DATA IS SAVED IN THE CONSTANT AREA OF * 00011021
*    IGG019NH BY STORING THE TOTAL SIZE OF QUEUE AREA IN QOFF, POLL   * 00012021
*    LIST SIZE IN POLLOFF, AND LCB SIZE IN LCBOFF.  THE TOTAL CHECK-  * 00013021
*    POINT RECORD SIZE IS STORED IN CPSIZE.                           * 00014021
*         THE OPEN WORK AREA IS SET UP AS A CHANNEL PROGRAM AREA. IF  * 00015021
*    THE DISP OF THE CHECKPOINT DATA SET IS OLD, A RESTART IS IN      * 00016021
*    PROGRESS.  A SUBROUTINE IS EXECUTED TO READ A FOUR BYTE CONTROL  * 00017021
*    RECORD TO CHECK THE STATUS.  IF THE FIRST BYTE IS ZERO, QTAM WAS * 00018021
*    CLOSED PROPERLY, AND NO RESTART IS INITIATED.                    * 00019021
*         IF NON ZERO, A RESTART MUST BE PERFORMED.  A GETMAIN IS     * 00020021
*    ISSUED FOR THE CHECKPOINT AREA SIZE. THE CONTROL RECORD INDICATOR* 00021021
*    IS CHECKED TO DETERMINE WHICH CHECKPOINT RECORD IS MORE RECENT   * 00022021
*    ( 01 INDICATES FIRST, 02 INDICATES SECOND IS MORE RECENT).  IF   * 00023021
*    THE SECOND SET OF RECORDS IS NEEDED, THE TTR IS UPDATED BY NOPING* 00024021
*    THE READ AND CALCULATING THE TRACKS TO BE READ FOR THE FIRST READ* 00025021
*    THE CHECKPOINT RECORD IS READ FROM DISK INTO THE WORK AREA FROM  * 00026021
*    THE GETMAIN.  THE CHECKPOINTED DISK ADDRESS IS RESTORED IN THE   * 00027021
*    LOCATION LABELED 'ADDRESS' IN IGG019NG AND THE ERROR DATA QUEUE  * 00028021
*    IS RESTORED.  THE TERMINAL TABLE IS SCANNED TO RESTORE THE       * 00029021
*    TERMINAL TABLE ENTRIES, QUEUES, AND POLLING LIST.  THE FIRST 4   * 00030021
*    BYTES (SIZE-QCB ADDRESS) ARE NOT RESTORED SINCE THE QCB ADDRESS  * 00031021
*    COULD BE DIFFERENT FROM THE CHECKPOINT ADDRESS.  THE OFFSET FROM * 00032021
*    THE OLD QCB AREA TO THE NEW QCB AREA IS CALCULATED.  THIS OFFSET * 00033021
*    IS ADDED TO THE OLD QCB ADDRESS FOR EACH TERMINAL TABLE ENTRY TO * 00034021
*    OBTAIN THE NEW QCB ADDRESS.  THIS VALUE IS STORED IN THE TERMINAL* 00035021
*    TABLE ENTRY.  THE QCB FIELDS ARE THEN UPDATED.  FOR PROCESS QCBS,* 00036021
*    QLINK IS SET EQUAL TO QFAC.  IF THE DISK ADDRESS OF THE NEXT     * 00037021
*    MESSAGE TO COME OFF THE QUEUE(QFAC) IS GREATER THAN OR EQUAL TO  * 00038021
*    THE DISK ADDRESS OF THE NEXT MESSAGE TO GO ON THE QUEUE (QNAGSEG)* 00039021
*    QFAC IS SET BACK TO QNAGSEG TO RETRANSMIT THE MESSAGES. THE      * 00040021
*    POLLING LISTS ARE RESTORED WITH THE DATA RECORDED IN THE CHECK-  * 00041021
*    POINT DATA SET IF NOT PREVIOUSLY UPDATED.  RESTORING OF THE LCB  * 00042021
*    DATA IS DEFERRED UNTIL THE LINE GROUPS ARE OPENED BECAUSE THE    * 00043021
*    STORAGE FOR THE LCBS IS NOT OBTAINED UNTIL THAT TIME.  A CODE OF * 00044021
*    X'F2' IS SET IN THE TERMTBL FIELD IN THE CHECKPOINT MODULE       * 00045021
*    CONSTANT AREA TO INDICATE THAT A RESTART PROCEDURE HAS BEEN      * 00046021
*    INITIATED.                                                       * 00047021
*         IF THE DISPOSITION OF THE DATA SET WAS OLD BUT QTAM HAD BEEN* 00048021
*    PROPERLY CLOSED OR THE DISPOSITION OF THE DATA SET IS NEW, A FOUR* 00049021
*    BYTE CONTROL RECORD IS WRITTEN IN THE FIRST RECORD OF THE DATA   * 00050021
*    SET.  THE CHECKPOINT DATA SET IS FURTHER INITIALIZED BY WRITING  * 00051021
*    TWO COMPLETE DUMMY CHECK POINT RECORDS.                          * 00052021
*         THE CHECKPOINT INTERVAL OR NUMBER OF CKREQ MACROS           * 00053021
*    SPECIFIED IN THE TERMTBL MACRO IS STORED AT CPINT AND CHECKPOINT * 00054021
*    FLAGS IS STORED AT QCPADR IN THE CONSTANT AREA OF THE CHECKPOINT * 00055021
*    MODULE.                                                          * 00056021
*         A SUBROUTINE IN THE OPEN MODULE IS USED FOR ALL DISK READS  * 00057021
*    AND WRITES.  THE SKELTON CCWS ARE IN THE CONSTANT AREA OF        * 00058021
*    MODULE IGG019NH AND ARE MOVED INTO THE WTG WORKAREA.  THE        * 00059021
*    CONVERT ROUTINE, ACCESSED BY X'1C' INTO THE CVT, IS USED TO      * 00060021
*    CONVERT THE TTR TO THE ACTUAL DISK ADDRESS.  IF THE TTR IS       * 00061021
*    INVALID, AN 0A4 ABEND IS ISSUED.  THE DISK READ OR WRITE         * 00062021
*    OPERATION IS EXECUTED VIA AN EXCP/WAIT SEQUENCE USING AN IOB AND * 00063021
*    DECB IN THE CONSTANT AREA OF MODULE IGG019NH.  IF THE CHECKPOINT * 00064021
*    RECORD CANNOT BE CONTAINED IN A SINGLE TRACK, AS MANY EXCP/WAIT  * 00065021
*    SEQUENCES AS ARE NEEDED ARE ISSUED TO READ OR WRITE THE ENTIRE   * 00066021
*    LOGICAL RECORD.  IF A PERMANENT ERROR OCCURS, AN 0A4 ABEND IS    * 00067021
*    ISSUED.                                                          * 00068021
*         IF THE WHERE-TO-GO TABLE INDICATES THAT THIS ROUTINE IS     * 00069021
*    REQUIRED AGAIN, THE PROGRAM ISSUES A 713 ABEND BECAUSE THERE IS  * 00070021
*    ONLY ONE DCB FOR CHECKPOINT DATA SET.  NORMAL COMPLETION IS AN   * 00071021
*    XCTL TO THE NEXT NON-ZERO ENTRY IN THE WTG TABLE OF SYSTEM OPEN. * 00072021
*                                                                     * 00073021
* ENTRY POINTS- ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE BY AN   * 00074021
*         XCTL TO IGG0193V AS SPECIFIED BY IGG0193O WHEN A DD CARD    * 00075021
*         SPECIFIES 'TPCHKPNT'.                                       * 00076021
*                                                                     * 00077021
* INPUT-                                                              * 00078021
*    5- ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST          * 00079021
*    6- ADDRESS OF THE BEGINNING OF THE WHERE-TO-GO TABLE             * 00080021
*    7- ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00081021
*    8- ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO    * 00082021
*    0- ADDRESS OF LAST TERM TABLE ENTRY.                             * 00083021
*    1 - SIZE OF SAVE AREA FOR 1 QCB.                                 * 00084021
*    9- 0                                                             * 00085021
*    10- 0                                                            * 00086021
*    12- 0                                                            * 00087021
*    13- ADDRESS OF CHECKPOINT MODULE IGG019NH.                       * 00088021
*    14- ADDRESS OF TERMINAL TABLE.                                   * 00089021
*    15- SIZE OF SAVE AREA FOR 1 LCB.                                 * 00090021
*                                                                     * 00091021
* OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES IN* 00092021
*    THE DCB PARAMETER LIST AND THE WHERE-TO-GO TABLE.                * 00093021
*                                                                     * 00094021
* EXTERNAL REFERENCES- USES THE CONVERT ROUTINE VIA THE ADDRESS IN CVT* 00095021
*                                                                     * 00096021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA AN XCTL TO THE NEXT NON-ZERO  * 00097021
*    ENTRY IN THE WHERE-TO-GO TABLE.                                  * 00098021
*                                                                     * 00099021
* EXITS,ERROR- 713 ABEND IF MORE THAN ONE CHECKPOINT DATA SET IS TO   * 00100021
*    BE OPENED.                                                       * 00101021
*         0A4 ABEND FOR AN INVALID TTR OR PERMANENT DISK ERROR.       * 00102021
*                                                                     * 00103021
* TABLES/WORK AREAS-                                                  * 00104021
*    1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED * 00105021
*    IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO TABLE CONTAINS * 00106021
*    THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE DCB. 3. THE  * 00107021
*    WHERE-TO-GO TABLE POINTS TO A WORK AREA IN WHICH REGISTERS 9-15  * 00108021
*    ARE PASSED TO AND FROM THIS ROUTINE.  A CONSTANT AREA IN IGG019NH* 00109021
*    DESCRIBED BY A DSECT IN THIS ROUTINE.                            * 00110021
*                                                                     * 00111021
* ATTRIBUTES-  RE-ENTRANT AND PRIVILEGED.                             * 00112021
*                                                                     * 00113021
* CHARACTER CODE DEPENDENCY- NONE                                     * 00114021
*                                                                     * 00115021
* NOTES- NONE                                                         * 00116021
*                                                                     * 00117021
*********************************************************************** 00118021
         TITLE ' QTAM OPEN CHECK-POINT DATA SET '                       00200013
IGG0193V START                                                          00400013
*                                                                       00600013
*A000010-001200                                                  S21016 00700021
*      REGISTER USAGE                                                   00800013
*                                                                       01000013
R0       EQU   0                  WORK REGISTER                         01200013
R1       EQU   1                  WORK REGISTER                         01400013
RDCB     EQU   2                  DCB ADDRESS                           01600013
RBASE    EQU   3                  BASE REGISTER                         01800013
RCORE    EQU   4                  WORK AREA ADDRESS                     02000013
RPAR     EQU   5                  PARAMETER LIST ADDRESS                02200013
RWTG     EQU   6                  FRONT OF WHERE-TO-GO TABLE (WTG)      02400013
RPARC    EQU   7                  CURRENT ENTRY IN PARAMETER LIST       02600013
RWTGC    EQU   8                  CURRENT ENTRY IN WHERE-TO-GO TABLE    02800013
R9       EQU   9                  WORK REGISTER                         03000013
RA       EQU   10                 WORK REGISTER                         03200013
RDEB     EQU   11                 DEB ADDRESS                           03400013
RC       EQU   12                 WORK REGISTER                         03600013
RD       EQU   13                 WORK REGISTER                         03800013
RE       EQU   14                 WORK REGISTER                         04000013
RF       EQU   15                 WORK REGISTER                         04200013
EXCP     EQU   0                                                        04400013
WAIT     EQU   1                                                        04600013
OLDQUE   EQU   4                                                        04800013
IOERR    EQU   8                                                        05000013
QRET     EQU   8                                                        05200013
LCBLEN   EQU   11                                                       05400013
QLEN     EQU   11                                                       05600013
QDCBA    EQU   16                                                       05800013
QRLNN    EQU   16                                                       06000013
RW       EQU   16                                                       06200013
RD1      EQU   16                                                       06400013
WRT2     EQU   24                                                       06600013
WRT2S    EQU   28                                                       06800013
CONVERT  EQU   28                                                       07000013
WCKDS    EQU   32                                                       07200013
RSAVE    EQU   40                                                       07400013
DCBPLPTR EQU   52                                                       07600013
CVTTRMTB EQU   156                                                      07800013
JFCBINDX EQU   187                                                      08000013
QCPADR   EQU   304                                                      08200013
*                                                                       08400013
*                                                                       08600013
*                                                                       08800013
         USING IHADCB,RDCB                                              09000013
         USING IECTDEB,RDEB                                             09200013
         USING FORCORE,RCORE                                            09400013
         USING IGG019NH,RD                                              09600013
         USING QBLOCK,RF                                                09800013
         BALR  RBASE,0                                                  10000013
         USING *,RBASE                                                  10200013
*                                                                       10400013
*      LOAD REGISTERS PASSED FROM LOAD 1 AS FOLLOWS                     10600013
*                                                                       10800013
*                R0      = ADDRESS OF LAST TERM TABLE ENTRY             11000013
*                RD      = ADDRESS OF THE CHECKPOINT MODULE (IGG019NH)  11200013
*                RE      = ADDRESS OF THE TERMINAL TABLE                11400013
*                RDEB    = ADDRESS OF THE CORRECT DADT ENTRY            11600013
*                R9      = 0                                            11800013
*                RA      = 0                                            12000013
*                RC      = 0                                            12200013
*                RF      = SIZE OF SAVE AREA FOR 1 LCB                  12400013
*                R1 =    = SIZE OF SAVE AREA FOR 1 QCB                  12600013
*                                                                       12800013
         L     RCORE,4(RWTGC)     LOAD ADDRESS OF THE WORK AREA         13000013
         LM    9,1,0(RCORE)       LOAD REGISTERS FROM THE LAST LOAD     13200013
*                                                                       13400013
*      COMPUTE SIZE OF THE CHECK-POINT RECORDS                          13600013
*                                                                       13800013
TERMLOOP L     RDCB,8(RE)         LOAD NEXT QUEUE ADDRESS               14000013
         LA    RDCB,0(RDCB)       CLEAR THE HIGH ORDER BYTE             14200013
         CLI   QRET(RDCB),X'02'   TEST QUEUE TYPE FOR DISTRIBUTION LIST 14400013
         BE    SAMEQUE            BRANCH IF DIST. LIST                  14600013
         OC    QUEUEST(4),QUEUEST  HAS THE FIRST QUEUE ADDR. BEEN SAVED 14800013
         BNZ   *+8                BRANCH IF ALREADY SAVED               15000013
         ST    RDCB,QUEUEST       STORE ADDRESS OF THE FIRST QUEUE      15200013
         CR    RDCB,RC            COMPARE TO LAST QUEUE ADDRESS         15400013
         LR    RC,RDCB            SAVE QUEUE ADDRESS AS LAST QUEUE      15600013
         BE    SAMEQUE            BRANCH NEW QUEUE SAME AS LAST         15800013
         LA    R1,QLEN+3(R1)      ADD SIZE FOR THIS QUEUE ASSUMING PROC 16000013
         CLI   QRET(RC),X'68'     TEST QUEUE TYPE FOR DESTINATION QUEUE 16200013
         BNE   SAMEQUE            BRANCH IF PROCESS QUEUE               16400013
         SH    R1,CON3            DESTINATION QUEUE SUB THREE           16600013
         L     RDCB,QDCBA(RC)     LOAD ADDRESS OF THE DCB FOR THIS Q    16800013
         IC    R9,QRLNN(RC)       LOAD THE RELATIVE LINE NUMBER         17000013
         SLL   R9,2               MULTIPLY LINE NUMBER BY FOUR          17200013
         LA    RDCB,DCBPLPTR(RDCB,R9) ADDRESS OF POLL POINTER FOR LINE  17400013
         SR    R9,R9              ZERO INDEX REGISTER AGAIN             17600013
         TM    0(RDCB),X'01'      TEST POLLING LIST COUNTED FLAG        17800013
         BO    SAMEQUE            BRANCH IF LIST HAD BEEN COUNTED       18000013
         OI    0(RDCB),X'01'      FLAG LIST AS HAS BEEN COUNTED         18200013
         LA    RF,LCBLEN(RF)      ADD SIZE FOR THIS LCB                 18400013
         L     RDCB,0(RDCB)       LOAD POLLING LIST ADDRESS             18600013
         IC    R9,0(RDCB)         LENGTH OF THIS POLLING LIST           18800013
         ALR   RA,R9              ADD TO CURRENT POLL SUM               19000013
         BCTR  RA,0               SUB ONE SIZE BTYE NOT SAVED           19200013
SAMEQUE  IC    R9,8(RE)           LENGTH OF THIS TERM ENTRY             19400013
         AR    RE,R9              INCREMENT TO NEXT TERM ENTRY          19600013
         CR    RE,R0              END OF TERM TABLE REACHED             19800013
         BNH   TERMLOOP           BRANCH LAST ENTRY NOT PROCESSED       20000013
         S     RE,TERMTBL         SUB START OF TABLE FOR TOTAL LENGTH   20200013
         STH   RE,TERMSZ          STORE TERM TABLE LENGTH IN IGG019NH   20400013
*                                                                       20600013
*      NOW STORE OFFSETS TO FIELDS IN THE CHECK-POINT RECORDS           20800013
*                                                                       21000013
         LA    RE,RCDFIX+1(RE)    ADD SIZE OF FIXED PORTION PLUS 1      21200013
         STH   RE,QOFF            STORE OFFSET TO THE QUEUE SAVE AREA   21400013
         ALR   RE,R1              ADD LENGTH OF THE QUEUE AREA          21600013
         STH   RE,POLLOFF         STORE OFFSET TO POLL LIST SAVE AREA   21800013
         ALR   RE,RA              ADD IN SIZE OF THE POLL LIST AREA     22000013
         STH   RE,LCBOFF          STORE OFFSET TO LCB SAVE AREA         22200013
         ALR   RE,RF              ADD IN SIZE OF THE LCB AREA           22400013
         STH   RE,CPSIZE          STORE TOTAL CHECK-POINT RECORD LENGTH 22600013
*                                                                       22800013
*      BUILD VASIC I/O COMMAND IN OPEN WORK AREA                        23000013
*                                                                       23200013
         ST    RCORE,IOBCCWAD     STORE CCW ADDRESS IN THE IOB          23400013
         ST    RCORE,8(RCORE)     STORE ADDRESS IN THE TIC COMMAND      23600013
         MVC   0(9,RCORE),DISKCCWS SEARCH COMMAND TO WORK AREA          23800013
         MVC   WCKDS(8,RCORE),LCBSTATE SAVE WRITE COUNT/KEY/DATA COMM.  24000013
*                                                                       24200013
*      READ CONTROL RECORD IF OLD DATA SET                              24400013
*                                                                       24600013
         TM    JFCBINDX(RCORE),X'C0' TEST DATA SET DISP.                24800013
         BO    NEWDS              BRANCH IF NEW DATA SET                25000013
         MVC   16(8,RCORE),DISKRW READ COMMAND TO CHANNEL PROGRAM AREA  25200013
         BAL   RDCB,PREPARE       GO READ THE CONTROL RECORD            25400013
*                                                                       25600013
*      SKIP DISK FORMATTING IF RESTART IS INDICATED                     25800013
*                                                                       26000013
         TM    CONTROL,X'FF'      TEST CONTROL RECORD STATUS            26200013
         BNZ   RESTART            BRANCH IF RESTART                     26400013
*                                                                       26600013
*      NEW DATA SET OR NO RESTART-FORMAT THE DISK                       26800013
*                                                                       27000013
NEWDS    MVC   16(8,RCORE),WCKDS(RCORE) WRITE COUNT/KEY/DATA COMMAND    27200013
         BAL   RDCB,PREPARE       GO WRITE THE CONTROL RECORD           27400013
         BAL   RDCB,PREP          GO WRITE FIRST SET OF CK-PT. RECORDS  27600013
         ST    RC,CONTROL         SAVE TTR OF THE SECOND SET OF RECORDS 27800013
         BAL   RDCB,PREP          GO WRITE SECOND SET OF CK-PT. RECORDS 28000013
         MVI   CONTROL,2          SET TO WRITE FIRST SET OF RECORDS     28200013
         MVI   TERMTBL,X'F1'      SET INDICATOR FOR NO RESTART          28400013
         B     LEAVE                                                    28600013
*                                                                       28800013
*        GET MAIN FOR CHECK POINT READ IN AREA                          29000013
*                                                                       29200013
RESTART  L     R0,SUBPOOL         LOAD SUBPOOL AND LENGTH FOR GETMAIN   29400013
         LH    R9,CPSIZE          LOAD SIZE OF THE CHECK-POINT AREA     29600013
         GETMAIN R,LV=(0)                                               29800013
         ST    R1,WKAREA          STORE ADDRESS OF THE WORK AREA        30000013
*                                                                       30200013
*      READ THE CHECK POINT RECORD                                      30400013
*                                                                       30600013
         MVC   17(3,RCORE),WKAREA+1 READ ADDRESS TO THE READ COMMAND    30800013
         LA    RDCB,REREAD        SET RETURN ADDRESS FOR SECOND READ    31000013
         TM    CONTROL,X'01'      TEST FOR REQUIRE RECORD               31200013
         MVI   RW(RCORE),X'03'    SET NO-OP COMMAND FOR FIRST READ      31400013
         BNO   DISKIO             BRANCH IF SECOND SET OF RECORDS REQ.  31600013
REREAD   MVI   RW(RCORE),X'06'    SET READ COMMAND                      31800013
         LH    R9,CPSIZE          RELOAD SIZE OF THE CK.-PT. RECORD     32000013
         BAL   RDCB,DISKIO        GO READ THE CHECK POINT RECORD        32200013
*                                                                       32400013
*      RESTORE THE TERM TABLE,QUEUE FIELDS AND POLLING LISTS            32600013
*                                                                       32800013
         L     RE,WKAREA          ADDRESS OF THE INPUT AREA             33000013
         L     RA,TERMTBL         LOAD ADDRESS OF THE TERM TABLE        33200013
         L     RF,4(RA)           ADDRESS OF IGG019NG                   33400013
         L     RF,0(RF)           ADDRESS OF THE LPS QUEUE              33600013
         MVC   ADDRESS+1(3,RF),1(RE) REPLACE ADDRESS FIELD              33800013
         L     RC,QUEUEST         ADDRESS OF THE FIRST QUEUE            34000013
         LH    R0,TERMSZ          LENGTH OF THER TERM TABLE             34200013
         LR    RDEB,R0            LOAD REGISTER RDEB                    34400013
         LH    R9,QOFF            OFFSET TO QUEUE INPUT AREA            34600013
         ALR   R9,RE              START ADDRESS FOR QUEUE DATA          34800013
         LH    RDCB,POLLOFF       OFFSET TO START OF POLLING LIST DATA  35000013
         ALR   RDCB,RE            START ADDRESS FOR POLL DATA           35200013
         LA    RF,ERRORQ(RF)      ADDRESS OF THE ERROR QUEUE            35400013
         SH    RDCB,CON11         BACK UP TO ERROR QUEUE DATA           35600013
         MVC   QSIZE(5),0(RDCB)   RESTORE QUEUE SIZE AND QNASEG         35800013
         MVC   QBACK(3),5(RDCB)   RESTORE QBACK                         36000013
         MVC   QFAC(3),8(RDCB)    RESTORE QFAC                          36200013
         AH    RDCB,CON11         RESTORE POLL DATA POINTER             36400013
         MVI   COUNTSW,X'10'      FLIP COUNT SWITCH                     36600013
*                                                                       36800013
*      INITIALIZE FOR RESTORE SCAN OF THE TERM TABLE,QUEUES AND POLL    37000013
*                                                                       37200013
RESTLOOP SR    RF,RF                                                    37400013
         IC    RF,8(RA)           LOAD SIZE OF THIS TERM TABLE ENTRY    37600013
         SH    RF,CON5            SUB FIVE FOR MOVE MINUS LENGTH AND    37800013
*                                 QUEUE ADDRESS                         38000013
         EX    RF,MOVETERM                                              38200013
         L     RF,RCDFIX(RE)      LOAD ADDRESS OF THE OLD QUEUE         38400013
         L     R1,WKAREA          LOAD ADDRESS OF THE INPUT AREA        38600013
         MVI   OLDQUE(R1),0       ASSURE ZERO IN HIGH ORDER BYTE        38800013
         SL    RF,OLDQUE(R1)      COMPUTE OLD QUEUE OFFSET              39000013
         L     R1,8(RA)           LOAD ADDRESS OF THE NEW QUEUE         39200013
         CLI   QRET(R1),X'02'     IS THIS A DIST. LIST                  39400013
         BE    STORELN            BRANCH IF DISTRIBUTION LIST           39600013
         ALR   RF,RC              START OF NEW QUEUE AREA TO OLD QUEUE  39800013
*                                 OFFSET                                40000013
         ST    RF,8(RA)           QUEUE ADDRESS TO THE TERM ENTRY       40200013
STORELN  LA    R1,0               ZERO REG. BUT LEAVE CONDITION CODE    40400013
         IC    R1,RCDFIX(RE)      TERM ENTRY LENGTH                     40600013
         BE    UPDATE             BRANCH IF DISTRIBUTION LIST           40800013
         STC   R1,8(RA)           RESTORE LENGTH OF ENTRY               41000013
*                                                                       41200013
*      RESTORE QUEUE FIELDS IF DIFFERENT QUEUE THAN LAST                41400013
*                                                                       41600013
         LA    RF,0(RF)           CLEAR THE HIGH ORDER BYTE             41800013
         CR    RDEB,RF            COMPARE QUEUE ADDRESSES               42000013
         BE    UPDATE             BRANCH IF QUEUES ARE THE SAME         42200013
         MVC   QSIZE(5),0(R9)     RESTORE QUEUE SIZE AND QNASEG         42400013
         MVC   QBACK(3),5(R9)     RESTORE QBACK                         42600013
         MVC   QFAC(3),8(R9)      RESTORE QFAC                          42800013
         LA    R9,QLEN(R9)        INCREMENT INPUT DATA POINTER          43000013
         CLI   QRET(RF),X'68'     TEST THE QUEUE TYPE                   43200013
         BE    NOTPROC            BRANCH IF DESTINATION QUEUE           43400013
         MVC   QLINK(3),QFAC      SET QLINK EQUAL OLD QFAC              43600013
         CLC   QFAC(3),0(R9)      COMPARE QFAC TO NEXT MESSAGE ADDRESS  43800013
         BL    NOSWAP             BRANCH OLD QFAC LESS                  44000013
         MVC   QFAC(3),0(R9)      RESET QFAC TO THE LAST MESSAGE        44200013
NOSWAP   LA    R9,3(R9)           ADD THREE MORE FOR PROCESS QUEUE      44400013
         B     QREST              GO SAVE ADDRESS OF THIS QUEUE         44600013
*                                                                       44800013
*      RESTORE POLLING LIST IF NOT PREVIOUSLY RESTORED                  45000013
*                                                                       45200013
NOTPROC  L     RDEB,QDCBA(RF)     LOAD DCB ADDRESS FROM THE QUEUE       45400013
         SR    RCORE,RCORE                                              45600013
         IC    RCORE,QRLNN(RF)    LOAD RELATIVE LINE NUMBER             45800013
         SLL   RCORE,2            MULTIPLY BY FOUR                      46000013
         LA    RCORE,DCBPLPTR(RDEB,RCORE) ADDRESS OF POLL LIST POINTER  46200013
         TM    0(RCORE),X'01'     TEST PREVIOUSLY RESTORED FLAG         46400013
         BZ    QREST              BRANCH IF PREVIOUSLY RESTORED         46600013
         NI    0(RCORE),X'FE'     TRUN OFF NOT RESTORED FLAG            46800013
         L     RCORE,0(RCORE)     LOAD ADDRESS OF THE POLLING LIST      47000013
         SR    RDEB,RDEB                                                47200013
         IC    RDEB,0(RCORE)      LOAD SIZE OF THE POLLING LIST         47400013
         BCTR  RDEB,0             SUB ONE FOR SIZE BYTE NOT MOVED       47600013
         BCTR  RDEB,0             SUB ONE FOR MOVE CHARACTER INST.      47800013
         EX    RDEB,MOVEPOLL      RESTORE THE POLLING LIST              48000013
         LA    RDCB,1(RDEB,RDCB)  INCREMENT INPUT DATA POINTER          48200013
*                                                                       48400013
*      UPDATE POINTER AND TEST FOR MORE ENTRIES                         48600013
*                                                                       48800013
QREST    LR    RDEB,RF            SAVE ADDRESS OF THIS QUEUE            49000013
UPDATE   ALR   RE,R1              UPDATE WORKAREA POINTER               49200013
         ALR   RA,R1              UPDATE TERM TABLE POINTER             49400013
         SR    R0,R1              SUB ENTRY LENGTH FROM TABLE LENGTH    49600013
         BC    2,RESTLOOP         BRANCH IF MORE ENTRIES                49800013
         MVI   TERMTBL,X'F2'      SET INDICATOR FOR RESTART             50000013
         B     LEAVE                                                    50200013
*                                                                       50400013
*      PREPARE TO FORMAT CHECK-POINT RECORD                             50600013
*                                                                       50800013
PREP     LH    R9,CPSIZE          LOAD SIZE OF THE CHECK-POINT RECORD   51000013
         SR    R0,R0              ZERO THE WRITE ADDRESS                51200013
         B     DISKIO             TO THE WRITE ROUTINE                  51400013
*                                                                       51600013
*      PREPARE TO READ OR WRITE THE CONTROL RECORD                      51800013
*                                                                       52000013
PREPARE  LA    R0,CONTROL         LOAD READ/WRITE ADDRESS               52200013
         LH    RA,TRKLN           LOAD TRACK LENGTH OF THE CK. PT. DV.  52400013
         LA    R9,4               LENGTH OF THE READ OR WRITE           52600013
         LA    RC,1               TTR OF THE CONTROL RECORD             52800013
*                                                                       53000013
*      PREPARE TO READ/WRT TRACK LENGTH OR RECORD LENGTH                53200013
*                                                                       53400013
DISKIO   ST    R0,WRT2(RCORE)     STORE WRITE DATA ADDRESS              53600013
         SH    RA,OVERHEAD        SUB OVERHEAD SIZE FROM TRACK LENGTH   53800013
         SR    RA,R9              SUB DATA LENGTH                       54000013
         LR    R0,R9              SAVE DATA LENGTH                      54200013
         BC    4,NOFIT            BRANCH IF DATA TOO LARGE FOR THIS TRK 54400013
         SR    R9,R9              ZERO COUNT OF DATA REMAINING          54600013
         B     STORE              GO STORE READ/WRT LENGTH              54800013
NOFIT    AR    RA,R9              RESTORE THE REMAINING TRACK LENGTH    55000013
         LR    R0,RA              READ/WRT LENGTH EQUAL TRACK LENGTH    55200013
         SR    R9,RA              COMPUTE LENGTH OF REMAINING DATA      55400013
         SR    RA,RA              REMAINING TRACK LENGTH TO ZERO        55600013
STORE    STH   R0,LCBSTATE+6      STORE DATA LENGTH IN COUNT AREA       55800013
         ST    R0,WRT2S(RCORE)    STORE LENGTH IN WRT. COMMAND          56000013
*                                                                       56200013
*      SKIP READ IF NO-OP COMMAND                                       56400013
*                                                                       56600013
         CLI   RD1(RCORE),3       TEST FOR NO-OP                        56800013
         BE    NOTRAN             BRANCH IF NO-OP                       57000013
*                                                                       57200013
*      CONVERT TTR TO ACTUAL DISK ADDRESS                               57400013
*                                                                       57600013
         STM   9,2,RSAVE(RCORE)   SAVE REGISTERS REQUIRED FOR CONVERT   57800013
         LR    R0,RC              COPY THE TTR TO REGISTER ZERO         58000013
         CLI   RW(RCORE),6        IS THIS A READ OPERATION              58200013
         BNE   WRITE              BRANCH IF WRITE OPERATION             58400013
         MVC   RW+6(2,RCORE),WRT2S+2(RCORE) MOVE LENGTH TO READ COMMAND 58600013
         LA    R0,1(RC)           ADD 1 TO THE TTR                      58800013
WRITE    BCTR  R0,0               SUB ONE FROM THE TTR                  59000013
         SLL   R0,8               POSITION THE TTR FOR THE CONVERT RT.  59200013
         L     RDCB,0(RPARC)      LOAD THE DCB ADDRESS                  59400013
         L     R1,DCBDEBAD        LOAD THE DEB ADDRESS                  59600013
         LA    RDCB,SEEKAD        RETURN MBBCCHHR ADDRESS               59800013
         L     RF,16              LOAD ADDRESS OF THE CVT               60000013
         L     RF,CONVERT(RF)     ADDRESS OF THE CONVERT ROUTINE        60200013
         BALR  RE,RF              BRANCH TO THE CONVERT ROUTINE         60400013
         USING *,RE                                                     60600013
         LTR   15,15              TEST FOR VALID TTR                    60800013
         BNZ   ABEND              BRANCH NOT VALID TTR                  61000013
         DROP  RE                                                       61200013
         LM    9,2,RSAVE(RCORE)   RESTORE SAVED REGISTERS               61400013
*                                                                       61600013
*      PREPARE OUTPUT AREA FOR THE COUNT AND KEY                        61800013
*                                                                       62000013
         MVC   LCBSTATE(4),SEEKAD+3 CCHH TO THE COUNT/KEY OUTPUT AREA   62200013
         STC   RC,LCBSTATE+4      STORE RECORD NUMBER                   62400013
*                                                                       62600013
*      ROUTINE TO ISSUE EXCP FOR READ OR WRITE ON THE DISK              62800013
*                                                                       63000013
EXCPRT   LA    1,DISKIOB          LOAD IOB PARAMETER FOR IOS            63200013
         SVC   EXCP                                                     63400013
*                                                                       63600013
*      NOW WAIT FOR COMPLECTION AND TEST FOR PERMANENT ERROR            63800013
*                                                                       64000013
         LA    R0,1               LOAD WAIT COUNT                       64200013
         LA    R1,DECB            LOAD WAIT PARAMETER                   64400013
         SVC   WAIT                                                     64600013
         CLI   DECB,X'7F'         TEST FOR PERMANENT I/O ERROR          64800013
         BC    8,NOTRAN           BRANCH NOT PERMANENT ERROR            65000013
*                                                                       65200013
*      PERMANENT I/O ERROR SYSTEM ABEND                                 65400013
*                                                                       65600013
         LA    15,IOERR           RETURN CODE FOR IO ERROR              65800013
ABEND    L     1,DISKERR          LOAD DISK ERROR ABEND CODE            66000013
         ABEND (1)                                                      66200013
*                                                                       66400013
*      ROOM FOR MORE DATA ON THIS TRACK-IF NO UPDATE TTR FOR NEXT TRACK 66600013
*                                                                       66800013
NOTRAN   LA    RC,1(RC)           ADD ONE TO THE TTR                    67000013
         CH    RA,OVERHEAD        COMPARE TRACK LENGTH TO OVERHEAD      67200013
         BH    EXITTEST           BRANCH IF MORE ROOM ON THIS TRACK     67400013
         IC    RC,LCBSTATE+5      ZERO THE RECORD NUMBER                67600013
         LA    RC,257(RC)         ADD ONE TO TRACK AND RECORD           67800013
         LH    RA,TRKLN           RESET THE TRACK LENGTH                68000013
*                                                                       68200013
*      TEST FOR MORE DATA TO BE READ OR WRITTEN                         68400013
*                                                                       68600013
EXITTEST LTR   R9,R9              DATA COUNT EQUAL ZERO                 68800013
         BCR   8,RDCB             BRANCH IF DATA COUNT ZERO             69000013
         CLI   RW(RCORE),6        IS THIS A READ OPERATION              69200013
         BNE   DISKIO             BRANCH NOT READ OPERATION             69400013
         L     R1,RW(RCORE)       LOAD LAST READ ADDRESS                69600013
         LH    R0,RW+6(RCORE)     LOAD LENGTH OF LAST READ              69800013
         ALR   R1,R0              COMPUTE NEXT READ ADDRESS             70000013
         ST    R1,RW(RCORE)       STORE THE NEW READ ADDRESS            70200013
         B     DISKIO             GO READ THE NEXT RECORD               70400013
*                                                                       70600013
*      STORE CHECKPOINT INTERVAL IN CHECKPOINT ROUTINE                  70800013
*                                                                       71000013
LEAVE    L     R1,TERMTBL         LOAD ADDRESS OF THE TERM TABLE        71200013
         SH    R1,CON5            BACK UP TERM TABLE POINTER            71400013
         USING TMINUS5,R1                                               71600013
         MVN   CPINT+1(1),INPUTINV MOVE VALUE ASSUMING CKREQ MACROS     71800013
         L     R9,CKQUE           ADDRESS OF THE CKREQ MACRO QUEUE      72000013
         MVC   2(2,R9),CPINT      SET INITIAL REQUEST VALUE             72200013
         LH    R9,INPUTINV        LOAD INTERVAL OR REQUEST VALUE        72400013
         LTR   R9,R9              REQUEST VALUE WILL BE MINUS           72600013
         BM    CKREQ              BRANCH IF CKREQ MACROS ARE TO BE USED 72800013
         SRL   R9,8               POSITION THE INTERVAL FOR MULTIPLY    73000013
         MH    R9,CON15                                                 73200013
         NI    TERMTBL,X'EF'      CLEAR CPREQ FLAG FOR CHECK POINT RT.  73400013
         STH   R9,CPINT           STORE INTERVAL IN PLACE OF REQUEST    73600013
*                                 VALUE                                 73800013
*                                                                       74000013
*      SET FLAG TO INDICATE RESTART/NO-RESTART                          74200013
*                                                                       74400013
CKREQ    L     R1,NGPOINTR        ADDRESS OF MODULE IGG019NG            74600013
         DROP  R1                                                       74800013
         L     R1,0(R1)           LOAD ADDRESS OF THE LPS QUEUE         75000013
         MVC   QCPADR(1,R1),TERMTBL MOVE PRESET FLAG TO CHECK PT. FLAGS 75200013
         MVI   TERMTBL,2          SET RETURN CODE IN THE STCB           75400013
         MVI   LCBSTATE+4,X'E0'   SET THE LCB PRIORITY                  75600013
         MVC   IOBCCWAD+1(3),DISKTIC+1 RESTORE IOBCCW ADDRESS           75800013
         MVI   DISKRW+4,X'20'     SET THE SLI FLAG FOR FURTURE WRITES   76000013
         L     RCORE,4(RWTGC)     RELOAD ADDRESS OF THE WORK AREA       76200013
*********************************************************************** 76400013
*                                                                     * 76600013
*      THIS IS AN OPEN PROVIDED SECTION OF CODE THAT SETS UP XCTL     * 76800013
*                                                                     * 77000013
*********************************************************************** 77200013
         XC    0(2,RWTGC),0(RWTGC) CLEAR TO INDICATE COMPLECTION        77400013
RELOOP   LA    RWTGC,WGOFF(RWTGC) INCREMENT CURRENT WTG ENTRY           77600013
         LA    RPARC,PLOFF(RPARC) INCREMENT CURRENT PARAMETER LIST ENT. 77800013
         CLC   0(2,RWTGC),AMIDCNST SAME EXECUTOR REQUIRED               78000013
         BC    7,NOABEND          NO GO CHECK FOR END OF TABLE          78200013
*                                                                       78400013
*      SYSTEM ABEND                                                     78600013
*                                                                       78800013
         L     R1,ABCODE          LOAD ABEND CODE                       79000013
         ABEND (1)                                                      79200013
NOABEND  CLC   0(2,RWTGC),OPIDCNST END OF WTG TABLE                     79400013
         BC    7,RELOOP           NO GO CHECK NEXT ENTRY                79600013
         LR    RPARC,RPAR         RESET PARAMETER LIST ADDRESS          79800013
         LA    RWTGC,WAOFF(RWTG)  RESET WHERE-TO-GO TABLE POINTER       80000013
ZCHEK    CLI   0(RWTGC),0         IS THIS ENTRY ZERO                    80200013
         BC    7,XCTLRTN          NO BRANCH TO XCTL ROUTINE             80400013
         LA    RWTGC,WGOFF(RWTGC) ADDRESS OF THE NEXT ENTRY             80600013
         LA    RPARC,PLOFF(RPARC)                                       80800013
         BC    15,ZCHEK                                                 81000013
*                                                                       81200013
*      TRANSFER CONTROL TO THE NEXT EXECUTOR OF FIRST INCOMPLETE DCB    81400013
*                                                                       81600013
XCTLRTN  LA    RF,DXCCW12                                               81800013
         MVC   6(2,RWTG),0(RWTGC) EXECUTOR ID TO PARAMETER LIST         82000013
         MVC   14(3,RWTG),2(RWTGC) TTR TO THE WHERE-TO-GO TABLE         82200013
         XCTL  DE=(RWTG),SF=(E,(15))                                    82400013
CON5     DC    H'5'                                                     82600013
CON11    DC    H'11'                                                    82800013
MOVETERM MVC   12(0,RA),RCDFIX+4(RE)                                    83000013
MOVEPOLL MVC   1(0,RCORE),0(RDCB)                                       83200013
WAOFF    EQU   32                                                       83400013
PLOFF    EQU   4                                                        83600013
WGOFF    EQU   8                                                        83800013
OPIDCNST DC    C'0S'                                                    84000013
AMIDCNST DC    C'3V'                                                    84200013
NENT     EQU   1                                                        84400013
LEN      EQU   NENT*6+6                                                 84600013
WDS      EQU   (LEN+7)/8                                                84800013
ORG      EQU   1024-WDS*8                                               85000013
         ORG   IGG0193V+ORG                                             85200013
         DC    XL2'0'                                                   85400013
CON15    DC    H'15'                                                    85600013
ABCODE   DC    X'00713000'                                              85800013
DISKERR  DC    X'800A4000'                                              86000013
LOADID   DC    C'019'                                                   86200013
         DC    YL1(X'80'-WDS)                                           86400013
         IECTDEBX                                                       86600013
         DCBD  DSORG=(CQ,DA)                                            86800013
FORCORE  DSECT                                                          87000013
         IECDSECT                                                       87200013
         QCBD                                                           87400013
         EJECT                                                          87600013
IGG019NH DSECT                                                          87800013
CPBASE   EQU   9                                                        88000013
RCDFIX   EQU   8                                                        88200013
ADDRESS  EQU   196                                                      88400013
ERRORQ   EQU   200                                                      88600013
         USING *,CPBASE                                                 88800013
LCBSTATE DC    X'1D'              WRITE COUNT/KEY/DATA COMMAND          89000013
         DC    AL3(LCBSTATE)      WRITE ADDRESS                         89200013
         DC    X'80'              DATA CHAINING FLAG                    89400013
         DC    AL3(8)             LENGTH                                89600013
COUNTSW  DC    X'80'                                                    89800013
         DC    AL3(TERMTBL)       STCB ADDRESS                          90000013
         DC    A(0)               LINK FIELD WHEN IN THE TIME QUEUE     90200013
TERMSZ   DC    H'0'               STORAGE FOR THE TERMINAL TABLE SIZE   90400013
POLLOFF  DC    H'0'               POLLING LIST OFFSET IN THE CP RECORD  90600013
QOFF     DC    H'0'               QUEUE DATA OFFSET IN THE C/P RECORDS  90800013
LCBOFF   DC    H'0'               LCB DATA OFFSET IN THE C/P RECORDS    91000013
WKAREA   DC    A(0)               ADDRESS OF THE C/P RECORD IN CORE     91200013
CKQUE    DC    A(0)               ADDRESS OF THE CKREQ QUEUE            91400013
SUBPOOL  DC    X'FE00'            SUBPOOL FOR GETMAIN                   91600013
CPSIZE   DC    H'0'               SIZE OF THE CHECK POINT OUTPUT        91800013
OVERHEAD DC    H'0'               OVERHEAD VALVE FOR THE CK. PT. DEVICE 92000013
TRKLN    DC    H'0'               TRACK LENGTH OF THE CHECK PT. DEVICE  92200013
CPINT    DC    H'0'               CHECK/POINT INTERVAL IN SECONDS       92400013
TIMEQ    DC    H'0'               USED BY TIME DELAY ROUTINE            92600013
DECB     DC    A(0)               DECB TO BE USED FOR READ AND WRITE    92800013
DISKIOB  DC    X'42'              START OF THE DISK IOB                 93000013
         DC    AL3(0)                                                   93200013
         DC    A(DECB)            IOBDECB ADDRESS                       93400013
         DC    A(0)                                                     93600013
         DC    X'0F000000'                                              93800013
IOBCCWAD DC    A(DISKCCWS)        IOBCCW ADDRESS                        94000013
DISKDCB  DC    A(0)               ADDRESS OF THE DISK DCB               94200013
         DC    2A(0)                                                    94400013
SEEKAD   DC    2A(0)              DISK SEEK ADDRESS                     94600013
DISKCCWS DC    X'31'              SEARCH COMMAND                        94800013
         DC    AL3(SEEKAD+3)      SEARCH ADDRESS                        95000013
         DC    X'40000005'        FLAGS AND LENGTH                      95200013
DISKTIC  DC    X'08'              TIC COMMAND                           95400013
         DC    AL3(DISKCCWS)      TIC ADDRESS                           95600013
CONTROL  DC    X'00'              INPUT AREA FOR THE CONTROL RECORD     95800013
         DC    AL3(0)             TTR OF THE SECOND SET OF RECORDS      96000013
DISKRW   DC    X'06'              READ DATA COMMAND                     96200013
         DC    AL3(CONTROL)       INPUT ADDRESS                         96400013
         DC    A(2)               LENGTH                                96600013
QUEUEST  DC    A(0)               START OF QUEUE AREA                   96800013
TERMTBL  DC    A(0)               ADDRESS OF THE TERMINAL TABLE         97000013
CON3     DC    H'3'                                                     97200013
TMINUS8  DSECT                                                          97400013
         DS    XL3                                                      97600013
TMINUS5  DS    XL1                                                      97800013
INPUTINV DS    XL2                                                      98000013
         DS    XL6                                                      98200013
NGPOINTR DS    XL4                                                      98400013
         END                                                            98600013
