         TITLE 'IGG019NF  QTAM PUT RECORDS'                             00300013
*********************************************************************** 00310021
*                                                                     * 00320021
* STATUS       CHANGE LEVEL= 19    JANUARY 1971                       * 00330021
*                                                                     * 00340021
* FUNCTION- THE PUT RECORD ROUTINE IS COMPOSED OF TWO SECTIONS.  THE  * 00350021
*    FIRST SECTION IS ENTERED FROM THE MACRO EXPANSION.  A 'NEW ENTRY'* 00360021
*    SWITCH, X'80', IS SET IN DCBEODAD. IF AN ERROR IS DETECTED, THE  * 00370021
*    FOLLOWING RETURN CODES ARE SET, RIGHT ADJUSTED, IN REGISTER 15,  * 00380021
*    AND RETURN IS MADE TO THE NEXT INSTRUCTION IN THE PROCESSING     * 00390021
*    PROGRAM.                                                         * 00400021
*         1.  IF THE SIZE SPECIFIED IN THE PUT PREFIX IS NEGATIVE OR 4* 00410021
*    OR LESS,  AN ERROR CODE OF X'80' IS SET.                         * 00420021
*         2.  AN ERROR CODE OF X'40' IS SET IF THE SEQUENCE OF SEG-   * 00430021
*    MENTS IS INVALID; THAT IS IF THE LAST BUFFER WAS THE LAST SEGMENT* 00440021
*    AND THIS SEGMENT IS NOT A HEADER, OR IF THE LAST BUFFER WAS NOT  * 00450021
*    THE LAST SEGMENT AND THE NEXT SEGMENT IS A HEADER.               * 00460021
*         3.  IF, BY SEARCHING THROUGH THE TERMINAL TABLE, A MATCH FOR* 00470021
*    THE TERM ID IS NOT FOUND, AN ERROR CODE OF X'20' IS SET.         * 00480021
*         IF THERE ARE NO ERRORS, THE ADDRESS OF THE TERMINAL ENTRY IS* 00490021
*    PLACED IN DCBEXLST.  THE ROUTINE ISSUES AN SVC QPOST TO POST THE * 00500021
*    BRB IN THE DEB TO THE ACTIVE BRB QUEUE TO REQUEST A NEW BUFFER. A* 00510021
*    QWAIT IS ISSUED ON THE QCB IN THE DEB TO WAIT FOR THE BUFFER.    * 00520021
*         IF A BUFFER HAS BEEN SAVED IN DCBSYNAD THAT BUFFER IS SAVED * 00530021
*    IN  REGISTER 1 FOR QPOST, AND THE NEW BUFFER IS STORED IN        * 00540021
*    DCBSYNAD.  A QWAIT IS ISSUED ON THE READY QUEUE FOR THE BRB TO BE* 00550021
*    REMOVED.  (IF THE BRB WAS ON THE READY QUEUE WHEN ANOTHER PUT WAS* 00560021
*    ISSUED, THE BRB WOULD BE LINKED TO ITSELF.)                      * 00570021
*         IF DCBSEGAD + 3 INDICATES THAT NO BUFFER WAS HELD OVER, A   * 00580021
*    POST IS REQUIRED.  THE NEW BUFFER IS POSTED TO THE MS DESTINATION* 00590021
*    QCB.  A QWAIT IS ISSUED ON QATTACH TO EMPTY THE READY QUEUE.  IF * 00600021
*    THE REGISTERS SAVED IN THE DEB INDICATE THAT THERE IS MORE DATA  * 00610021
*    TO BE MOVED, THE ROUTINE RETURNS TO REQUEST ANOTHER BUFFER BY    * 00620021
*    POSTING THE BRB TO THE ACTIVE BRB QUEUE AS PREVIOUSLY DESCRIBED. * 00630021
*         IF THERE IS NO MORE DATA TO BE MOVED OR DCBSEGAD + 3 INDI-  * 00640021
*    CATED THAT A BUFFER WAS HELD OVER,THE EXTRA BUFFER MUST BE FREED.* 00650021
*    IF A BUFFER HAS BEEN SAVED IN DCBSYNAD, THE BUFFER IS POSTED TO  * 00660021
*    THE AVAILABLE BUFFER QUEUE.  IF A BUFFER HAS NOT BEEN SAVED OR   * 00670021
*    AFTER THE POST TO THE AVAILABLE BUFFER QUEUE, RETURN IS MADE TO  * 00680021
*    THE PROCESSING PROGRAM.                                          * 00690021
*         THE SECOND SECTION OF THE ROUTINE IS ENTERED BY A BRANCH    * 00700021
*    FROM THE BUFFER BRB ROUTINE.  (THIS BRANCH ENTRY IS BASED ON A   * 00710021
*    FIXED OFFSET THAT IS GUARENTEED BY AN ORG IN IGG019NF.)  THE     * 00720021
*    REGISTERS 6 AND 8 SAVED IN THE DEB ARE RESTORED.                 * 00730021
*         IF DCBEODAD INDICATES THAT THIS IS A NEW PUT REQUEST,       * 00740021
*    DCBSYNAD IS ZEROED AND THE WORKAREA LENGTH IS OBTAINED.  FOR ALL * 00750021
*    PUT REQUESTS, DCBSEGAD + 3 IS TESTED FOR 'BUFFER LEFT' (0).  IF  * 00760021
*    THERE IS NO LEFT OVER BUFFER, THE PREFIX IS SET WITH THE ADDRESS * 00770021
*    OF THE LCB IN THE DEB IN MSLCB, ZERO IN TTSKEY, AND X'01' IN     * 00780021
*    MSTATUS.  FOR HEADER SEGMENTS, THE PREFIX IS FURTHER INITIALIZED * 00790021
*    WITH ZERO IN MSNUMIN, NUMBER OF IDLES IN THE MESSAGE IN MSPTR,   * 00800021
*    ZERO IN MSTATUS, AND OFFSET TO DESTINATION TERMINAL IN TTDKEY.   * 00810021
*    THE LCBSTATE OF THE LCB IN THE DEB IS SET TO X'18'.  THE ADDRESS * 00820021
*    OF THE QCB FOR THE DESTINATION TERMINAL, SAVED IN DCBEXLST, IS   * 00830021
*    MOVED INTO THE LCBDESTQ FIELD OF THE LCB IN THE DEB.  IF THE USER* 00840021
*    HAS SPECIFIED PRIORITY, THAT PRIORITY IS MOVED FROM THE PUT      * 00850021
*    PREFIX INTO DEB + 121; OTHERWISE THE PRIORITY IS SET TO A BLANK. * 00860021
*         FOR HEADER AND TEXT SEGMENTS, THE BUFFER SIZE AND CURRENT   * 00870021
*    DATA COUNT (MAY BE HDSTRT,TXTSTRT, OR LAST DATA IN BUFFER) ARE   * 00880021
*    COMPARED TO SEE IF THE BUFFER HAD BEEN FILLED.  IF THE BUFFER HAS* 00890021
*    NOT BEEN FILLED, THE LENGTH IS COMPUTED.  IF THE BUFFER IS LARGER* 00900021
*    THAN THE WORKAREA, THE LENGTH OF THE WORK AREA IS USED TO MOVE   * 00910021
*    THE DATA; OTHERWISE, THE BUFFER LENGTH IS USED.  THE DATA IS     * 00920021
*    MOVED FROM THE WORK AREA TO THE BUFFER, AND THE DATA COUNT IS SET* 00930021
*    IN THE PREFIX.  IF THERE IS NO DATA LEFT IN THE WORKAREA, THE    * 00940021
*    BUFFER ADDRESS IS SAVED IN DCBSEGAD.  ALSO IF THE PUT PREFIX     * 00950021
*    INDICATED END OF MESSAGE, THE LAST SEGMENT IS SET IN THE MSTATUS * 00960021
*    FIELD OF THE PREFIX OF THE BUFFER BEFORE THE ADDRESS OF THE NEXT * 00970021
*    CHARACTER IN THE WORK AREA IS CALCULATED.                        * 00980021
*         IF THE BUFFER HAS BEEN FILLED OR THE PUT PREFIX INDICATED   * 00990021
*    THAT THIS WAS NOT THE LAST SEGMENT, DCBSEGAD + 3 IS SET TO X'01' * 01000021
*    TO INDICATE NO BUFFER HELD OVER.  IN ALL CASES, THE RECORD TYPE  * 01010021
*    IS SAVED IN DEB + 72.  IF A BUFFER HAS BEEN SAVED IN DCBSYNAD,   * 01020021
*    THE SAVED BUFFER AND PRESENT BUFFER ARE EXCHANGED.  REGISTERS 6, * 01030021
*    7, AND 8 ARE SAVED AT DEB + 108 FOR RETURN TO IGG019NG.  THE     * 01040021
*    ROUTINE EXITS TO IGG019NG TO POST THE BUFFER TO THE MS-DESTINA-  * 01050021
*    TION QUEUE.                                                      * 01060021
*         IF DCBSEGAD + 3 INDICATES THAT A BUFFER WAS HELD OVER FROM  * 01070021
*    THE LAST PUT, THE NEW BUFFER ADDRESS IS STORED IN DCBSYNAD, THE  * 01080021
*    PREVIOUS BUFFER IS GOTTEN FROM DCBSEGAD, AND THE CURRENT DATA    * 01090021
*    COUNT IS OBTAINED FROM MSEGSZE.  IF THE PUT PREFIX INDICATES A   * 01100021
*    TEXT SEGMENT, THE ROUTINE BRANCHES TO THE SECTION THAT MOVES     * 01110021
*    THE DATA INTO THE BUFFER.  IF NOT A TEXT SEGMENT, RETURN IS MADE * 01120021
*    AS IF A BUFFER HAS BEEN FILLED.                                  * 01130021
*                                                                     * 01140021
* ENTRY POINTS - ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE WHOSE  * 01150021
*         ADDRESS IS IN THE DCB.                                      * 01160021
*         ENTRY IS ALSO MADE AT IGG019NF + 134 BY A BRANCH FROM       * 01170021
*         IGG019NG.                                                   * 01180021
*                                                                     * 01190021
* INPUT - REGISTERS UPON ENTRY FROM PUT MACRO EXPANSION               * 01200021
*    0 - WORKAREA ADDRESS                                             * 01210021
*    1 - DCB ADDRESS                                                  * 01220021
*    13 - SAVE AREA                                                   * 01230021
*    14 - RETURN ADDRESS                                              * 01240021
*    15 - ADDRESS OF PUT MODULE                                       * 01250021
*         REGISTERS UPON ENTRY FROM IGG019NG                          * 01260021
*    5 - DCB ADDRESS                                                  * 01270021
*    11 - DEB ADDRESS                                                 * 01280021
*    14 - RETURN ADDRESS                                              * 01290021
*    15 - PUT ROUTINE SPECIAL ENTRY POINT                             * 01300021
*                                                                     * 01310021
* OUTPUT- REGISTER 15 CONTAINS RETURN CODES                           * 01320021
*                                                                     * 01330021
* EXTERNAL REFERENCES                                                 * 01340021
*         SVC QPOST                                                   * 01350021
*         SVC QWAIT                                                   * 01360021
*                                                                     * 01370021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA A BRANCH REGISTER 14 TO EITHER* 01380021
*         THE NEXT INSTRUCTION FOLLOWING THE PUT MACRO, OR TO THE     * 01390021
*         BUFFER BRB ROUTINE IN MODULE IGG019NG.                      * 01400021
*                                                                     * 01410021
* EXITS, ERROR THIS ROUTINE EXITS VIA A BRANCH REGISTER 14 WITH THE   * 01420021
*         ERROR CODE IN REGISTER 15.                                  * 01430021
*                                                                     * 01440021
* TABLES/WORKAREAS- PUT PREFIX (SEE NOTE)                             * 01450021
*                                                                     * 01460021
* ATTRIBUTES - REENTRANT, ENABLED OR IN SUPERVISOR MODE, ONLY LOADABLE* 01470021
*                                                                     * 01480021
* CHARACTER CODE DEPENDENCY- NONE                                     * 01490021
*                                                                     * 01500021
*NOTE' THE FIRST FOUR BYTES IN THE WORK AREA ARE THE SEGMENT PREFIX.    02700013
* THE FIRST TWO BYTES SPECIFY THE NUMBER OF CHARACTERS IN THIS SEGMENT. 03000013
* THE THIRD BYTE SPECIFIES THE MESSAGE TYPE .                           03300013
* 00000000    HEADER SEGMENT MULTIPLE SEGMENT MESSAGE.                  03600013
*  00000001  INTERMEDIATE TEXT SEGMENT                                  03900013
*  00000010  SINGLE SEGMENT MESSAGE.                                    04200013
*  00000011  LAST TEXT SEGMENT OF A MULTI-SEGMENT MESSAGE.              04500013
* THE FOURTH BYTE OF THE PREFIX IS FOR MESSAGE PRIORITY                 04800013
*    THIS MODULE IS LOADED BY THE OPEN ROUTINE, IGG0193P              * 04820021
*    THE FOLLOWING FIELDS OF THE DCB ARE USED BY THIS ROUTINE         * 04840021
*    DCBSYNAD   SAVED, NEW BUFFER ADDRESS                             * 04860021
*    DCBEODAD+1 WORK AREA ADDRESS                                     * 04880021
*    DCBEODAD   FIRST BYTE IS SET TO X'80' FOR NEW ENTRY              * 04900021
*    DCBSEGAD+3 1= NO BUFFER HELD OVER                                * 04920021
*               0= BUFFER HELD OVER                                   * 04940021
*    DCBSEGAD+1 PREVIOUS BUFFER ADDRESS                               * 04960021
*    DCBEXLST   ADDRESS OF TERMINAL ENTRY                             * 04980021
*********************************************************************** 05000021
IGG019NF START                                                          05100013
*1770511000                                                        7487 05200016
*2010193000-195000                                                 8064 05300016
*2540276000                                                        8064 05350017
*3411550000,568000-569000                                         19561 05370017
* 169000-170000                                                  A27529 05380019
*A003100-015000,048200-050000                                    S21016 05390021
R0       EQU   0                                                        05400013
FREG     EQU   1                                                        05700013
TREG     EQU   2                                                        06000013
BUFLREG  EQU   3                                                        06300013
R4       EQU   4                                                        06600013
DCBR     EQU   5                                                        06900013
MVREG    EQU   6                                                        07200013
WR2      EQU   7                                                        07500013
WR1      EQU   8                                                        07800013
TTREG    EQU   9                                                        08100013
RF       EQU   10                                                       08400013
RDEB     EQU   11                                                       08700013
RD       EQU   12                                                       09000013
RC       EQU   13                                                       09300013
WREG0    EQU   14                                                       09600013
SREG     EQU   15                                                       09900013
QWAIT    EQU   65                                                       10200013
QPOST    EQU   67                                                       10500013
TERMERR  EQU   X'20'                                                    10800013
SIZEERR  EQU   X'80'                                                    11100013
LAST     EQU   2                                                        11400013
HDR      EQU   1                                                        11700013
SEQER    EQU   64                                                       12000013
         USING IECKPREF,FREG                                            12300013
         USING IECKTERM,TTREG                                           12600013
         USING IHADCB,DCBR                                              12900013
         USING *,SREG                                                   13200013
         SAVE  (14,12)                                                  13500013
         LR    DCBR,FREG           GET DCB ADDRESS                      13800013
         ST    R0,DCBEODAD             SAVE WORK AREA ADDRESS           14100013
         MVI   DCBEODAD,128            SET NEW ENTRY SWITCH             14400013
         BAL   TTREG,LOADSUB        GO INITIALIZE RDEB, RD, RF          14700013
