         TITLE 'IGG019ND  QTAM PUT MESSAGE SEGMENT'                     00400013
*********************************************************************** 00460021
*                                                                     * 00520021
* STATUS-      CHANGE LEVEL = 18        JANUARY 1971                  * 00580021
*                                                                     * 00640021
* FUNCTION - THE PUT SEGMENT ROUTINE IS COMPOSED OF TWO SECTIONS.  THE* 00700021
*    FIRST SECTION IS ENTERED FROM THE MACRO EXPANSION.  IF AN ERROR  * 00760021
*    IS DETECTED, THE FOLLOWING ERROR CODES ARE SET, RIGHT ADJUSTED,  * 00820021
*    IN REGISTER 15; AND RETURN IS MADE TO THE NEXT INSTRUCTION IN THE* 00880021
*    PROCESSING PROGRAM.                                              * 00940021
*         1. IF, BY SEARCHING THROUGH THE TERMINAL TABLE, A MATCH FOR * 01000021
*    THE TERM ID IS NOT FOUND, AN ERROR CODE OF X'20' IS SET.         * 01060021
*         2. IF THE SIZE SPECIFIED IN THE PUT PREFIX PLUS THE PREFIX  * 01120021
*    IS GREATER THAN THE BUFFER SIZE (GOTTEN FROM A CONSTANT IN       * 01180021
*    IGG019NG), AN ERROR CODE OF X'10' IS SET.                        * 01240021
*         3. AN ERROR CODE OF X'40' IS SET IF THE SEQUENCE OF SEGMENTS* 01300021
*    IS INVALID; THAT IS, IF IT IS INITIAL ENTRY AND THE MESSAGE TYPE * 01360021
*    DOES NOT INDICATE A HEADER SEGMENT, OR IT IS NOT THE FIRST OR    * 01420021
*    LAST SEGMENT AND THE MESSAGE TYPE DOES NOT INDICATE A TEXT SEG-  * 01480021
*    MENT, OR IF THE PREVIOUS SEGMENT WAS THE LAST SEGMENT AND THIS   * 01540021
*    SEGMENT IS NOT A HEADER.                                         * 01600021
*         IF THERE ARE NO ERRORS, THE ROUTINE ISSUES AN SVC QPOST TO  * 01660021
*    POST THE BRB IN THE DEB TO THE ACTIVE BRB QUEUE TO REQUEST A NEW * 01720021
*    BUFFER.  AN SVC QWAIT IS ISSUED ON THE QCB IN THE DEB TO WAIT FOR* 01780021
*    THE BUFFER.  A QWAIT IS ISSUED ON THE READY QUEUE FOR THE BRB TO * 01840021
*    BE REMOVED. (IF THE BRB WAS ON THE READY QUEUE WHEN ANOTHER PUT  * 01900021
*    WAS ISSUED, THE BRB WOULD BE LINKED TO ITSELF.)                  * 01960021
*         IF A BUFFER HAS BEEN SAVED IN DCBSEGAD, IT IS POSTED TO THE * 02020021
*    DESTINATION QCB.  AN SVC QWAIT IS ISSUED TO CLEAR THE READY      * 02080021
*    QUEUE.  THE NEW BUFFER IS SAVED IN DCBSEGAD.  IF A BUFFER HAD NOT* 02140021
*    BEEN SAVED IN DCBSEGAD, THE NEW BUFFER IS SAVED IN DCBSEGAD.  FOR* 02200021
*    EITHER CASE, IF THE NEW BUFFER (NOW IN DCBEODAD), IS NOT THE LAST* 02260021
*    SEGMENT, RETURN IS MADE TO THE NEXT INSTRUCTION IN THE PROCESSING* 02320021
*    PROGRAM.  IF IT IS THE LAST SEGMENT, THE BUFFER IS POSTED TO THE * 02380021
*    DESTINATION QUEUE FOLLOWED BY A QWAIT TO EMPTY THE READY QUEUE.  * 02440021
*    DCBSEGAD IS SET TO INDICATE NO BUFFER HAS BEEN SAVED.  RETURN IS * 02500021
*    MADE TO THE NEXT INSTRUCTION IN THE MESSAGE PROCESSING PROGRAM.  * 02560021
*         THE SECOND SECTION OF THE ROUTINE IS ENTERED BY A BRANCH    * 02620021
*    FROM THE BUFFER BRB ROUTINE. (THIS BRANCH ENTRY IS BASED ON A    * 02680021
*    FIXED OFFSET THAT IS GUARANTEED BY AN ORG IN IGG019ND.) TO INIT- * 02740021
*    IALIZE THE PREFIX, THE ADDRESS OF THE LCB IN THE DEB (DEB + 40)  * 02800021
*    IS SET IN THE MSLCB FIELD, THE STATUS FROM THE PUT PREFIX IS     * 02860021
*    MOVED INTO MSTATUS, AND TTSKEY IS ZEROED TO SHOW FROM PROCESSING * 02920021
*    PROGRAM.  IN A FLAG AT DCB + 104 IS SAVED THE STATUS AND 'NOT    * 02980021
*    FIRST TIME' SWITCH.                                              * 03040021
*         FOR A HEADER SEGMENT, THE SEQUENCE IN FIELD IN THE PREFIX IS* 03100021
*    ZEROED AND THE NUMBER OF IDLES IS STORED IN MSPTR FIELD IN THE   * 03160021
*    PREFIX.  THE DATA IS MOVED FROM THE WORKAREA SPECIFIED IN        * 03220021
*    DCBEODAD INTO THE BUFFER.  THE ADDRESS OF THE QCB FOR THE DESTIN-* 03280021
*    ATION TERMINAL SPECIFIED IN DCBEXLST IS MOVED INTO THE LCBDESTQ  * 03340021
*    FIELD OF THE LCB IN THE DEB.  IF THE USER HAS SPECIFIED PRIORITY,* 03400021
*    THAT PRIORITY IS MOVED FROM THE PUT PREFIX INTO DEB + 121; OTHER-* 03460021
*    WISE, THE PRIORITY IS SET TO A BLANK.  THE OFFSET TO THE DESTINA-* 03520021
*    TION TERM ENTRY IN THE TERMINAL TABLE IS STORED IN TTDKEY OF THE * 03580021
*    PREFIX.                                                          * 03640021
*         FOR A TEXT SEGMENT, THE DATA FROM THE WORKAREA IS MOVED INTO* 03700021
*    THE BUFFER.  FOR ALL BUFFERS, THE MESSAGE SIZE IS SET IN MSEGSZE * 03760021
*    OF THE PREFIX AND RETURN IS MADE TO IGG019NG WHICH POST THE      * 03820021
*    BUFFER TO THE MS-DESTINATION QUEUE                               * 03880021
*                                                                     * 03940021
* ENTRY POINTS- ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE WHOSE   * 04000021
*         ADDRESS IS IN THE DCB.                                      * 04060021
*         ENTRY IS ALSO MADE AT IGG019ND + 134 BY A BRANCH FROM       * 04120021
*         IGG019NG.                                                   * 04180021
*                                                                     * 04240021
* INPUT - REGISTERS UPON ENTRY FROM PUT MACRO EXPANSION               * 04300021
*    0 = WORKAREA ADDRESS                                             * 04360021
*    1 = DCB ADDRESS                                                  * 04420021
*    13 = SAVE AREA                                                   * 04480021
*    14 = RETURN ADDRESS                                              * 04540021
*    15 = ADDRESS OF PUT MODULE                                       * 04600021
*         REGISTERS UPON ENTRY FROM IGG019NG                          * 04660021
*    5 = DCB ADDRESS                                                  * 04720021
*    11 = DEB ADDRESS                                                 * 04780021
*    14 = RETURN ADDRESS                                              * 04840021
*    15 = PUT ROUTINE SPECIAL ENTRY POINT                             * 04900021
*                                                                     * 04960021
* OUTPUT- REGISTER 15 CONTAINS RETURN CODES                           * 05020021
*                                                                     * 05080021
* EXTERNAL REFERENCES.                                                * 05140021
*         SVC QPOST                                                   * 05200021
*         SVC QWAIT                                                   * 05260021
*                                                                     * 05320021
* EXITS,NORMAL- THIS ROUTINE EXITS VIA A BRANCH REGISTER 14 TO EITHER * 05380021
*         THE NEXT INSTRUCTION FOLLOWING THE PUT MACRO, OR TO THE     * 05440021
*         BUFFER BRB ROUTINE IN MODULE IGG019NG.                      * 05500021
*                                                                     * 05560021
* EXITS,ERROR-  THIS ROUTINE EXITS VIA A BRANCH REGISTER 14 WITH      * 05620021
*         THE ERROR CODE IN REGISTER 15.                              * 05680021
*                                                                     * 05740021
* TABLES AND WORKAREAS- PUT PREFIX (SEE NOTE)                         * 05800021
*                                                                     * 05860021
* ATTRIBUTES- REENTRANT, ENABLED OR IN SUPERVISOR MODE, ONLY LOADABLE * 05920021
*                                                                     * 05980021
* CHARACTER CODE DEPENDENCY- NONE                                     * 06040021
*                                                                       06800013
*    THIS MODULE IS LOADED BY THE OPEN ROUTINE,IGG0193P.              * 06900021
*********************************************************************** 07000021
IGG019ND START                                                          07200013
*2010230000-234000                                                 8064 07400016
*2540360000                                                        8064 07800017
R0       EQU   0                                                        07850017
*3411106000,684600,687600-691200,712500-713000,714500-715500      19509 07900017
*3411685200-687000,713500-714000                                  20391 07950017
*1201630000-634000,638000                                         23163 07970018
*A004200-022800,069000-070000                                    S21016 07980021
R2       EQU   2                                                        08000013
FREG     EQU   1                                                        08400013
TREG     EQU   2                                                        08800013
R3       EQU   3                                                        09200013
R4       EQU   4                                                        09600013
DCBR     EQU   5                                                        10000013
TTREG    EQU   6                                                        10400013
WR2      EQU   7                                                  19509 10600017
WR1      EQU   8                                                        10800013
WREG0    EQU   9                                                        11200013
RF       EQU   10                                                       11600013
RDEB     EQU   11                                                       12000013
RD       EQU   12                                                       12400013
RC       EQU   13                                                       12800013
RETR     EQU   14                                                       13200013
SREG     EQU   15                                                       13600013
QWAIT    EQU   65                                                       14000013
QPOST    EQU   67                                                       14400013
TERMERR  EQU   X'20'                                                    14800013
         USING IECKPREF,FREG                                            15200013
         USING IECKTERM,TTREG                                           15600013
         USING IHADCB,DCBR                                              16000013
         USING *,SREG                                                   16400013
         SAVE  (14,12)                                                  16800013
         LR    DCBR,FREG           GET DCB ADDR                         17200013
         ST    R0,DCBEODAD             SAVE ADDRESS OF WORK AREA        17600013
         BAL   TTREG,LOADSUB       GO INITIALIZE REGISTERS              18000013
