         TITLE 'IGG019NE  QTAM PUT MESSAGE'                             00400013
*********************************************************************** 00430021
*                                                                     * 00460021
* STATUS -     CHANGE LEVEL=19     JANUARY 1971                       * 00490021
*                                                                     * 00520021
* FUNCTION - THE PUT MESSAGE ROUTINE IS COMPOSED OF 2 SECTIONS.  THE  * 00550021
*    FIRST SECTION IS ENTERED FROM THE MACRO EXPANSION.  A 'NEW ENTRY'* 00580021
*    SWITCH, X'80',IS SET IN DCBEODAD.  IF AN ERROR IS DETECTED, THE  * 00610021
*    FOLLOWING ERROR CODES ARE SET, RIGHT ADJUSTED, IN REGISTER 15,   * 00640021
*    AND RETURN IS MADE TO THE NEXT INSTRUCTION IN THE PROCESSING     * 00670021
*    PROGRAM.                                                         * 00700021
*         1. IF THE SIZE SPECIFIED IN THE PUT PREFIX IS NEGATIVE OR 4 * 00730021
*    OR LESS, AN ERROR CODE OF X'80' IS SET.                          * 00760021
*         2. IF, BY SEARCHING THROUGH THE TERMINAL TABLE, A MATCH FOR * 00790021
*    THE TERM ID IS NOT FOUND, AN ERROR CODE OF X'20' IS SET.         * 00820021
*         IF THERE ARE NO ERRORS, THE ADDRESS OF THE TERMINAL ENTRY IS* 00850021
*    PLACED IN DCBEXLST.  THE ROUTINE ISSUES AN SVC QPOST TO POST THE * 00880021
*    BRB IN DEB TO THE ACTIVE BRB QUEUE TO REQUEST A NEW BUFFER. A    * 00910021
*    QWAIT IS ISSUED ON THE QCB IN THE DEB TO WAIT FOR THE BUFFER. A  * 00940021
*    QWAIT IS ISSUED ON THE READY QUEUE FOR THE BRB TO BE REMOVED. (IF* 00970021
*    THE BRB WAS ON THE READY QUEUE WHEN ANOTHER PUT WAS ISSUED, THE  * 01000021
*    BRB WOULD BE LINKED TO ITSELF.)                                  * 01030021
*         IF A BUFFER HAS BEEN SAVED IN DCBSEGAD, IT IS POSTED TO THE * 01060021
*    DESTINATION QCB (DEB + 68).  AN SVC QWAIT IS ISSUED TO CLEAR THE * 01090021
*    READY QUEUE.  THE NEW BUFFER IS SAVED IN DCBSEGAD.  IF A BUFFER  * 01120021
*    HAD NOT BEEN SAVED IN DCBSEGAD, THE NEW BUFFER IS SAVED IN       * 01150021
*    DCBSEGAD.  FOR EITHER CASE, IF THERE IS MORE DATA IN THE WORK-   * 01180021
*    AREA, THE ROUTINE RETURNS TO REQUEST A NEW BUFFER BY POSTING THE * 01210021
*    BRB TO THE ACTIVE BRB QUEUE.  IF THERE IS NO MORE DATA TO MOVE,  * 01240021
*    THE BUFFER IN DCBSEGAD IS POSTED TO THE DESTINATION QCB FOLLOWED * 01270021
*    BY A QWAIT TO EMPTY THE READY QUEUE.  DCBSEGAD IS SET TO INDICATE* 01300021
*    NO BUFFER HAS BEEN SAVED.  RETURN IS MADE TO THE NEXT INSTRUCTION* 01330021
*    IN THE MESSAGE PROCESSING PROGRAM.                               * 01360021
*         THE SECOND SECTION OF THE ROUTINE IS ENTERED BY A BRANCH    * 01390021
*    FROM THE BUFFER BRB ROUTINE. (THIS BRANCH ENTRY IS BASED ON A    * 01420021
*    FIXED OFFSET THAT IS GUARENTEED BY AN ORG IN IGG019NE.)  THE     * 01450021
*    REGISTERS 6 AND 7 SAVED IN THE DEB ARE RESTORED.                 * 01480021
*         IF THIS IS AN ENTRY FOR THE FIRST PUT OF THE BUFFER, THE    * 01510021
*    LENGTH IS OBTAINED FROM THE PUT PREFIX AND ADJUSTED FOR PREFIX.  * 01540021
*    TO INITIALIZE THE PREFIX, THE ADDRESS OF THE LCB IN THE DEB      * 01570021
*    (DEB + 40) IS SET IN THE MSLCB FIELD AND TTSKEY IS ZEROED TO SHOW* 01600021
*    FROM PROCESSING PROGRAM.                                         * 01630021
*         FOR A HEADER SEGMENT, THE SEQUENCE IN FIELD IN THE PREFIX IS* 01660021
*    ZEROED AND THE NUMBER OF IDLES IS STORED IN MSPTR FIELD IN THE   * 01690021
*    PREFIX.  LCBSTATE OF THE LCB IN THE DEB IS SET TO X'18'. THE     * 01720021
*    ADDRESS OF THE QCB FOR THE DESTINATION TERMINAL SAVED IN DCBEXLST* 01750021
*    IS MOVED INTO THE LCBDESTQ FIELD OF THE LCB IN THE DEB.  IF THE  * 01780021
*    USER HAS SPECIFIED PRIORITY, THAT PRIORITY IS MOVED FROM THE PUT * 01810021
*    PREFIX INTO THE DEB + 121; OTHERWISE, THE PRIORITY IS SET TO A   * 01840021
*    BLANK.  THE OFFSET TO THE DESTINATION TERM ENTRY IN THE TERMINAL * 01870021
*    TABLE IS STORED IN TTDKEY OF THE PREFIX.  MSTATUS OF THE BUFFER  * 01900021
*    PREFIX IS OR'ED WITH X'02' TO INDICATE A HEADER SEGMENT.         * 01930021
*         FOR A TEXT SEGMENT, TEXT, END OF SEGMENT (X'03') IS OR'ED IN* 01960021
*    MSTATUS OF THE BUFFER PREFIX.  FOR ALL BUFFERS, THE LENGTH OF THE* 01990021
*    BUFFER IS COMPARED WITH THE WORKAREA. IF THE WORKAREA IS LARGER  * 02020021
*    THAN THE BUFFER, THE LAST SEGMENT (X'01') IS TURNED OFF IN       * 02050021
*    MSTATUS,AND THE BUFFER LENGTH IS USED TO MOVE THE DATA FROM THE  * 02080021
*    WORKAREA TO BUFFER.  OTHERWISE, THE WORKAREA LENGTH IS USED TO   * 02110021
*    MOVE THE DATA INTO THE BUFFER.  MESSAGE SIZE IS MOVED INTO THE   * 02140021
*    MSEGSZE FIELD OF THE PREFIX.  IF THERE IS MORE DATA TO BE MOVED, * 02170021
*    THE POINTER TO THE NEXT DATA IS SAVED IN DCBEODAD.  THE REMAINING* 02200021
*    WORKAREA LENGTH AND ORIGINAL WORKAREA LENGTH ARE STORED IN REG-  * 02230021
*    ISTER 6 AND 7 RESPECTFULLY AND STORED IN DEB + 108.  RETURN IS   * 02260021
*    MADE TO IGG019NG WHICH POSTS THE BUFFER TO THE MS DESTINATION    * 02290021
*    QUEUE.                                                           * 02320021
*                                                                     * 02350021
* ENTRY POINTS - ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE WHOSE  * 02380021
*         ADDRESS IS IN THE DCB.                                      * 02410021
*         ENTRY IS ALSO MADE AT IGG019NE + 134 BY A BRANCH FROM       * 02440021
*         IGG019NG.                                                   * 02470021
*                                                                     * 02500021
* INPUT - REGISTERS UPON ENTRY FROM PUT MACRO EXPANSION               * 02530021
*    0 - WORKAREA ADDRESS                                             * 02560021
*    1 = DCB ADDRESS                                                  * 02590021
*    13 = SAVE AREA                                                   * 02620021
*    14 = RETURN ADDRESS                                              * 02650021
*    15 = ADDRESS OF PUT MODULE                                       * 02680021
*         REGISTERS UPON ENTRY FROM IGG019NG                          * 02710021
*    5 = DCB ADDRESS                                                  * 02740021
*    11 = DEB ADDRESS                                                 * 02770021
*    14 = RETURN ADDRESS                                              * 02800021
*    15 = PUT ROUTINE SPECIAL ENTRY POINT                             * 02830021
*                                                                     * 02860021
* OUTPUT- REGISTER 15 CONTAINS RETURN CODES                           * 02890021
*                                                                     * 02920021
* EXTERNAL REFERENCES                                                 * 02950021
*         SVC QPOST                                                   * 02980021
*         SVC QWAIT                                                   * 03010021
*                                                                     * 03040021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA A BRANCH REGISTER 14 TO EITHER* 03070021
*         THE NEXT INSTRUCTION FOLLOWING THE PUT MACRO, OR TO THE     * 03100021
*         BUFFER BRB ROUTINE IN MODULE IGG019NG.                      * 03130021
*                                                                     * 03160021
* EXITS, ERROR- THIS ROUTINE EXITS VIA A BRANCH REGISTER 14 WITH      * 03190021
*         THE ERROR CODE IN REGISTER 15.                              * 03220021
*                                                                     * 03250021
* TABLES AND WORKAREAS- PUT PREFIX (SEE NOTE)                         * 03280021
*                                                                     * 03310021
* ATTRIBUTES- REENTRANT,ENABLED OR IN SUPERVISOR MODE, ONLY LOADABLE  * 03340021
*                                                                     * 03370021
* CHARACTER CODE DEPENDENCY- NONE                                     * 03400021
*NOTE' THE FIRST FOUR BYTES IN THE WORK AREA ARE THE SEGMENT PREFIX.    03600013
* THE FIRST TWO BYTES SPECIFY THE NUMBER OF CHARACTERS IN THIS SEGMENT. 04000013
* THE THIRD BYTE SPECIFIES THE MESSAGE TYPE .                           04400013
* 00000000    HEADER SEGMENT MULTIPLE SEGMENT MESSAGE.                  04800013
*  00000001  INTERMEDIATE TEXT SEGMENT                                  05200013
*  00000010  SINGLE SEGMENT MESSAGE.                                    05600013
*  00000011  LAST TEXT SEGMENT OF A MULTI-SEGMENT MESSAGE.              06000013
* THE FOURTH BYTE OF THE PREFIX IS FOR MESSAGE PRIORITY                 06400013
*    THIS MODULE IS LOADED BY THE OPEN ROUTINE, IGG0193P.             * 06500021
*********************************************************************** 06600021
IGG019NE START                                                          06800013
*2010242000-246000                                                 8064 07000016
*2540344000                                                        8064 07100017
*3411636600,639600-643200,665000-667000,677000-679000             19509 07130017
*3411637200-639000                                                20396 07160017
* 213000-214000,228000                                           A27529 07180019
*A004300-034000,065000-066000                                    S21016 07190021
R0       EQU   0                                                        07200013
FREG     EQU   1                                                        07600013
TREG     EQU   2                                                        08000013
BUFLREG  EQU   3                                                        08400013
TTREG    EQU   4                                                        08800013
DCBR     EQU   5                                                        09200013
WR1      EQU   6                                                        09600013
WR2      EQU   7                                                        10000013
R4       EQU   8                                                        10400013
MVREG    EQU   10                                                       10800013
RF       EQU   10                                                       11200013
RDEB     EQU   11                                                       11600013
RD       EQU   12                                                       12000013
RC       EQU   13                                                       12400013
WREG0    EQU   14                                                       12800013
SREG     EQU   15                                                       13200013
QWAIT    EQU   65                                                       13600013
QPOST    EQU   67                                                       14000013
TERMERR  EQU   X'20'                                                    14400013
SIZEERR  EQU   X'80'                                                    14800013
         USING IECKPREF,FREG                                            15200013
         USING IECKTERM,TTREG                                           15600013
         USING IHADCB,DCBR                                              16000013
         USING *,SREG                                                   16400013
         SAVE  (14,12)                                                  16800013
         LR    DCBR,FREG           GET DCB ADDRESS                      17200013
         ST    R0,DCBEODAD             SAVE WORK AREA POINTER           17600013
         MVI   DCBEODAD,X'80'          SET NEW ENTRY SWITCH             18000013
         BAL   TTREG,LOADSUB       GO INITIALIZE RDEB, RD, RF           18400013