*                                                                       15000013
*      ASSURE VALID TERMINAL BEING PUT TO                               15300013
*                                                                       15600013
         LA    R4,TERMERR+SIZEERR ERROR CODES FOR TERM ERROR AND SIZE   15900013
*                                 ERRORS                                16200013
         ST    R4,16(13)          STORE RETURN CODE IN REGISTER 15      16500013
         LR    TTREG,R0           WORK AREA TO ADDRESSABLE REGISTER     16800013
         TM    0(TTREG),X'80'     NEGATIVE NUMBER SPECIFIED      A27529 16900019
         BO    TERMTEST           BRANCH IF YES                  A27529 17000019
         CLC   0(2,TTREG),FOUR    COMPARE USERS LENGTH TO FOUR          17100013
         BNH   *+8                BRANCH IF NOT GREATER THAN FOUR       17400013
         NI    19(13),255-SIZEERR TURN OFF SIZE ERROR FLAG              17700013
         B     SEQTEST            TO TEST FOR PROPER RECORD SEQUENCE    18000013
TERMTEST LA    TREG,8(RD)         ADDRESS OF THE FIRST TERM ENTRY       18300013
         IC    TTREG,4(RD)        LENGTH OF TERM NAMES                  18600013
         BCTR  TTREG,0            SUB ONE FOR THE COMPARE INSTRUCTION   18900013
         L     FREG,DCBTRMAD      ADDRESS OF PUT TERM NAME              19200013
