*STATUS-  CHANGE LEVEL 001                                OS QTAM II  * 00400013
*                                                                     * 00800013
*FUNCTION-  THE GET RECORD FORM OF THE GET MACRO OBTAINS THE NEXT     * 01200013
*   SEQUENTIAL MESSAGE FROM THE INPUT QUEUE ASSOCIATED WITH THE DCB   * 01600013
*   REFERRED TO IN THE GET MACRO.                                     * 02000013
*        IF EODAD IS SPECIFIED, NO MESSAGES ARE IN THE QUEUE, AND     * 02400013
*   DATA IS LEFT IN THE BUFFER FROM A PREVIOUS GET, THE DATA IS       * 02800013
*   MOVED TO THE WORK AREA.  IF NO DATA IS LEFT IN THE BUFFER, THE    * 03200013
*   PREVIOUSLY USED BUFFER (THE FIRST TIME A DUMMY BUFFER IS USED)    * 03600013
*   IS RETURNED BY A QPOST AND A NEW BUFFER IS OBTAINED BY A QWAIT.   * 04000013
*        IF THE BUFFER CONTAINS A HEADER SEGMENT AND THE PREFIX       * 04400013
*   INDICATES A PROCESS QUEUE, THE TERMINAL ID IS MOVED INTO THE      * 04800013
*   SOURCE AREA.  IF THE BUFFER IS EMPTY AND IT IS NOT THE LAST       * 05200013
*   SEGMENT, ANOTHER BUFFER IS OBTAINED.  IF IT IS END OF MESSAGE,    * 05600013
*   THE DATA COUNT IS SET IN THE WORK AREA AND RETURN IS TO THE       * 06000013
*   NEXT PROCESSING PROGRAM INSTRUCTION.                              * 06400013
*        THE SEGMENT IS MOVED INTO THE WORK AREA IF ENOUGH SPACE IS   * 06800013
*   AVAILIABLE.  IF THE SPACE IS NOT AVAILABLE AND SYNAD IS SPECIFIED,* 07200013
*   THE COUNT IS SET IN THE WORK AREA AND THE PROCESSING PROGRAM'S    * 07600013
*   SYNCHRONOUS EXIT ROUTINE IS ENTERED BEFORE RETURN IS MADE.  IF    * 08000013
*   NO SYNAD IS SPECIFIED, THE COUNT IS SET IN THE WORK AREA AND      * 08400013
*   RETURN IS TO THE NEXT PROCESSING PROGRAM INSTRUCTION.             * 08800013
*        IF ANY CHARACTER IN THE BUFFER IS AN NL (NEW LINE) OR AN     * 09200013
*   EOB (END OF BLOCK), THEN ALL CONSECTUTIVE NL'S OR EOB'S ARE       * 09600013
*   MOVED INTO THE WORK AREA, THE COUNT IS SET, AND RETURN IS TO      * 10000013
*   THE NEXT PROCESSING PROGRAM INSTRUCTION.                          * 10400013
*        IF THERE IS NO MORE DATA IN THE BUFFER AND IT IS NOT END OF  * 10800013
*   MESSAGE, ANOTHER BUFFER IS OBTAINED.  IF THERE IS NO MORE DATA    * 11200013
*   IN THE BUFFER AND IT IS END OF MESSAGE, THEN THE DATA COUNT IS    * 11600013
*   STORED IN THE WORK AREA AND RETURN IS TO THE NEXT PROCESSING      * 12000013
*   PROGRAM INSTRUCTION.                                              * 12400013
*                                                                     * 12800013
*ENTRY POINTS-  IGG019NC - EXPANSION OF THE GET RECORD FORM OF THE    * 13200013
*   GET MACRO GENERATES A BALR TO THIS POINT USING REGISTER 15 AS     * 13600013
*   THE ENTRY POINT REGISTER AND REGISTER 14 AS THE RETURN ADDRESS    * 14000013
*   REGISTER.                                                         * 14400013
*                                                                     * 14800013
*INPUT-                                                               * 15200013
*   REGISTER  0- ADDRESS OF THE WORK AREA INTO WHICH THE MESSAGE IS   * 15600013
*        TO BE MOVED.                                                 * 16000013
*   REGISTER  1- ADDRESS OF THE DCB TO BE USED IN THE GET OPERATION.  * 16400013
*   REGISTER 14- RETURN ADDRESS.                                      * 16800013
*   REGISTER 15- ENTRY POINT.                                         * 17200013
*                                                                     * 17600013
*OUTPUT-  THE NEXT MESSAGE WILL BE PLACED IN THE WORK AREA POINTED    * 18000013
*   TO BY REGISTER 0.  THE FIRST FOUR BYTES OF THE WORK AREA WILL     * 18400013
*   CONTAIN THE MESSAGE PREFIX.  THE FIRST TWO BYTES SPECIFIES THE    * 18800013
*   NUMBER OF CHARACTERS IN THE MESSAGE, THE THIRD BYTE INDICATES     * 19200013
*   SEGMENT TYPE, AND THE FOURTH BYTE IS A ZERO.                      * 19600013
*                                                                     * 20000013
*EXTERNAL ROUTINES-                                                   * 20400013
*        IGG065 - QWAIT ROUTINE IN MODULE IECKQQ01.                   * 20800013
*        IGG067 - QPOST ROUTINE IN MODULE IECKQQ01.                   * 21200013
*                                                                     * 21600013
*EXITS- NORMAL - RETURN IS TO THE NEXT PROCESSING PROGRAM INSTRUCTION.* 22000013
*        ERRORS - IF EODAD IS SPECIFIED AND NO MESSAGES ARE IN THE    * 22400013
*   QUEUE, THE PROCESSING PROGRAM'S EXIT ROUTINE IS ENTERED BEFORE    * 22800013
*   CONTROL IS RETURNED TO THE NEXT PROCESSING PROGRAM INSTRUCTION.   * 23200013
*   IF THE MESSAGE IS TOO LARGE TO FIT IN THE WORK AREA AND SYNAD IS  * 23600013
*   SPECIFIED, THE PROCESSING PROGRAM'S SYNCHRONOUS EXIT ROUTINE IS   * 24000013
*   ENTERED BEFORE RETURN IS MADE.                                    * 24400013
*                                                                     * 24800013
*TABLES/WORK AREAS-  N/A.                                             * 25200013
*                                                                     * 25600013
*ATTRIBUTES-  PROBLEM PROGRAM MODE, SERIALLY REUSABLE, ENABLED,       * 26000013
*   RESIDENT.                                                         * 26400013
*                                                                     * 26800013
*NOTES-  REGISTERS ARE SAVED ON ENTRY AND RESTORED ON RETURN.         * 27200013
*                                                                     * 27600013
*********************************************************************** 28000013
IGG019NC START                                                          28400013
*1210397000-398000,558000,597000-598000                            5123 28600016
R0       EQU   0                                                        28800013
FREG     EQU   1                                                        29200013
TREG     EQU   2                                                        29600013
DCBR     EQU   3                                                        30000013
WR1      EQU   4                                                        30400013
R5       EQU   5                                                        30800013
RDEB     EQU   6                                                        31200013
RD       EQU   7                                                        31600013
ENDREG   EQU   8                                                        32000013
RE       EQU   9                                                        32400013
SIZE     EQU   10                                                       32800013
QREG     EQU   11                                                       33200013
WR2      EQU   12                                                       33600013
SREG     EQU   15                                                       34000013
TXT      EQU   X'01'                                                    34400013
EOM      EQU   X'02'                                                    34800013
QATTACH  EQU   72                                                       35200013
QWAIT    EQU   65                                                       35600013
QPOST    EQU   67                                                       36000013
         USING IHADCB,FREG                                              36400013
         USING QBLOCK,QREG                                              36800013
         USING *,SREG                                                   37200013
         SAVE  (14,12)             SAVE REGISTERS                       37600013
         TM    DCBEODAD,X'F0'     IS A BUFFER PRESENT                   38000013
         BZ    GETBUF             BRANCH IF YES                         38400013
         TM    DCBEODAD+3,X'01'    EODAD SPECIFIED BY USER              38800013
         BNZ   GETBUF              BRANCH IF NO TO WAIT ON MESSAGE      39200013
         L     RDEB,DCBDEBAD       GET DEB ADDR                         39600013
         TM    60(RDEB),7     IN PROCESS OF READING FROM DISK      5123 39700016
         BC    6,GETBUF          BRANCH IS YES                     5123 39800016
         L    QREG,36(0,RDEB)          ACCESS NEXT ELEMENT IN ELT CHAIN 40000013