*                                                                       18800013
*      ASSURE VALID TERMINAL BEING PUT TO                               19200013
*                                                                       19600013
         LA    R4,TERMERR+SIZEERR ERROR CODES FOR TERM ERROR AND SIZE   20000013
*                                 ERRORS                                20400013
         ST    R4,16(13)          STORE RETURN CODE IN REGISTER 15      20800013
         LR    TTREG,R0           WORK AREA TO ADDRESSABLE REGISTER     21200013
         TM    0(TTREG),X'80'     NEGATIVE NUMBER SPECIFIED      A27529 21300019
         BO    NEGATIVE           BRANCH IF YES                  A27529 21400019
         CLC   0(2,TTREG),FOUR    COMPARE USERS LENGTH TO FOUR          21600013
         BNH   *+8                BRANCH IF NOT GREATER THAN FOUR       22000013
         NI    19(13),255-SIZEERR TURN OFF SIZE ERROR FLAG              22400013
NEGATIVE LA    TREG,8(RD)         ADDRESS OF FIRST TERM ENTRY    A27529 22800019
         IC    TTREG,4(RD)        LENGTH OF TERM NAMES                  23200013
         BCTR  TTREG,0            SUB ONE FOR THE COMPARE INSTRUCTION   23600013
         L     FREG,DCBTRMAD      ADDRESS OF PUT TERM NAME              24000013