TERMLOOP IC    R4,DCBRECFM         SAVE RECFM                      8064 19300016
         ST    TREG,DCBEXLST       STORE IN CASE OF EQUAL COMPARE  8064 19400016
         STC   R4,DCBRECFM         RESTORE RECFM                   8064 19500016
         EX    TTREG,COMPARE      COMPARE TERM NAMES                    19800013
         BE    NOTHEADR           BRANCH IF EQUAL                       20100013
         IC    R4,0(TREG)         LENGTH OF THIS ENTRY                  20400013
         AR    TREG,R4            INCREMENT TERM TABLE POINTER          20700013
         C     TREG,0(RD)         COMPARE TO LAST TERM ENTRY            21000013
         BH    EXIT               BRANCH IF TERM NAME NOT FOUND         21300013
         B     TERMLOOP           GO LOOK AT THE NEXT TERM TABLE ENTRY  21600013
NOTHEADR NI    19(13),255-TERMERR TURN OFF TERM ERROR FLAG              21900013
         BNZ   EXIT               BRANCH IF ANY ERRORS                  22200013
RESTART  LA    TREG,BREQ(RF)           BUFFER REQUEST QUEUE             22500013
         AL    TREG,PRICON             SET BRB PRIORITY IN REGISTER     22800013
         LA    FREG,QELEMAD(RDEB)      LOAD BRB ADDRESS                 23100013
         SVC   QPOST               POST REQUEST FOR NEW BUFFER          23400013
         B     POSTBUFF                TO POST FILLED BUFFER            24300013
