         TITLE 'IGG019NA  QTAM GET SEGMENTS'                            00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-  IGG019NA     QTAM GET SEGMENT                                 * 01600013
*                                                                     * 02000013
*STATUS-  CHANGE LEVEL 001                                OS QTAM II  * 02400013
*                                                                     * 02800013
*FUNCTION-  THE GET SEGMENT FORM OF THE GET MACRO GENERATES A BALR TO * 03200013
*   THIS ROUTINE WITH THE ADDRESS OF THE DCB TO BE USED IN REGISTER   * 03600013
*   ONE.  IF EODAD HAS BEEN SPECIFIED BY THE PROCESSING PROGRAM AND   * 04000013
*   THERE ARE NO MESSAGES ON THE QUEUE, THE PROCESSING PROGRAM'S EXIT * 04400013
*   ROUTINE IS ENTERED VIA A BALR.  IF EODAD WAS NOT SPECIFIED OR     * 04800013
*   IS RETURNED BY A QPOST (THE FIRST TIME, A DUMMY BUFFER IS USED),  * 05200013
*   IF THERE IS A MESSAGE IN THE QUEUE, THE PREVIOUSLY USED BUFFER    * 05600013
*   AND A QWAIT OBTAINS THE NEXT BUFFER.                              * 06000013
*        IF THE BUFFER CONTAINS A HEADER SEGMENT AND THE PREFIX       * 06400013
*   INDICATES    A PROCESS QUEUE, THE TERMINAL ID IS MOVED TO THE     * 06800013
*   SOURCE AREA.  IF THE BUFFER IS EMPTY, THE DATA COUNT IS STORED    * 07200013
*   IN THE WORK AREA AND RETURN IS TO THE NEXT INSTRUCTION IN THE     * 07600013
*   PROCESSING PROGRAM.  IF THE BUFFER IS NOT EMPTY, THE SEGMENT IS   * 08000013
*   MOVED INTO THE WORK AREA.  IF ALL DATA IN THE BUFFER HAS BEEN     * 08400013
*   MOVED, RETURN IS TO THE NEXT INSTRUCTION IN THE PROCESSING        * 08800013
*   PROGRAM.  IF THE WORK AREA IS FILLED AND SOME DATA STILL REMAINS  * 09200013
*   IN THE BUFFER AND SYNAD IS SPECIFIED, THE PROCESSING PROGRAM'S    * 09600013
*   SYNCHRONOUS EXIT ROUTINE IS ENTERED BEFORE RETURNING TO THE NEXT  * 10000013
*   INSTRUCTION.  OTHERWISE, RETURN IS TO THE NEXT INSTRUCTION IN     * 10400013
*   THE PROCESSING PROGRAM.                                           * 10800013
*                                                                     * 11200013
*ENTRY POINTS-  IGG019NA - EXPANSION OF THE GET SEGMENT FORM OF THE   * 11600013
*   GET MACRO GENERATES A BALR TO THIS POINT USING REGISTER 15 AS THE * 12000013
*   ENTRY POINT REGISTER AND REGISTER 14 AS THE RETURN REGISTER.      * 12400013
*                                                                     * 12800013
*INPUT-                                                               * 13200013
*   REGISTER  0- ADDRESS OF WORK AREA.                                * 13600013
*   REGISTER  1- ADDRESS OF THE DCB SPECIFIED IN THE GET MACRO.       * 14000013
*   REGISTER 14- RETURN ADDRESS.                                      * 14400013
*   REGISTER 15- ENTRY POINT.                                         * 14800013
*                                                                     * 15200013
*OUTPUT-  THE NEXT MESSAGE SEGMENT WILL BE PLACED IN THE WORK AREA    * 15600013
*   POINTED TO BY REGISTER 0.  THE FIRST FOUR BYTES IN THE WORK AREA  * 16000013
*   WILL CONTAIN THE SEGMENT PREFIX.  THE FIRST TWO BYTES SPECIFIES   * 16400013
*   THE NUMBER OF CHARACTERS IN THE SEGMENT, THE THIRD BYTE           * 16800013
*   INDICATES SEGMENT TYPE, AND THE FOURTH BYTE IS A ZERO.            * 17200013
*                                                                     * 17600013
*EXTERNAL ROUTINES-                                                   * 18000013
*        IGG065 - QWAIT MODULE IN IECKQQ01.                           * 18400013
*        IGG067 - QPOST MODULE IN IECKQQ01.                           * 18800013
*                                                                     * 19200013
*EXITS-  NORMAL- RETURN IS TO THE NEXT INSTRUCTION IN THE PROCESSING  * 19600013
*   PROGRAM.                                                          * 20000013
*        ERRORS- IF EODAD IS SPECIFIED AND NO MESSAGES ARE IN THE     * 20400013
*   QUEUE, THE PROCESSING PROGRAM'S EXIT ROUTINE IS ENTERED BEFORE    * 20800013
*   CONTROL IS RETURNED TO THE NEXT PROCESSING PROGRAM INSTRUCTION.   * 21200013
*   IF THE MESSAGE SEGMENT IS TOO LARGE TO FIT IN THE WORK AREA AND   * 21600013
*   SYNAD IS SPECIFIED, THE PROCESSING PROGRAM'S SYNCHRONOUS EXIT     * 22000013
*   ROUTINE IS ENTERED BEFORE RETURNING TO THE NEXT PROCESSING        * 22400013
*   RPOGRAM INSTRUCTION.                                              * 22800013
*                                                                     * 23200013
*TABLES/WORK AREAS-  N/A.                                             * 23600013
*                                                                     * 24000013
*ATTRIBUTES-  SERIALLY REUSABLE, ENABLED, RESIDENT, PROBLEM PROGRAM   * 24400013
*   MODE.                                                             * 24800013
*                                                                     * 25200013
*NOTES-  REGISTERS ARE SAVED ON ENTRY AND RESTORED ON RETURN.         * 25600013
*                                                                     * 26000013
*********************************************************************** 26400013
IGG019NA START                                                          26800013
*1210377000-378000,514000,561000-562000                            5123 27000016
R0       EQU   0                                                        27200013
FREG     EQU   1                                                        27600013
TREG     EQU   2                                                        28000013
DCBR     EQU   3                                                        28400013
WR1      EQU   4                                                        28800013
R5       EQU   5                                                        29200013
RDEB     EQU   6                                                        29600013
RD       EQU   7                                                        30000013
RE       EQU   9                                                        30400013
SIZE     EQU   10                                                       30800013
QREG     EQU   11                                                       31200013
WR2      EQU   12                                                       31600013
SREG     EQU   15                                                       32000013
TXT      EQU   X'01'                                                    32400013
EOM      EQU   X'02'                                                    32800013
QATTACH  EQU   72                                                       33200013
QWAIT    EQU   65                                                       33600013
QPOST    EQU   67                                                       34000013
         USING IHADCB,FREG                                              34400013
         USING QBLOCK,QREG                                              34800013
         USING *,SREG                                                   35200013
         SAVE  (14,12)             SAVE REGISTERS                       35600013
         TM    DCBEODAD,X'F0'     IS A BUFFER PRESENT                   36000013
         BZ    GETBUF             BRANCH IF YES                         36400013
         TM    DCBEODAD+3,X'01'    EODAD SPECIFIED BY USER              36800013
         BNZ   GETBUF              BRANCH IF NO TO WAIT ON MESSAGE      37200013
         L     RDEB,DCBDEBAD       GET DEB ADDRESS                      37600013
         TM    60(RDEB),7     IN PROCESS OF READING FROM DISK      5123 37700016
         BC    6,GETBUF          BRANCH IS YES                     5123 37800016
         L    QREG,36(0,RDEB)          ACCESS NEXT ELEMENT IN ELT CHAIN 38000013