TERMLOOP IC    R4,DCBRECFM         SAVE RECFM                      8064 24200016
         ST    TREG,DCBEXLST       STORE IN CASE OF EQUAL COMPARE  8064 24400016
         STC   R4,DCBRECFM         RESTORE RECFM                   8064 24600016
         EX    TTREG,COMPARE      COMPARE TERM NAMES                    24800013
         BE    NOTHEADR           BRANCH IF EQUAL                       25200013
         IC    R4,0(TREG)         LENGTH OF THIS ENTRY                  25600013
         AR    TREG,R4            INCREMENT TERM TABLE POINTER          26000013
         C     TREG,0(RD)         COMPARE TO LAST TERM ENTRY            26400013
         BH    RETURN             BRANCH IF TERM NAME NOT FOUND         26800013
         B     TERMLOOP           GO LOOK AT THE NEXT TERM TABLE ENTRY  27200013
NOTHEADR NI    19(13),255-TERMERR TURN OFF TERM ERROR FLAG              27600013
         BNZ   RETURN             BRANCH IF ANY ERRORS                  28000013
RESTART  LA    TREG,BREQ(RF)           ADDRESS OF FREE BUFFER QUEUE     28400013
         AL    TREG,PRICON             SET BRB PRIORITY                 28800013
         LA    FREG,QELEMAD(RDEB)      BRB ADDRESS                      29200013
         SVC   QPOST               POST REQUEST FOR NEW BUFFER          29600013
         LA    TREG,DEBQCBAD(RDEB)     QCB ADDRESS FOR WAIT             30000013
         SVC   QWAIT               WAIT FOR BUFFER                      30400013
         B     POSTBUFF                TO POST FILLED BUFFER            30800013