*                                                                       24600013
*        ENTRY TO THIS POINT IS IN SUPERVISOR MODE  VIA A BRANCH FROM   24900013
*    THE BUFFER BRB ROUTINE.  THE FOLLOWING REGISTERS ARE SET AS        25200013
*    LISTED BELOW                                                       25500013
*                                                                       25800013
*            DCBR=DCB ADDRESS                                           26100013
*            RDEB=DEB ADDRESS                                           26400013
*            14= RETURN ADDRESS                                         26700013
*            15= BASE REGISTER                                          27000013
*                                                                       27300013
         ORG   IGG019NF+134                                        8064 27600017
         ST    WREG0,DEBSV(RDEB)       SAVE RETURN ADDRESS              27900013
         LR    R0,RD                   SAVE QQ01 BASE                   28200013
         BAL   TTREG,LOADSUB       GO INITIALIZE RDEB, RD, RF           28500013
         LM    MVREG,WR1,DEBSV+4(RDEB) LOAD SAVED REGISTERS FROM DEB    28800013
         L     WREG0,DCBEODAD          LOAD POINTER TO WORK AREA        29100013
         LTR   WREG0,WREG0             TEST FOR NEW PUT REQUEST         29400013
         BP    SKIP1                   BRANCH NOT NEW PUT REQUEST       29700013
         SR    TTREG,TTREG         CLEAR TTREG                          30000013
         ST    TTREG,DCBSYNAD          ZERO BUFFER SAVE AREA            30300013
         MVC   HALFWORD(2),0(WREG0) MOVE LENGTH OF THE WORK AREA TO A   30600013