*                                                                       18400013
*      ASSURE VALID TERMINAL BEING PUT TO                               18800013
*                                                                       19200013
         SR    R4,R4                                                    19600013
         ST    R4,16(13)          STORE RETURN CODE IN REGISTER 15      20000013
         LR    TTREG,R0           WORK AREA TO ADDRESSABLE REGISTER     20400013
         TM    2(TTREG),1         IS THIS A TEXT SEGMENT                20800013
         BO    FOUND              SKIP TERM TEST IF NOT HEADER          21200013
         LA    TREG,8(RD)         ADDRESS OF FIRST TERM ENTRY           21600013
         IC    TTREG,4(RD)        LENGTH OF TERM NAMES                  22000013
         BCTR  TTREG,0            SUB ONE FOR THE COMPARE INSTRUCTION   22400013
         L     FREG,DCBTRMAD      ADDRESS OF PUT TERM NAME              22800013
TERMLOOP IC    R4,DCBRECFM         SAVE RECFM                      8064 23000016
         ST    TREG,DCBEXLST       STORE IN CASE OF EQUAL COMPARE  8064 23200016
         STC   R4,DCBRECFM         RESTORE RECFM                   8064 23400016
         EX    TTREG,COMPARE      COMPARE TERM NAMES                    23600013
         BE    FOUND              BRANCH EQUAL TERM FOUND               24000013
         IC    R4,0(TREG)         LENGTH OF THIS ENTRY                  24400013
         AR    TREG,R4            INCREMENT TERM TABLE POINTER          24800013
         C     TREG,0(RD)         COMPARE TO LAST TERM ENTRY            25200013
         BNH   TERMLOOP           BRANCH NOT END OF TABLE               25600013
         OI    19(13),TERMERR     SET FLAG INDICATING TERM ERROR        26000013