*                                                                       31200013
*        THIS POINT IS ENTERED FROM IGG019NG VIA A BRANCH IN            31600013
*     SUPERVISOR MODE.                                                  32000013
*     REGISTERS ON ENTRY               DCBR      DCB ADDRESS            32400013
*                                      RDEB      DEB ADDRESS            32800013
*                                      15        BASE REGISTER          33200013
*                                      14        RETURN ADDRESS         33600013
*                                                                       34000013
         ORG   IGG019NE+134                                        8064 34400017
         ST    WREG0,DEBSV(RDEB)       SAVE RETURN ADDRESS              34800013
         LR    R0,RD                   SAVE BASE FOR QQ01               35200013
         BAL   TTREG,LOADSUB+4     GO INITIALIZE RD AND RF              35600013
         LM    WR1,WR2,DEBSV+4(RDEB)   LOAD SAVED REGISTERS             36000013
         L     WREG0,DCBEODAD          LOAD WORK AREA POINTER           36400013
         LTR   WREG0,WREG0             TEST FOR NEW PUT ENTRY           36800013
         BP    SKIP1                   BRANCH NOT NEW ENTRY             37200013
         MVC   HALFWORD(2),0(WREG0) MOVE LENGTH OF THE WORK AREA TO A   37600013
*                                   HALF WORD BOUNDRY                   38000013
         LH    WR2,HALFWORD       LOAD LENGTH OF USERS WORK AREA        38400013
         SH    WR2,FOUR            ADJUST FOR FIRST FOUR BYTES          38800013
         LR    WR1,WR2                 SIGNAL NEW ENTRY                 39200013