*                                   HALF WORD BOUNDRY                   30900013
         LH    WR2,HALFWORD       LOAD LENGTH OF USERS WORK AREA        31200013
         SH    WR2,FOUR            ADJUST FOR FIRST 4 BYTES             31500013
         LR    WR1,WREG0               SAVE WORK AREA ADDRESS           31800013
SKIP1    LH    BUFLREG,BUFSZ(RF)       LOAD BUFFER SIZE                 32100013
         TM    DCBSEGAD+3,1            TEST FOR LEFT OVER BUFFER        32400013
         BZ    CONT                    BRANCH BUFFER LEFT FROM LAST PUT 32700013
*                                                                       33000013
*        FILL THE NEW BUFFER                                            33300013
*                                                                       33600013
         BAL   TTREG,SWAPSUB       GO EXCHANGE BUFFER ADDRESSES         33900013
         LA    MVREG,40(RDEB)          LOAD LCB ADDRESS                 34200013
         ST    MVREG,MSLCB-1       PUT LCB ADDRESS IN PREFIX            34500013
* MOVE WORKAREA TO BUFFER                                               34800013
         SR    MVREG,MVREG         CLEAR MVREG FOR WORK REGISTER        35100013
         STH   MVREG,TTSKEY        CLEAR SOURCE KEY IN HEADER           35400013
         LA    MVREG,TXSTRT-MSEGSZE  GET OFFSET TO START OF TEXT        35700013
         MVI   MSTATUS,TXT         PUT TEXT INDICATOR IN HEADER         36000013
         CR    WREG0,WR1           TEST WORKAREA ADDR                   36300013
         BNE   CKLGN                                                    36600013
         TM    2(WREG0),TXT        IS THIS A TEXT SEGMENT               36900013
         BNZ   CKLGN               BRANCH IF YES                        37200013