FOUND    LR    FREG,R0            WORK AREA ADDRESS TO USABLE REGISTER  26400013
         SR    TREG,TREG                                                26800013
         IC    TREG,0(FREG)       INSERT FIRST BYTE OF LENGTH           27200013
         SLL   TREG,8             POSITION FOR NEXT INSERT              27600013
         IC    TREG,1(FREG)       INSERT SECOND BYTE OF LENGTH          28000013
         B     SIZETEST           GO TEST VALID SIZE AND SEQUENCE       28400013
VALID    CLI   19(13),0           ANY ERROR FLAGS STILL ON              28800013
         BNE   RETURN             BRANCH IF YES                         29200013
         LA    TREG,BREQ(RF)       FREE BUFFER QUEUE ADDRESS            29600013
         AL    TREG,PRICON             SET THE BRB PRIORITY             30000013
         LA    FREG,QELEMAD(RDEB)      BRB ADDRESS                      30400013
         SVC   QPOST               POST REQUEST FOR NEW BUFFER          30800013
         LA    TREG,DEBQCBAD(RDEB)     QCB ADDRESS FOR WAIT             31200013
         SVC   QWAIT               WAIT FOR NEW BUFFER                  31600013
         B     POSTBUFF            GO POST PREVIOUS BUFFER TO           32000013