*                                         OF MAIN STORAGE PROCESS Q     40400013
         CLI   4(QREG),255                IS IT DUMMY LAST ELEMENT      40800013
         BNE   GETBUF              BRANCH IF YES                        41200013
         CLI   DCBSEGAD,0         BUFFER LEFT OVER                      41600013
         BNE   GETBUF             BRANCH IF YES                         42000013
*  EODAD ROUTINE                                                        42400013
         L     15,DCBEODAD         LOAD EXIT ADDRESS                    42800013
         LM    2,12,28(13)         RESTORE REGISTERS 2-12 FOR USER EXIT 43200013
         BALR  14,15               TAKE EXIT                            43600013
* RETURN FROM USER EXIT RESTORE REGISTERS                               44000013
         LM    14,1,12(13)         RESTORE REGISTERS 14-1 FOR GET       44400013
         USING IHADCB,DCBR                                              44800013
         USING IECKPREF,FREG                                            45200013
GETBUF   EQU   *                                                        45600013
         LR    DCBR,FREG           LOAD DCB ADDRESS                     46000013
         L     RDEB,DCBDEBAD       GET DEB ADDRESS                      46400013
         LR    R5,R0               GET WORKAREA ADDRESS IN R5           46800013
         LA    ENDREG,MOVE         LOAD BRANCH ADDRESS FOR FINISH       47200013
         LH    R0,DCBSOWA          GET SIZE OF WORKAREA                 47600013
         LA    WR1,3               SET UP ADJUSTMENT FOR WORKAREA       48000013
         SR    R0,WR1              DECREMENT WORKAREA SIZE BY 3         48400013
         LA    WR1,4(0,R5)         SET INDEX TO FIRST WORKAREA LOC      48800013
         L     RD,CVTABLE(0,0)     GET CVT ADDRESS                      49200013
         L     RD,CVTTRMTB(0,RD)    GET TERMTBL ADDRESS                 49600013
         L    WR2,DCBSEGAD             GET ADDR OF BUFFER STORED IN DCB 50000013
         CLI   DCBSEGAD,0         IS THIS FROM A PREVIOUS GET           50400013
         BNE   CONT                BRANCH IF YES                        50800013
         MVI   2(R5),0             MOVE ZERO TO SEGMENT TYPE            51200013