SKIP1    LH    BUFLREG,BUFSZ(RF)       LOAD BUFFER SIZE                 39600013
*                                                                       40000013
*    FILL THE BUFFER                                                    40400013
*                                                                       40800013
         LA    RF,40(RDEB)             LCB ADDRESS                      41200013
         ST    RF,MSLCB-1              LCB ADDRESS TO THE BUFFER        41600013
         SR    RF,RF               CLEAR RF                             42000013
         STH   RF,TTSKEY           ZERO SOURCE KEY IN PREFIX            42400013
         CR    WR1,WR2             IS THIS THE START OF WORKAREA        42800013
         BNE   TEXTSEG             BRANCH IF NO                         43200013
* THIS IS A HEADER SEGMENT.                                             43600013
         SR    RF,RF               CLEAR RF                             44000013
         ST    RF,MSNUMIN          ZERO SEQUENCE NUMBERS IN PREFIX      44400013
         MVI   40(RDEB),X'18'          SET LCB STATE                    44800013
         BCTR  RF,0                    INITIALIZE FOR FIRST TIME        45200013
IDLOOP   LA    RF,1(RF)                ADD ONE TO IDLE CHARACTER COUNT  45600013
         LA    TTREG,4(WREG0,RF)       ADDRESS OF CHARACTER TO TEST     46000013
         CLI   0(TTREG),X'17'          IS THIS AN IDLE CHARACTER        46400013
         BE    IDLOOP                  BRANCH IF IDLE CHARACTER FOUND   46800013
         STC   RF,MSPTR                STORE IDLE CHARACTER COUNT       47200013
         L     TTREG,DCBEXLST     ADDRESS OF TERM BEING PUT TO          47600013
FOUND    MVC   DEBDESTQ+1(3,RDEB),TQCBADDR LOAD LCB WITH ADDRESS OF     48000013
*                                      QCB FOR DESTINATION TERMINAL     48400013
         MVI   121(RDEB),C' '      LOAD PRIORITY BYTE WITH BLANK        48800013
         CLI   3(WREG0),X'0'       HAS USER SPECIFIED PRIORITY          49200013
         BE    *+10                LEAVE BLANK IF NOT SPECIFIED         49600013
         MVC   121(1,RDEB),3(WREG0) ELSE MOVE IN PRIORITY FROM WORKAREA 50000013
         SR    TTREG,RD           GET OFFSET TO TERMTBL ENTRY           50400013
         STH   TTREG,TTDKEY             AND STORE IN DESTINATION KEY    50800013
         LA    MVREG,HDSTRT        GET START OF HEADER                  51200013
         OI    MSTATUS,HDR         LOAD STATUS BIT IN PREFIX            51600013
         SH    BUFLREG,K24         ADJUST BUFFER LENGTH FOR PREFIX      52000013