*                                          DESTINATION QUEUE            32400013
*                                                                       32800013
*        ENTRY TO THIS POINT IS VIA A BRANCH FROM IGG019NG IN           33200013
*       SUPERVISOR MODE                                                 33600013
*                                                                       34000013
*         REGISTERS AT ENTRY           DCBR      DCB ADDRESS            34400013
*                                      RDEB      DEB ADDRESS            34800013
*                                      15        PUT ROUTINE ENTRY PT.  35200013
*                                      14        RETURN ADDRESS         35600013
         ORG   IGG019ND+134                                        8064 36000017
         LR    R0,RD                   SAVE BASE OF QQ01                36400013
         BAL   TTREG,LOADSUB+4     GO INITIALIZE REGISTERS              36800013
         LA    WR1,40(RDEB)        GET ADDRESS OF LCB IN WR1            37200013
         ST    WR1,MSLCB-1         STORE IT IN MESSAGE PREFIX           37600013
* MOVE WORKAREA TO BUFFER                                               38000013
         L     WREG0,DCBEODAD          LOAD ADDRESS OF WORK AREA        38400013
         MVC   MSTATUS(1),2(WREG0) MOVE MESSAGE TYPE INTO BUFFER        38800013
         MVC   DEBSEGF(1,RDEB),2(WREG0) SAVE SEGMENT IN DEB             39200013
         OI    DEBSEGF(RDEB),X'F0'    SET NOT FIRST TIME SWITCH         39600013
         MVC   HALFWORD(2),0(WREG0) MOVE LENGTH OF THE WORK AREA TO A   40000013
*                                   HALF WORD BOUNDRY                   40400013
         LH    WR1,HALFWORD       LOAD LENGTH OF USERS WORK AREA        40800013
         SH    WR1,FIVE            ADJUST COUNT FOR EXECUTE MOVE        41200013
         SR    R2,R2               CLEAR R2                             41600013
         STH   R2,TTSKEY          SET SOURCE EQUAL 0 - PROCESS QUEUE    42000013
         TM    MSTATUS,TXT         IS THIS TEXT SEGMENT                 42400013
         BO    TEXT                BRANCH IF YES                        42800013
         ST    R2,MSNUMIN          ZERO MESSAGE SEQUENCE NUMBERS        43200013
         MVI   40(RDEB),X'18'          SET LCB STATE                    43600013
         BCTR  R2,0                    INITIALIZE FOR FIRST TIME        44000013
IDLOOP   LA    R2,1(R2)                ADD ONE TO IDLE CHARACTER COUNT  44400013
         LA    R3,4(WREG0,R2)          ADDRESS OF CHARACTER TO TEST     44800013
         CLI   0(R3),X'17'             IS THIS AN IDLE CHARACTER        45200013
         BE    IDLOOP                  BRANCH IF IDLE CHARACTER FOUND   45600013
         STC   R2,MSPTR                STORE IDLE CHARACTER COUNT       46000013
         CLC   HALFWORD(2),FIVE   COMPARE USERS WORK AREA LENGTH TO 5   46400013
         BNL   *+8                BRANCH IF FIVE OR GREATER             46800013
         LA    WR1,0              ZERO REG. WITHOUT CHANGING COND. CODE 47200013
         EX    WR1,MVHDR           CAUSE HEADER TO BE MOVED TO BUFFER   47600013
         LA    WR1,25(WR1)        ADD 24 FOR BUFFER PREFIX AND 1 FOR EX 48000013
         BNL   *+6                BRANCH USER WORK AREA NOT LESS THAN 5 48400013
         BCTR  WR1,0              SUB ONE ADDED FOR THE EX OF MOVE      48800013
         L     TTREG,DCBEXLST     ADDRESS OF TERM BEING PUT TO          49200013
         MVC   DEBDESTQ+1(3,RDEB),TQCBADDR LOAD LCB WITH ADDRESS OF     49600013