GETSEG   LR    FREG,WR2            ACCESS PREVIOUS BUFFER FOR POST      51600013
         L     TREG,4(0,RD)        GET ADDRESS OF QTAM MAIN PROGRAM     52000013
         LR    SIZE,TREG          SAVE ADDRESS OF QTAM MAIN PROGRAM     52400013
         L     TREG,0(TREG)            GET ADDRESS OF RETURN            52800013
         L    TREG,280(TREG)              BUFFER QCB                    53200013
         TM    DCBEODAD,X'F0'     IS A BUFFER PRESENT                   53600013
         BO    QWAITT             BRANCH BUFFER NOT PRESENT             54000013
         SVC   QPOST               POST TO RETURN BUFFER QUEUE          54400013
         OI    DCBEODAD,X'F0'     FLAG TO INDICATE NO BUFFER PRESENT    54800013
         TM    DCBEODAD,X'0F'     THIS FIRST BUFFER OF MESSAGE          55200013
         BO    QWAITT             BRANCH NOT FIRST BUFFER               55600013
RELOAD   EQU   *                                                   5123 55800016
         LM    14,12,12(13)       RELOAD REGISTERS                      56000013
         BR    SREG               GO BACK AND TEST FOR EODAD            56400013
QWAITT   LA    TREG,36(RDEB)       GET POINTER TO QCB                   56800013
* QWAIT  CORE PROCESS QUEUE                                             57200013
         SVC   QWAIT               WAIT FOR NEXT BUFFER                 57600013
         LA   FREG,0(0,FREG)           SAVE ADDRESS OF BUFFER IN DCB    58000013
         ST   FREG,DCBSEGAD               AND INITIALIZE 1ST BYTE TO 0  58400013
         LA    TREG,QATTACH(SIZE) ADDRESS OF QATTACH FOR QWAIT          58800013
         SVC   QWAIT              ASSURE PROCESS QUEUE OFF READY QUEUE  59200013
         MVI   DCBEODAD,0         FLAG TO INDICATE BUFFER PRESENT       59600013
         TM    MSTATUS,X'80'      HAS MESSAGE BEEN CANCELED        5123 59700016
         BO    RELOAD             RETURN TO GET NEXT BUFFER        5123 59800016
         L     FREG,DCBSEGAD      RELOAD BUFFER ADDRESS                 60000013
         LA    WR2,TXSTRT-8        GET START OF TEXT MINUS 8            60400013