*                                         OF MAIN STORAGE PROCESS Q     38400013
         CLI   4(QREG),255                IS IT DUMMY LAST ELEMENT      38800013
         BNE   GETBUF              BRANCH IF YES                        39200013
*  EODAD ROUTINE                                                        39600013
         LM    2,12,28(13)         RESTORE REGISTERS 2-12 FOR USER EXIT 40000013
         L     15,DCBEODAD         LOAD EXIT ADDRESS                    40400013
         BALR  14,15               TAKE EXIT IF NO MESSAGES IN QUEUE    40800013
* RETURN FROM USER EXIT RESTORE REGISTERS                               41200013
         LM    14,1,12(13)         RESTORE REGISTERS 14-1 FOR GET       41600013
         USING IHADCB,DCBR                                              42000013
         USING IECKPREF,FREG                                            42400013
GETBUF   EQU   *                                                        42800013
         LR    DCBR,FREG           LOAD DCB ADDR                        43200013
         L     RDEB,DCBDEBAD       GET DEB ADDRESS                      43600013
         LR    R5,R0               GET WORKAREA ADDRESS IN R5           44000013
         LH    R0,DCBSOWA          GET SIZE OF WORKAREA                 44400013
         LA    WR1,4               FOUR BYTE ADJUSTMENT FOR WORKAREA    44800013
         SR    R0,WR1              GET START OF MESSAGE ADDRESS         45200013
         AR    WR1,R5                    IN WR1                         45600013
         L     RD,CVTABLE(0,0)     GET CVT ADDRESS                      46000013
         L     RD,CVTTRMTB(0,RD)    GET TERMTBL ADDRESS                 46400013
         L     FREG,DCBSEGAD           GET ADDRESS OF LAST BUFFER       46800013
         L     TREG,4(0,RD)        GET ADDRESS OF QTAM MAIN PROGRAM     47200013
         LR    SIZE,TREG          SAVE ADDRESS OF QTAM MAIN PROGRAM     47600013
         L    TREG,0(TREG)             GET ADDRESS OF RETURN            48000013
         L    TREG,280(TREG)               BUFFER QCB                   48400013
