         TITLE 'IGG019NB  QTAM GET MESSAGE'                             00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-  IGG019NB     QTAM GET MESSAGE                                 * 01600013
*                                                                     * 02000013
*STATUS-  CHANGE LEVEL 001                                OS QTAM II  * 02400013
*                                                                     * 02800013
*FUNCTION-  THE GET MESSAGE FORM OF THE GET MACRO OBTAINS THE NEXT    * 03200013
*   SEQUENTIAL MESSAGE FROM THE INPUT QUEUE ASSOCIATED WITH THE DCB   * 03600013
*   REFERRED TO IN THE GET MACRO.  THE GET MACRO EXPANSION OBTAINS THE* 04000013
*   ADDRESS OF THIS MODULE FROM THE DCB SPECIFIED IN THE GET MACRO.   * 04400013
*        IF EODAD HAS BEEN SPECIFIED AND THERE ARE NO MESSAGES IN THE * 04800013
*   QUEUE, THE PROCESSING PROGRAM'S EXIT ROUTINE IS ENTERED.  IF EODAD* 05200013
*   WAS NOT SPECIFIED OR THERE IS A MESSAGE IN THE QUEUE, THE ADDRESS * 05600013
*   OF THE CURRENT SEGMENT IS OBTAINED FROM THE DCB.                  * 06000013
*        IF DATA REMAINS IN THE BUFFER FROM A PREVIOUS GET, THE DATA  * 06400013
*   IS MOVED TO THE PROCESSING PROGRAM'S WORK AREA.  IF NO DATA       * 06800013
*   REMAINS, THE PREVIOUSLY USED BUFFER (THE FIRST TIME A DUMMY BUFFER* 07200013
*   IS USED) IS RETURNED BY THE QPOST ROUTINE, AND A QWAIT OBTAINS    * 07600013
*   THE NEXT BUFFER.                                                  * 08000013
*        IF THE SEGMENT IS A HEADER SEGMENT, THE ADDRESS OF THE SOURCE* 08400013
*   AREA IS OBTAINED, AND IF THE PREFIX INDICATES A PROCESS QUEUE, THE* 08800013
*   TERMINAL ID IS PLACED IN THIS AREA.                               * 09200013
*        IF THE BUFFER IS EMPTY AND IT IS NOT THE LAST SEGMENT,  THE  * 09600013
*   NEXT BUFFER IS OBTAINED.  IF THE BUFFER IS EMPTY AND IT IS END    * 10000013
*   OF MESSAGE, ZERO IS SET IN THE MESSAGE SEGMENT ADDRESS FIELD OF   * 10400013
*   THE DCB, THE DATA COUNT IS SET IN THE WORK AREA, AND RETURN IS TO * 10800013
*   THE NEXT INSTRUCTION IN THE PROCESSING PROGRAM.                   * 11200013
*        IF THE BUFFER IS NOT EMPTY, THE DATA IS MOVED TO THE WORK    * 11600013
*   AREA.  IF THE SIZE OF THE BUFFER IS SMALLER THAN OR EQUAL TO THE  * 12000013
*   SIZE OF THE WORK AREA AND END OF MESSAGE IS NOT INDICATED,        * 12400013
*   ANOTHER BUFFER IS OBTAINED.  IF END OF MESSAGE IS INDICATED, ZERO * 12800013
*   IS SET IN THE MESSAGE SEGMENT ADDRESS FIELD OF THE DCB, THE DATA  * 13200013
*   COUNT IS SET IN THE WORK AREA, AND RETURN IS TO THE NEXT          * 13600013
*   PROCESSING PROGRAM INSTRUCTION.  IF THE WORK AREA IS FILLED, DATA * 14000013
*   REMAINS IN THE BUFFER, AND SYNAD IS NOT SPECIFIED, ZERO IS SET    * 14400013
*   IN THE MESSAGE SEGMENT ADDRESS FIELD OF THE DCB, THE DATA COUNT   * 14800013
*   IS SET IN THE WORK AREA, AND RETURN IS TO THE NEXT PROCESSING     * 15200013
*   PROGRAM INSTRUCTION.  IF SYNAD IS SPECIFIED, THE PROCESSING       * 15600013
*   PROGRAM'S SYNCHRONOUS EXIT ROUTINE IS ENTERED BEFORE RETURN IS    * 16000013
*   MADE.                                                             * 16400013
*                                                                     * 16800013
*ENTRY POINTS-  IGG019NB - EXPANSION OF THE GET MESSAGE FORM OF THE   * 17200013
*   GET MACRO GENERATES A BALR TO THIS POINT USING REGISTER 15 AS THE * 17600013
*   ENTRY POINT REGISTER AND REGISTER 14 AS THE RETURN REGISTER.      * 18000013
*                                                                     * 18400013
*INPUT-                                                               * 18800013
*   REGISTER  0- ADDRESS OF WORK AREA INTO WHICH MESSAGE IS TO BE     * 19200013
*        MOVED.                                                       * 19600013
*   REGISTER  1- ADDRESS OF DCB ASSOCIATED WITH THE GET OPERATION.    * 20000013
*   REGISTER 14- RETURN ADDRESS.                                      * 20400013
*   REGISTER 15- ENTRY POINT                                          * 20800013
*                                                                     * 21200013
*OUTPUT-  THE NEXT SEQUENTIAL MESSAGE FROM THE INPUT QUEUE ASSOCIATED * 21600013
*   WITH THE DCB REFERENCED IN THE GET MACRO WILL BE MOVED TO THE WORK* 22000013
*   AREA REFERRED TO IN THE GET MACRO.  THE FIRST FOUR BYTES OF THE   * 22400013
*   WORK AREA ARE USED FOR THE SEGMENT PREFIX.  THE FIRST TYO BYTES   * 22800013
*   SPECIFY THE NUMBER OF CHARACTERS IN THE MESSAGE, THE THIRD BYTE   * 23200013
*   SPECIFIES THE SEGMENT TYPE, AND THE FOURTH BYTE IS A ZERO.        * 23600013
*                                                                     * 24000013
*EXTERNAL ROUTINES-                                                   * 24400013
*        IGG065- QWAIT ROUTINE OF MODULE IECKQQ01.                    * 24800013
*        IGG067- QPOST ROUTINE OF MODULE IECKQQ01.                    * 25200013
*                                                                     * 25600013
*EXITS-NORMAL- RETURN IS TO THE NEXT INSTURCTION IN THE PROCESSING    * 26000013
*   PROGRAM.                                                          * 26400013
*       ERRORS- IF EODAD IS SPECIFIED AND THERE ARE NO MESSAGES IN THE* 26800013
*   QUEUE, THE PROCESSING PROGRAM'S EXIT ROUTINE IS ENTERED BEFORE    * 27200013
*   RETURN IS MADE.  IF SYNAD IS SPECIFIED AND THE MESSAGE IS TOO     * 27600013
*   LARGE FOR THE WORK AREA, THE PROCESSING PROGRAM'S SYNCHRONOUS     * 28000013
*   EXIT ROUTINE IS ENTERED BEFORE RETURN IS MADE.                    * 28400013
*                                                                     * 28800013
*TABLES/WORK AREAS-  N/A.                                             * 29200013
*                                                                     * 29600013
*ATTRIBUTES-  PROBLEM PROGRAM MODE, RESIDENT, SERIALLY REUSABLE,      * 30000013
*   ENABLED.                                                          * 30400013
*                                                                     * 30800013
*NOTES-  REGISTERS ARE SAVED ON ENTRY AND RESTORED ON RETURN.         * 31200013
*                                                                     * 31600013
*********************************************************************** 32000013
IGG019NB START                                                          32400013
*1210433000-434000,582000,621000-622000                            5123 32600016
* 738000-740000,760000,810000,812000                             A20408 32660019
* 809000,811000                                                  A28765 32720019
* 537000-539000,625000                                           A37728 32740020
* 620500                                                           00PS 32760020
R0       EQU   0                                                        32800013
FREG     EQU   1                                                        33200013
TREG     EQU   2                                                        33600013
DCBR     EQU   3                                                        34000013
WR1      EQU   4                                                        34400013
R5       EQU   5                                                        34800013
RDEB     EQU   6                                                        35200013
RD       EQU   7                                                        35600013
RE       EQU   9                                                        36000013
SIZE     EQU   10                                                       36400013
QREG     EQU   11                                                       36800013
WR2      EQU   12                                                       37200013
SREG     EQU   15                                                       37600013
TXT      EQU   X'01'                                                    38000013
EOM      EQU   X'02'                                                    38400013
QATTACH  EQU   72                                                       38800013
QWAIT    EQU   65                                                       39200013
QPOST    EQU   67                                                       39600013
         USING IHADCB,FREG                                              40000013
         USING QBLOCK,QREG                                              40400013
         USING *,SREG                                                   40800013
         SAVE  (14,12)                                                  41200013
         TM    DCBEODAD,X'F0'     IS A BUFFER PRESENT                   41600013
         BZ    GETBUF             BRANCH IF YES                         42000013
         TM    DCBEODAD+3,X'01'    EODAD SPECIFIED?                     42400013
         BNZ   GETBUF              BRANCH IF NO                         42800013
         L     RDEB,DCBDEBAD       GET DEB ADDRESS                      43200013
         TM    60(RDEB),7     IN PROCESS OF READING FROM DISK      5123 43300016
         BC    6,GETBUF          BRANCH IS YES                     5123 43400016
         L    QREG,36(0,RDEB)          ACCESS NEXT ELEMENT IN ELT CHAIN 43600013