CKLGN    SR    WR2,BUFLREG         IS WORKAREA LARGER THAN BUFFER       52400013
         BP    SETCOUNT            BRANCH IF YES                        52800013
MOVE     BCTR  WR1,0               ELSE DECREMENT FOR EXECUTE           53200013
         EX    WR1,EXMOV           CAUSE DATA TO BE MOVED TO BUFFER     53600013
         TM    MSTATUS,TXT         IS THIS TEXT SEGMENT                 54000013
         BO    TEXT                BRANCH IF YES                        54400013
         LA   WR1,25(0,WR1)        INCREMENT COUNT FOR HEADER PREFIX    54800013
         B     POST                GO TO RETURN                         55200013
TEXT     LA    WR1,15(0,WR1)       INCREMENT COUNT FOR TEXT PREFIX      55600013
*                                                                       56000013
*    RETURN TO IGG019NG TO REVERT TO PROBLEM PROGRAM MODE               56400013
*                                                                       56800013
POST     STH   WR1,MSEGSZE                                              57200013
         LTR   WR2,WR2                 TEST FOR MORE DATA               57600013
         BC    13,SKIP                 BRANCH NO MORE DATA              58000013
         LA    WREG0,0(WREG0,BUFLREG)  UPDATE WORK AREA POINTER         58400013
         ST    WREG0,DCBEODAD          SAVE NEW WORK AREA POINTER       58800013
         LR    WR1,WR2             SAVE REMAINING WORKAREA LENGTH       59200013
         AR    WR2,BUFLREG         RESTORE ORIGINAL WORKAREA LENGTH     59600013
SKIP     STM   WR1,WR2,DEBSV+4(RDEB)   SAVE REGISTERS FOR RETURN TO NG  60000013
         LA    TREG,QELEMAD(RDEB)      RESET BRB ADDRESS                60400013
         LR    RD,R0                   RELOAD QQ01 BASE                 60800013
         L     WREG0,DEBSV(RDEB)       LOAD RETURN ADDRESS              61200013
         BR    14                      RETURN TO IGG019NG               61600013
COMPARE  CLC   0(1,FREG),9(TREG)                                        62000013
HALFWORD DC    H'0'                                                     62400013
*                                                                       62800013
*   POST THE FILLED BUFFER                                              63200013
*                                                                       63600013
POSTBUFF  EQU  *                                                  19509 63660017
         L    TREG,4(RD)           ACCESS ADDRESS OF              20396 63720017
         LA    TREG,72(TREG)        QATTACH QCB                   20396 63780017
         SVC    QWAIT               WAIT FOR BRB TO BE REMOVED    20396 63840017
*                                   FROM READY QUEUE              20396 63900017
         TM    DCBSEGAD+3,1       HAS A BUFFER BEEN SAVED         19509 63960017
         BO    NOBUFF             NO, THERE IS NO SAVED BUFFER    19509 64020017
         L     WR1,DCBSEGAD       LOAD SAVED BUFFER ADDRESS       19509 64080017
         ST    FREG,DCBSEGAD      SAVE PRESENT BUFFER ADDRESS     19509 64140017
         LR    FREG,WR1           GET BUFFER ADDRESS FOR POST     19509 64200017
         LA    WR2,LOADREGS       LOAD RETURN ADDRESS             19509 64260017
POSTBUF2 L     TREG,DEBDESTQ(RDEB) GET DESTINATION QUEUE ADDRESS  19509 64320017
         LA    TREG,0(0,TREG)      CLEAR HIGH ORDER BYTE.               64400013
         SVC   QPOST               POST BUFFER TO DESTINATION QUEUE     64800013
         L     TREG,4(RD)          ACCESS ADDRESS OF                    65200013
         LA    TREG,72(TREG)            QATTACH QCB                     65600013
         SVC   QWAIT               WAIT FOR BRB TO BE REMOVED           66000013