* TEST FOR HEADER OR TEXT SEGMENT                                       60800013
         TM    MSTATUS,TXT         IS THIS TEXT SEGMENT                 61200013
         BC    1,TEXTSEG           IF YES BRANCH                        61600013
         LA    WR2,HDSTRT-8        GET START OF HEADER MINUS 8          62000013
         L     QREG,DCBTRMAD       GET ADDRESS OF SOURCE AREA           62400013
*                                                                       62800013
*      MOVE TERM NAME TO USERS AREA                                     63200013
*                                                                       63600013
         IC    SIZE,4(RD)         MAX TERM NAME LENGTH                  64000013
         BCTR  SIZE,0                  SUB ONE FOR MOVE                 64400013
         EX    SIZE,CLEARNM       CLEAR NAME FIELD                      64800013
         LH    RE,TTSKEY           GET SOURCE KEY TO TERMTBL            65200013
         LTR   RE,RE               IS IT PROCESS QUEUE                  65600013
         BZ    TEXTSEG             BRANCH IF YES                        66000013
         AR    RE,RD               GET ADDRESS OF SOURCE IN TERMTBL     66400013
         EX    SIZE,MOVETERM           MOVE TERM NAME TO USERS AREA     66800013
TEXTSEG  LA    FREG,FBLOCK         ACCESS BUFFER FROM PROCESS QUEUE     67200013
         AH    FREG,MSEGSZE        BUMP TO END OF SEGMENT               67600013
         SR    FREG,WR2            IS ANYTHING IN BUFFER                68000013
         BNP   TEOM                BRANCH IF NO                         68400013
CHECK    CLI   8(WR2),X'15'        IS THIS CHARACTER NL (NEW LINE)      68800013
         BE    END                 BRANCH IF YES                        69200013
         CLI   8(WR2),X'03'       2260 ETX CHARACTER                    69600013
         BE    END                BRANCH IF YES                         70000013
         CLI   8(WR2),X'26'       IS THIS AN EOB CHARACTER              70400013
         BCR   7,ENDREG            BRANCH TO MOVE IF NO                 70800013