*                                         OF MAIN STORAGE PROCESS Q     44000013
         CLI   4(QREG),255        IS IT DUMMY LAST ELEMENT              44400013
         BNE   GETBUF             BRANCH IF NO                          44800013
*  EODAD ROUTINE                                                        45200013
         LM    2,12,28(13)         RESTORE REGISTERS 2-12 FOR USER EXIT 45600013
         L     15,DCBEODAD         LOAD EXIT ADDRESS                    46000013
         BALR  14,15               TAKE EXIT IF NO MESSAGES IN QUEUE    46400013
* RETURN FROM USER EXIT RESTORE REGISTERS                               46800013
         LM    14,1,12(13)         RESTORE REGISTERS 14-1 FOR GET       47200013
         USING IHADCB,DCBR                                              47600013
         USING IECKPREF,FREG                                            48000013
GETBUF   EQU   *                                                        48400013
         LR    DCBR,FREG           LOAD DCB ADDRESS                     48800013
         L     RDEB,DCBDEBAD       GET DEB ADDRESS                      49200013
         LR    R5,R0               GET WORKAREA ADDRESS IN R5           49600013
         LH    R0,DCBSOWA          GET SIZE OF WORKAREA                 50000013
         LA    WR1,4               GET 4 BYTE ADJUSTMENT                50400013
         SR    R0,WR1              GET START OF MESSAGE ADDRESS         50800013
         AR    WR1,R5                    IN WR1                         51200013
         L     RD,CVTABLE(0,0)     GET CVT ADDRESS                      51600013
         L     RD,CVTTRMTB(0,RD)    GET TERMTBL ADDRESS                 52000013
         L    WR2,DCBSEGAD             GET ADDR OF BUFFER STORED IN DCB 52400013
         CLI   DCBSEGAD,0          IS THIS FROM A PREVIOUS GET          52800013
         BNE   CONT                BRANCH IF YES                        53200013
         MVI   2(R5),0             MOVE ZERO TO SEGMENT TYPE            53600013
         TM    DCBEODAD,X'0F'      THIS FIRST BUFFER OF MESSAGE  A37728 53700020
         BZ    GETSEG              BRANCH IF FIRST BUFFER        A37728 53800020
         MVI   2(R5),1             ELSE INDICATE TEXT SEGMENT    A37728 53900020