* THIS IS A HEADER SEGMENT.                                             37500013
         SR    RF,RF               CLEAR RF                             37800013
         ST    RF,MSNUMIN          ZERO SEQUENCE NUMBERS IN PREFIX      38100013
         MVI   40(RDEB),X'18'          SET LCB STATE                    38400013
         BCTR  RF,0                    INITIALIZE FOR FIRST TIME        38700013
IDLOOP   LA    RF,1(RF)                ADD ONE TO IDLE CHARACTER COUNT  39000013
         LA    TTREG,4(WREG0,RF)       ADDRESS OF CHARACTER TO TEST     39300013
         CLI   0(TTREG),X'17'          IS THIS AN IDLE CHARACTER        39600013
         BE    IDLOOP                  BRANCH IF IDLE CHARACTER FOUND   39900013
         STC   RF,MSPTR                STORE IDLE CHARACTER COUNT       40200013
         L     TTREG,DCBEXLST     ADDRESS OF TERM BEING PUT TO          40500013
FOUND    MVC   DEBDESTQ+1(3,RDEB),TQCBADDR LOAD LCB WITH ADDRESS OF     40800013
*                                              QCB FOR DESTINATION TERM 41100013
         MVI   121(RDEB),C' '      LOAD PRIORITY BYTE WITH BLANK        41400013
         CLI   3(WREG0),X'0'       HAS USER SPECIFIED PRIORITY          41700013
         BE    *+10                LEAVE BLANK IF NOT SPECIFIED         42000013
         MVC   121(1,RDEB),3(WREG0) ELSE MOVE IN PRIORITY FROM WORKAREA 42300013
         SR    TTREG,RD            GET OFFSET TO TERMTBL ENTRY          42600013
         STH   TTREG,TTDKEY              AND STORE IN DESTINATION KEY   42900013
         LA    MVREG,HDSTRT-MSEGSZE GET OFFSET TO START OF HEADER       43200013
         NI    MSTATUS,EOM         LOAD STATUS BIT IN PREFIX            43500013
CKLGN    SR    BUFLREG,MVREG       HAS BUFFER BEEN FILLED               43800013
         BZ    POST                BRANCH IF YES                        44100013
         SR    WR2,BUFLREG         IS WORKAREA LARGER THAN BUFFER       44400013
         BP    MOVE                BRANCH IF YES - USE BUFFER LENGTH    44700013
         AR    BUFLREG,WR2         ELSE USE WORKAREA LENGTH FOR MOVE    45000013