END      LA    ENDREG,RESET        ENSURE RETURN FROM LAST EOB          71200013
MOVE     BCT   R0,MOVSEG           DECREMENT WORKAREA - TEST IF DONE    71600013
         SPACE                                                          72000013
*  GO TO SYNCHRONOUS EXIT IF WORKAREA SPACE EXHAUSTED                   72400013
SYNEXIT  TM    DCBSYNAD+3,X'01'    SYNEXIT SPECIFIED?                   72800013
         BNZ   RESET               BRANCH IF NO                         73200013
         BAL   14,RESET            ELSE SET RETURN TO NSI               73600013
         L     15,DCBSYNAD-IHADCB(0,1) LOAD SYNCHRONOUS USER EXIT       74000013
         BALR  14,15               TAKE EXIT                            74400013
         RETURN (14,12)            RESTORE REGISTERS 14-12 AND EXIT     74800013
         SPACE                                                          75200013
*  GO TO MOVE CHARACTER IF WORKAREA NOT EXHAUSTED                       75600013
MOVSEG   MVC   0(1,WR1),8(WR2)   MOVE CHARACTER FROM BUFFER TO WORKAREA 76000013
         LA    WR1,1(WR1)          BUMP WORKAREA TO NEXT CHARACTER      76400013
         LA    WR2,1(WR2)          BUMP BUFFER TO NEXT LOCATION         76800013
         BCT   FREG,CHECK          BRANCH IF MORE BUFFER TO MOVE        77200013
TEOM     L    WR2,DCBSEGAD             GET ADDR OF BUFFER STORED IN DCB 77600013
         OI    DCBEODAD,X'0F'     SET NOT FIRST BUFFER SWITCH           78000013
         TM    MSTATUS-FBLOCK(WR2),EOM     LAST OF MESSAGE              78400013
         BZ    GETSEG              BRANCH IF NO                         78800013
         NI    DCBEODAD,X'F0'     CLEAR NOT FIRST BUFFER SWITCH         79200013
         OI    2(R5),2             SET SEGMENT TYPE                     79600013
RESET    STC   FREG,DCBSEGAD                                            80000013
         SR    WR1,R5              STORE DATA COUNT IN LOCATIONS        80400013
         STC   WR1,1(R5)          STORE LENGTH IN USERS WORK AREA       80800013
         SRL   WR1,8              POSITION SECOND BYTE OF LENGTH        81200013
         STC   WR1,0(R5)          STORE LENGTH IN USERS WORK AREA       81600013
         RETURN  (15,12)           RESTORE REGISTERS 15-12 AND EXIT     82000013
         SPACE                                                          82400013
* SET UP TO MOVE REMAINDER OF BUFFER FROM PREVIOUS GET                  82800013
CONT     AH    WR2,MSEGSZE-FBLOCK(0,WR2) GET NEXT MESSAGE ADDRESS       83200013
         SR    FREG,FREG           ACCESS COUNT OF UNMOVED              83600013
         IC    FREG,DCBSEGAD             CHARACTERS IN BUFFER           84000013
         SR    WR2,FREG            GET ADDRESS OF DATA TO BE MOVED      84400013
         MVI   2(R5),1             SET TO INDICATE NEXT SEGMENT         84800013
         B     CHECK               GO TO CHECK NEXT CHARACTER           85200013
MOVETERM MVC   0(1,QREG),TERMID(RE)                                     85600013
CLEARNM  XC    0(0,QREG),0(QREG)                                        86000013
         SPACE                                                          86400013
         CNOP  0,8                                                      86800013
CVTABLE  EQU   16                                                       87200013
TERMID   EQU   9                                                        87600013
CVTTRMTB EQU   156                                                      88000013
TTQUES   EQU   4                                                        88400013
         EJECT                                                          88800013
         DCBD  DSORG=(MQ)                                               89200013
         EJECT                                                          89600013
         PREFIXD                                                        90000013
         EJECT                                                          90400013
         QCBD                                                           90800013
         END                                                            91200013