GETSEG   LR    FREG,WR2            ACCESS BUFFER FOR POST               54000013
         L     TREG,4(0,RD)        GET ADDRESS OF QTAM MAIN PROGRAM     54400013
         LR    SIZE,TREG          SAVE ADDRESS OF QTAM MAIN PROGRAM     54800013
         L    TREG,0(TREG)             GET ADDRESS OF RETURN            55200013
         L    TREG,280(TREG)               BUFFER QCB                   55600013
         TM    DCBEODAD,X'F0'     IS A BUFFER PRESENT                   56000013
         BO    QWAITT             BRANCH BUFFER NOT PRESENT             56400013
         SVC   QPOST               POST TO RETURN BUFFER QUEUE          56800013
         OI    DCBEODAD,X'F0'     FLAG TO INDICATE NO BUFFER PRESENT    57200013
         TM    DCBEODAD,X'0F'     THIS FIRST BUFFER OF MESSAGE          57600013
         BO    QWAITT             BRANCH NOT FIRST BUFFER               58000013
RELOAD   EQU   *                                                   5123 58200016
         LM    14,12,12(13)       RELOAD REGISTERS                      58400013
         BR    SREG               GO BACK AND TEST FOR EODAD            58800013
QWAITT   LA    TREG,36(RDEB)       GET POINTER TO QCB                   59200013
* QWAIT  CORE PROCESS QUEUE                                             59600013
         SVC   QWAIT               WAIT FOR NEXT BUFFER                 60000013
         LA    FREG,0(0,FREG)          SAVE ADDRESS OF BUFFER IN DCB    60400013
         ST    FREG,DCBSEGAD              AND INITIALIZE 1ST BYTE TO 0  60800013
         LA    TREG,QATTACH(SIZE) ADDRESS OF QATTACH FOR QWAIT          61200013
         SVC   QWAIT              ASSURE PROCESS QUEUE OFF READY QUEUE  61600013
         MVI   DCBEODAD,0         FLAG TO INDICATE BUFFER PRESENT       62000013
         L     FREG,DCBSEGAD       RELOAD BUFFER ADDRESS           00PS 62050020
         TM    MSTATUS,X'80'      HAS MESSAGE BEEN CANCELED        5123 62100016
         BO    RELOAD             RETURN TO GET NEXT BUFFER        5123 62200016
         OI    DCBEODAD,X'0F'      SET NOT FIRST BUFFER SWITCH   A37728 62500020
         LA    WR2,TXSTRT-8        GET START OF TEXT MINUS 8            62800013