*                                      QCB FOR DESTINATION TERMINAL     50000013
         MVI   121(RDEB),C' '      LOAD PRIORITY BYTE WITH BLANK        50400013
         CLI   3(WREG0),X'0'       HAS USER SPECIFIED PRIORITY          50800013
         BE    *+10               LEAVE PRIORITY BYTE BLANK IF NOT      51200013
         MVC   121(1,RDEB),3(WREG0) ELSE MOVE IN PRIORITY FROM WORKAREA 51600013
         SR    TTREG,RD            GET OFFSET TO TERMTBL ENTRY          52000013
         STH   TTREG,TTDKEY              AND STORE IN DESTINATION KEY   52400013
         B     POST                GO TO RETURN                         52800013
TEXT     CLC   HALFWORD(2),FIVE   COMPARE USERS WORK AREA LENGTH TO 5   53200013
         BNL   *+8                BRANCH IF FIVE OR GREATER             53600013
         LA    WR1,0              ZERO REG. WITHOUT CHANGING COND. CODE 54000013
         EX    WR1,MVTXT                                                54400013
         LA    WR1,15(WR1)        ADD 14 FOR BUFFER PREFIX AND 1 FOR EX 54800013
         BNL   *+6                BRANCH USER WORK AREA NOT LESS THAN 5 55200013
         BCTR  WR1,0              SUB ONE ADDED FOR THE EX OF MOVE      55600013
POST     STH   WR1,MSEGSZE         STORE SEGMENT SIZE IN PREFIX         56000013
         LA    TREG,QELEMAD(RDEB)      RELOAD BRB ADDRESS               56400013
         LR    RD,R0                   RESTORE BASE FOR QQ01            56800013
         BR    14                      RETURN TO IGG019NG               57200013
COMPARE  CLC   0(1,FREG),9(TREG)                                        57600013
*                                                                       58000013
*      TEST FOR VALID DATA LENGTH FROM USER                             58400013
*                                                                       58800013
SIZETEST TM    2(FREG),TXT        TEST FOR TEXT SEGMENT                 59200013
         LA    TREG,10(TREG)       ADD 10 ASSUMING TEXT SEGMENT         59600013
         BO    ISTXT               BRANCH IF TEXT SEGMENT               60000013
         LA    TREG,10(TREG)       ADD 10 MORE FOR HEADER SEGMENTS      60400013
ISTXT    C     TREG,BUFSZ(RF)      COMPARE LENGTH TO BUFFER SIZE        60800013
         BNH   SIZEOK             BRANCH IF VALID SIZE                  61200013
         OI    19(13),ERRCD       SET RETURN CODE FOR INVALID LENGTH    61600013
*                                                                       62000013
*      CHECK FOR VALID SEGMENT SEQUENCE                                 62400013
*                                                                       62800013
SIZEOK   TM    DEBSEGF(RDEB),X'FF'     TEST THE FIRST TIME SWITCH 23163 63000018
         BZ    CHECKHDR                BRANCH IF INITIAL ENTRY    23163 63200018
         TM    DEBSEGF(RDEB),LAST      TEST THE LAST SEGMENT TYPE 23163 63400018
         BZ    MSGEND              BRANCH IF NOT LAST SEGMENT           63600013
CHECKHDR EQU   *                                                        63800018
         TM    2(FREG),HDR         TEST FOR HEADER IN NEW SEGMENT       64000013
         BZ    VALID               BRANCH IF HEADER                     64400013
         B     INVALID                                                  64800013
MSGEND   TM    2(FREG),HDR         TEST FOR HEADER IN NEW SEGMENT       65200013
         BO    VALID               BRANCH IF NOT HEADER                 65600013
INVALID  OI    19(13),SEQER                                             66800013
         B     RETURN              RETURN TO CALLER                     67200013
*                                                                       67600013
*    POST THE FILLED BUFFER                                             68000013
*                                                                       68400013
POSTBUFF  EQU  *                                                  19509 68460017
         L    TREG,4(RD)           ACCESS ADDRESS OF              20396 68520017
         LA    TREG,72(TREG)        QATTACH QCB                   20396 68580017
         SVC    QWAIT               WAIT FOR BRB TO BE REMOVED    20396 68640017