MOVE     BCTR  BUFLREG,0           DECREMENT FOR EXECUTE                45300013
         AR    MVREG,FREG          ACCESS ADDRESS OF DATA IN BUFFER     45600013
         EX    BUFLREG,EXMOV       CAUSE DATA TO BE MOVED TO BUFFER     45900013
         LA    MVREG,1(BUFLREG,MVREG) SET UP ADDR OF NEXT CHAR IN BUFR  46200013
         SR    MVREG,FREG          GET DATA COUNT OF BUFFER             46500013
         STH   MVREG,MSEGSZE       STORE IT IN PREFIX                   46800013
         LTR   WR2,WR2             ANY DATA LEFT IN WORKAREA            47100013
         BP    POST-4              BRANCH IF YES                        47400013
         ST    FREG,DCBSEGAD       SAVE BUFFER ADDRESS                  47700013
         TM    2(WR1),EOM          IS THIS END OF MESSAGE               48000013
         BZ    POST+4              BRANCH IF NO                         48300013
         OI    MSTATUS,EOM         ELSE INDICATE EOM                    48600013
         LA    WREG0,1(BUFLREG,WREG0) GET ADDR OF NEXT CHAR IN WORKAREA 48900013
*                                                                       49200013
*        RETURN TO IGG019NG TO REVERT TO PROBLEM PROGRAM MODE           49500013
*                                                                       49800013
POST     OI    DCBSEGAD+3,1        SET SWITCH TO INDICATE NO BUFFER     50100013
*                                         HELD OVER                     50400013
         MVC   DEBDESTQ+4(1,RDEB),MSTATUS SAVE RECORD TYPE              50700013
        BAL   TTREG,SWAPSUB        GO TO SWITCH BUFFER ADDRESSES        51000013
         LA    WREG0,0(0,WREG0)    CLEAR HIGH ORDER BYTE           7487 51100016
         ST    WREG0,DCBEODAD          SAVE NEW WORK AREA POINTER       51300013
*                                        AND CLEAR NEW ENTRY SWITCH     51600013
         STM   MVREG,WR1,DEBSV+4(RDEB) SAVE REGISTERS FOR RETURN TO NG  51900013
         LA    TREG,QELEMAD(RDEB)      RELOAD QCB ADDRESS FOR NG        52200013
         LR    RD,R0                   RESTORE BASE FOR QQ01            52500013
         L     WREG0,DEBSV(RDEB)       LOAD RETURN ADDRESS              52800013
         BR    14                      RETURN TO IGG019NG               53100013
*                                                                       53400013
*        POST THE FILLED BUFFER TO THE DEST. QUEUE                      53700013
*                                                                       54000013
POSTBUFF  LA   TREG,DEBQCBAD(RDEB)  LOAD QCB ADDRESS              M4076 54100019
         SVC   QWAIT              WAIT FOR BUFFER                 M4076 54200019
         BAL   TTREG,SWAPSUB      GO TO SWITCH BUFFER ADDRESSES   M4076 54300019
         L     TREG,4(RD)          ACCESS ADDRESS OF                    54600013
         LA    TREG,72(TREG)             QATTACH QCB                    54900013
         LR    WR2,TREG           SAVE QATTACH ADDRESS            19561 55000017
         SVC   QWAIT               WAIT FOR BRB TO LEAVE READY QUEUE    55200013
         TM    DCBSEGAD+3,1            TEST FOR POST BUFFER REQUIRED    55500013
         BC    8,RETURN                BRANCH NOT REQUIRED              55800013
         L     TREG,DEBDESTQ(RDEB)     LOAD DEST. QUEUE ADDRESS         56100013
         LA    TREG,0(0,TREG)      CLEAR HIGH ORDER BYTE.               56400013
         SVC   QPOST               POST BUFFER TO DESTINATION QUEUE     56700013
         LR    TREG,WR2           RESTORE QATTACH ADDRESS         19561 56800017
         SVC   QWAIT              WAIT FOR BRB TO LEAVE READY Q.  19561 56900017
         LM    MVREG,WR2,DEBSV+4(RDEB) RELOAD SAVED REGISTERS           57000013
         LTR   WR2,WR2                 TEST FOR MORE DATA TO MOVE       57300013
         BP    RESTART                 BRANCH ON MORE DATA              57600013
*                                                                       57900013
*        POST THE EXTRA BUFFER TO THE FREE BUFFER QUEUE                 58200013
*                                                                       58500013
RETURN   BAL   TTREG,SWAPSUB       GO SWITCH BUFFER ADDRESSES           58800013
         BZ    EXIT                    BRANCH IF NO EXTRA BUFFER        59100013
         LA    TREG,BUFFER(RF)         FREE BUFFER QCB ADDRESS          59400013
         SVC   QPOST           POST UNUSED BUFFER TO FREE BUFFER QUEUE  59700013