*  THE FOLLOWING CODE RETURNS A PREVIOUSLY USED BUFFER TO THE RETURN    48800013
*  BUFFER QUEUE AND WAITS FOR THE NEXT BUFFER.  IF FIRST TIME, A DUMMY  49200013
*  BUFFER IS USED FOR THE RETURN FUNCTION                               49600013
         TM    DCBEODAD,X'F0'     IS A BUFFER PRESENT                   50000013
         BO    QWAITT             BRANCH BUFFER NOT PRESENT             50400013
         SVC   QPOST               POST PREVIOUS BUFR TO RETURN BUFR Q  50800013
         MVI   DCBEODAD,X'F0'     FLAG TO INDICATE NO BUFFER PRESENT    51200013
RELOAD   EQU   *                                                   5123 51400016
         LM    14,12,12(13)       RELOAD REGISTERS                      51600013
         BR    SREG               GO BACK AND TEST FOR EODAD            52000013
QWAITT   LA    TREG,36(RDEB)       GET POINTER TO QCB                   52400013
* QWAIT  CORE PROCESS QUEUE                                             52800013
         SVC   QWAIT               WAIT FOR NEXT BUFFER                 53200013
         MVC   2(1,R5),MSTATUS     STORE SEGMENT TYPE IN WORKAREA       53600013
         NI    2(R5),3             CLEAR EXTRANEOUS BITS FROM SEG TYPE  54000013
         LA    FREG,0(0,FREG)          SAVE ADDRESS OF BUFFER IN DCB    54400013
         ST    FREG,DCBSEGAD              AND INITIALIZE 1ST BYTE TO 0  54800013
         LA    TREG,QATTACH(SIZE) ADDRESS OF QATTACH FOR QWAIT          55200013
         SVC   QWAIT              ASSURE PROCESS QUEUE OFF READY QUEUE  55600013
         MVI   DCBEODAD,0         FLAG TO INDICATE BUFFER PRESENT       56000013
         TM    MSTATUS,X'80'      HAS MESSAGE BEEN CANCELED        5123 56100016
         BO    RELOAD             RETURN TO GET NEXT BUFFER        5123 56200016
         L     FREG,DCBSEGAD      RELOAD BUFFER ADDRESS                 56400013
         LA    WR2,TXSTRT-8        GET START OF TEXT MINUS 8            56800013