*                                   FROM READY QUEUE              20396 68700017
         TM    DCBSEGAD+3,1       HAS A BUFFER BEEN SAVED         19509 68760017
         BO    NOBUFF             NO, THERE IS NO SAVED BUFFER    19509 68820017
         L     WR1,DCBSEGAD       LOAD SAVED BUFFER ADDRESS       19509 68880017
         ST    FREG,DCBSEGAD      SAVE PRESENT BUFFER ADDRESS     19509 68940017
         LR    FREG,WR1           GET BUFFER ADDRESS FOR POST     19509 69000017
         LA    WR2,TESTEOM        TEST FOR LAST SEGMENT           19509 69060017
POSTBUF2 L     TREG,DEBDESTQ(RDEB) GET DESTINATION QUEUE ADDRESS  19509 69120017
         LA    TREG,0(0,TREG)      CLEAR HIGH ORDER BYTE.               69200013
         SVC   QPOST               POST BUFFER TO DESTINATION QUEUE     69600013
         L     TREG,4(RD)          LOAD ADDRESS OF IGG019NG IN TREG     70000013
         LA    TREG,72(TREG)       POINT TO QATTACH                     70400013
         SVC   QWAIT               WAIT FOR BRB TO BE REMOVED FROM      70800013
*                                        THE READY QUEUE                71200013
         BR    WR2                RETURN                          19509 71250017
NOBUFF   ST    FREG,DCBSEGAD       SAVE PRESENT BUFFER ADDRESS    19509 71300017
TESTEOM  L    FREG,DCBSEGAD        GET ADDRESS OF LAST SEGMENT    20391 71350017
         TM    MSTATUS,LAST        IS THIS LAST SEGMENT           20391 71400017
         BNO   RETURN              NO, RETURN                     19509 71450017
         BAL   WR2,POSTBUF2        AND POST IT TO DESTINATION     19509 71500017
         OI    DCBSEGAD+3,1        SET NO BUFFER SAVED            19509 71550017
RETURN   RETURN (14,12)                                                 71600013
LOADSUB  L     RDEB,DCBDEBAD           LOAD THE DEB ADDRESS             72000013
         L     RD,CVTABLE              LOAD ADDRESS OF COMM. VECTOR TB. 72400013
         L     RD,CVTTRMTB(RD)         LOAD TERM TABLE ADDRESS          72800013
         L     RF,4(RD)                LOAD ADDRESS OF IGG019NG         73200013
         L     RF,0(RF)                LOAD ADDRESS OF LPS SECTION      73600013
         BR    TTREG                   RETURN                           74000013
MVHDR    MVC   HDSTRT,SEGSTRT(WREG0)          MV SEG TO BUFFER          74400013
MVTXT    MVC   TXSTRT,SEGSTRT(WREG0)          MV SEG TO BUFFER          74800013
HALFWORD DC    H'0'                                                     75200013
FIVE     DC    H'5'                                                     75600013
         DS    0F                                                       76000013
PRICON   DC    X'EC000000'                                              76400013
         CNOP  0,8                                                      76800013
QELEMAD  EQU   32                                                       77200013
DEBQCBAD EQU   32                                                       77600013
DEBSTATE EQU   40                  LCB IS IN THE DEB                    78000013
BUFFAD   EQU   48                                                       78400013
DEBDESTQ EQU   68                                                       78800013
SEGSTRT  EQU   4                                                        79200013
CVTABLE  EQU   16                                                       79600013
CVTTRMTB EQU   156                                                      80000013
TTQUES   EQU   4                                                        80400013
BREQ     EQU   12                                                       80800013
BUFSZ    EQU   152                                                      81200013
ERRCD    EQU   16                                                       81600013
*                                                                       82000013
TXT      EQU   X'01'                                                    82400013
SEQER    EQU   64                                                       82800013
HDR      EQU   1                                                        83200013
DEBSEGF  EQU   104                                                      83600013
LAST     EQU   2                                                        84000013
*                                                                       84400013
         EJECT                                                          84800013
         DCBD  DSORG=MQ                                                 85200013
         EJECT                                                          85600013
         PREFIXD                                                        86000013
         EJECT                                                          86400013
         TERMTBLD                                                       86800013
         END                                                            87200013