* TEST FOR HEADER OR TEXT SEGMENT                                       63200013
         TM    MSTATUS,TXT         IS THIS TEXT SEGMENT                 63600013
         BC    1,TEXTSEG           IF YES BRANCH                        64000013
         LA    WR2,HDSTRT-8        GET START OF HEADER MINUS 8          64400013
         L     QREG,DCBTRMAD       GET ADDRESS OF SOURCE AREA           64800013
*                                                                       65200013
*      MOVE TERM NAME TO USERS AREA                                     65600013
*                                                                       66000013
         IC    SIZE,4(RD)         MAX TERM NAME LENGTH                  66400013
         BCTR  SIZE,0                  SUB ONE FOR MOVE                 66800013
         EX    SIZE,CLEARNM       CLEAR NAME FIELD                      67200013
         LH    RE,TTSKEY           GET SOURCE KEY TO TERMTBL            67600013
         LTR   RE,RE               IS IT PROCESS QUEUE                  68000013
         BZ    TEXTSEG             BRANCH IF YES                        68400013
         AR    RE,RD               GET ADDRESS OF SOURCE IN TERMTBL     68800013
         EX    SIZE,MOVETERM           MOVE TERM NAME TO USERS AREA     69200013
TEXTSEG  LA    FREG,FBLOCK         ACCESS BUFFER FROM PROCESS QUEUE     69600013
         AH    FREG,MSEGSZE        BUMP TO END OF SEGMENT               70000013
         SR    FREG,WR2            IS ANYTHING IN BUFFER                70400013
         BNP   TEOM                BRANCH IF NO                         70800013
CHECK    SR    R0,FREG             IS WORKAREA SUFFICIENT FOR DATA      71200013
         BNM   MOVE                BRANCH IF YES - USE COUNT OF DATA    71600013
         AR    FREG,R0             ELSE USE SIZE OF WORKAREA            72000013