EXIT     RETURN  (14,12)          RESTORE 14-12 AND RETURN              60000013
         SPACE                                                          60300013
COMPARE  CLC   0(1,FREG),9(TREG)                                        60600013
EXMOV    MVC   8(1,MVREG),4(WREG0) MOVE WORKAREA TO BUFFER              60900013
         SPACE                                                          61200013
CONT     ST    FREG,DCBSYNAD           STORE EXTRA BUFFER ADDRESS       61500013
         L     FREG,DCBSEGAD           LOAD PREVIOUS BUFFER ADDRESS     61800013
         LH    MVREG,MSEGSZE       GET CURRENT BUFFER DATA COUNT        62100013
         TM    2(WREG0),TXT        IS THIS A TEXT SEGMENT               62400013
         BNZ   CKLGN               BRANCH IF YES                        62700013
         OI    MSTATUS,EOM         ELSE INDICATE END OF MESSAGE         63000013
         B     POST                GO TO RETURN                         63300013
LOADSUB  L     RDEB,DCBDEBAD           LOAD THE DEB ADDRESS             63600013
         L     RD,CVTABLE              LOAD ADDRESS OF COMM. VECTOR TB. 63900013
         L     RD,CVTTRMTB(RD)         LOAD TERM TABLE ADDRESS          64200013
         L     RF,4(RD)                LOAD ADDRESS OF IGG019NG         64500013
         L     RF,0(RF)                LOAD ADDRESS OF LPS SECTION      64800013
         BR    TTREG               RETURN                               65100013
SWAPSUB  L     TREG,DCBSYNAD           LOAD SAVED BUFFER ADDRESS        65400013
         LTR   TREG,TREG               TEST FOR ANY SAVED BUFFER        65700013
         BCR   8,TTREG                 RETURN IF NO SAVED BUFFER        66000013
         ST    FREG,DCBSYNAD           SAVE PRESENT WORKING BUFFER      66300013
         LR    FREG,TREG               SET NEW WORKING BUFFER ADDRESS   66600013
         BCR   15,TTREG            RETURN                               66900013
         SPACE                                                          67200013
SEQTEST  TM    DEBDESTQ+4(RDEB),LAST WAS LAST RECORD END OF MESSAGE     67500013
         BZ    NOTEND             BRANCH LAST NOT END OF MESSAGE        67800013
         TM    2(TTREG),HDR       TEST TYPE OF RECORD                   68100013
         BZ    TERMTEST           BRANCH HDR EXPECTED HDR RECEIVED      68400013
         B     NOTVALID           HEADER NOT RECEIVED WHEN EXPECTED     68700013
NOTEND   TM    2(TTREG),HDR       TEST TYPE OF RECORD                   69000013
         BO    NOTHEADR           BRANCH HDR NOT EXPECTED NOT RECEIVED  69300013
NOTVALID OI    19(13),SEQER       SET SEQUENCE ERROR FLAG               69600013
         B     NOTHEADR                                                 69900013
FOUR     DC    H'04'                                                    70200013
HALFWORD DC    H'0'                                                     70500013
         DS    0F                                                       70800013
PRICON   DC    X'EC000000'                                              71100013
         CNOP    0,8                                                    71400013
QELEMAD  EQU   32                                                       71700013
DEBQCBAD EQU   32                                                       72000013
DEBSTATE EQU   40                  LCB IS IN THE DEB                    72300013
BUFFAD   EQU   48                                                       72600013
DEBDESTQ EQU   68                                                       72900013
DEBSV    EQU   104                                                      73200013
BUFFER   EQU   24                                                       73500013
SEGSTRT  EQU   4                                                        73800013
CVTABLE  EQU   16                                                       74100013
CVTTRMTB EQU   156                                                      74400013
BUFSZ    EQU   154                                                      74700013
TTQUES   EQU   4                                                        75000013
BREQ     EQU   12                                                       75300013
TXT      EQU   X'01'                                                    75600013
EOM      EQU   X'02'                                                    75900013
         EJECT                                                          76200013
         DCBD  DSORG=MQ                                                 76500013
         EJECT                                                          76800013
         PREFIXD                                                        77100013
         EJECT                                                          77400013
         TERMTBLD                                                       77700013
         END                                                            78000013