*                                          FROM THE READY QUEUE         66400013
         BR    WR2                RETURN                          19509 66500017
NOBUFF   ST    FREG,DCBSEGAD                                      19509 66600017
LOADREGS  EQU  *                                                  19509 66700017
         LM    WR1,WR2,DEBSV+4(RDEB)   RELOAD WORK REGISTERS            66800013
         LTR   WR2,WR2             IS THERE MORE DATA IN THE WORKAREA   67200013
         BP    RESTART                 BRANCH IF MORE DATA              67600013
         L    FREG,DCBSEGAD       LOAD SAVED BUFFER ADDRESS       19509 67700017
         BAL   WR2,POSTBUF2       GO POST BUFFER TO DESTINATION   19509 67800017
         OI    DCBSEGAD+3,1       SET NO BUFFER SAVED             19509 67900017
RETURN   EQU   *                                                        68000013
         RETURN  (14,12)                                                68400013
* THIS IS A TEXT SEGMENT.                                               68800013
TEXTSEG  LA    MVREG,TXSTRT        GET START OF TEXT                    69200013
         OI    MSTATUS,EOM         SET TEXT EOM IN PREFIX               69600013
         SH    BUFLREG,K14         ADJUST BUFFER LENGTH FOR PREFIX      70000013
         LR    WR2,WR1             SAVE LENGTH OF WORKAREA              70400013
         B     CKLGN               GO TO CHECK SIZE                     70800013
LOADSUB  L     RDEB,DCBDEBAD           LOAD THE DEB ADDRESS             71200013
         L     RD,CVTABLE              LOAD ADDRESS OF COMM. VECTOR TB. 71600013
         L     RD,CVTTRMTB(RD)         LOAD TERM TABLE ADDRESS          72000013
         L     RF,4(RD)                LOAD ADDRESS OF IGG019NG         72400013
         L     RF,0(RF)                LOAD ADDRESS OF LPS SECTION      72800013
         BR    TTREG                   RETURN                           73200013
EXMOV    MVC   0(1,MVREG),4(WREG0) MOVE DATA FROM WORKAREA TO BUFFER    73600013
* THIS IS NOT THE END OF THE AREA ADDITIONAL BUFFER(S) REQUIRED         74000013
SETCOUNT LR    WR1,BUFLREG         USE BUFFER LENGTH FOR MOVE           74400013
         NI    MSTATUS,TXT         TURN OFF EOM                         74800013
         B     MOVE                GO TO MOVE DATA                      75200013
FIVE     DC    H'5'                                                     75600013
         DS    0F                                                       76000013
PRICON   DC    X'EC000000'                                              76400013
FOUR     DC    H'04'                                                    76800013
K14      DC    H'14'                                                    77200013
K24      DC    H'24'                                                    77600013
         CNOP  0,8                                                      78000013
QELEMAD  EQU   32                                                       78400013
DEBQCBAD EQU   32                                                       78800013
DEBSTATE EQU   40                  LCB IS IN THE DEB                    79200013
BUFFAD   EQU   48                                                       79600013
DEBDESTQ EQU   68                                                       80000013
DEBSV    EQU   104                                                      80400013
SEGSTRT  EQU   4                                                        80800013
CVTABLE  EQU   16                                                       81200013
CVTTRMTB EQU   156                                                      81600013
BUFSZ    EQU   154                                                      82000013
TTQUES   EQU   4                                                        82400013
BREQ     EQU   12                                                       82800013
*                                                                       83200013
HDR      EQU   X'02'                                                    83600013
EOM      EQU   X'03'                                                    84000013
TXT      EQU   X'01'                                                    84400013
         EJECT                                                          84800013
         DCBD  DSORG=MQ                                                 85200013
         EJECT                                                          85600013
         PREFIXD                                                        86000013
         EJECT                                                          86400013
         TERMTBLD                                                       86800013
         END                                                            87200013