MOVE     BCTR  FREG,0              DECREMENT FOR EXECUTE                72400013
         EX    FREG,MOVSEG     CAUSE SEGMENT TO BE MOVED TO WORKAREA    72800013
         LA    WR1,1(FREG,WR1) GET ADDRESS OF LAST CHAR IN WORKAREA     73200013
         LCR   FREG,R0             ANY BUFFER REMAINING                 73600013
         BZ    SYNEXIT            BRANCH IF END OF BUFFER        A20408 73800019
         BP    SYNEXIT2           BRANCH IF Y5S                  A20408 74000019
TEOM     L    WR2,DCBSEGAD             GET ADDR OF BUFFER STORED IN DCB 74400013
         TM    MSTATUS-FBLOCK(WR2),EOM     LAST OF MESSAGE              75200013
         BZ    GETSEG              BRANCH IF NO                         75600013
ISEOM    NI    DCBEODAD,X'F0'     CLEAR NOT FIRST BUFFER SWITCH   20408 76000019
         SR    FREG,FREG           CLEAR WORKAREA SIZE                  76400013
         OI    2(R5),2             SET SEGMENT TYPE                     76800013
RESET    STC   FREG,DCBSEGAD       STORE ZERO IN FIRST BYTE OF SEG ADDR 77200013
         SR    WR1,R5              STORE DATA COUNT IN LOCATIONS        77600013
         STC   WR1,1(R5)          STORE LENGTH IN USERS WORK AREA       78000013
         SRL   WR1,8              POSITION SECOND BYTE OF LENGTH        78400013
         STC   WR1,0(R5)          STORE LENGTH IN USERS WORK AREA       78800013
         RETURN  (15,12)           RESTORE REGISTERS 15-12 AND EXIT     79200013
         SPACE                                                          79600013
MOVSEG   MVC   0(1,WR1),8(WR2)     MOVE MESSAGE TO WORKAREA             80000013
         SPACE                                                          80400013
*  GO TO SYNCHRONOUS EXIT IF WORK AREA SPACE EXHAUSTED                  80800013
SYNEXIT  L     WR2,DCBSEGAD       GET ADDR OF BUFFER STORED IN DCB28765 80900019
         TM    MSTATUS-FBLOCK(WR2),EOM  LAST OF MESSAGE           20408 81000019
         BO    ISEOM              BRANCH IF YES                  A28765 81100019
SYNEXIT2 TM    DCBSYNAD+3,X'01'   SYNEXIT SOECIFIED?             A20408 81200019
         BNZ   RESET               BRANCH IF NO                         81600013
         BAL   14,RESET            ELSE SET RETURN TO NSI               82000013
         L     15,DCBSYNAD-IHADCB(0,1)   LOAD SYNCHRONOUS USER EXIT     82400013
         BALR  14,15               TAKE EXIT                            82800013
         RETURN (14,12)            RESTORE REGISTERS 14-12 AND EXIT     83200013
         SPACE                                                          83600013
* SET UP TO MOVE REMAINDER OF BUFFER FROM PREVIOUS GET                  84000013
CONT     AH    WR2,MSEGSZE-FBLOCK(0,WR2) GET NEXT MESSAGE ADDRESS       84400013
         SR    FREG,FREG           ACCESS COUNT OF UNMOVED              84800013
         IC    FREG,DCBSEGAD             CHARACTERS IN BUFFER           85200013
         SR    WR2,FREG      GET ADDR OF DATA TO BE MOVED FROM BUFFER   85600013
         MVI   2(R5),1       INDICATE NEXT SEGMENT IN SEGMENT TYPE      86000013
         B     CHECK               GO TO MOVE                           86400013
MOVETERM MVC   0(1,QREG),TERMID(RE)                                     86800013
CLEARNM  XC    0(0,QREG),0(QREG)                                        87200013
         SPACE                                                          87600013
         CNOP  0,8                                                      88000013
CVTABLE  EQU   16                                                       88400013
TERMID   EQU   9                                                        88800013
CVTTRMTB EQU   156                                                      89200013
TTQUES   EQU   4                                                        89600013
         EJECT                                                          90000013
         DCBD  DSORG=(MQ)                                               90400013
         EJECT                                                          90800013
         PREFIXD                                                        91200013
         EJECT                                                          91600013
         QCBD                                                           92000013
         END                                                            92400013