* TEST FOR HEADER OR TEXT SEGMENT                                       57200013
         TM    MSTATUS,TXT         IS THIS TEXT SEGMENT                 57600013
         BC    1,TEXTSEG           IF YES BRANCH                        58000013
         LA    WR2,HDSTRT-8        IF NO, GET START OF HDR MINUS 8      58400013
         L     QREG,DCBTRMAD       GET ADDRESS OF SOURCE AREA           58800013
*                                                                       59200013
*      MOVE TERM NAME TO USERS AREA                                     59600013
*                                                                       60000013
         IC    SIZE,4(RD)         MAX TERM NAME LENGTH                  60400013
         BCTR  SIZE,0                  SUB ONE FOR MOVE                 60800013
         EX    SIZE,CLEARNM       CLEAR NAME FIELD                      61200013
         LH    RE,TTSKEY           GET SOURCE KEY TO TERMTBL            61600013
         LTR   RE,RE               IS IT PROCESS QUEUE                  62000013
         BZ    TEXTSEG             BRANCH IF YES                        62400013
         AR    RE,RD               GET ADDRESS OF SOURCE IN TERMTBL     62800013
         EX    SIZE,MOVETERM           MOVE TERM NAME TO USERS AREA     63200013
TEXTSEG  LA    FREG,FBLOCK         ACCESS BUFFER FROM PROCESS QUEUE     63600013
         AH    FREG,MSEGSZE        BUMP TO END OF SEGMENT               64000013
         SR    FREG,WR2            IS ANYTHING IN THE BUFFER            64400013
         BNP   RESET                                                    64800013
CHECK    SR    R0,FREG            IS WORKAREA SUFFICIENT FOR DATA       65200013
         BNM   MOVE                BRANCH IF YES - USE COUNT OF DATA    65600013
         AR    FREG,R0             ELSE USE SIZE OF WORKAREA            66000013
MOVE     BCTR  FREG,0              DECREMENT FOR EXECUTE                66400013
         EX    FREG,MOVSEG     CAUSE SEGMENT TO BE MOVED TO WORKAREA    66800013
         LA    WR1,1(FREG,WR1)     GET ADDRESS OF LAST DATA CHARACTER   67200013
         LCR   FREG,R0             ANY BUFFER REMAINING                 67600013
         BP    SYNEXIT             BRANCH IF YES                        68000013
RESET    SR    WR1,R5              NO - STORE DATA COUNT IN LOCATIONS   68400013
         STC   WR1,1(R5)          STORE LENGTH IN USERS WORK AREA       68800013
         SRL   WR1,8              POSITION SECOND BYTE OF LENGTH        69200013
         STC   WR1,0(R5)          STORE LENGTH IN USERS WORK AREA       69600013
         RETURN  (15,12)           RESTORE REGISTERS 15-12 AND EXIT     70000013
         SPACE                                                          70400013
MOVSEG   MVC   0(1,WR1),8(WR2)     MOVE DATA INTO WORKAREA              70800013
         SPACE                                                          71200013
*  GO TO SYNCHRONOUS EXIT IF WORK AREA SPACE EXHAUSTED                  71600013
SYNEXIT  TM    DCBSYNAD+3,X'01'    SYNEXIT SPECIFIED?                   72000013
         BNZ   RESET               BRANCH IF NO                         72400013
         BAL   14,RESET            ELSE SET RETURN TO NSI               72800013
         L     15,DCBSYNAD-IHADCB(0,1)   LOAD SYNCHRONOUS USER EXIT     73200013
         BALR  14,15               TAKE EXIT                            73600013
         RETURN (14,12)            RESTORE REGISTERS 14-12 AND EXIT     74000013
MOVETERM MVC   0(1,QREG),TERMID(RE)                                     74400013
CLEARNM  XC    0(0,QREG),0(QREG)                                        74800013
         SPACE                                                          75200013
         CNOP  0,8                                                      75600013
CVTABLE  EQU   16                                                       76000013
TERMID   EQU   9                                                        76400013
CVTTRMTB EQU   156                                                      76800013
TTQUES   EQU   4                                                        77200013
         EJECT                                                          77600013
         DCBD  DSORG=(MQ)                                               78000013
         EJECT                                                          78400013
         PREFIXD                                                        78800013
         EJECT                                                          79200013
         QCBD                                                           79600013
         END                                                            80000013
