IGG019NG START                                                          00030013
*2010100180-100420,100900-101000,116150-116350,118000-118300       7461 00030516
*2010119420-119660,136900-137300,138970-139110                     7461 00031016
*2010360400-360600,782700                                          8514 00031516
*2010827900-828700                                                 7814 00032016
*2541055320-055640,067300                                          00PS 00032117
*2541219600                                                        8064 00032217
*2541714810-714860                                                 7766 00032317
*2010860170-860310                                                 00PS 00032516
* 845200-845700,858700-858800                                    A27524 00033119
* 827730                                                         A26774 00033719
* 015000                                                         A27855 00033819
* 118360-119200,119460-119640,75013-750160                       A28771 00033919
* 722800-723100                                                  26776  00034019
* 827730                                                         28763  00034119
* 843999                                                         A29193 00034219
* 859730-859770                                                  A29182 00034319
* 721300-722200,842950-843250                                    A26763 00034419
* 044460-044640,0489500                                           25340 00034518
* 049100,52101-052106,054503-054506                               25336 00036518
* 241500-241800                                                   26023 00038518
* 531800-533000                                                   24957 00040518
* 708300,713100,745800,824800,833160-833340,896700,898000          00PS 00042518
* 719800-719900                                                   22423 00044518
* 843636,843699-843708,843726,843789                               000D 00046518
* 843997,844001,856270-856690                                      000D 00047518
* 724900-725200                                                    00PS 00048518
* 872780                                                          M3140 00050518
*A844144-844154                                                  A46042 00050721
*D639100,639200,640800,641200                                    A46045 00050921
*A085000-085100                                                  A46054 00051021
* 171400,175900,176700,827715                                      00PS 00051120
* 272800-273200,279300                                           A29218 00051720
* 306070-306210,900030,900420,900662-900672                      A29210 00052320
* 673020-673140,901420                                           A31036 00052920
* 844050,844077,844095,844124-844134                               000D 00053520
*D550800,669900,672600-672900                                    A33039 00053620
*A550560-550980,551730-551970,578500-578600,629800-629900        A33039 00053720
*A669700-670100,673150-673170                                    A33039 00053820
*C901420                                                         A33039 00053920
* 117910-117980                                                  A39114 00054020
* 100460,136200                                                  A39103 00054120
* 154366-154390,154980-155060                                    A36516 00054220
* 154746-154752                                                  A37734 00054320
* 298830-298860                                                  A39109 00054420
* 832500,836300-836500,842906-842942,900780                      A39104 00054520
* 052107-052108,053210-053310,054860-054870,626800,848400,901420 A36503 00054620
* 827720                                                         A35209 00054720
*D644000,A644000-644020                                          A50602 00054821
*D550860,A550880-550900                                          A52243 00054921
*C64400,644020                                                    59550 00055021
*1210727800,730000,730100,735400-735500                            3727 00055116
*1210842100-842400                                                 4391 00055216
*1210872730-872760                                                 6497 00055316
*1210883200                                                        4778 00055416
*1210889200-891900                                                 4989 00055516
*1210901200                                                        00PS 00055616
*2719033970-034110,038700,039000-039300,052110-052180              000C 00056017
*2719088530-088710,287740-288180,290800,311430-311670              000C 00056417
*2719315300,824160-824340,835207-835284,901410,902100              000C 00056817
*2719564700-564800,568300,827730-827850                            000C 00057217
*16400695000-069700,071306-071384,092140-092900,131420-131620      000D 00057716
*1640138300,626500-626900,675630-675930,749150-749400,             000D 00058416
*1640824600-824800,859713-859776,900906-901464                     000D 00059116
*1770587740-587940,688200,695100,696000,698200-698300              6990 00059216
*1770768600,899200                                                 00PS 00059316
*1770873550                                                        6482 00059416
*1770893400-894300                                                 7218 00059516
*3411014100                                                       19539 00061517
*3411053230-053350,298260-298320                                  18921 00063517
*3411245400                                                       18539 00065517
*3411628900,658700-659300,660300,673000,698250                    19509 00067517
*3411642050-642250                                                19198 00069517
*3411643850-644150                                                17543 00071517
*3411672200                                                       18900 00073517
*3411672400                                                       19563 00075517
*3411827730                                                       20181 00077517
*3411846500                                                       18930 00079517
*3411887980-888220                                                19663 00081517
*3411901445                                                        00PS 00083517
*83660655850-656150,657100,672920-672980                          21207 00083717
*83660890300-890900                                               20401 00083917
*0300645030-645100,890000,892000                                   00PS 00084117
*90354901011-901020                                               21217 00084317
*90354639100-639200,639650,640800-641200,643850,644300             00PS 00084517
*90354827200-827300                                                00PS 00084717
*1201050250,050700,054510-054590,055310,053320,099970-100050      22437 00085018
*1201154960                                                       22437 00085318
*1201092400-092700,346260-346680,626800,675700,829000-829100,      000D 00085618
*1201829500,829830-830010,830200,839600-839800,843609-844167,901420000D 00085918
*1201139040,249700,250600-250800                                  21857 00086218
*1201298900,892500,893800,896500                                  22436 00086518
*1201481036-481042                                                22430 00086818
*1201630370-630510,721800,784300,865230-865410,872300              00PS 00087118
*1201842600                                                       22743 00087418
*1201859100                                                       21858 00087718
*1201860170                                                       21856 00088018
*1201882960-883140                                                21849 00088318
*A639100,639200,640800,641200                                    A64632 00088421
*A873560-873590,D873600,A873650,C901492                         A65111  00090421
*1201887200-887300                                                23159 00096621
*1990150000,052170,052340,054545,054850,714825-714835,854800-85510000PS 00100521
*1990856400-856600,900901-900908                                   000D 00104421
REG0     EQU    0                                                  00PS 00108321
FREG     EQU  1                   BASE FOR MESSAGE PREFIX               00112221
TREG     EQU   2                   BASE FOR TCB,STCB                    00116121
Y        EQU   3                   BASE FOR DCB                         00120013
LCBREG   EQU   4                   BASE FOR LCB                         00150013
SPREG    EQU   5              CONTAINS HDR SCAN POINTER                 00180013
X        EQU   6    TEMP REG FOR DCB OR 1ST LCB BASE                    00210013
LGREG    EQU   7              BASE FOR USER'S LPS PROGRAM               00240013
TCREG    EQU   8                                                        00270013
QREG     EQU   9                   BASE FOR QCB                         00300013
TCBREG   EQU   10                                                       00330013
EOSREG   EQU   11                                                       00360013
BREG     EQU   12                  BASE FOR MODULE IECKQQ01             00390013
Z        EQU   13                  BASE FOR MODULE (IGG019NG)           00420013
LNKRG2   EQU   14                                                       00450013
         SPACE 2                                                        00480013
QWAIT    EQU   65                                                       00510013
QPOST    EQU   67                                                       00540013
         ENTRY RCVSCH,ENQUEUE,RQCONSTR,BREQENQ,BFRENQ,ADDBUF,IECKACT    00546019
         ENTRY INTERM,IECKRC,IECKPR,LPS,QPRIRTY,QLIFO,QEVENT,IECKMQ     00552019
         ENTRY GETSCH,GETRET,MRRE,DISKENQ,DISKSIO,DISKEND,LINESIO       00558019
         ENTRY LINEPCI,LINEEND,QMOVER                                   00564019
         USING IECKPREF,FREG                                            00570013
         USING QBLOCK,QREG                                              00600013
         USING TBLOCK,TREG                                              00630013
         USING IECKLCB0,LCBREG                                          00660013
         USING IHADCB,Y                                                 00690013
         USING IGG019NG,Z                                               00720013
         USING SVCBASE+2,BREG                                           00750013
         EJECT                                                          00780013
* QPOST-QWAIT STATUS SAVE AREA                                          00810013
         DC    A(LPS)                                                   00840013
         DC    17A(0)                                                   00870013
         SPACE                                                          00900013
*                   PSUEDO 'NOT WAITING' QCB                            00930013
IECKSTOP EQU   *                                                        00960013
QSAVE    EQU   *                                                        00990013
WAITRB   EQU   *                                                        01020013
         SPACE                                                          01050013
*                                  READY QUEUE                          01080013
QATTACH  DC    X'02'               QKEY                                 01110013
         DC    AL3(WAITRB)         ADDRESS OF LAST DISPATCHED QUEUE     01140013
         DC    X'FF'               PRIORITY (SIGNALS END OF CHAIN)      01170013
         DC    AL3(WAITRB)         LINK FIELD TO ITSELF                 01200013
READY    DC    A(WAITRB)           POINTER TO 1ST ITEM ON READY QUEUE   01230013
         SPACE                                                          01260013
         DC    X'00'                                                    01290013
DUMMY    DC    AL3(WAITRB)         ALWAYS HAS ADDRESS OF QATTACH        01320013
         SPACE                                                          01350013
STARTIO  DC    A(0)                                                     01380013
         DC    X'E3'                                              19539 01410017
         DC    AL3(0)                                                   01440013
CLOSEOUT DC    A(0)                                                     01470013
         DC    X'EC'                                             A27855 01500019
         DC    AL3(0)                                                   01530013
         SPACE                                                          01560013
* TRANSFERS TO VARIOUS TRUNCATED SUBTASK ENTRY POINTS                   01590013
NRET     EQU   *-2                                                      01620013
ENQUE    B     6(0,TREG)                                                01650013
SEND     NOPR  0                                                        01680013
RQRET    LR    LCBREG,TREG         GET ADDR OF PASSED LCB/QCB           01710013
         LA    TREG,AVREQ          GET POINTER TO ADDR OF USERS BRB    -01740013
                                   CHAIN                                01770013
         B     RQSETUP           BRANCH TO START BRB RING CONSTRUCTION  01800013
         TITLE 'RECEIVE SCHEDULER ROUTINE'                              01830013
* RECEIVE-SCHEDULING SUBTASK                                            01860013
*      STCB--THERE IS ONE RECEIVE-SCHEDULING SUBTASK FOR                01890013
*      EACH LINE.  THE STCB FOR THE SUBTASK IS CONTAINED IN             01920013
*      THE THIRD AND FOURTH FULLWORDS OF THE CORRESPONDING LCB.         01950013
*      PROGRAM ENTRY--ALL RECEIVE-SCHEDULING SUBTASKS ENTER             01980013
*      THE RECEIVE-SCHEDULER ROUTINE AT RCVSCH.                         02010013
* RECEIVE-SCHEDULER ROUTINE                                             02040013
*      THIS ROUTINE EXAMINES THE CURRENT POLLING LIST ENTRY             02070013
* FOR A LINE.  IF POLLING IS TO BE PERFORMED ON THE LINE AND            02100013
* IF THE CURR ENTRY IS VALID (I.E., IS NOT THE DUMMY                    02130013
* ENTRY SIGNALLING THE END OF THE POLLING LIST), THE                    02160013
* ROUTINE BRANCHES TO THE BRB-RING ROUTINE (RQCONST) TO                 02190013
* INIT FOR RECEIVING.  BEFORE THE BRANCH IS EXECUTED,                   02220013
* THE ROUTINE SETS THE LINE RECEIVING CODE (LCBSTATE=8)                 02250013
* IN THE LCB TO INDICATE THE KIND OF OPERATION ANTICIPATED.             02280013
*      IF THE CURR POLLING LIST ENTRY IS THE DUMMY LAST                 02310013
* ENTRY, THE ROUTINE CLEARS THE LINE RECEIVING CODE AND                 02340013
* BRANCHES TO THE DEFER-ENTRY SUBROUTINE (UNAVAIL) AFTER                02370013
* RESETTING THE CURR ENTRY POINTER TO THE TOP OF THE                    02400013
* POLLING LIST.  THE PURPOSE OF THIS BRANCH IS TO PERMIT                02430013
* THE LINE'S SEND SCHEDULING SUBTASK TO BECOME ELIGIBLE FOR             02460013
* ACTIVATION IF ITS STCB IS ALSO IN THE CHAIN.  IF                      02490013
* THE SEND SCHEDULING SUBTASK IS NOT IN THE CHAIN, THE                  02520013
* RECEIVE SCHEDULING SUBTASK WILL AGAIN BE ACTIVATED TO                 02550013
* RECOMMENCE POLLING AT THE TOP OF THE POLLING LIST.                    02580013
*      BEFORE THE BRANCH TO THE DEFER-ENTRY SUBR IS                     02610013
* TAKEN, A POSSIBLE ENDLESS LOOP IS CIRCUMVENTED BY A TEST              02640013
* TO DETERMINE THAT THE POLLING LIST CONTAINS AT LEAST ONE              02670013
* ENTRY IN ADDITION TO THE DUMMY LAST ENTRY.  IF THE LIST               02700013
* CONTAINS NO TRUE ENTRY, THE RECEIVE-SCHEDULING SUBTASK IS             02730013
* LEFT AT THE HEAD OF THE STCB CHAIN BUT IS SKIPPED OVER.               02760013
* CONTROL PASSES TO THE SECOND SUBTASK IN THE CHAIN.                    02790013
         SPACE 2                                                        02820013
**********                         TEST IF POLLING DESIRED              02850013
RCVSCH   LA    LCBREG,0(0,FREG) WHEN ENTERED HERE, FREG POINTS TO A LCB 02880013
         SR    Y,Y                 CLEAR FOR CALCULATION OF POLLING     02910013
*                                        LIST ADDRESS                   02940013
         IC    Y,LCBUCBX           LCBUCBX HAS RELATIVE LINE NUMBER - 1 02970013
         SLA   Y,2                 MULTIPLY BY 4 TO GET OFFSET FROM     03000013
*                                      DCBCPOLL OF POLLING LIST ADDRESS 03030013
         A     Y,LCBDCBPT          ADD ADDRESS OF DCB                   03060013
         L     Y,DCBCPOLL          LOAD ADDRESS OF POLLING LIST FROM    03090013
*                                      DCB USING Y AS A BASE REGISTER   03120013
*                                                                       03150013
         CLI   1(Y),0              IS THIS AN ACTIVE POLLING LIST       03180013
         BE    NOGO              BRANCH IF NO, LINE WILL NOT BE POLLED  03210013
         SPACE                                                          03300013
**********                         IF LINE IS TO BE POLLED,             03330013
* RESET POLL LIST AND REORDER WAIT QUEUE AT END OF LIST                 03360013
         MVI   LCBSTATE,RQRET-NRET   SET CODE 8--LINE IS RECEIVING      03390013
         L     X,LCBDCBPT              GET DCB ADDRESS             000C 03397017
         TM    DCBCPOLL-IHADCB(X),X'68' IS IT A WTTA LINE GROUP    000C 03404017
         BO    WTTARCVS                YES                         000C 03411017
         L     X,LCBPOLPT-1        GET ADDRESS OF CURRENT ACTIVE ENTRY  03420013
*                                      IN POLLING LIST                  03450013
         NC    0(2,X),0(X)         TEST FOR END OF LIST                 03480013
*                                  DUMMY ENTRY=0 IF AT END              03510013
         BNZ   RQCONSTR            BRANCH TO BRB-RING ROUTINE IF NOT    03540013
*                                      END OF LIST                      03570013
         SPACE                                                          03600013
**********   TO HERE IF AT END OF POLLING LIST                          03630013
         ST    LCBREG,LCBSTATE       ZERO LINE RECEIVING CODE           03660013
*                            AND SAVE LCB ADDRESS OF ORIGINATING LINE   03690013
         LA    Y,2(Y)              IF AT END RESET CURRENT ENTRY       -03720013
                                   POINTER TO START OF POLLING LIST     03750013
         TM    LCBFLAG2,X'01'      IS THIS AN AUTOPOLL LINE             03780013
         BZ    RSA                 IF NO SKIP NEXT INSTRUCTION          03810013
         LA    Y,3(Y)              IF YES RESET POINTER FOR AUTOPOLL    03840013
         B     RSA                     BRANCH TO RESET LCB POINTER 000C 03870017
         SPACE                                                          03960013
K24      DC    H'24'                                                    03990013
         TITLE 'SEND SCHEDULER ROUTINE'                                 04020013
* SEND-SCHEDULING SUBTASK                                               04050013
*      STCB--THERE IS ONE SEND-SCHEDULING SUBTASK FOR EACH              04080013
*      LINE OR TERMINAL, DEPENDING ON THE QUEUEING TECHNIQUE            04110013
*      SELECTED BY THE USER.  THE STCB FOR THE SUBTASK IS               04140013
*      CONTAINED WITHIN THE THIRD AND FOURTH FULLWORDS OF THE           04170013
*      QCB FOR THE CORRESPONDING DESTINATION-DASD QUEUE.                04200013
*      PROGRAM ENTRY--ALL SEND-SCHEDULING SUBTASKS ENTER THE            04230013
*      SEND-SCHEDULER ROUTINE AT ENQUEUE.                               04260013
**********                         TEST FOR MESSAGE TO SEND             04290013
         ORG   NRET+X'68'                                               04320013
         B     ENQUEUE            ENTRY POINT FOR SEND-SCHEDULAR        04350013
         B     8(TREG)            ENTRY POINT FOR 8 BYTE STCB'S NRET+6C 04380013
ENQUEUE  SH    TREG,K8             SET TREG TO QCB ADDRESS FOR THE      04410013
*                                      DESTINATION DASD QUEUE           04440013
         CLI   FPRI,X'FE'          IS THIS A SPECIAL PRIMER      A25340 04446018
*                                    ELEMENT POSTED TO THE QCB   A25340 04452018
*                                    BY RELEASEM OR STOPLINE     A25340 04458018
         BE    STARTSND            YES, BYPASS DESTINATION-DASD  A25340 04464018
         CLI   FKEY+8,X'12'       IF EQUAL TO X'12' FREG POINTS TO LCB  04470013
*                                 NOT EQUAL X'12' FREG POINTS TO BUFFER 04500013
         BE    SENDSCH            BRANCH IF FREG EQUALS LCB             04530013
         BAL   TREG,SCREEN         LINK TO SCREEN TO CAUSE AN EFFECTIVE 04560013
*                                    POST TO THE DISK I/O QCB BY        04590013
*                                    CHANGING THE FIRST WORD OF THE     04620013
*                                    BUFFER TO POINT TO THE DISK I/O    04650013
*                                    QUEUE AND PUTTING THE BUFFER ON    04680013
*                                    THE READY QUEUE.  THIS EVENTUALLY  04710013
*                                    CAUSES THE MESSAGE TO BE WRITTEN   04740013
*                                    ON THE DISK.                       04770013
          TM     LCBSTATE,X'10'   TEST IF COMPLETE MSG HAS ARRIVED      04800013
          BZ    DISPATCH      BRANCH IF NONE                            04830013
         SPACE                                                          04860013
*                                                                  000A 04870015
* TEST IF DCB FOR LINE HAS BEEN OPENED FOR OUTPUT                  000A 04880015
*                                                                  000A 04890015
STARTSND EQU   *                                                 A25340 04895018
         SR    LCBREG,LCBREG                                       000A 04900015
         LA    LCBREG,1           SET RELATIVE LINE NUMBER TO ONE 25336 04910018
         L     Y,QDCB-1            LOAD DCB ADDRESS                000A 04920015
         L     X,DCBDEBAD          LOAD DEB ADDRESS                000A 04930015
         LR    TREG,X              COPY DEB ADDRESS                000A 04940015
        SH    TREG,K24       GET CALL QUEUE ADDRESS MUNUS EIGHT    000A 04950015
         TM    DCBOFLGS,X'10'      HAS DCB BEEN OPENED             000A 04960015
         BZ    DISPATCH      EXIT-IGNORE ENTRY IF DCB NOT OPNED    000A 04970015
         TM    12(X),3             HAS DEB BEEN OPENED FOR OUTPUT  000A 04980015
         BZ    DISPATCH      EXIT-IGNORE ENTRY IS NOT FOR OUTPUT   000A 04990015
*                                                                  000A 05000015
* TEST IF RELATIVE LINE NUMBER IS GREATER THAN NUMBER OF LINES     000A 05010015
*                                                                  000A 05020015
         SR    LGREG,LGREG         CLEAR FLAG REGISTER            22437 05025018
DIALLOOP SR    FREG,FREG                                           000A 05030015
         IC    FREG,DEBNMEXT-DEB(X) GET NUMBER OF EXTENTS(LINES)   000A 05040015
         CLR   LCBREG,FREG   IS RLN GREATER THAN NUMBER OF LINES   000A 05050015
         BH    FOUND               YES, SEE IF LINE AVAILABLE     22437 05070018
*                                                                  000A 05090015
* COMPUTE ADDRESS OF LCB FOR THE SPECIFIED RELATIVE LINE NUMBER    000A 05100015
*                                                                  000A 05110015
         IC    FREG,DCBEIOBX       GET SIZE OF LCB FROM DCB        000A 05120015
         MR    FREG-1,LCBREG       MULTIPLY BY RELATIVE LINE NUMBER000A 05130015
         A     FREG,DCBLCBAD       ADD BASE ADDRESS TO GET         000AX05140015
                                        SPECIFIC LCB               000A 05150015
*                                                                  000A 05160015
* TEST FOR DIAL LINE                                               000A 05170015
*                                                                  000A 05180015
         LR    SPREG,LCBREG        COPY RELATIVE LINE NUMBER       000A 05190015
         SLL   SPREG,2             MULTIPLY BY FOUR                000A 05200015
         L     SPREG,EXT1-4-DEB(SPREG,X) GET UCB ADDRESS           000A 05210015
         TM    17(SPREG),X'90'    IS THIS A DIAL LINE            A25336 05210118
         BNZ   FINDLINE           BRANCH IF DIAL                 A25336 05210218
         LR    EOSREG,LCBREG      SAVE RLN                       A25336 05210318
         IC    LCBREG,QRLN        GET RLN FROM QCB               A25336 05210418
         CLR   EOSREG,LCBREG      IS THIS THE RIGHT RLN          A25336 05210518
         BNE   DIALLOOP           NO LOOK AT CORRECT LCB         A25336 05210618
         NI    LCBINCAM-LCB(FREG),X'FE' TURN OFF INITIAL CONTACT A36503 05210720
*               THIS BIT WILL BE RESET AFTER LABEL NONDIAL       A36503 05210820
         TM    DCBCPOLL,X'68'          IS IT A WTTA LINE GROUP     000C 05211017
         BNO   NOWTTA                  BRANCH IF NO                000C 05212017
         CLI   LCBCPA+37-LCB(FREG),255  IS PREPARE COMPLETE        000C 05213017
         BNE   NONDIAL                 BRANCH IF YES               000C 05214017
         MVI   LCBCPA+37-LCB(FREG),0   CLEAR SENSE BYTE            000C 05215017
         OI    LCBINCAM-LCB(FREG),X'08' SET HIO FLAG ON            000C 05216017
         B     HIOLOOP                 GET UNIT ADDRESS            00PS 05217018
NOWTTA   EQU   *                                                   000C 05218017
         CLI   LCBCPA-LCB+16(FREG),X'04' IS THIS A SENSE COMMAND   6646 05224016
*                             (2740 BASIC OR WITH CHECKING)        6646 05226016
         BNE   NONDIAL                  NOT DIAL OR 2740           6646 05228016
         CLI   LCBCPA-LCB+21(FREG),X'00' TP OP CODE =00, LINE IS   6646 05230016
*                             BUSY - NO HIO ISSUED                 6646 05232016
         BNE   HIOLOOP                 HIO TO ALLOW SENDING        00PS 05234018
         B     NONDIAL        NOT A DIAL LINE NO HIO NECESSARY     6646 05236016
*                                                                  000A 05240015
* IS THE LINE SPECIFIED BY THE RLN CONNECTED TO THE                000A 05250015
*              DESTINATION TERMINAL                                000A 05260015
FINDLINE EQU   *                                                 A25336 05265018
         LH    TCREG,LCBTTIND-LCB(FREG) GET LINE'S TERMINAL        000A 05270015
*              TABLE INDEX                                         000A 05280015
         A     TCREG,TTBASE        ADD BASE FOR TERMINAL TABLE     000A 05290015
         L     TCREG,0(TCREG)      LOAD ADDRESS OF TERMINAL'S QCB  000A 05300015
         LA    TCREG,0(TCREG)      CLEAR HIGH ORDER BYTE           000A 05310015
         CLR   TCREG,QREG          IS LINE CONNECTED TO TERMINAL   000A 05320015
         BNE   NEXTLINE            NO, LOOK AT NEXT LINE         A36503 05321020
         CLI   LCBCPA+32-LCB(FREG),4 DOES CHANNEL PROGRAM        A36503 05322020
*                                  CONTAIN A SENSE COMMAND       A36503 05323020
         BNE   LNKLCB              NO, BRANCH TO LINK SEND SCHED A36503 05324020
*                                  INTO LCB SUBTASK CHAIN        A36503 05325020
         CLI   LCBCPA+37-LCB(FREG),0 HAS SENSE COMPLETED         A36503 05326020
         BE    LNKLCB              YES, LINK SEND SCHEDULER      A36503 05327020
         OI    LCBINCAM-LCB(FREG),1  SET INITIAL CONTACT BIT     A36503 05328020
*               THIS BIT WILL BE TURNED OFF AFTER LABEL NONDIAL  A36503 05329020
         B     HIOLOOP             DO HIO TO ALLOW SENDING       A36503 05330020
NEXTLINE EQU   *                                                A36503  05331020
*                                                                  000A 05340015
* IF THE TERMINAL IS CONNECTED GO TRY THE NEXT LINE                000A 05350015
*                                                                  000A 05360015
         LA    LCBREG,1(LCBREG)    INCREMENT THE RLN BY ONE        000A 05370015
         CLI   QTRAN+4,X'01'       IS THE TERMINAL CONNECTED       000A 05380015
         BNE   DIALLOOP            IF YES TRY NEXT LINE            000A 05390015
*                                                                  000A 05400015
* IF THE TERMINAL IS NOT CONNECTED GO GET A FREE LINE              000A 05410015
*                                                                  000A 05420015
         TM    LCBINCAM-LCB(FREG),2 IS LINE SPECIFIED BY RLN       000A 05430015
*                            CONNECTED                             000A 05440015
         BNZ   DIALLOOP            IF YES TRY NEXT LINE            000A 05450015
         EX    LCBREG,RLNCMPR     COMPARE RLN TO QCB RLN          25336 05450318
         BNL   DIALLOOP           BRANCH IF QCB RLN HIGHER        25336 05450618
         LTR   LGREG,LGREG         HAS A LINE BEEN FOUND YET      22437 05451018
         BNZ   DIALLOOP            YES, CONTINUE SEARCH TO SEE IF 22437 05452018
*                                   CONNECTED ON ANOTHER LINE     22437 05453018
         LR    LGREG,FREG          SAVE A FOUND CALL              22437 05454018
         LR    EOSREG,SPREG            SAVE UCB OF FOUND CALL      00PS 05454518
         B     DIALLOOP            AND CONTINUE SEARCH            22437 05455018
FOUND    LTR   FREG,LGREG          WAS A CALL FOUND               22437 05456018
         BZ    UNAVAIL             NO, PUT THE STCB ON THE CALL   22437 05457018
*                                   QUEUE (THIS BRANCH CANNOT BE  22437 05458018
*                                   TAKEN FOR NON-SWITCHED LINES) 22437 05459018
*                                                                  000A 05460015
* PREPARE LINE FOR OUTPUT                                          000A 05470015
*                                                                  000A 05480015
         LR    SPREG,EOSREG       RESTORE UCB FOR LINE TO STOP     00PS 05485018
         NI    LCBINCAM-LCB(FREG),X'FE' TURN OFF INITIAL CONTACT A36503 05486020
*               THIS BIT WILL BE RESET AFTER LABEL NONDIAL       A36503 05487020
         OI    LCBINCAM-LCB(FREG),2 INDICATE LINE IS ASSIGNED FOR  000A 05490015
*                            DIAL                                  000A 05500015
HIOLOOP  NI    LCBFLAG1-LCB(FREG),X'DB' TURN OFF ERP FLAGS         000A 05530015
         MVI   LCBECBPT-LCB(FREG),X'48'  SET HIO FLAG FOR LINE-END22437 05531018
UCBFLAGS EQU   6                                                   00PS 05532017
UCBRQEAD EQU   20                                                  00PS 05534017
CVT      EQU   16                                                  00PS 05536017
CVTIXAVL EQU   124                                                 00PS 05538017
HIORTN   EQU   8                                                   00PS 05540017
         IC    TREG,UCBFLAGS(SPREG)  SAVE UCBFLAGS STATUS          00PS 05542017
         STM   8,15,SAVE      SAVE REGISTERS FOR HALT I/O          00PS 05544017
         LR    TCREG,SPREG    UCB ADDRESS TO REG 8                 00PS 05546017
         LH    QREG,UCBRQEAD(TCREG)  RQE ADDRESS IN REG 9          00PS 05548017
         LR    REG0,Z         SAVE BASE REGISTER                   00PS 05550017
         L     TCBREG,CVT     CVT ADDRESS                          00PS 05552017
         L     TCBREG,CVTIXAVL(TCBREG)  PARAMETER LIST ADDRESS     00PS 05554017
         L     TCBREG,HIORTN(TCBREG)    HALT I/O ROUTINE ADDRESS   00PS 05556017
         BALR  R15,TCBREG     LINK TO HALT I/O ROUTINE             00PS 05558017
         LR    Z,REG0         RESTORE BASE REGISTER                00PS 05560017
         LM    8,15,SAVE      RESTORE REGISTERS                    00PS 05562017
         STC   TREG,UCBFLAGS(SPREG)  RESTORE UCBFLAGS STATUS       00PS 05564017
*                                                                  000A 05580015
* SET UP TO LINK STCB INTO LCB                                     000A 05590015
*                                                                  000A 05600015
NONDIAL  CLI   DCBCPRI,1     TEST THE LINE GROUP FOR SEND PRIORITY 000A 05610015
         BC    2,*+8               BRANCH IF NOT SEND PRIORITY     000A 05620015
         XI    LCBINCAM-LCB(FREG),1  SET INITIAL CONTACT BIT -   A36503X05630020
                       INDICATES   LINE IS TRYING TO SEND AND SIO  000AX05640015
                                   APPENDAGE SHOULD PREVENT POLLING000A 05650015
LNKLCB   LA    TREG,0(FREG)  PREPARE TO LINK STCB INTO LCB CHAIN   000A 05660015
*                                                                  000A 05670015
* IF THIS IS AUTOPOLLED LINE CAUSE A LINE END AT END OF POLLING    000A 05680015
*              LIST                                                000A 05690015
         CLI   LCBSTATE-LCB(FREG),1  IS LINE FREE (FOR NON DIAL LINE)   06420013
         BE    SSCNT               IF FREE SKIP AUTOPOLL TESTS          06450013
         TM    LCBFLAG2-LCB(FREG),X'01' IS THIS AN AUTOPOLL LINE        06480013
         BZ    UNAVAIL             IF NO EXIT TO DEFER-ENTRY ROUTINE    06510013
         TM    LCBSTATE-LCB(FREG),X'08' IS LINE IN RECEIVE STATUS       06540013
         BZ    UNAVAIL             IF NO EXIT TO DEFER ENTRY ROUTINE    06570013
         TM    LCBCECB-LCB(FREG),X'02' READ CONTINUE OR READ REPEAT     06600013
         BO    *+8                 BRANCH IF EITHER                     06630013
         MVI   LCBCPA+16-LCB(FREG),X'03' I/O NOP TIC AFTER 1ST POLL CCW 06660013
         MVI   LCBCPA+40-LCB(FREG),X'03' I/O NOP TIC AFTER 2ND POLL CCW 06690013
         B     UNAVAIL             TO DEFER ENTRY                       06720013
SAVE     DS    8F       SAVE AREA FOR LINK TO HALT I/O ROUTINE     00PS 06730017
       SPACE                                                            06750013
*                                                                  000A 06770015
* SINCE DESTINATION LINE IS FREE PREPARE IT FOR IMMEDIATE DISPATCH 000A 06790015
*                                                                  000A 06810015
SSCNT    MVC   FLINK(3),READY+1    MOVE POINTER TO TOP OF READY QUE000AX06830015
               INTO THE DESTINATION LCB LINK FIELD                 000A 06850015
         ST    FREG,READY    PUT DEST LCB AT TOP OF READY QUEUE    000A 06870015
         ST    TREG,0(FREG)        EFFECTIVLY POST LCB TO ITSELF   000A 06890015
         B     UNAVAIL       GO GET SEND SCHEDULER PLACED INTO     000AX06910015
               STCB CHAIN OF LCB AND DISPATCH LCB                  000A 06930015
         SPACE                                                          06990013
*  TEST FOR MESSAGES QUEUED UP FOR CURRENT FREE LINE FOR DESTINATION    07020013
*    FROM SOURCE TERMINALS                                              07050013
SENDSCH  LA    LCBREG,0(0,FREG)    INITIALIZE LCBREG WITH LCB BASE      07080013
*                                      FOR DESTINATION                  07110013
         LA    Y,RQCONST     GET ADDRESS OF BRB RING ROUTINE FOR EXIT   07140013
         SPACE                                                          07170013
*  THIS IS AN ENTRY POINT FROM THE GET SCHEDULER ROUTINE                07200013
MSGTEST  L     X,QSORCE-QBLOCK-1(TREG) GET THE ADDRESS OF THE FIRST LCB 07230013
*                                      ON LCB CHAIN FOR MESSAGES FROM   07260013
*                                      A SOURCE TERMINAL                07290013
         BCTR  X,0        MUST SUBTRACT 'IN-SOURCE CHAIN' CODE          07320013
*                            (CLEARS THE 1 BIT IN THE ADDRESS)          07350013
         CLI   LCBMSGPR-LCB(X),X'40' ARE PRIORITY MESSAGES COMING IN    07380013
         BH    INITTEST            BRANCH IF YES                        07410013
*                             TO HERE IF NO PRIORITY MESSAGES           07440013
**********                    TEST FOR ANY COMPLETED MESSAGES           07470013
         MVC   LCBCSEG(3),TFILL+1 MOVE MESSAGE POINTER INTO LCB         07500013
         CLC   LCBCSEG(3),LCBNASEG-LCB(X) HAS COMPLETE INCOMING MESSAGE 07530013
*                                      FROM SOURCE TERMINAL BEEN PUT ON 07560013
*                                      DISK YET                         07590013
         BL    PREPARE             BRANCH IF YES, LCBNASEG HAS BEEN     07620013
*                                    BUMPED TO NEXT SEGMENT LOCATION    07650013
*                                    ON THE DISK                        07680013
         SPACE                                                          07710013
**********             TO HERE IF NO COMPLETED NON-PRIORITY MESSAGES    07740013
**********               OR  IF PRIORITY MSGS ARE COMING IN             07770013
* IF PRIORITY OR INITIATE MODE REMOVE SOURCE LCB FROM CHAIN             07800013
INITTEST TM    LCBSTATE-LCB(X),20  ARE EITHER INITIATE(16) OR SENDING   07830013
*                            (4) BITS ON IN LCB FOR SOURCE TERMINAL     07860013
         BC    7,*+16              BRANCH IF EITHER.  IF NEITHER,       07890013
         MVI   LCBSTATE,0  CLEAR CURRENT LCB STATUS FOR DESTINATION     07920013
         TM    LCBSTATE-LCB(X),2   PARTIALLY ENQUEUED MESSAGE INDICATED-07950013
                                     IN LCB FOR SOURCE TERMINAL (AND    07980013
*                                    NOT INITIATE MODE)                 08010013
         BC    7,UNAVAIL-6         EXIT IF ENQUEUED MESSAGE AND NOT     08040013
*                                    INITIATE MODE - AN INVALID         08070013
*                                    CONDITION HAS RESULTED             08100013
       SPACE                                                            08130013
         MVC   LCBCSEG,LCBNASEG-LCB(X) UPDATE ADDRESS OF CURRENT        08160013
*                                    MESSAGE SEGMENT IN LCB             08190013
         MVC   QSORCE-QBLOCK(3,TREG),LCBSORCE-LCB(X)                    08220013
*                            REMOVE THE LCB FROM THE SOURCE CHAIN       08250013
         XI    LCBSORCE+2-LCB(X),3 SET SWITCH FOR DESTINATION-DASD 00PS 08280015
         LR    TREG,X              POINT TREG TO DE-CHAINED LCB         08310013
PREPARE  ST    TREG,LCBENDOP-1                                          08340013
*                                  LCB HOLDS 'SOURCE LCB' PUTTING       08370013
*                                  MESSAGES INTO QUEUE THIS LCB IS      08400013
*                                  SENDING FROM. STORE FOR FUTURE       08430013
*                                  REFERENCE.                           08460013
         MVI   LCBSTATE,SEND-NRET    SET STATUS CODE                    08490013
         NI    LCBERCCW+2,X'7F'   RESET FLAG SO THAT WRITE NAK   A46054 08500021
*                                 WILL NOT BE SET UP             A46054 08510021
*                                                                       08520013
*        THE FOLLOWING BRANCH RETURNS TO THE GET SCHEDULER (IF ENTERED  08550013
*        AT MSGTEST) WHICH MAY HAVE BEEN ENTERED FROM THE RETURN        08580013
*        BUFFER ROUTINE                                                 08610013
*            --OR--                                                     08640013
*                  IS A DIRECT BRANCH TO BRB-RING ROUTINE AT RQCONST.   08670013
*                  IF THE LINE IS SENDING                               08700013
*                                                                       08730013
         BR    Y                                                        08760013
         SPACE 2                                                        08790013
*    THE FOLLOWING CODE IS PART OF THE RECEIVE SCHEDULER INSERTED HERE  08820013
*    AS A RESULT OF THE ORG IN SEND SCHEDULER                           08850013
WTTARCVS ST    LCBREG,LCBSTATE         CLEAR LINE STATUS           000C 08853017
         TM    LCBINCAM,X'10'          EOT FLAG ON                 000C 08856017
         BZ    RQCONSTR                BRANCH IF NONE              000C 08859017
         CLI   LCBPTEMP,0              YES,IT IS FIRST TIME        000C 08862017
         BNE   DELAY                   YES,ACTIVE THE NEXT STCB    000C 08865017
         B     RQCONSTR                NO,START A READ INITIAL     000C 08868017
RSA      ST    Y,LCBPOLPT-1            RESET LCB PTR               000C 08871017
RSC      CLI   LCBPTEMP,0          THIS TEST PERTAINS TO THE CASE IN    08880013
         BNE   DELAY               WHICH A PASS HAS BEEN MADE THROUGH   08910013
*                                    THE POLLING LIST AND THE SIO       08940013
*                                    APPENDAGE HAS DETERMINED THAT NO   08970013
*                                    TERMINAL IN THE CURRENT POLLING    09000013
*                                    LIST CAN BE POLLED.  IF THAT IS    09030013
*                                    THE CASE, THE BRANCH IS NOT        09060013
*                                    EXECUTED AND WE FALL THROUGH       09090013
*                                    TO NOGO.  AN ENTRY IN THE TERMINAL 09120013
*                                    TABLE IS USED TO TEST FOR AN       09150013
*                                    OPERATIONAL TERMINAL.              09180013
         MVI   LCBSTATE,3          RESET TO ENTRY VALUE                 09190013
         SPACE                                                          09210013
NOGO     LA    QREG,QPRI           POINT QREG TO NEXT STCB IN CHAIN000D 09240018
*                          (SEND SCHEDULER, QEVENT OR FULL STCB)   000D 09270018
         L     TREG,QTRAN          LOAD STCB ADDRESS                    09300013
         CLI   0(TREG),0          TEST FOR FULL STCB                    09330013
         BNE   RETURN             BRANCH NOT FULL STCB                  09360013
         MVC   READY+1(3),1(QREG)  REMOVE LCB FROM THE READY QUEUE      09390013
         MVC   QSAVE(4),DUMMY-1    QATTACH ADDRESS TO QSAVE             09420013
         ST    FREG,XRBREG+4       STORE LCB ADDRESS IN FULL STCB       09450013
         B     LNKLOOP-10                                               09480013
         SPACE 3                                                        09490018
RLNCMPR  CLI   QRLN,0             COMPARE QRUL WITH LCBRLN        25336 09500018
         TITLE 'END OF POLL TIME DELAY ROUTINE'                         09510013
DELAY    MVI   LCBPTEMP,0          RESET SWITCH USED BY RECEIVE         09540013
*                                      SCHEDULER TO DETERMINE IF ANY    09570013
*                                      TERMINAL WAS POLLED.             09600013
         LR    TREG,QREG           GET QCB ADDRESS IN TREG FOR STCB     09630013
*                                      CHAIN (I. E. THE READY QUEUE     09660013
*                                      ADDRESS)                         09690013
         CLI   IOSSAVE,255         WAS IECKQQ01 ENTERED VIA AN I/O      09720013
*                                    INTERRUPT OR AN SVC                09750013
         BNE   UNAVAIL             BRANCH IF ASYNCHRONOUS I/O INTERRUPT 09780013
*                                    SINCE AN SVC CANNOT BE GIVEN WHEN  09810013
*                                    AN INTERRUPT HAS OCCURRED (TIME)   09840013
         L     Y,LCBDCBPT          GET THE DCB ADDRESS                  09930013
         SR    X,X                 CLEAR A WORKING REGISTER             09960013
         IC    X,DCBINTVL          GET POLLING INTERVAL (IN SECONDS)    09990013
         LTR   X,X            IS INTERVAL ZERO                     3922 09996016
         BNZ   NOTZERO             BRANCH IF NO                   22437 09997018
         CLI   LCBCPRI,0           IS RECEIVE SCHEDULER PRIORITY  22437 09998018
*                                   ZERO (IS THIS A DIAL LINE)    22437 09999018
         BNE   UNAVAIL             NO, CHAIN RECEIVE SCHEDULER    22437 10000018
*                                   BY PRIORITY                   22437 10001018
         B     DISPATCH            PREVENT RECIEVE SCHEDULER      22437 10002018
*                                   BEING CHAINED AFTER CLOSEDOWN 22437 10003018
*                                   SVRB                          22437 10004018
NOTZERO  EQU   *                                                  22437 10005018
         MVC   LCBSCHAD+1(3),LCBSCHLK   MOVE LINK ADDRESS TO NEXT  3922 10008016
*                                         WAITING SUBTASK FIELD    3922 10014016
CPENTRY  LR    LGREG,X             LOAD INTERVAL INTO ODD REGISTER 7461 10018016
         M     X,UNITSDAY          MULTIPLY BY 65535 (X'FFFF')     7461 10022016
         D     X,SECPRDAY          DIVIDE BY SECONDS PER DAY       7461 10026016
         LTR   X,LGREG             IS INTERVAL ZERO                7461 10030016
         BNZ   TIME                BRANCH IF NO                    7461 10034016
         LA    X,1(X)              FORCE INTERVAL TO ONE           7461 10038016
TIME     TIME  BIN                                                 7461 10042016
         MVI   IOSSAVE,X'FF'      SET SVC ENTRY FLAG             A39103 10046020
         BAL   Y,DIVIDE           LINK TO THE DIVIDE ROUTINE            10050013
         AR    X,FREG             ADD TIME OF DAY TO INTERVAL           10080013
*      IF THE PRESENT TIME IS LATER THAN THE TIME OF INTERRUPT FOR AN   10110013
*      ENTRY IN THE QUEUE, THE ENTRY WOULD BECOME THE LAST ENTRY TO BE  10140013
*      INTERUPTED, E.G. PRESENT TIME= 2 O'CLOCK AND INTERUPT TIME       10170013
*      SHOULD HAVE BEEN AT ONE O'CLOCK IT IS 11 HOURS UNTIL INTERUPT.   10200013
*      THEREFORE A REFERENCE TIME IS  ESTABLISHED AT ONE HALF THE CLOCK 10230013
*      SPAN(6HRS) EARLIER THAN THE PRESENT TIME,E.G. 8 O'CLOCK. THE     10260013
*      INTERUPT TIMES OF BOTH THE CURRENT REQUEST AND THE ENTRY IN THE  10290013
*      QUEUE ARE COMPARED TO THIS REFERENCE TIME. IF BOTH COMPARE LOWER 10320013
*      (SEE EXAMPLE) OR BOTH COMPARE HIGHER, THEN BOTH REQUESTS ARE IN  10350013
*      THE SAME RELATIVE PORTION OF THE TIME SPAN AND A DIRECT          10380013
*      COMPARISON OF THEIR INTERUPT TIMES IS MADE TO DETERMINE WHICH    10410013
*      WILL BE INTERUPTED FIRST. IF THE CURRENT REQUEST IS FIRST IT IS  10440013
*      INSERTED , OTHERWISE THE NEXT ENTRY IN THE QUEUE IS OBTAINED AND 10470013
*      THE ABOVE COMPARISONS MADE. IF THE ENTRY IN THE QUEUE IS LOWER   10500013
*      THAN THE REFERENCE TIME AND THE CURRENT REQUEST IS HIGHER, THEN  10530013
*      THE ENTRY IN THE QUEUE MUST BE IN THE LATTER PORTION OF THE TIME 10560013
*      SPAN WHEN  USING PRESENT TIME AS A REFERENCE AND THE CURRENT     10590013
*      REQUEST IS SOONER AND MAY BE INSERTED HERE. IF THE CURRENT       10620013
*      REQUEST IS LOWER THAN THE REFERENCE TIME AND THEENTRY IN THE     10650013
*      QUEUE IS HIGHER, THEN THE CURRENT REQUEST MUST BE IN THE LATTER  10680013
*      PORTION OF THE TIME SPAN WHEN USING PRESENT TIME AS A REFERENCE  10710013
*      AND THE NEXT ENTRY IN THE QUEUE IS OBTAINED AND THE ABOVE TESTS  10740013
*      PERFORMED. IF WE EXHAUST THE ENTRIES IN THE QUEUE, THE CURRENT   10770013
*      REQUEST IS INSERTED LAST.                                        10800013
KEPON1   ST    FREG,INTERVAL      SAVE TIME OF DAY                 3922 10830016
         XI    INTERVAL+2,128      ESTABLISH A REFERENCE TIME           10860013
         STH   X,LCBBRKCT          PUT TIME PLUS INTERVAL INTO LCB      10890013
         LA    Y,TIMEQ             GET ADDRESS OF TIME QCB              10920013
TIMELOOP LR    X,Y                 NOW X HAS THE ADDRESS OF THE         10950013
*                                      PREVIOUS ENTRY OR THE QCB        10980013
         L     Y,LCBSCHLK-1-LCB(0,X) GET ADDRESS OF THE NEXT ENTRY      11010013
         CLC   LCBBRKCT,INTERVAL+2 COMPARE CURRENT ENTRY WITH REFERENCE 11040013
         BNH   TIMESKIP            BRANCH IF IN LATTER PORTION          11070013
         CLC   LCBBRKCT-LCB(2,Y),INTERVAL+2 COMPARE ENTRY IN QUEUE TO   11100013
*                                                REFERENCE              11130013
         BNH   TIMEINS             BRANCH IF IN LATTER PORTION          11160013
         B     TIMEADD             BOTH ARE IN EARLIER PORTION          11190013
TIMESKIP CLC   LCBBRKCT-LCB(2,Y),INTERVAL+2 COMPARE ENTRY IN QUEUE TO   11220013
*                                                REFERENCE              11250013
         BH    TIMELOOP          BRANCH IF ENTRY IS IN EARLIER PORTION  11280013
TIMEADD  CLC   LCBBRKCT,LCBBRKCT-LCB(Y) COMPARE CURRENT REQUEST TO      11310013
*                                           ENTRY IN QUEUE              11340013
         BH    TIMELOOP            BRANCH IF CURRENT REQUEST IS LATER   11370013
TIMEINS  MVC   LCBSCHLK,LCBSCHLK-LCB(X) MOVE NEXT LCB POINTER INTO      11400013
*                                           CURRENT LCB                 11430013
         IC    Y,LCBSCHLK-1-LCB(0,X) SAVE RETURN CODE                   11460013
         ST    LCBREG,LCBSCHLK-1-LCB(0,X) STORE LCB ADDRESS INTO        11490013
*                                           PREVIOUS ELEMENT IN CHAIN   11520013
         STC   Y,LCBSCHLK-1-LCB(0,X) RESTORE RETURN CODE                11550013
STIMER   L     LCBREG,TIMEEND      GET ADDRESS OF FIRST LCB IN CHAIN    11580013
         LH    X,LCBBRKCT          GET INTERRUPT TIME FROM FIRST LCB    11610013
KEPON2   SR    X,FREG        SUB CURRENT TIME OF DAY FROM TIME     3922 11645016
*                             OF INTERRUPT                         3922 11655016
         SLL   X,16 SHIFT LOWER HALF WORD TO UPPER HALF WORD LOCATION   11670013
         SRA   X,16 PROPAGATE SIGN AND RESTORE LOWER HALF WORD          11700013
         BC   12,RESUME       BRANCH IF TIME HAS ELAPSED FOR FIRST LCB  11730013
*  THIS BRANCH WILL BE TAKEN WHEN NO DELAY HAS BEEN SPECIFIED FOR       11760013
*    CURRENT LCB                                                        11790013
         L     TREG,CVT           GET CVT ADDRESS                A39114 11791020
         L     TREG,CVTTCB(TREG)  GET TCB POINTER                A39114 11792020
         CLC   CURTCB(3,TREG),MRCVSW+1     IS MCP TCB IN CONTROL A39114 11793020
         BE    CONVT              IF YES, CONTINUE PROCESSING    A39114 11794020
         MVC   DUMMYTME(4),0(Z)   IF NO, POST BACK TO LPS QUEUE  A39114 11795020
         B     DISPATCH           (DUMMYTME Q. STILL ON READY Q. A39114 11796020
CVTTCB   EQU   0                                                 A39114 11797020
CURTCB   EQU   5                                                 A39114 11798020
CONVT    LR    LGREG,X             LOAD INTERVAL INTO ODD REGISTER 7461 11800016
         M     X,SECSX100          MULTIPLY BY SECONDS/DAY X 100   7461 11810016
         D     X,UNITSDAY          DIVIDE BY UNITS PER DAY         7461 11820016
         ST    LGREG,INTERVAL      IF TIME NOT ELAPSED GET INTERVAL7461 11830016
         STIMER  REAL,TIMEEXIT,BINTVL=INTERVAL SET TIMER INTERVAL FOR   11880013
*                                  FIRST LCB WHICH HAS NOT EXPIRED      11910013
         MVI   IOSSAVE,X'FF'      SET SVC ENTRY FLAG             A28771 11920019
         B     DISPATCH  GO TO DISPATCH NEXT ITEM ON READY QUEUE        11940013
         EJECT                                                          11970013
         USING *,15                                                     12000013
TIMEEXIT LA    TREG,LPS           PREPARE FOR POST TO LPS               12030013
         LR    FREG,0             TO ADDRESSING REGISTER                12060013
         L     FREG,12(FREG)      TCB ADDRESS                           12090013
         TM    29(FREG),X'E0'     IS PARTITION SHUT DOWN                12120013
         BCR   7,14               RETURN IF YES                         12150013
         LA    FREG,DUMMYTME      PREPARE FOR POST TO LPS               12180013
         LA    15,TTBASE          SET BASE FOR LINE PCI ROUTINE         12210013
         USING TTBASE,15                                                12240013
         LTR   15,15               SET CONDITION CODE FOR BRANCH IN     12270013
*                                       LINEPCI                         12300013
         B     LINEPCI+6               ENTER LINE PCI ROUTINE FOR       12330013
*                                        COMMON CODE AND PROCEED TO     12360013
*                                        POST TIME QCB TO ITSELF TO PUT 12390013
*                                        TIME QUEUE ON THE READY QUEUE  12420013
         DROP  15                                                       12450013
TIMEQ    DC    A(TIMEQ)                                                 12480013
         DC    X'E0000000'                                              12510013
         DC    A(TIMEEND)                                               12540013
TIMEEND  DC    AL1(2)                                                   12570013
         DC    AL3(TIMEQ)                                               12600013
         DC    X'FF00'                                                  12630013
         SPACE                                                          12660013
*             THE FOLLOWING CODE IS EXECUTED WHEN THE TIMEQ QCB IS      12690013
*             DISPATCHED FROM THE TOP OF THE READY QUEUE AS A RESULT    12720013
*             OF THE QCB HAVING BEEN POSTED TO ITSELF                   12750013
         CLC   TIMEQ+1(3),TIMEEND+1  IS THE TIME QUEUE EMPTY            12780013
         BE    DISPATCH    BRANCH IF YES TO DISPATCH NEXT ITEM          12810013
         TIME  BIN                 GET TIME OF DAY IN BINARY            12840013
         B     FIXTIME                                                  12870013
         SPACE                                                          12900013
         SPACE                                                          12960013
         ORG   TIMEQ+40       TIMEQ+LCBBRKCT-2-LCB                      12990013
INTERVAL DC    A(0)                                                     13020013
RESUME   NI    DUMMYTME,2         RESET QKEY TO REDISPATCH  THIS TASK   13050013
         MVC   TIMEEND+1(3),LCBSCHLK REMOVE LCB FROM TIME QUEUE         13080013
         LA    TREG,0(LCBREG)     CLEAR HIGH ORDER BYTE AND LOAD REG.   13110013
         LR    FREG,TREG          LOAD FREG FOR POSSIBLE POST           13140013
         CLI   LCBSCHAD,X'12'     TEST FOR LINE LCB OR CHECK POINT LCB  13170013
         BNE   POST               BRANCH IF CHECK/POINT LCB             13200013
         LA    QREG,LCBSCHAD  GET ADDRESS OF RECEIVE SCHEDULER STCB     13230013
         LR    FREG,QREG           LOAD INTO FREG                       13260013
         CLI   LCBSTATE,1          IS THE LINE FREE                     13290013
         BNE   PRIORITY            BRANCH IF NO TO PUT RECEIVE          13320013
*                                    SCHEDULER INTO SUBTASK CHAIN OF    13350013
*                                      LCB                              13380013
         MVC   LCBRCADD,READY+1  ELSE ACTIVATE LINE BY PUTTING LINK     13410013
*                              ADDRESS AT TOP OF READY QUEUE INTO LCB   13440013
         ST    LCBREG,READY  AND PUT LCB AT TOP OF READY QUEUE          13470013
         B     PRIORITY            GO TO IECKQQ01 TO PUT RECEIVE        13500013
*                                      SCHEDULER STCB IN LCB SUBTASK    13530013
*                                        CHAIN                          13560013
FIXTIME  LA    Y,STIMER                                                 13600017
         MVI   IOSSAVE,X'FF'      SET SVC ENTRY FLAG             A39103 13620020
DIVIDE   LR    FREG,0             COPY TIME OF DAY FOR DIVIDE INST.     13650013
         M     0,UNITSDAY          MULTIPLY TIME BY UNITS PER DAY  7461 13690016
         D     0,SECSX100          DIVIDE BY SECONDS PER DAY X 100 7461 13730016
         BR    Y                  RETURN TO CALLING ROUTINE             13770013
DUMMYTME DC    A(0)                                                     13800013
         DC    X'E300000002'                                       6928 13830016
         DC    AL3(TIMEEND)       STCB ADDRESS                          13860013
         DC    A(0)                                                     13890013
SECSX100 DC    F'8640000'          NUMBER OF SECONDS PER DAY X 100 7461 13897016
UNITSDAY  DC  F'65536'            UNITS PER DAY                   21857 13904018
SECPRDAY DC    F'86400'            NUMBER OF SECONDS PER DAY       7461 13911016
         TITLE 'BRB-RING ROUTINE'                                       13920013
* BRB--RING ROUTINE (RQCONST)                                           13950013
*      THIS ROUTINE CONSTRUCTS THE BRB RING USED TO SEND OR             13980013
* RECEIVE A MESSAGE, AND BEGINS INITIALIZATION OF A CCW IN              14010013
* EACH BRB.  THE BRBS ARE DRAWN FROM THE POOL GENERATED ON              14040013
* EXPANSION OF THE BUFFER MACRO-INSTRUCTION, THE ROUTINE                14070013
* ATTEMPTS TO FORM A RING CONTAINING THE NUMBER OF BRBS                 14100013
* SPECIFIED IN THE BUFRQ PARAMETER OF THE DCB.                          14130013
*      WHEN THE ROUTINE IS ENTERED, A REGISTER IS ADJUSTED SO           14160013
* THAT THE LCB APPEARS TO THE SYSTEM TO BE                              14190013
* AN STCB.  THIS ANTICIPATES THE SITUATION IN WHICH NOT                 14220013
* ENOUGH BRBS ARE AVAILABLE TO COMPLETE THE RING, IN THIS               14250013
* CASE THE LCB IS PLACED ON THE STCB CHAIN OF THE ACTIVE                14280013
* BUFFER REQUEST QUEUE (THROUGH A BRANCH TO UNAVAIL-6, THE              14310013
* INSTR PRECEDING THE DEFER-ENTRY SUBR).  WHEN                          14340013
* A BRB IS POSTED TO THAT QUEUE, THE BRB-RING ROUTINE MAKES             14370013
* ANOTHER ATTEMPT TO COMPLETE THE RING.  WHEN SUFFICIENT                14400013
* BRB'S ARE AVAILABLE, THE RESULTING BRB RING CONSISTS OF A             14430013
* SERIES OF BRB'S, EACH CONTAINING 1) IN THE THIRD FULLWORD,            14460013
* THE TIC OP CODE AND THE ADDR OF THE PRECEDING BRB/CCW IN THE RING,    14490013
* AND 2) IN THE FOURTH FULLWORD, A POINTER TO THE LCB FOR WHICH THE     14520013
* RING WAS CONSTRUCTED.                                                 14550013
*      SINCE EACH BRB/CCW CONTAINS A TIC TO THE PREVIOUSLY              14580013
* BUILT BRB/CCW, THE TIC ADDR IN THE FIRST BRB/CCW IS INITIALLY         14610013
* MEANINGLESS.  THE LAST STEP IN COMPLETING THE RING (IF ENOUGH BRBS    14640013
* WERE AVAILABLE) IS, THEREFORE, TO RESET THE FIRST BRB/CCW TO TIC      14670013
* TO THE LAST.  IF THE ORDER OF CONSTRUCTION OF A FOUR-MEMBER           14700013
* BRB/CCW CHAIN WAS A-B-C-D, THE ORDER OF EXECUTION WILL BE A-D-C-B.    14730013
*      WHEN THE BRB/CCW RING IS COMPLETE THE LCB IS REMOVED             14760013
* FROM THE LOCATION WHERE IT WAS ENCOUNTERED AS AN APPARENT             14790013
* STCB -- THAT IS, FROM THE HEAD OF AN STCB CHAIN OR THE                14820013
* READY QUEUE.  DEPENDING UPON WHETHER A SEND OR A RECEIVE              14850013
* OPERATION IS BEING PREPARED FOR, FURTHER INITIALIZATION IS PERFORMED. 14880013
*  1.  THE ECB PORTION OF THE FIRST BRB/CCW IS GIVEN APRIORITY VALUE.   14910013
*      RECEIVE - 12                                                     14940013
*      SEND    - 0                                                      14970013
*  2.  INTO THE LCB IS INSERTED AN OP-TYPE CODE FOR                     15000013
*      SUBSEQUENT USE BY BTAM.                                          15030013
*      RECEIVE - 1 (READ INITIAL)                                       15060013
*      SEND    -2 (WRITE INITIAL)                                       15090013
*  3.  A REGISTER IS INITIALIZED FOR THE QCB OF THE QUEUE               15120013
*      TO WHICH THE FIRST BRB/CCW IS TO BE EFFECTIVELY (BUT             15150013
*      NOT LITERALLY) POSTED.                                           15180013
*      RECEIVE -  ACTIVE-BUFFER-REQUEST QUEUE                           15210013
*      SEND    -  DISK  INPUT/OUTPUT  QUEUE  (FOR SEND                  15240013
*                 OPERATIONS, ADDITIONAL INITIALIZATION                 15270013
*                 CONSISTS OF SETTING AN MSTATUS CODE OF 9              15300013
*                 AND INSERTING THE RELATIVE RECORD NUMBER              15330013
*                 FOR THIS FIRST SEG OF THE MSG.)                       15360013
         SPACE 2                                                        15390013
RQCONSTR TM    LCBINCAM,2          IS THIS A NON DIAL LINE         000A 15392015
         BNO   NODISC              BRANCH IF YES                   000A 15394015
OUTONLY  L     TCREG,TTBASE        GET BASE FOR TERMINAL TABLE     000A 15404015
         AH    TCREG,LCBTTIND      ADD OFFSET TO THE TERMINAL ENTRY000A 15406015
         L     QREG,0(TCREG)       ACCESS THE QCB FOR THE TERMINAL 000A 15408015
         LA    QREG,8(QREG)        BUMP TO THE SEND SCHEDULER      000A 15410015
         SR    SPREG,SPREG         CLEAR TO TEST FOR OUTGOING CALL 000A 15412015
         LA    FREG,K8-QRLN+QTRAN  INITIALIZE TO LINE NUMBER EQUAL 000AX15414015
               ZERO                                                000A 15416015
         L     Y,LCBDCBPT          GET ADDRESS OF LINE GROUP'S DCB 000A 15418015
         L     X,DCBDEBAD          ACCESS THE DEB FOR CALL QUEUE   000A 15420015
         SH    X,H20               INITIALIZE TO SCAN CALL QUEUE   000A 15422015
LOOPOCQ  LR    TREG,X              SAVE PREVIOUS ENTRY             000A 15424015
         L     X,TLINK-1           GET NEXT ENTRY IN CALL QUEUE    000A 15426015
         CLC   5(3,X),TLINK        IS THIS END OF THE QUEUE        000A 15428015
         BE    ENDOCQ              BRANCH IF YES                   000A 15430015
         CLI   TPRI-TBLOCK(X),X'01' IS CALL OUT PERMITTED          000AX15432015
               (NO AUTOCALL)                                       000A 15434015
         BNE   CALLIN              BRANCH IF NO TO SEE IF CONNECTED000A 15436015
         TM    MRCVSW,X'0F'        IS CLOSEDOWN IN PROCESS       A36516 15436620
         BZ    *+12                YES, MASTER RECEIVE SWITCH IS A36516 15437220
*                                    TURNED OFF                  A36516 15437820
         TM    LCBINCAM,4          CAN TERMINAL BE DISCONNECTED  A36516 15438420
         BNO   CALLIN              NO, GO SEE IF TERM CONNECTED  A36516 15439020
         IC    Y,LCBUCBX           ACCESS RELATIVE LINE NUMBER-1   000A 15440015
         LA    Y,1(Y)              BUMP TO RELATIVE LINE NUMBER    000A 15442015
         EX    Y,RLNCPR            IS QCB RLN HIGHER THAN LCB RLN  000A 15444015
*  I.E. IS IT NECESSARY TO DETERMINE IF THE TERMINAL HAS CALLED    000A 15446015
*              THE CPU                                             000A 15448015
         BH    CALLIN              BRANCH IF YES                   000A 15450015
         CLC   QRLN-QTRAN(1,X),QRLN-QTRAN(FREG) IS NEW CALL        000A 15452015
*                         CLOSER THAN   PREVIOUSLY FOUND CALL      000A 15454015
         BNH   CALLIN              BRANCH IF NO                    000A 15456015
         LR    FREG,X              SAVE A FOUND CALL               000A 15458015
         LR    SPREG,TREG    SAVE POINTER TO FOUND SEND SCHEDULER  000A 15460015
CALLIN   LA    X,0(X)              CLEAR HIGH ORDER BYTE           000A 15462015
         CLR   X,QREG        IS THIS QUEUE CONNECTED TO TERMINAL   000A 15464015
         BNE   LOOPOCQ             BRANCH IF NO - TEST NEXT QUEUE  000A 15466015
         LR    FREG,X              ELSE PREPARE TO START SENDING   000A 15468015
REMOVEOC MVC   TLINK,FLINK   REMOVE SEND SCHEDULER FROM CALL QUEUE 000A 15470015
         MVI   LCBSTATE,0          ENSURE SEND SCHEDULER WILL BE   000A 15472015
*                                       DISPATCHED                 000A 15474015
         NI    LCBERCCW+2,X'7F'    RESET FLAG SO WRITE NAK WILL  A37734 15474620
*                                    NOT BE SET UP               A37734 15475220
         LA    QREG,LCBSCHAD       AND SET UP TO RESCHEDULE THE    000A 15476015
         B     LIFO                     LINE TO SEND               000A 15478015
         SPACE 1                                                        15480015
RLNCPR   CLI   QRLN-QTRAN(X),0     COMPARE QRLN WITH LCB LINE NUMB 000A 15482015
H20      DC    H'20'                                               000A 15484015
         SPACE 1                                                        15486015
ENDOCQ   EQU   *                                                  22437 15496018
         TM    MRCVSW,X'0F'        IS CLOSEDOWN IN PROCESS       A36516 15498020
         BZ    *+12                YES, MASTER RECEIVE SWITCH IS A36516 15500020
*                                    TURNED OFF                  A36516 15502020
         TM    LCBINCAM,4          CAN TERMINAL BE DISCONNECTED  A36516 15504020
         BNO   NODISC              NO, GO SEE IF TERM CONNECTED  A36516 15506020
         XC    LCBTTIND,LCBTTIND   ZERO TERMINAL OFFSET            000A 15512015
NOSRCE   OI    LCBINCAM,X'01'      SET INITIAL CONTACT FLAG        000A 15514015
         LTR   TREG,SPREG         TEST FOR OUT GOING CALL FOUND    000A 15516015
         BNZ   REMOVEOC            BRANCH IF FOUND TO SEND         000A 15518015
NODISC   MVI   LCBSTATE,8         SET RECEIVE CODE                 000A 15520015
        TM    LCBINCAM,1         IS AN OUTGOING MESSAGE IN QUEUE   000A 15522015
        BZ     *+8               BRANCH IF NO                      000A 15524015
        MVI   LCBINCAM,0         TURN OFF ALL DIAL CODES           000A 15526015
        LR    QREG,LCBREG        PREPARE QREG FOR CLOSE            000A 15528015
        LR    FREG,QREG          PREPARE FREG FOR CLOSE            000A 15530015
         TM    MRCVSW,X'0F'       IS A CLOSE IN PROGRESS           000A 15532015
        BNO   NOGO-4             BRANCH IF YES                     000A 15534015
RQCONST  LA    QREG,QATTACH        MAKE LCB (AT READY) AN APPARENT STCB 15600013
         LA    TREG,AVREQ          POINT TREG TO INACTIVE-BRB QCB       15630013
         MVI   LCBCECB,1           MOVE IN 'READ INITIAL' OPCODE (FOR  -15660013
                                   BTAM USE)                            15690013
         SPACE                                                          15720013
* TEST FOR AVAILABLE REQUEST                                            15750013
ALOOP    L     FREG,TFILL          ACCESS HEAD OF INACTIVE-BRB CHAIN    15780013
*                                      UTILIZING TREG AS A BASE AND     15810013
*                                      POINTER TO QCB                   15840013
         MVC   TFILL+1(3),FLINK    REMOVE HEAD OF CHAIN GET POINTER TO -15870013
                                   FOLLOWING BRB                        15900013
         CL    FREG,TFILL          COMPARE EQUAL WHEN CHAIN EXHAUSTED   15930013
         BE    UNAVAIL-6           IF INSUFFICIENT BRBS, BRANCH TO TAKE-15960013
                                   LCB OFF READY, PUT IT (AS AN STCB)  -15990013
                                   IN INACTIVE-BRB QUEUES STCB CHAIN    16020013
         SPACE                                                          16050013
* ASSIGN REQUEST TO LINE           (BRB WAS AVAILABLE)-START CCW BUILD -16080013
                                   IN BRB                               16110013
RQSETUP  ST    LCBREG,FDATA+4      STORE POINTER TO LCB IN BRB          16140013
         LH    Y,COUNT             GET COUNT (INITIALLY 1)              16170013
         MVC   FDATA+1(3),LCBCLCCW+1  INSERT POINTER TO PRECEDING BRB  -16200013
                                   TIC                                  16230013
         MVI   FDATA,8             INSERT TRANSFER-IN-CHANNEL OP CODE   16260013
         ST    FREG,LCBCLCCW       RESET PRECEDING-CCW POINTER FOR NEXT-16290013
                                   PASS                                 16320013
         BCT   Y,NOTFIRST          FALL THRU ON FIRST BRB ASSIGNMENT    16350013
         LA    FREG,FKEY           ZERO OUT FIRST BYTE                  16380013
         ST    FREG,LCBCLPCI-1     STORE POINTER TO FIRST BRB OF SERIES 16410013
         L     X,LCBDCBPT          ACCESS DCB, GET NUMBER OF BRBS TO BE-16440013
                                   ASSIGNED                             16470013
         IC    Y,DCBBUFRQ-IHADCB(X) OPEN LOAD 1 ENSURES BUFFER REQUESTS 16500013
*                                      OF NOT LESS THAN TWO             16530013
NOTFIRST STH   Y,COUNT             SET COUNT TO TOTAL NUMBER REQUIRED,  16560013
         OI    LCBCLCCW+3,3        SET 'IDLE' FLAG ON FOR MOVE INTO    -16590013
                                   BRB/CCW (MAKE THE BRB UNADDRESSABLE  16620013
*                                      WHICH INDICATES NO BUFFER IS     16650013
*                                      ASSIGNED TO THE BRB)             16680013
         BCT   Y,ALOOP             LOOP IF MORE BRBS TO BE ASSIGNED     16710013
         SPACE                                                          16740013
* COMPLETE LOOP OF REQUESTS AND PLACE REQUEST FOR FIRST BUFFER         -16770013
                                   (ALL BRBS ASSIGNED)                  16800013
         MVC   QTRAN+1(3),LCBRCADD   REMOVE LCB FROM STCB CHAIN OR     *16830013
                                     READY QUEUE HEAD                   16860013
         L     FREG,LCBCLPCI-1     RETRIEVE POINTER TO FIRST BRB OF    -16890013
                                   SERIES                               16920013
         MVC   FDATA+1(3),LCBCLCCW+1  MOVE TIC ADDRESS INTO FIRST BRB   16950013
         SPACE                                                          16980013
* IF LINE IS RECEIVING REQUEST GOES TO ACTIVE REQUEST QUEUE             17010013
         MVI   FPRI,X'EC'          SET HI-PRIORITY FOR FIRST BRB (GET  -17040013
                                   BUFR IN ANY CIRCUMSTANCE)            17070013
         LA    TREG,BREQ           POINT TREG TO ACTIVE-BUFFER-REQUEST I17100013
                                   QCB                                  17130013
         SR    Y,Y                 CLEAR WORKING REGISTER          00PS 17140020
         CLI   LCBSTATE,RQRET-NRET   IS LINE RECEIVE CODE SET (8)       17160013
         BE    GOREQ               BRANCH IF RECEIVING                  17190013
         SPACE                                                          17220013
**********                    TO HERE IF LINE SENDING                   17250013
         LA    TREG,HDSTRT-MSEGSZE  GET ADDR OF CURR SEG                17280013
         STH   TREG,LCBTRST        STORE FOR RETRIEVAL BY SEND         -17310013
                                   SCHEDULER                            17340013
         MVC   LCBCHDR,LCBCSEG     INITIALIZE WITH DISK ADDRESS         17370013
         MVC   MSLCB,LCBCSEG           OF SEGMENT                       17400013
         MVI   MSTATUS,9           SET DISK OPERATION INDICATOR         17430013
         MVI   FPRI,X'E0'          CANCEL HI-PRIORITY                   17460013
         XI    LCBCECB,3           MOVE IN 'WRITE INITIAL' OP CODE (FOR-17490013
                                   BTAM USE)                            17520013
         LA    TREG,DISK           POINT TREG TO DISK INPUT/OUTPUT QCB  17550013
*                                  (AN EFFECTIVE QPOST)                 17580013
         STH   Y,LCBTTIND          CLEAR TERMINAL OFFSET FIELD     00PS 17590020
         SPACE                                                          17610013
* CLEAR LCB STATUS AND COUNTS                                           17640013
GOREQ    EQU   *                                                   00PS 17670020
         STH   Y,LCBERRST          CLEAR ERROR STATUS BYTE              17700013
         STH   Y,LCBDLPTR         CLEAR DISTRIBUTION LIST POINTER  000A 17730015
         NI    LCBSTART+2,252      (REMOVE ERROR FLAG) ENSURE BOUNDARY -17760013
                                   ALIGNMENT                            17790013
         LA    Y,LCBCLPCI-9        SET LCB CCW POINTER TO               17820013
         ST    Y,LCBCLCCW          APPARENT BRB                         17850013
*                                  THIS POINTS LCBCLCCW TO AN APPARENT  17880013
*                                  BRB TIC ADDRESS FIELD THAT IS        17910013
*                                  ACTUALLY LCBCLPCI ITSELF             17940013
*                                  CONTENTS OF LCBCSEG                  17970013
*                                  ON SEND-POINTER TO LOCATION WHERE    18000013
*                                  SEGMENT WILL BE WRITTEN              18030013
*                                  ENDSEND-POINTER TO LOCATION WHERE    18060013
*                                  SEGMENT CAME FROM                    18090013
*                                  WHILE PROCESSING HEADER OF INCOMING  18120013
*                                  MESSAGE-HOLDS MESSAGE PRIORITY       18150013
*                                  WHILE PROCESSING HEADER OF OUTGOING  18180013
*                                  MESSAGE-HOLDS POINTER TO HEADER OF   18210013
*                                  FIRST MESSAGE NOT COMPLETELY WRITTEN 18240013
         MVC   LCBRCADD,LCBCHDR    GET RECALL ADDRESS IN LCB            18270013
         B     POST                READY QUEUE BY PRIORITY              18300013
         SPACE                                                          18330013
COUNT    DC    H'1'                                                     18360013
K8       DC    H'8'                                                     18390013
         TITLE 'ENDINSRT ROUTINE'                                       18430020
*  THE ENDINSRT ROUTINE IS ENTERED FROM THREE ROUTINES, VIZ.            18470020
*                        IECKCVRS                                       18510020
*                        IECKEOAD                                       18550020
*                        IECKDLQT                                       18590020
*  THE PURPOSE OF ENDINSRT IS TO INSERT FUNCTIONS FROM THE ABOVE THREE  18630020
*  ROUTINES INTO A QUEUE OF EVENTS TO BE HANDLED BY THE BUFFER CLEANUP  18670020
*  ROUTINE.  THE FIRST EVENT TO BE PROCESSED BY THE BUFFER CLEANUP      18710020
*  ROUTINE WILL BE FOUND IN MRRE.                                       18750020
*  THE EXIT POINT RETURNS TO THE INSTRUCTION IN THE ROUTINE WHICH       18790020
*  ENTERED ENDINSRT INITIALLY BUT WHICH HAS BEEN MODIFIED BY ENDINSRT   18830020
*  TO PREVENT REENTRY FROM THE SAME ROUTINE.                            18870020
MRRE     DC    A(LINEFREE-4)       THIS CONSTANT IS OVERLAID WITH THE   18910020
*                                    ADDRESS OF THE HIGHEST PRIORITY    18950020
*                                    ROUTINE                            18990020
ENDINSRT LA    0,MRRE              GET ADDRESS OF CONSTANT              19030020
         LR    TREG,0              PUT IT IN TREG                       19070020
         L     0,0(0,TREG)         AND GET CONTENTS OF MRRE             19110020
         CL    0,0(0,Y)            IN EFFECT, COMPARES PRIORITY IN      19150020
*                                    FIRST BYTE OF ADDRESSES TO FIND    19190020
*                                    INSERTION POINT OF ROUTINE IN QUE  19230020
         BC    10,ENDINSRT+4       BRANCH IF NEW PRIORITY IS LOW        19270020
         ST    Y,0(0,TREG)         ELSE PUT ROUTINE ADDRESS IN CHAIN    19310020
         MVC   0(1,TREG),0(Y)      PUT ROUTINE PRIORITY BYTE IN ADDRESS 19350020
         SH    Y,K4                RESET RETURN ADDRESS TO THE BRANCH   19390020
*                                    THAT ENTERED THIS ROUTINE          19430020
         MVC   2(2,Y),6(Y)         OVERLAY THE BRANCH IN CALLING        19470020
*                                    ROUTINE WITH LAST TWO BYTES OF     19510020
*                                    CONSTANT FOLLOWING THE BRANCH      19550020
         ST    0,4(0,Y)            OVERLAY THE CONSTANT IN CALLING      19590020
*                                    ROUTINE WITH CONSTANT IN MRRE      19630020
         BR    Y                   RETURN TO THE CALLING ROUTINE        19670020
         SPACE                                                          19740013
         TITLE 'AVAILABLE BUFFER ROUTINE'                               19770013
* AVAILABLE-BUFFER SUBTASK                                              19800013
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED BFRENQ.         19830013
*      PROGRAM ENTRY--ENTERS THE AVAILABLE-BUFFER ROUTINE               19860013
*      AT BFRENQ+6 (ALTERNATE LABEL BFRREQ).                            19890013
* AVAILABLE-BUFFER ROUTINE                                              19920013
*      THIS ROUTINE IS ENTERED ON ACTIVATION OF THE                     19950013
* AVAILABLE-BUFFER SUBTASK, OR FROM THE BUFFER-BRB ROUTINE.             19980013
* THE ROUTINE RESPONDS TO THE AVAILABILITY OF A BUFFER BY               20010013
* ATTEMPTING TO LOCATE AN AVAILABLE BRB.  IF NO BRB IS                  20040013
* AVAILABLE, THE BUFFER IS CHAINED INTO THE ELEMENT CHAIN               20070013
* OF THE AVAILABLE-BUFFER QUEUE THROUGH A BRANCH TO THE                 20100013
* QUEUE INSERT SUBR.  IF A BRB IS AVAILABLE, THIS                       20130013
* ROUTINE BRANCHES TO THE BUFFER-BRB ROUTINE.                           20160013
         SPACE 2                                                        20190013
BFRENQ   DC    AL1(ENQUE-NRET)                                          20220013
         DC    AL4(255)                                                 20250013
         SPACE                                                          20280013
BFRREQ   L     X,BREQ              ACCESS FIRST BRB IN THE CHAIN FROM   20310013
*                                    THE ACTIVE BUFFER REQUEST QUEUE    20340013
         CLI   FPRI-FBLOCK(X),255  IS A BRB AVAILABLE                   20370013
         BE    LIFO                BRANCH IF NO - PUT THIS BUFFER ON    20400013
*                                    THE AVAILABLE BUFFER QUEUE         20430013
         CLI   FPRI-FBLOCK(X),X'EC' DOES THE BRB HAVE HIGH PRIORITY     20460013
         BE    BFRSCH              BRANCH IF YES TO ASSIGN THIS BUFFER  20490013
         LH    Y,CNVT              NO--GET EXCESS OF BUFFERS OVER BRB'S 20520013
         BCTR  Y,0                 DECREMENT BY ONE FOR CURRENT BUFFER  20550013
         LCR   LCBREG,Y            ARE THERE MORE BRB'S THAN BUFFERS    20580013
         BC    12,LOWPR            BRANCH IF NO - FEWER BRB'S           20610013
         LA    TREG,AVREQ-4  GET ADDRESS OF INACTIVE BUFFER REQUEST QCB 20640013
AVSZLOOP L     TREG,TPRI           GET ADDRESS OF FIRST BRB IN CHAIN    20670013
         CLI   TPRI,255            IS A BRB IN THE CHAIN                20700013
         BE    LIFO                BRANCH IF NO - PUT THIS BUFFER ON    20730013
*                                    AVAILABLE BUFFER QUEUE SINCE NO    20760013
*                                    BRB FOR THE AVAILABLE BUFFER       20790013
         BCT   LCBREG,AVSZLOOP     COUNT AND EXIT THE LOOP IF EXCESS    20820013
*                                    IS EXHAUSTED BEFORE BRB'S IN CHAIN 20850013
*                                    ARE GONE                           20880013
LOWPR    STH   Y,CNVT              RESTORE DECREMENTED BUFFER EXCESS    20910013
BFRSCH   MVC   BREQ+1(3),FLINK-FBLOCK(X)                                20940013
*                                  REMOVE BRB FROM HEAD OF CHAIN        20970013
*                        AND FALL THRU TO BUFFER-BRB ROUTINE            21000013
         TITLE 'BUFFER-BRB ROUTINE'                                     21030013
* BUFFER-BRB ROUTINE                                                    21060013
*      THIS ROUTINE IS ENTERED FROM EITHER THE                          21090013
* ACTIVE-BUFFER-REQUEST OR THE AVAILABLE-BUFFER ROUTINE.                21120013
* ITS FUNCTION IS TO EXAMINE A BUFFER AND A BRB AND MAKE                21150013
* THE APPROPRIATE DISPOSITION DEPENDING UPON THE STATUS OF EACH.        21180013
*      IF THE BRB IS ASSOCIATED WITH A READ-FROM-DASD                   21210013
* OPERATION, THE ROUTINE EFFECTIVELY (BUT NOT THROUGH AN                21240013
* SVC) POSTS THE BRB TO THE DISK I/O QUEUE AND THE BUFFER               21270013
* TO THE AVAILABLE-BUFFER QUEUE.                                        21300013
*      IF THE BRB IS ASSOCIATED WITH A RECEIVE-FROM-LINE                21330013
* OPERATION, THE ROUTINE ASSIGNS THE BUFFER TO THE LINE AND             21360013
* EXITS TO THE PRE-LPS ROUTINE TO CAUSE THE BUFFER TO BE                21390013
* PLACED ON THE LPS QUEUE.                                              21420013
         SPACE 2                                                        21450013
* ASSIGN BUFFER TO REQUEST AND QPOST                                    21480013
*                                  (X POINTS TO A BRB)                  21510013
         LA    TREG,DISK           POINT TREG TO DISK I/O QUEUE QCB     21540013
         CLI   MSTATUS-FBLOCK(X),9 IS THIS BRB TO BE USED FOR DISK READ 21570013
         BE    DISKENT             BRANCH IF YES                        21600013
         LA    TREG,0(X)           ELSE GET BRB ADDRESS IN TREG         21630013
         MVC   QFAC-QBLOCK(3,TREG),DUMMY  PUT END OF QUEUE ELEMENT      21660013
*                                    ADDRESS INTO FIRST WORD OF BRB TO  21690013
*                                    MAKE BRB A QCB                     21720013
         CLI   MSTIC-FBLOCK(X),8   TEST FOR A 'PUT' OPERATION           21750013
         BE    NOTPUT                  BRANCH NOT PUT OPERATION         21780013
         LR    11,TREG                 COPY ADDRESS OF BRB              21810013
         SH    11,K32                  COMPUTE DEB ADDRESS              21840013
         L     5,24(11)                LOAD DCB ADDRESS FROM THE DEB    21870013
         L     15,48(5)                LOAD PUT ROUTINE ENTRY POINT     21900013
         LA    14,LPSDRCT+10           LOAD RETURN POINT FOR PUT        21930013
         B     134(15)       EXIT TO THE PUT ROUTINE TO ALLOW      8064 21960017
*                                 FILLING THE BUFFER                    21990013
         SPACE                                                          22020013
*    AT THIS POINT, HAVE NEITHER A PUT NOR A DISK READ                  22050013
NOTPUT   L     LCBREG,MSLCB-1-FBLOCK(X) LOAD LCB ADDRESS FROM BRB       22080013
         TM    MSTIC+3-FBLOCK(X),3 TEST BRB-STATUS CODE                 22110013
         BZ    DISCARD   BRANCH IF LINE HAS GONE 'NOT-READY'            22140013
         BO    IBUF                BRANCH IF BRB FIRST IN RING          22170013
         TM    LCBSTATE,8          IS LINE RECEIVING                    22200013
         BZ    RQIDLE          BRANCH IF NO TO ASSIGN BUFFER ELSEWHERE  22230013
         L     TREG,LCBCLPCI-1     YES--GET POINTER TO FIRST BRB        22260013
         TM    MSTIC+3-FBLOCK(TREG),3                                   22290013
*                                  BRANCH SUCCEEDS IF A 'RECALL'       -22320013
                                   OPERATION IS IN                      22350013
         BO    RQIDLE      PROGRESS--NO BUFFER IS TO BE ASSIGNED        22380013
         XI    MSTIC+3-FBLOCK(X),3 SET BRB-STATUS CODE TO'IDLE'         22410013
IBUF     ST    LCBREG,MSLCB-1      STORE LCB POINTER IN BUFFER (ASSIGN  22440013
*                                    BUFFER TO LINE)                    22470013
         MVI   MSTATUS,5           5 ROUTES THIS MESSAGE DIRECTLY       22500013
*                                    TO ACTIVATE                        22530013
         MVC   MSEGSZE,DISKCCW+22  REPLACE SEGMENT SIZE WITH TOTAL      22560013
*                                    BUFFER SIZE                        22590013
         B     LPSDRCT+6           PUT BUFFER ON LPS QUEUE              22620013
         SPACE                                                          22650013
* SET IDLE FLAG IN REQUEST AND TEST NEXT REQUEST                        22680013
RQIDLE   OI    MSTIC+3-FBLOCK(X),3 SET IDLE FLAG IN BRB                 22710013
         B     BFRREQ              TO AVAILABLE BUFFER ROUTINE          22740013
         SPACE                                                          22770013
* REQUEST GOES TO DISK OR INACTIVE BUFFER REQUEST QUEUE                 22800013
DISCARD  LA    TREG,AVREQ          RESET TREG FOR INACTIVE BUFFER       22830013
*                                    REQUEST QCB                        22860013
DISKENT  ST    TREG,FKEY-FBLOCK(0,X)  PUT SELECTED QCB ADDRESS IN BRB   22890013
         MVC   FLINK-FBLOCK(3,X),READY+1                                22920013
*                                  LINK BRB TO CURRENT READY ITEM AND   22950013
         ST    X,READY             PLACE BRB AT HEAD OF READY QUEUE     22980013
         CLI   FPRI-FBLOCK(X),X'EC' HAS THE BRB BEEN IN THE DISK I/O    23010013
*                                    QUEUE BEFORE AND NOT HAD A BUFFER  23040013
*                                    ASSIGNED                           23070013
         BE    LIFO                BRANCH IF YES TO QUEUE INSERT        23100013
*                                    ROUTINE TO RETURN BUFFER TO        23130013
*                                    AVAILABLE BUFFER QUEUE             23160013
         XI    MSTIC+3-FBLOCK(X),3 ELSE CHANGE MSTIC CODE (10 TO 01) TO 23190013
*                                    BE USED BY DISK QUEUE              23220013
         B     BFRREQ              TO AVAILABLE BUFFER ROUTINE          23250013
K32      DC    H'32'                                                    23280013
         TITLE 'LPS CONTROL ROUTINE'                                    23310013
* LPS SUBTASK                                                           23340013
*      STCB--THE STCB FOR THE LPS SUBTASK IS DYNAMICALLY                23370013
*      FORMED WITHIN THE SUPERVISOR REQUEST BLOCK CREATED               23400013
*      ON ISSUANCE OF AN SVC 65 OR 67 BY THE SUBTASK, AND IS TRANSIENT. 23430013
*      PROGRAM ENTRY--ACTIVATION OF THE LPS SUBTASK CAUSES              23460013
*      THE MESSAGE CONTROL PROGRAM TO BE RE-ENTERED AT THE              23490013
*      INSTRUCTION FOLLOWING THE SUPERVISOR CALL.                       23520013
* LPS CONTROL ROUTINE                                                   23550013
*      THE LPS CONTROL ROUTINE, WHEN ENTERED, ISSUES AN                 23580013
* IMMEDIATE SVC TO QWAIT ON THE LPS QUEUE FOR--1) AN                    23610013
* AVAILABLE BUFFER INTO WHICH A MESSAGE SEGMENT IS TO BE                23640013
* READ, 2) A BUFFER CONTAINING A TEXT OR HEADER SEGMENT                 23670013
* (THAT IS, A MESSAGE-FILLED BUFFER) THAT HAS BEEN READ OR              23700013
* IS TO BE WRITTEN-OR 3) THE LAST SEGMENT OF A MESSAGE                  23730013
* AFTER IT HAS BEEN WRITTEN.                                            23760013
*      WHEN AN AVAILABLE 'FIRST' BUFFER IS ENCOUNTERED, THE             23790013
* ROUTINE EXITS TO THE ACTIVATE ROUTINE TO CAUSE RECEIPT OF             23820013
* THE MESSAGE TO BE INITIATED.  WHEN A FULL BUFFER OR THE               23850013
* LAST BUFFER IS ENCOUNTERED, THE ROUTINE BRANCHES TO THE               23880013
* BEGINNING OF THE LINE-GROUP ROUTINE DEFINED BY THE USER               23910013
* THROUGH LPS MACRO-INSTR.                                              23940013
         SPACE 2                                                        23970013
ADDBUF   NI    MSTIC+3-FBLOCK(TREG),252  IF THE CURRENT CCW IS THE      24000013
         SR    X,X                     SECOND OF A CHAINED SERIES       24030013
         IC    X,LCBERCCW+3            OFFSET TO DATA CCW               24060013
         LA    X,LCBCPA(X)             ADDRESS OF DATA CCW              24090013
         TM    MSTIC+3-FBLOCK(X),3  THE FIRST HAS BEEN SET UP           24120013
         BZ    NOBUFFER           BY BTAM                        A26023 24130018
         MVC   MSTIC+1-FBLOCK(3,X),MSTIC+1-FBLOCK(TREG)   MAKE   A26023 24140018
*                                 FIRST TIC TO THE SECOND        A26023 24150018
NOBUFFER TM    LCBSTART+2,X'03'   IS BUFFER ASSIGNED             A26023 24160018
         BNZ   INSBF              BRANCH IF NO                   A26023 24170018
         SPACE                                                          24210013
* OBTAIN NEXT LPS ENTRY REQUEST                                         24240013
IECKSU   DS    0H                                                       24270013
*  THIS IS AN ENTRY POINT FROM THE CLEANUP/RECALL AND FREE BRB ROUTINES 24300013
*  AND IS ALSO AN ENTRY POINT FROM ENDREADY                             24330013
STARTUP  LA    TREG,LPS            GET ADDRESS OF LPS QCB               24360013
         SVC   QWAIT               WAIT FOR NEXT EVENT IN LPS QUEUE     24390013
         LA    FREG,0(FREG)            CLEAR HIGH ORDER BYTE            24420013
         LA    LCBREG,STARTIO          STARTIO ELEMENT ADDRESS          24450013
         CR    LCBREG,FREG             WAS STARTIO ELEMENT RETURNED     24480013
         BNE   NOTSIO                  BRANCH NOT STARTIO ELEMENT       24510013
         CLI   STARTIO+4,X'E3'     IS AN ABEND REQUESTED          18539 24540017
         BE    NOABEND            BRANCH IF NO                          24570013
         L     1,ABCODE           LOAD ABEND CODE OUT OF DISK SPACE     24600013
         ABEND (1)                                                      24630013
NOABEND  LA    1,DISKIOB          EXCP PARAMETER                        24660013
         SVC   0                       START DISK OPERATION WITH EXCP   24690013
        B     STARTUP                  RETURN TO WAIT                   24720013
NOTSIO   C     FREG,CLOSECON           RETURNED ELEMENT CLOSE OUT REQ.  24750013
         BNE   NOTCLOSE                BRANCH NOT CLOSEOUT              24780013
         L     13,4(13)                CALLERS SAVE  AREA ADDRESS       24810013
         RETURN (14,12)                RETURN TO USER TO FIRST          24840013
*                                      INSTRUCTION FOLLOWING ENDREADY   24870013
NOTCLOSE L     LCBREG,MSLCB-1          RETRIEVE LCB ADDRESS FROM BUFFER 24900013
         LTR   LCBREG,LCBREG      IS THIS THE CHECK-POINT ELEMENT       24930013
         BNZ   NOTCPEL            BRANCH NOT CHECK-POINT ELEMENT        24960013
POSTLCB  EQU   *                                                 23157  24970018
         LA    TREG,0(FREG)       SET TREG FOR THE POST                 24990013
         SVC   QPOST                                                    25020013
         B     STARTUP            GO WAIT ON LPS                        25050013
NOTCPEL  CLI   8(FREG),X'12'       IS THIS AN LCB                23157  25060018
         BE    POSTLCB             YES, POST LCB TO ITSELF       23157  25070018
         L     X,LCBDCBPT          GET ADDRESS OF LINE GROUP'S DCB23157 25080018
         L     LGREG,DCBCLPS-IHADCB(X) GET ADDR OF USER'S LPS PROGRAM   25110013
         LR    X,FREG              PUT BUFFER ADDRESS IN WORK REGISTER  25140013
         LH    EOSREG,MSEGSZE      SET EOSREG TO END-OF-SEGMENT         25170013
         LA    EOSREG,7(X,EOSREG)  (BUFFER START & SEG SIZE & 7)        25200013
         L     TCREG,TTBASE  SET TCREG TO                               25230013
         AH    TCREG,LCBTTIND  APPLICABLE TERMINAL TABLE ENTRY          25260013
         SR    SPREG,SPREG         CLEAR SCAN POINTER REGISTER          25290013
         IC    SPREG,MSPTR         GET SCAN POINTER FOR HEADER ANALYSIS 25320013
         LA    SPREG,HDSTRT-1(SPREG)                                    25350013
         TM    LCBSTATE,X'C0'      TEST FOR RECALL AND/OR CLEANUP       25380013
         BC    7,RCRET            BRANCH IF EITHER CLEANUP OR RECALL    25410013
*                                      OR BOTH ARE SET                  25440013
*  AN ADDITIONAL TEST AFTER RETURN TO RCRET DETERMINES IF BOTH BITS ARE 25470013
*  ON.  IF EITHER (BUT NOT BOTH) ARE ON, THE ROUTINE IS ENTERED WHICH   25500013
*  RETURNS BUFFERS TO THE AVAILABLE BUFFER QUEUE.  IF BOTH ARE ON, NO   25530013
*  BUFFERS ARE TO BE RETURNED.                                          25560013
         CLI   MSTATUS,5  5=AN AVAILABLE 'FIRST' BUFFER FOR ACTIVATE    25590013
*                            THE 5 IS SET IN THE BUFFER BRB ROUTINE     25620013
         BCR   7,LGREG           IF NOT=5,BRANCH TO USER'S LPS PROGRAM  25650013
         MVI   MSTATUS,3           OTHERWISE, SET 'SRVCD' CODE          25680013
*                                                                       25710013
*              FALL THRU TO ACTIVATE ROUTINE.                           25740013
         TITLE 'ACTIVATE ROUTINE'                                       25770013
* ACTIVATE ROUTINE                                                      25800013
*      THIS ROUTINE INITIALIZES FOR A COMMUNICATIONS-LINE               25830013
* READ OR WRITE OPERATION AND BRANCHES TO THE BTAM                      25860013
* READ/WRITE ROUTINE.  AN EXCEPTION ARISES IF A SEND                    25890013
* OPERATION IS SCHEDULED FOR A TERMINAL NOT ELIGIBLE FOR                25920013
* RECEIVING, AN ERROR STATUS CODE IS SET IN THE LCB, AND                25950013
*  THE ROUTINE EXITS TO THE USER'S LPS PROGRAM.                         25980013
*      BEFORE ENTERING BTAM, THE ROUTINE INITIALIZES THE LCB            26010013
* TO ROUTE THE RECEIVED MESSAGE SEGMENT TO A QUEUE OF                   26040013
* MESSAGES HAVING ERRONEOUS DESTINATION INFORMATION.  THIS              26070013
* ROUTING INFORMATION WILL BE OVERLAID IF VALID DESTINATION             26100013
* INFORMATION APPEARS LATER.                                            26130013
*  REG X POINTS TO A BUFFER.                                            26160013
         SPACE 2                                                        26190013
IECKACT  LA    Y,TXSTRT-FBLOCK(X)  GET START OF TEXT ADDRESS            26220013
         NI    MSTATUS-FBLOCK(X),63    TURN OFF REROUTE AND CANCEL BITS 26250013
*                                        IN MESSAGE PREFIX              26280013
         L     TREG,LCBCLCCW       GET THE ADDRESS OF THE BRB WHICH     26310013
*                                    POINTS TO THE BRB TO WHICH THE     26340013
*                                    CURRENT BUFFER IS ASSIGNED         26370013
         L     FREG,MSTIC-FBLOCK(0,TREG) GET THE ADDRESS OF THE BRB TO  26400013
*                                    WHICH THE BUFFER IS ASSIGNED FROM  26430013
*                                    THE TIC ADDRESS OF THE PREVIOUS    26460013
*                                    BRB.  NOW FREG POINTS TO THE       26490013
*                                    CURRENT BRB.                       26520013
         N     FREG,ADCLR          CLEAR THE TWO LOW ORDER BITS IN THE  26550013
*                                   ADDRESS TO MAKE THE BRB ADDRESSABLE 26580013
         ST    Y,0(FREG)           PUT TEXT START ADDRESS IN BRB/CCW    26610013
         MVI   FKEY,2    MOVE 'READ' CHANNEL COMMAND CODE INTO BRB/CCW  26640013
         TM    LCBSTATE,4          IS THE LINE SEND BIT ON              26670013
         BZ    STSCK               BRANCH IF NO FOR RECEIVE             26700013
         MVI   FKEY,1              IF SEND, SET 'WRITE' CHANNEL COMMAND 26730013
*                                    CODE IN BRB/CCW                    26760013
         OI    MSTATUS-FBLOCK(X),16 AND SET OUTPUT MESSAGE PREVIOUSLY   26790013
*                                    SERVICED BIT IN BUFFER PREFIX      26820013
STSCK    LA    EOSREG,1(EOSREG)    BUMP POINTER TO LAST CHARACTER + 1   26850013
         LR    SPREG,FREG          INITIALIZE SPREG WITH BRB ADDRESS    26880013
         MVI   5(SPREG),X'11'          SET TP OP CODEB= DATA TRANSFER   26910013
         CLI   MSTATUS,128   IS THIS AN INSERT BLOCK RATHER THAN A BRB  26940013
*                                    MSTATUS HAS FREG AS BASE. THEREFOR 26970013
*                                    THE TEST IS ON BRB+12 WHICH IS     27000013
*                                    ZERO IN A BRB (FIRST BYTE OF LCB   27030013
*                                    ADDRESS). BRB+12 FOR AN INSERT     27060013
*                                    BLOCK IS THE FLAGS BYTE OF THE     27090013
*                                    WRITE IDLES CCW.                   27120013
         BNE   NOTINSRT            BRANCH IF NOT INSERT BLOCK           27150013
         L     EOSREG,16(FREG)     ELSE ACCESS NEXT BLOCK FROM TIC      27180013
*                                    ADDRESS OF THE INSERT BLOCK        27210013
         L     EOSREG,0(EOSREG)  ACCESS NEXT BLOCK'S ASSOCIATED BUFFER  27240013
*  LOOP STARTS HERE TO LOCATE NEXT BRB WHILE SKIPPING INSERT BLOCKS     27270013
XLOOP    MVI   8(SPREG),1          SET WRITE OP CODE IN WRITE    A29218 27280020
*                                   IDLES CCW                    A29218 27290020
         MVI   13(SPREG),X'11'     SET TEXT TRANSFER TP OP CODE  A29218 27300020
         L     SPREG,16(0,SPREG)   GET ADDRESS OF NEXT BLOCK     A29218 27310020
BRBLOOP  EQU   *                                                 A29218 27320020
         MVI   5(SPREG),X'11'          SET TP OP CODEB= DATA TRANSFER   27330013
*                                      FOR SUBSEQUENT INSERT BLOCKS IF  27360013
*  LOOP STARTS HERE TO SET CHAINING FLAGS IN BRB/CCW'S                  27390013
         CLI   MSTATUS-FBLOCK(SPREG),128 IS NEXT BLOCK AN INSERT BLOCK  27420013
         BE    XLOOP               BRANCH IF YES TO FIND NEXT BRB       27450013
NOTINSRT MVI   4(SPREG),136        TURN ON CHAIN DATA AND PCI FLAGS IN  27480013
*                                    CURRENT BRB/CCW                    27510013
         TM    MSTATUS-FBLOCK(X),18 IS END OF MESSAGE FLAG ON IN PREFIX 27540013
*                           (THE SERVICED BIT WAS SET PREVIOUSLY)       27570013
         BC    14,*+8              NO - LEAVE CHAINING FLAG ON          27600013
         MVI   4(SPREG),8        YES-TURN CHAINING FLAG OFF IN BRB/CCW  27630013
         TM    MSTIC+3-FBLOCK(SPREG),3 NEXT BRB HAVE BUFFER ASSIGNED    27660013
         BC    7,STCLCCW           BRANCH IF NO BUFFER ASSIGNED         27690013
         L     SPREG,MSTIC-FBLOCK(0,SPREG) ELSE GET ADDRESS OF NEXT BRB 27720013
*                                    FROM TIC ADDRESS OF CURRENT BRB    27750013
         L     X,0(0,SPREG)        AND GET BUFFER ADDRESS ASSOCIATED    27780013
*                                    WITH NEXT BRB                      27810013
         SH    X,DSTART            ADJUST TO START OF PREFIX SINCE      27840013
*                                    BUFFER ADDRESS IN BRB/CCW IS SET   27870013
*                                    TO START OF TEXT                   27900013
         B     BRBLOOP             RELOOP FOR NEXT BLOCK         A29218 27930020
         SPACE 2                                                        27960013
*  TO HERE WHEN NO MORE BRB'S WITH ASSIGNED BUFFERS                     27990013
STCLCCW  ST    SPREG,LCBCLCCW      STORE ADDRESS OF LAST BRB FOR WHICH  28020013
*                                    A BUFFER WAS ASSIGNED              28050013
         SR    EOSREG,Y            GET DATA COUNT FOLLOWING PREFIX AND  28080013
         STH   EOSREG,6(FREG)      STORE COUNT IN BRB/CCW COUNT FIELD   28110013
         BCR  15,0                 FLUSH INST. FOR MODEL91              28140013
         TM    LCBSTART+2,3        TEST AND BRANCH ON PROGRAM CHECK     28170013
         BC    7,INSBF             WHICH PREVIOUSLY OCCURRED (BUFFER    28200013
*                                    NOT SUPPLIED ON TIME BUT NOW       28230013
*                                    AVAILABLE SO GO RESTART            28260013
*                                    CHANNEL PROGRAM)                   28290013
*                                      LCBSTART HOLDS INVALID TIC       28320013
*                                      CONTENTS IF NO BUFFER ASSIGNED   28350013
         TM    MSTIC+3-FBLOCK(TREG),1  IF THE STATUS OF THE TIC ADDRESS 28380013
*                                    IN THE PRECEDING BRB IS ZERO, THEN 28410013
*                                    THIS IS THE FIRST BRB AND          28440013
*                                    INITIALIZATION MUST BE DONE FOR    28470013
*                                    ENTRY TO BTAM.  IF THE TIC ADDRESS 28500013
*                                    HAS A 1 IN THE LOW BIT POSITION,   28530013
*                                    THEN THIS IS NOT THE FIRST BRB AND 28560013
*                                    INITIALIZATION HAS BEEN DONE.      28590013
         BC    7,ADDBUF            BRANCH IF BRB HAS INVALID TIC        28620013
*                                    ADDRESS (NOT ZERO IN LOW ORDER     28650013
*                                    BIT) - NO BTAM INITIALIZATION      28680013
*                                    IS REQUIRED                        28710013
*  PROCEED WITH PREPARATION TO ENTER BTAM                               28740013
* PREPARE ACTIVATE FOR SENDING                                          28770013
BTAMRDT  SR    FREG,FREG               CLEAR WORK REGISTER         000C 28774017
         L     SPREG,TTBASE            ADDRESS OF THE TERM TABLE   000C 28778017
         IC    FREG,4(SPREG)           LENGTH OF THE TERM NAMES    000C 28782017
         IC    FREG,9(TCREG,FREG)      OFFSET TO ADDRESSING CHAR   000C 28786017
*                                      IN THIS TERM ENTRY          000C 28790017
         AR    FREG,TCREG              ADD IN POINTER TO TERMTBL   000C 28794017
*                                 ENTRY TO GET ADDRESSING CHARAC.  000C 28798017
         ST    FREG,LINEDECB+32        SET IN DECB ADDRESSING ENTRY000C 28802017
*                                       (FOR WTTA TERMINAL IDENT)  000C 28806017
         MVC   LINEDECB+37(3),LCBPOLPT SET IN DECB POLLING ENTRY   000C 28810017
*                                       (FOR WTTA COMPUTER IDENT ) 000C 28814017
         CLI   LCBCECB,1                IS READ INITIAL OP CODE    000C 28818017
         BE    ACTRCV              BRANCH IF YES                        28830013
         LH    TREG,LCBTRST        GET EOB CHARACTER OFFSET             28860013
         CLI   LCBCECB,2  IS WRITE INITIAL OP CODE SET IN LCB FOR BTAM  28890013
         BE    Q2260                   BRANCH IF YES                    28920013
         TM    LCBCECB,X'0C'           2260 WRITE ERASE OR LINE ADDR    28950013
         BC    14,BTAMENT              BRANCH IF NO                     28980013
Q2260    NI    LCBINCAM,251            TURN OFF POLLING AND ADDRES 000C 29080017
*                                    ERROR INDICATOR SINCE IT MAY BE    29250013
*                                    SET AGAIN IN LINE END APPENDAGE    29280013
         CLI   LCBINCAM,2          IS THIS A DIAL LINE (THAT HAS BEEN   29310013
*                                    MADE UNAVAILABLE) - IF YES THEN    29340013
*                                    THE ADDRESSING CHARACTERS LOCATION 29370013
*                                    ACTUALLY CONTAINS THE COUNT FOR    29400013
*                                    THE DIAL DIGITS.  THE BIT IS SET   29430013
*                                    IN THE SEND SCHEDULER.             29460013
         BNE   BTAMT               BRANCH IF NOT A DIAL LINE            29490013
         MVI   LCBCECB,6           SET WRITE CONVERSATION SINCE INITIAL 29520013
*                                    CONTACT HAS BEEN ESTABLISHED       29550013
BTAMT    NI    LCBINCAM,250      CLEAR STATUS BITS-INITIAL CONTACT MADE 29580013
         TM    8(TCREG),2          IS THE SEND BIT ON FOR THE TERMINAL  29610013
*                                    IN THE TERMINAL TABLE              29640013
         BNZ   BTAMC       BRANCH IF YES TO INTERFACE WITH BTAM WRITE   29670013
*  THE SEND BIT IS BIT 6 OF THE TSTATUS BYTE IN THE TERMINAL TABLE      29700013
*  ENTRY FOR THE TERMINAL.  THE BIT IS INITIALIZED TO 1 AND IS SET TO 0 29730013
*  IN THE INTERCPT ROUTINE TO INDICATE THAT MESSAGES DESTINED FOR THE   29760013
*  TERMINAL ARE TO BE WITHHELD FROM TRANSMISSION.                       29790013
         CLI   LCBCECB,6           IS THIS A CONNECTED DIAL LINE  18921 29800017
         BE    *+8                 IF YES, DON'T DISCONNECT       18921 29810017
         SPACE                                                          29820013
         OI    LCBINCAM,5          SET NO-DISCONNECT BIT FOR       000A 29840015
*                                       THE RECEIVE SCHEDULER      000A 29860015
         OI    LCBERRST,64         SET LCB ERROR INDICATOR-SEND BIT OFF 29880013
         MVI   LCBCPA+29,X'00'    TURN OFF 2740-2 FLAG THAT      A39109 29883020
*                                 INDICATES TERMINAL IS BUSY     A39109 29886020
         XC    LCBCSW+6(2),LCBCSW+6  CLEAR RESIDUAL COUNT FOR EOB 22436 29890018
         BR    LGREG               RETURN TO USER'S LPS PROGRAM         29910013
         SPACE                                                          29940013
* PREPARE TO ENTER ACTIVATE FOR RECIEVE - X POINTS TO A BUFFER          29970013
ACTRCV   MVI   MSTATUS-FBLOCK(X),2  2=THIS IS A (SINGLE-SEGMENT) HEADER 30000013
         LH    FREG,8(LGREG)       GET NUMBER OF CHARACTER POSITIONS TO 30030013
*                                    BE BYPASSED FOR HEADER EXPANSION   30060013
*                                    FROM THE LPSTART MACRO             30090013
         STC   FREG,MSPTR-FBLOCK(0,X) AND STORE IN BUFFER PREFIX        30120013
         LA    TREG,HDSTRT-8 INITIALIZE FOR LATER CALCULATION OF EOSREG 30150013
*  PUT IDLE CHARACTERS IN THOSE POSITIONS OF THE HEADER SEGMENT         30180013
*  RESERVED FOR TIME AND DATE STAMP                                     30210013
         LA    SPREG,X'17'             LOAD SPREG WITH IDLE             30240013
         LA    FREG,FQUEUE         INCREMENT FREG BY 1 TO INITIALIZE    30270013
*                                    FOR LOOP. (FREG CONTAINS NUMBER OF 30300013
*                                    IDLE CHARACTERS TO BE INSERTED AND 30330013
*                                    IS THE BASE FOR FQUEUE)            30360013
         STC   SPREG,HDSTRT-1(X)   BEGIN LOOP TO INSERT NUMBER OF IDLE  30390013
*                                    CHARACTERS SPECIFIED BY USER IN    30420013
*                                    LPSTART.  STORING IS FROM RIGHT TO 30450013
*                                    LEFT BEGINNING IN THE HEADER A     30480013
*                                    DISTANCE FREG PAST THE END OF THE  30510013
*                                    PREFIX.  FREG IS THE BASE FOR      30540013
*                                    HDSTRT.                            30570013
         BCT   FREG,*-4    DECREMENT COUNT AND BRANCH IF NOT DONE       30600013
         LH    SPREG,8(LGREG)      GET NUMBER OF IDLE            A29210 30607020
*                                   CHARACTERS INSERTED          A29210 30614020
         STC   FREG,HDSTRT-FBLOCK(SPREG,X) ZERO LAST IDLE CHAR.  A29210 30621020
         ST    FREG,MSNUMIN-FBLOCK(0,X) ZERO INPUT MESSAGE SEQUENCE NO. 30630013
         STH   FREG,LCBBRKCT       ZERO LCB SEQUENCE STATUS             30660013
*                                       AND OUTPUT SEQ NO IN HDR PREFIX 30690013
         MVC   LCBDESTQ,DESTERR  INITIALIZE FOR ROUTING TO DESTINATION  30720013
* ERROR QUEUE (OVERLAID BY VALID ROUTE OR DIRECT INFORMATION IF GIVEN   30750013
         SPACE                                                          30780013
* BUILD DECB AND ENTER BTAM FOR FIRST BUFFER                            30810013
         L     FREG,LCBPOLPT-1     GET ADDRESS OF CURRENT ACTIVE        30840013
*                                    POLLING LIST ENTRY                 30870013
BTAMC    ST    FREG,LINEDECB+20    STORE ADDRESS OF POLLING OR          30900013
*                                    ADDRESSING CHARACTERS              30930013
BTAMENT  LA    X,TXSTRT-MSEGSZE    CALCULATE THE LENGTH OF              30960013
         SR    X,TREG                THE INPUT AREA FOR THE             30990013
         AR    EOSREG,X                INITIAL READ                     31020013
         STH   EOSREG,LINEDECB+6   AND STORE AMOUNT TO BE READ          31050013
         SR    Y,X                 CALCULATE STARTING ADDRESS FOR       31080013
         ST    Y,LINEDECB+12         DATA IN BUFFER AND STORE           31110013
         L     Y,LCBDCBPT          GET DCB ADDRESS FROM LCB             31140013
         TM    DCBCPOLL,X'68'           IS IT A WTTA LINE GROUP    000C 31143017
         BNO   BTAMC2                  BRANCH IF NO                000C 31146017
         CLI   LCBCECB,1                IS READ INI IAL            000C 31149017
         BNE   BTAMC2                  NO                          000C 31152017
         MVI   LCBPTEMP,C' '           SET LCB MESSAGE PRIORITY    000C 31155017
         TM    LCBINCAM,X'10'          IS EOT FLAG ON              000C 31158017
         BO    BTAMC2                  YES,READ INITIAL REQUESTED  000C 31161017
         MVI   LCBCECB,3               SET READ CONTINUE OP CODE   000C 31164017
BTAMC2   EQU   *                                                   000C 31167017
         ST    Y,LINEDECB+8            AND STORE                        31170013
         TM    LCBERCCW+2,X'80'    SHOULD DIAL OUT LINE BE         000A 31173015
*                                  DISCONNECTED                    000A 31176015
         BNO   *+16               BRANCH IF NO                     000A 31179015
         MVI   LCBCECB,X'0A'       SET WRITE NOT ACKNOWLEDGE CODE  000A 31182015
         OI    LCBSTATE,X'80'     CAUSE BUFFER TO BE POSTED TO     000AX31185015
                                  AVAILABLE BUFFER QUEUE           000A 31188015
         XI    LCBERCCW+2,X'80'    CLEAR DIAL OUT SWITCH           000A 31191015
         MVC   LINEDECB+25(1),LCBUCBX  MOVE IN THE UCB ADDRESS          31200013
         MVC   LINEDECB+5(1),LCBCECB   AND THE BTAM OP CODE             31230013
         LA    01,LINEDECB         PASS THE DECB ADDRESS IN REGISTER 1  31260013
         L     15,DCBREAD          GET THE ADDRESS OF BTAM'S READ/WRITE 31290013
*                                   ROUTINE IN REGISTER 15              31320013
         BALR  14,15               BRANCH TO BTAM'S READ/WRITE ROUTINE  31350013
*                                    (BTAM'S CHANNEL END APPENDAGE      31380013
*                                    IS NOT USED HERE)                  31410013
         STH   TREG,LCBTRST  SAVE OFFSET FOR MESSAGE STARTING ADDRESS   31440013
         B     STARTUP             DONE-GO TO LPS CONTROL ROUTINE       31470013
         SPACE                                                          31500013
LINEDECB DC    10A(0)                  DECB INTERFACE FOR BTAM     000C 31530017
         SPACE                                                          31560013
* RECOVER FROM INSUFFICENT BUFFERS (BUFFER NOW AVAILABLE)               31590013
INSBF    MVC   LCBSTART,MSTIC+1-FBLOCK(TREG)  MOVE BRB/CCW ADDRESS (FOR 31620013
*                                    THE NEW BUFFER) INTO THE LCB (IOB) 31650013
         NI    LCBSTART+2,X'FC'        MAKE RESTART ADDR. ADDRESSABLE   31660015
         LA    1,LCBFLAG1  SET IOB ADDRESS IN REGISTER 1 AND            31680013
         SVC   0  EXCP             RESTART CHANNEL PROGRAM              31710013
         B     STARTUP             GO TO LPS CONTROL ROUTINE            31740013
         TITLE 'INTERIM LPS ROUTINE'                                    31770013
* INTERIM-LPS QUEUE                                                     31800013
*      QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED INTERM.          31830013
*      ELEMENT CHAIN--LIMITED TO THE DUMMY LAST ELEMENT                 31860013
*      LABELED IECKSTOP.  ELEMENTS ARE IMMEDIATELY TRANSFERRED          31890013
*      TO THE LPS QUEUE.                                                31920013
*      STCB CHAIN--LIMITED TO THE STCB FOR THE INTERIM-LPS SUBTASK.     31950013
* SPECIAL QUEUE TO DELAY LPS UNTIL ALL REQUESTS ARE PROCESSED           31980013
         SPACE 2                                                        32010013
INTERM   DC    2A(0)                                                    32040013
         DC    AL1(ENQUE-NRET)                                          32070013
         DC    AL3(INTERM+8)                                            32100013
         DC    AL1(255)                                                 32130013
         L     LCBREG,MSLCB-1      GET SOURCE LCB POINTER FROM PREFIX   32160013
         SPACE                                                          32190013
*  ENTRY POINT FROM                                                     32220013
*     A.  LINE END APPENDAGE                                            32250013
LPSDRCT  MVC   TTSKEY,LCBTTIND     SET SOURCE TERMINAL KEY IN MESSAGE   32280013
*                                    PREFIX FROM POINTER TO TERMTBL     32310013
*                                    ENTRY IN THE LCB                   32340013
         SPACE                                                          32370013
*  ENTRY POINT FROM                                                     32400013
*     A.  BUFFER BRB ROUTINE                                            32430013
*     B.  LINE END APPENDAGE                                            32460013
         LA    TREG,LPS            GET ADDRESS OF LPS QUEUE             32490013
         SPACE                                                          32520013
*  ENTRY POINT FROM                                                     32550013
*     A.  PUT ROUTINE AS A RESULT OF A BRANCH FROM BUFFER BRB ROUTINE   32580013
*     B.  GET SCHEDULER                                                 32610013
*     C.  RETURN BUFFER ROUTINE                                         32640013
*     D.  DISK END APPENDAGE                                            32670013
         MVI   FPRI,X'E0'          SET LOW PRIORITY IN BUFFER           32700013
         B     POST                GO POST BUFFER TO LPS QUEUE          32730013
         TITLE 'BUFFER RECALL/CLEANUP ROUTINE'                          32760013
* BUFFER RECALL/CLEANUP ROUTINE                                         32790013
*      THIS ROUTINE IS ENTERED THROUGH A BRANCH INSTR                   32820013
* GENERATED ON EXPANSION OF A MACRO-INSTR IN THE                        32850013
* PROB PROG.  THE ROUTINE PERFORMS A CLEANUP FUNCTION                   32880013
* WHEN ENTERED THROUGH THE CALLING SEQUENCE GENERATED BY A              32910013
* POSTSEND OR POSTRCVE MACRO-INSTRUCTION.  THE RECALL FUNCTION          32940013
* IS PERFORMED WHEN ENTRY IS THROUGH THE CALLING                        32970013
* SEQ ASSOCIATED WITH A CANCEL, EOBLC, ERRMSG, OR                       33000013
* REROUTE MACRO-INSTR.  THE DIFFERENCE BETWEEN THE                      33030013
* TWO ENTRY PATHS IS THAT IN THE SECOND CASE, THE RECALL                33060013
* FLAG IS SET ON IN THE LCB (LCBSTATE = 64).                            33090013
*      FOR EITHER A CLEANUP OR A RECALL OPERATION, THE                  33120013
* ROUTINE RELEASES ALL BUFFERS ASSIGNED TO THE LINE.                    33150013
* BUFFERS ARE RELEASED TO THE APPROP QUEUE THROUGH AN                   33180013
* SVC 67.  (THE FIRST BUFFER TO BE RELEASED MAY ALREADY                 33210013
* CONTAIN A MSG SEG.  IF SO, IT IS POSTED TO ITS                        33240013
* DESTINATION QUEUE.)  THE FIRST BUFFER (IF IT DOES NOT                 33270013
* ALREADY CONTAIN A MSG SEG) AND ALL SUBSEQUENT                         33300013
* BUFFERS NOT SCHEDULED TO BE FILLED ARE POSTED TO THE                  33330013
* AVAILABLE-BUFFER QUEUE.  ADDITIONAL CCW'S ENCOUNTERED IN              33360013
* THE BRB RING FROM WHICH BUFFERS ARE BEING RELEASED ARE                33390013
* POSTED TO THE ADDITIONAL-CCW QUEUE.                                   33420013
*      BUFFERS THAT HAVE BEEN ASSIGNED TO THE LINE AND HAVE             33450013
* ALSO BEEN SCHEDULED FOR A READ FROM DIRECT-ACCESS STORAGE             33480013
* ARE TREATED DIFFERENTLY.  WHEN SUCH A BUFFER IS ENCOUNTERED,          33510013
* THE ROUTINE BRANCHES TO THE LPS CONTROL ROUTINE.                      33540013
* AT THAT TIME, THE CLEANUP FLAG OR THE RECALL FLAG (BUT                33570013
* NOT BOTH) IS ON IN THE LCB FOR THE LINE, INDICATING THE               33600013
* TYPE OF OPERATION IN PROGRESS.                                        33630013
*      WHEN THE LPS CONTROL ROUTINE IS ENTERED, IT WAITS FOR            33660013
* A MESSAGE-FILLED BUFFER AND PROCEEDS AS USUAL UNLESS THE              33690013
* BUFFER IS ASSIGNED TO A LINE FOR WHICH THE RECALL OR                  33720013
* CLEANUP FLAG IS ON.  WHEN A BUFFER WITH EITHER FLAG (BUT              33750013
* NOT BOTH) ON IS FOUND, THE LPS CONTROL ROUTINE BRANCHES               33780013
* BACK INTO THE BUFFER RECALL/CLEANUP ROUTINE, WHERE THE                33810013
* BUFFER IS THEN RELEASED TO THE AVAILABLE-BUFFER QUEUE.                33840013
*      TO RECALL A MSG SEG, THE ROUTINE PROVIDES THE                    33870013
* BRB'S REQUIRED TO READ MSG SEGS FROM DIRECT-ACCESS STORAGE,           33900013
* OBTAINS THE SEG BEING RECALLED, AND EXITS TO THE CALLING ROUTINE.     33930013
*      WHEN THE CLEANUP OPERATION IS COMPLETE, THE ROUTINE              33960013
* FREES ALL BRB'S IN THE BRB RING AND POSTS EACH TO THE                 33990013
* INACTIVE-BRB QUEUE.  THE ROUTINE THEN POSTS THE LINE TO               34020013
* ITSELF, WHICH IS THE STANDARD TECHNIQUE FOR RETURNING A               34050013
* LINE TO THE FREE CONDITION, AND EXITS TO THE LPS CONTROL ROUTINE.     34080013
         SPACE 2                                                        34110013
******              RECALL ENTRY                                        34140013
IECKRC   STM   14,3,LCBCPA         SAVE REGISTERS FOR CALLING ROUTINE   34170013
         OI    LCBSTATE,X'40'      SET RECALL CODE IN THE LCB           34200013
         SPACE                                                          34230013
******              CLEANUP ENTRY                                       34260013
IECKPR   L     TREG,LCBDESTQ-1     GET QCB ADDRESS FOR DESTINATION      34290013
*                                    QUEUE SO THAT A BUFFER CONTAINING  34320013
*                                    A MESSAGE SEGMENT CAN BE POSTED    34350013
*                                    TO THE DESTINATION QUEUE           34380013
         LA    TREG,0(TREG)        CLEAR FIRST BYTE                     34410013
         TM    MSTATUS-FBLOCK(X),X'51' TEXT RECORD, POLLING ERROR OR    34440013
*                                      DEST. ERROR.                     34470013
         BC    7,PRTEXT            BRANCH IF YES                        34500013
         LA    FREG,HDSTRT-1-FBLOCK(0,X) GET END OF HEADER PREFIX       34530013
         SR    SPREG,FREG          GET SCAN POINTER OFFSET AND          34560013
         STC   SPREG,MSPTR-FBLOCK(0,X)   STORE IT IN HEADER PREFIX      34590013
PRTEXT   LR    FREG,X              NOW FREG CAN BE USED FOR BASE        34620013
NOT2742  TM    LCBSTATE,X'40'     ROUTINE ENTERED FOR RECALL       000D 34668018
         BO    RCPOST              BRANCH IF RECALL                     34680013
         TM    MSTATUS,X'52'       HAS LINE STOPPED RECEIVING           34710013
*         ENTRY MAY HAVE BEEN FROM ENDRECEIVE                           34740013
         BZ    POSTSU              BRANCH IF NO                         34770013
         OI    LCBSTATE,X'90'      SET CLEANUP/INITIATE CODES           34800013
         SPACE                                                          34830013
* FREE ALL ASSIGNED BUFFERS                                             34860013
RCPOST   LA    Y,LCBCLPCI-9        INITIALIZE FOR FIRST BRB             34890013
         TM    MSTATUS,X'10'       DOES FIRST BUFFER CONTAIN A          34920013
*                                    MESSAGE SEGMENT                    34950013
         BZ    RCLOOP+4            BRANCH IF YES TO POST TO             34980013
*                                    DESTINATION QUEUE                  35010013
         TM    LCBSTATE,X'82'      IS THIS RECALL THE RESULT OF A       35040013
*                                    POLLING ERROR                      35070013
         BZ    RCEXT               BRANCH IF YES                        35100013
RCLOOP   LA    TREG,BUFFER       GET ADDRESS OF AVAILABLE BUFFER QUEUE  35130013
         MVI   FPRI,X'E4'          SET BUFFER PRIORITY FOR POST         35160013
         SVC   QPOST               POST TO QUEUES SPECIFIED IN TREG     35190013
*                    MAY BE AVAILABLE BUFFER QUEUE                      35220013
*                    MAY BE DESTINATION QUEUE                           35250013
*                    MAY BE ADDITIONAL CCW QUEUE                        35280013
         L     FREG,MSTIC-FBLOCK(0,Y) ACCESS NEXT ELEMENT IN BRB RING   35310013
         N     FREG,ADCLR          CLEAR OUT LAST TWO BITS OF ADDRESS   35340013
*                                    TO MAKE BRB ADDRESSABLE            35370013
         ST    FREG,LCBCLCCW       SAVE BRB ADDRESS                     35400013
         CLI   MSTATUS,128         IS THIS AN INSERT BLOCK              35430013
         BE    RLSINS              BRANCH IF YES                        35460013
         L     X,MSTIC             GET TIC ADDRESS TO NEXT BRB          35490013
         TM    MSTIC+3,3         HAS A BUFFER BEEN ASSIGNED TO THIS BRB 35520013
         BC    7,ALLGONE           BRANCH IF NO - NO MORE TO CHECK      35550013
         OI    MSTIC+3,3     ELSE SET SWITCH TO SHOW NO BUFFER ASSIGNED 35580013
         LR    Y,FREG              GET BRB ADDRESS IN Y                 35610013
         L     FREG,0(X)           GET BUFFER ADDRESS FROM NEXT BRB     35640013
         SH    FREG,DSTART         ADJUST TO START OF BUFFER SINCE      35670013
*                                    BUFFER ADDRESS IN BRB IS POINTING  35700013
*                                    TO START OF DATA                   35730013
         B     RCLOOP              RETURN TO FREE NEXT BUFFER           35760013
         SPACE 2                                                        35790013
DSTART   DC    AL2(TXSTRT-FBLOCK)                                       35820013
         SPACE                                                          35850013
* RETURN INSERT CCW TO INSERT POOL                                      35880013
RLSINS   XC    MSTIC+1-FBLOCK(3,Y),LCBCLCCW+1  CLEAR ALL BUT LAST TWO   35910013
*                                    STATUS BITS IN BRB ADDRESS         35940013
         OC    MSTIC+1-FBLOCK(3,Y),17(FREG)  MOVE ADDRESS OF THE BRB    35970013
*                                    AFTER THE INSERT BLOCK INTO BRB    36000013
         L     TREG,20(FREG)       GET ADDRESS OF QINSERT QCB           36030013
         MVI   FPRI,X'E0'          SET PRIORITY IN INSERT BLOCK    8514 36040016
         B     RCLOOP+8            POST INSERT-BRB TO ADDITIONAL   8514 36050016
*                                   CCW QUEUE                      8514 36060016
         SPACE                                                          36090013
* WAIT FOR DISK OPERATIONS TO COMPLETE                                  36120013
ALLGONE  OI    MSTIC+3,3 SET NO BUFFER ASSIGNED SWITCH FOR PRESENT BRB  36150013
         N     X,ADCLR             CLEAR OUT LAST TWO BITS OF ADDRESS   36180013
*                                    TO MAKE BRB ADDRESSABLE            36210013
         TM    MSTIC+3-FBLOCK(X),2 IF OK TO CLEAR, CHANGE BRB FIELD TO  36240013
*                                    STOP FURTHER ASSIGNMENTS OR DISK   36270013
*                                    READS                              36300013
         BZ    STARTUP             ELSE GO TO LPS CONTROL ROUTINE TO    36330013
*                                  WAIT FOR BUFFER IN LPS OR DISK QUEUE 36360013
         LA    LCBREG,0(0,LCBREG)  CLEAR MSTATUS TO STOP FURTHER        36390013
*                                    ASSIGNMENTS                        36420013
         ST    LCBREG,MSLCB-1-FBLOCK(0,X)  REINITIALIZE LCB POINTER     36450013
*                                                 IN BRB                36480013
         TM    MSTIC+3-FBLOCK(X),2  IF STILL OK TO CLEAR, RELEASE       36510013
*                                    BUFFERS TO AVAILABLE BUFFER QUEUE  36540013
         BZ    STARTUP             ELSE GO TO LPS CONTROL ROUTINE TO    36570013
*                                    WAIT FOR ASSIGNED BUFFER           36600013
         TM    LCBSTATE,X'42'      TEST FOR RECALL                      36630013
         BO    RCACT               BRANCH IF RECALL                     36660013
          LA    15,MRRE            ELSE GET ADDRESS OF QUEUE OF         36690013
*                                    ROUTINES TO BE HANDLED BY CLEANUP. 36720013
*                                    THE ADDRESS WAS INITIALIZED BY     36750013
*                                    ENDINSRT                           36780013
ENDTL    L     15,0(0,15)          GET ADDRESS OF NEXT ROUTINE IN QUEUE 36810013
         BAL   14,4(0,15)          LINK TO LIST, EOA, OR CONVERSATIONAL 36840013
*                                    MODE ROUTINE                       36870013
         B     ENDTL               GO TO NEXT ROUTINE                   36900013
         TM    LCBSTATE,2    SPECIAL ENTRY FROM IECKDLQT OR IECKEOAD    36930013
*                                    TO RETRIEVE HEADER.                36960013
*  LCBSTATE IS CLEARED IN THE LIST AND EOA (THRU LINKAGE TO LOOKUP      36990013
*  THRU ROUTE) ROUTINES AND RESET TO 2 IN THE DESTINATION-DASD ROUTINE  37020013
*  AS A RESULT OF POSTING THE HEADER TO THE DISK I/O QUEUE              37050013
         BZ    LINEFREE            EXIT IF EXPEDITE, ELSE BRANCH        37080013
         STM   15,3,LCBCPA+4   SAVE REGISTERS IN CHANNEL PROGRAM AREA   37110013
         SPACE                                                          37140013
* PLACE REQUEST FOR DESIRED RECORD                                      37170013
RCACT    OI    LCBSTATE,X'C0'  SET TO INDICATE BOTH RECALL AND CLEANUP  37200013
         L     FREG,LCBCLPCI-1     ACCESS BRB FOR DISK READ             37230013
         MVC   LCBCSEG,LCBRCADD    MAKE DISK ADDRESS OF HEADER          37260013
*                                    AVAILABLE IN DISK BRB              37290013
         MVC   MSLCB,LCBRCADD  READ FROM THE DISK IF MULTI-ADDRESSING   37320013
*                                    RECALL, REROUTE, CANCEL, ERROR,    37350013
*                                    ET. AL.                            37380013
         MVI   MSTATUS,9           INDICATE DISK RECORD TO BE READ      37410013
         LA    TREG,DISK           GET ADDRESS OF DISK I/O QCB          37440013
         B     POSTSU              GO POST REQUEST FOR DISK READ        37470013
         SPACE 5                                                        37500013
* SPECIAL RETURN FROM STARTUP FOR RECALL                                37530013
RCRET    L     Y,LCBCLCCW          GET ADDRESS OF LAST BRB FOR WHICH    37560013
*                                    A BUFFER WAS ASSIGNED              37590013
         BC    4,RCLOOP            BRANCH IF EITHER RECALL OR CLEANUP   37620013
*                                  INDICATOR IS SET IN STARTUP ROUTINE  37650013
*  IF BOTH RECALL AND CLEANUP ARE ON, FALL THRU TO HERE                 37680013
         LA    Y,LCBCLPCI-9        GET ADDRESS OF FIRST BRB IN RING     37710013
RCEXT    ST    Y,LCBCLCCW          RESET BRB ADDRESS IN LCB             37740013
         OI    MSTATUS,64          SET DUPLICATE HEADER INDICATOR IN    37770013
*                                    PREFIX TO SHOW RECALL              37800013
         NI    LCBSTATE,X'3F'      RESET CLEANUP/RECALL FLAGS           37830013
         MVI  LCBPTEMP,C' '  INITIALIZE LCB PRIORITY (=MSG PRIORITY)    37860013
         LM    14,3,LCBCPA         RESTORE SAVED REGISTERS              37890013
*                                                                       37920013
* THE FOLLOWING BRANCH WILL RETURN TO THE CALLING ROUTINE---            37950013
*                             IECKCNCL                                  37980013
*                             IECKEOBC                                  38010013
*                             IECKERMG                                  38040013
*                             IECKRRTE                                  38070013
*                             IECKEOAD                                  38100013
*                             IECKDLQT                                  38130013
*                                                                       38160013
         BR    3                   RETURN TO ONE OF ABOVE               38190013
         TITLE 'FREE-BRB ROUTINE'                                       38220013
*  THIS ROUTINE RETURNS BRB'S TO THE INACTIVE BRB QUEUE SUBJECT TO      38222020
*  A.  IF A BUFFER REQUEST IS PENDING (BRB IS IN BUFFER REQUEST QUEUE)  38224020
*      THE BRB IS NOT FREED.                                            38226020
*                                                                       38228020
*  B.  POSTS ALL BRB'S TO THE INACTIVE BUFFER REQUEST QUEUE IF THEY ARE 38230020
*      NOT IN THE ACTIVE BUFFER REQUEST QUEUE.  BRB'S REMAINING WILL    38232020
*      BE FREED BY THE BUFFER-BRB ROUTINE.                              38234020
*                                                                       38236020
*  C.  WHEN ALL BRB'S ARE FREED (THOSE THAT HAVE NO BUFFER REQUEST      38238020
*      PENDING) THE LINE IS FREED BY POSTING THE LCB TO ITSELF.         38240020
*                                                                       38242020
LINEFREE LA    FREG,0(X)           GET ADDRESS OF BRB FOLLOWING LAST    38244020
*                                    ONE FOR WHICH A BUFFER WAS FREED   38246020
         NI    MSTIC+3,253   CLEAR CODE INDICATING BRB IS AN ACTIVE BRB 38248020
         L     X,MSTIC             BUMP X TO NEXT BRB                   38250020
         TM    MSTIC+3,1           DETERMINE IF A REQUEST FOR A BUFFER  38252020
*                                    IS PENDING IN BRB                  38254020
         BZ    LINEFREE            BRANCH IF REQUEST PENDING            38256020
         BCTR  X,0                 MAKE NEXT BRB ADDRESSABLE BY         38258020
*                                    CLEARING LAST BIT                  38260020
         LA    TREG,AVREQ  GET ADDRESS OF INACTIVE BUFFER REQUEST QUEUE 38262020
         MVI   FPRI,X'E4'          ESTABLISH PRIORITY FOR POST          38264020
         SVC   QPOST         POST BRB TO INACTIVE BUFFER REQUEST QUEUE  38266020
         CL    FREG,LCBCLCCW       IS THIS THE END OF THE LOOP          38268020
         BNE   LINEFREE            BRANCH IF NOT LAST BRB               38270020
         LR    FREG,LCBREG         IF LAST, ALL BRB'S ARE FREED         38272020
         LR    TREG,LCBREG   GET LCB ADDRESS FOR POSTING LINE TO ITSELF 38274020
         MVI   LCBSTATE,0               SET FOR SUBSEQUENT START LINE   38276020
         CLI   LCBCPA+4,255            SPECIAL FLAG FOR SIO CC 3        38278020
         BE    STARTUP                 DO NOT POST LCB TO ITSELF        38280020
POSTSU   MVI   FPRI,X'E4'          SET PRIORITY FOR POST                38282020
         SVC   QPOST  POST LINE (LCB) TO ITSELF, FREEING LINE           38284020
*  ALSO USED FOR POSTING REQUEST FOR DISK OPERATION                     38286020
*  AND FOR POSTING TO DESTINATION QUEUE WHEN LINE IS STILL RECEIVING    38288020
         B     STARTUP             BRANCH TO LPS CONTROL ROUTINE        38290020
         TITLE 'DESTINATION-DASD ROUTINE'                               38295020
* DESTINATION-DASD STCB (TRUNCATED)                                     38300020
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED IECKMQ.         38305020
*      PROGRAM ENTRY--ENTERS THE DESTINATION-DASD ROUTINE AT IECKMQ+6.  38310020
* DASD DESTINATION ROUTINE                                              38315020
*      THIS ROUTINE IS ENTERED ON ACTIVATION OF THE DASD                38320020
* DESTINATION SUBTASK, OR BY A BRANCH-AND-LINK FROM THE                 38325020
* GET-SCHEDULER ROUTINE OR THE SEND SCHEDULER ROUTINE.  THE LATTER      38330020
* ENTRY OCCURS WHEN THE SEND-SCHEDULING SUBTASK IS ACTIVATED BECAUSE    38335020
* OF THE AVAILABILITY OF A MESSAGE FILLED BUFFER.                       38340020
*      FOR BUFFERS CONTAINING TEXT SEGMENTS, THE ROUTINE                38345020
* ROUTES A FULL BUFFER TO THE DISK I/O QUEUE AND INCREMENTS             38350020
* THE MESSAGE COUNT (UNLESS A CANCEL OPERATION IS IN                    38355020
* PROGRESS).  THE LCB FOR THE SOURCE LINE -- THE LINE ON                38360020
* WHICH THE SEGMENT NOW IN THE BUFFER WAS RECEIVED -- IS                38365020
* REMOVED FROM THE SOURCE CHAIN IN WHICH IT PREVIOUSLY                  38370020
* APPEARED AND LINKED INTO THE SOURCE CHAIN FOR THE                     38375020
* DESTINATION QUEUE.  THE 'NEXT SEGMENT' RELATIVE RECORD                38380020
* NUMBER IS CALCULATED AND STORED,AND THE ROUTINE EITHER--              38385020
* (1) RETURNS TO THE CALLING ROUTINE OR (2) EXITS TO                    38390020
* THE DISPATCH SUBROUTINE.                                              38395020
         SPACE 2                                                        38400020
IECKMQ   DC    AL1(ENQUE-NRET)                                          38405020
         DC    FL4'255'                                                 38410020
         LA    TREG,DISPATCH       GET EXIT ADDRESS FOR NORMAL ENTRY    38415020
         SPACE                                                          38420020
*  ENTRY POINT FROM 1) SEND SCHEDULER OR 2) GET SCHEDULER ROUTINES      38425020
SCREEN   L     LCBREG,MSLCB-1      GET ADDRESS OF SOURCE LCB FROM       38430020
*                                    MESSAGE PREFIX                     38435020
         LR    SPREG,LCBREG            SAVE SOURCE LCB ADDR        5833 38440020
         LA    X,DISK              GET ADDRESS OF THE DISK I/O QUEUE    38445020
         ST    X,FKEY              STORE IT IN THE MESSAGE PREFIX (ECB) 38450020
         ST    FREG,READY          PUT BUFFER ON THE READY QUEUE        38455020
DSDAP    EQU   *                                                        38460020
         SPACE                                                          38465020
*  THE FOLLOWING PERTAINS TO INITIATE MODE IN WHICH THE MESSAGE HAS     38470020
*    BEEN DIRECTED OUT BEFORE IT WAS FULLY RECEIVED                     38475020
         TM    LCBSORCE+2,X'03'   IS THIS A RECALLED MESSAGE       000A 38480020
         BNZ   TEXT               BRANCH IF YES                    000A 38485020
         CLC   LCBCSEG,LCBNASEG HAS THE LAST SEGMENT RECEIVED BEEN SENT 38490020
         BNE   TEXT                BRANCH IF NO                         38495020
         L     Y,LCBSORCE-1        GET POINTER TO THE BRB USED TO READ  38500020
*                                    THIS SEGMENT FROM THE DISK         38505020
*                                    (THE BRB ADDRESS WAS STORED BY THE 38510020
*                                    DISK END APPENDAGE)                38515020
         CLI   MSTATUS-FBLOCK(Y),4 CHECK BRB FOR NOT YET RECEIVED SEGMT 38520020
         BNE   TEXT                BRANCH IF EXPECTED SEGMENT RECEIVED  38525020
         L     X,MSLCB-1-FBLOCK(0,Y)  GET SOURCE LCB ADDRESS FROM BRB   38530020
         CLC   MSLCB,LCBENDOP-LCB(X)  HAS THE BRB BEEN REASSIGNED       38535020
         BNE   TEXT                BRANCH IF YES                        38540020
         MVI   MSTATUS-FBLOCK(Y),9 INDICATE IN BRB THAT NEXT SEGMENT    38545020
*                                    ADDRESS HAS BEEN ASSIGNED          38550020
         MVC   MSLCB-FBLOCK(3,Y),LCBCSEG SET DISK ADDRESS OF NEXT       38555020
*                                    SEGMENT IN BRB                     38560020
         TM    MSTIC+3-FBLOCK(Y),3 HAS A BUFFER BEEN ASSIGNED TO NEXT   38565020
*                                    BRB FOR A DISK READ                38570020
         BC    12,TEXT             BRANCH IF YES                        38575020
*  LINK BRB TO BUFFER ON THE READY QUEUE                                38580020
         NI    MSTIC+3-FBLOCK(Y),253  CLEAR STATUS INDICATING BRB IS    38585020
*                                    IN ACTIVE BUFFER REQUEST QUEUE     38590020
         MVC   0(8,Y),FKEY         MOVE ECB FROM MESSAGE PREFIX TO BRB  38595020
*                                    WITH KEY OF 0                      38600020
         MVC   FLINK,LCBSORCE      PUT BRB ADDRESS IN LINK FIELD OF     38605020
*                                    BUFFER WHICH IS ON READY QUEUE     38610020
*  NOW BRB IS LINKED INTO READY QUEUE FOLLOWING BUFFER WHICH            38615020
*    EFFECTIVELY POSTS BRB TO DISK QUEUE                                38620020
         SPACE                                                          38625020
* FOR HEADER SEGMENTS COUNT MESSAGE IN QUEUE                            38630020
TEXT     TM    LCBSTATE,2          IS THIS PARTIALLY ENQUEUED MESSAGE   38635020
         BC    7,SEGRSM            BRANCH IF YES (BRANCH IF NOT HEADER) 38640020
         SPACE                                                          38645020
*  FROM HERE TO SEGRSM WE ARE CONCERNED WITH A HEADER MESSAGE           38650020
         LH    X,QSIZE             GET NUMBER OF MESSAGES IN QUEUE      38655020
         LA    X,1(X)              INCREMENT BY ONE                     38660020
         STH   X,QSIZE             AND RESTORE                          38665020
*     THE FOLLOWING CODE IS USED FOR REROUTING A PARTIALLY         5833 38670020
*     ENQUEUED INITIATE MODE MESSAGE                               5833 38675020
         TM    LCBSTATE,4              IS LINE SENDING             5833 38680020
         BZ    NOTINIT                 BRANCH IF NO                5833 38685020
         L     X,LCBENDOP-1            GET ADDRESS OF SOURCE       5833 38690020
         CLI   LCBMSGPR-LCB(X),0       IS THIS AN LCB OR QCB       5833 38695020
         BE    NOTINIT                 BRANCH IF QCB               5833 38700020
         TM    LCBSTATE-LCB(X),2       IS PARTIAL MESSAGE ENQUEUED 5833 38705020
         BZ    NOTINIT                 BRANCH IF NO                5833 38710020
         CLC   LCBCHDR,LCBCHDR-LCB(X)  IS THIS THE SAME MSG        5833 38715020
         BNE   NOTINIT                 BRANCH IF NO                5833 38720020
         TM    MSTATUS,2          IS THIS THE LAST SEGMENT         5833 38725020
         BO    NOTINIT             BRANCH IF YES                  22430 38730020
         MVC   MSLCB,LCBENDOP      SET UP NEW LCB ADDRESS         22430 38735020
         MVC   LCBCHDR-LCB(3,X),QNASEG    MOVE CURR. ADD. TO CHDR  5833 38740020
INIT     LR    LCBREG,X                 USE SOURCE LCB             5833 38745020
NOTINIT  EQU   *                                                   5833 38750020
         SPACE 2                                                        38755020
         OI    LCBSTATE-LCB(SPREG),2    INDICATE PARTIAL MESSAGE   5833 38760020
         MVC   LCBMSGPR,LCBPTEMP-LCB(SPREG)  SET MSG PRIORITY      5833 38765020
         SPACE                                                          38770020
* REMOVE LCB FROM SOURCE CHAIN FOR PREVIOUS MESSAGE                     38775020
         USING QBLOCK+1,Y          Y INITIALLY CONTAINS POINTER TO BRB  38780020
*                                    BUT WILL BE MADE TO CONTAIN THE    38785020
*                                    POINTER TO LCB+1                   38790020
         TM    LCBSORCE+2,1        IS IN-SOURCE-CHAIN BIT SET FOR LCB   38795020
         BZ    ILOOP-4             BRANCH IF NO                         38800020
         LA    X,LCBENDOP          INITIALIZE FOR SEARCH LOOP AND TO    38805020
*                                    RESET BASE REGISTER                38810020
RLOOP    LR    Y,X                 SET BASE TO ADDRESS OF LCB+1         38815020
         L     X,QSORCE-1          GET ADDRESS OF FIRST LCB IN QUEUE    38820020
         CLC   LCBSORCE,QSORCE-1-QBLOCK(X) IS THIS THE LCB TO REMOVE    38825020
         BNE   RLOOP               BRANCH IF NO                         38830020
         MVC   QSORCE,LCBSORCE     REMOVE THE LCB FROM THE SOURCE CHAIN 38835020
         SPACE                                                          38840020
* PLACE LCB IN SOURCE CHAIN FOR DESTINATION QUEUE                       38845020
         LA    X,1(QREG)           BUMP QCB BASE TO QCB+1               38850020
ILOOP    LR    Y,X                 SET UP FOR LOOP                      38855020
         L     X,QSORCE-1          GET IN-SOURCE LCB FROM CHAIN         38860020
         CLC   LCBMSGPR,LCBMSGPR-1-LCB(X) FIND INSERTION POINT BY       38865020
*                                    PRIORITY                           38870020
         BC    12,ILOOP            BRANCH IF THIS PRIORITY NOT HIGH     38875020
         ST    X,LCBSORCE-1        FILL LINK ADDRESS IN LCB WITH        38880020
*                                    ADDRESS OF NEXT LCB IN CHAIN       38885020
         MVC   QSORCE,MSLCB        LINK SOURCE LCB INTO CHAIN           38890020
         OI    QSORCE+2,1          INDICATE IN-SOURCE IN ADDRESS        38895020
         USING IHADCB,Y            RESET BASE                           38900020
         SPACE                                                          38905020
* ASSIGN DISK LOCATION FOR NEXT MESSAGE IN QUEUE                        38910020
         MVC   LCBNASEG,QNASEG     SET NEXT MESSAGE ADDRESS             38915020
         MVC   LCBCSEG-LCB(3,SPREG),QNASEG        IN LCB           5833 38920020
         MVC   QNASEG,ADDRESS+1    MOVE RELATIVE RECORD ADDRESS FOR THE 38925020
         MVC   MSDLINK,ADDRESS+1     DATA SET INTO QCB AND HEADER PREFX 38930020
         L     X,ADDRESS           LOAD RELATIVE RECORD ADDRESS         38935020
         LA    X,1(X)              BUMP BY 1 FOR NEXT RECORD            38940020
         ST    X,ADDRESS           AND RESTORE                          38945020
         SPACE                                                          38950020
* ESTABLISH BACKWARD LINK BY DESTINATION                                38955020
         MVC   MSMLINK,QBACK       PUT ADDRESS OF LAST MESSAGE IN QUEUE 38960020
*                                    INTO PREFIX                        38965020
         MVC   QBACK,LCBCSEG-LCB(SPREG) PUT NEXT MSG. ADDR. IN QCB 5833 38970020
SEGRSM   MVC   MSLCB,LCBCSEG-LCB(SPREG) AND INTO MSG. PREFIX       5833 38975020
         MVC   LCBCSEG-LCB(3,SPREG),ADDRESS+1 MOVE RELATIVE RECORD 5833 38980020
*                            ADDRESS TO THE LCB                    5833 38985020
         TM    MSTATUS,1           IS THIS A TEXT SEGMENT               38990020
         BC    7,TEXTX             BRANCH IF YES                        38995020
         TM    MSTATUS,64          IS THIS DUPLICATE HEADER FOR REROUTE 39000020
*                                                                       39005020
*  THE FOLLOWING BRANCH RETURNS TO THE SEND SCHEDULER OR GET SCHEDULER  39010020
*  OR EXITS TO THE DISPATCH ROUTINE IF ENTERED DUE TO ACTIVATION OF THE 39015020
*  DESTINATION DASD SUBTASK                                             39020020
*                                                                       39025020
         BCR   7,TREG              BRANCH IF YES                        39030020
         MVC   LCBCHDR,MSLCB       INITIALIZE WITH NEXT SEGMENT ADDRESS 39035020
         MVC   LCBRCADD,MSLCB                                           39040020
         SPACE                                                          39045020
* FOR OTHER THAN LAST SEGMENT ASSIGN ADDRESS OF NEXT SEGMENT            39050020
         B     TEXTX+6                                                  39055020
TEXTX    MVC   MSMLINK,LCBCHDR     MOVE HEADER ADDRESS TO PREFIX        39060020
         TM    MSTATUS,X'80'       IS THIS RECALL FROM EOBLC      23161 39065020
         BZ    TESTEOM             NO, CONTINUE PROCESSING        23161 39070020
         NI    MSTATUS,X'7F'       RESET CANCEL FLAG              23161 39075020
         BR    TREG                QBACK CHAIN OK, DO NOT RESET   23161 39080020
TESTEOM  EQU   *                                                  23161 39085020
         TM    MSTATUS,2           IS THIS LAST SEGMENT                 39090020
         BC    7,SBACK             BRANCH IF LAST SEGMENT               39095020
         MVC   MSLINK,ADDRESS+1   MOVE RELATIVE RECORD NUMBER TO PREFIX 39100020
         L     X,ADDRESS           LOAD RELATIVE RECORD ADDRESS         39105020
         LA    X,1(X)              BUMP BY ONE FOR NEXT RECORD          39110020
         ST    X,ADDRESS           AND RESTORE                          39115020
*                                                                       39120020
*  THE FOLLOWING BRANCH RETURNS TO THE SEND SCHEDULER OR GET SCHEDULER  39125020
*    OR EXITS TO THE DISPATCH ROUTINE IF ENTERED DUE TO ACTIVATION OF   39130020
*    THE DESTINATION DASD SUBTASK                                       39135020
*                                                                       39140020
         BR    TREG                EXIT                                 39145020
         SPACE                                                          39150020
* DEVELOP BACKWARD CHAIN BY SOURCE                                      39155020
SBACK    LH    X,TTSKEY            LOAD SOURCE TERMINAL OFFSET          39160020
         LTR   X,X                 IS IT ZERO                           39165020
*                                                                       39170020
*  THE FOLLOWING BRANCH RETURNS TO THE SEND SCHEDULER OR GET SCHEDULER  39175020
*    OR EXITS TO THE DISPATCH ROUTINE IF ENTERED DUE TO ACTIVATION OF   39180020
*    THE DESTINATION DASD SUBTASK                                       39185020
*                                                                       39190020
         BCR   8,TREG              EXIT IF YES                          39195020
         A     X,TTBASE            ELSE GET ADDRESS OF TERMTBL ENTRY    39200020
         L     X,0(X)              GET QCB ADDRESS FOR SOURCE           39205020
         MVC   MSLINK,QBACK-QBLOCK(X) MOVE DISK ADDRESS OF LAST MESSAGE 39210020
*                                    INTO SEGMENT PREFIX                39215020
         MVC   QBACK-QBLOCK(3,X),MSLCB LINK SEGMENT ADDRESS INTO QCB    39220020
*                                                                       39225020
*  THE FOLLOWING BRANCH RETURNS TO THE SEND SCHEDULER OR GET SCHEDULER  39230020
*    OR EXITS TO THE DISPATCH ROUTINE IF ENTERED DUE TO ACTIVATION OF   39235020
*    THE DESTINATION DASD SUBTASK                                       39240020
*                                                                       39245020
         BR    TREG                EXIT                                 39250020
         TITLE 'QUEUE CONTROL BLOCKS'                                   39300013
         CNOP  4,8                                                      39330013
         SPACE                                                          39360013
********************  FIXED CODE BEGINS HERE  ************************  39390013
* LPS QUEUE                                                             39420013
*      QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABLED LPS.              39450013
*      ELEMENT CHAIN--DYNAMICALLY CREATED.  A CHAIN OF EMPTY BUFFERS,   39480013
*      TO BE USED FOR MESSAGES INCOMING FROM TERMINALS, INTERSPERSED    39510013
*      WITH MESSAGE-FILLED BUFFERS TO BE PROCESSED BY THE LPS ROUTINES. 39540013
*      STCB CHAIN--MAY CONTAIN THE STCB FOR THE LPS SUBTASK.            39570013
*      ALWAYS ENDS WITH THE STCB FOR THE QUEUE INSERT BY                39600013
*      PRIORITY SUBTASK.                                                39630013
LPS      DC    A(IECKSTOP)                                              39660013
         DC    A(0)                                                     39690013
         DC    A(QPRIRTY)                                               39720013
         SPACE                                                          39750013
* ACTIVE-BUFFER-REQUEST QUEUE                                           39780013
*      QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED BREQ.            39810013
*      ELEMENT CHAIN--DYNAMICALLY CREATED.  AN ELEMENT                  39840013
*      APPEARING ON THIS CHAIN IS AN ACTIVE BUFFER REQUEST              39870013
*      BLOCK (BRB) REPRESENTING A BRB RING.  THE RING IS                39900013
*      FORMED BY A TIC ADDRESS IN EACH BRB                              39930013
*      POINTING TO THE NEXT BRB.  THE ELEMENT CHAIN, WHICH              39960013
*      IS DISTINCT FROM THE RING, IS FORMED BY THE LINK                 39990013
*      ADDR IN THE BRB'S IN THE CHAIN.                                  40020013
*      STCB CHAIN--LIMITED TO THE STCB FOR THE                          40050013
*      ACTIVE-BUFFER-REQUEST SUBTASK.                                   40080013
BREQ     DC    A(IECKSTOP)  ADDR OF FIRST BRB IN CHAIN                  40110013
         DC    A(0)                                                     40140013
         DC    A(BREQENQ)                                               40170013
         SPACE                                                          40200013
* AVAILABLE-BUFFER QUEUE                                                40230013
*      QCB--PREASSEMBLED IN THE QTAM NUCLEUS, LABELED BUFFER.           40260013
*      ELEMENT CHAIN--GENERATED IN THE PROB PROG ON                     40290013
* EXPANSION OF THE BUFFER MACRO-INSTR, LABELED                          40320013
*      IECKBUFF.  A CHAIN OF OPERATIONALLY-EMPTY BUFFERS.               40350013
*      STCB CHAIN--LIMITED TO THE STCB FOR THE AVAILABLE- BUFFER        40380013
*      SUBTASK.                                                         40410013
BUFFER   DC    AL1(1)                                                   40440013
         DC    AL3(0)  ADDR OF FIRST BUFFER IN CHAIN                    40470013
         DC    A(0)                                                     40500013
         DC    A(BFRENQ)                                                40530013
         SPACE                                                          40560013
* DISK INPUT/OUTPUT QUEUE                                               40590013
*      QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED DISK.            40620013
*      ELEMENT CHAIN--DYNAMICALLY CREATED.  A CHAIN OF BRB'S            40650013
*      (CONTAINING CCW'S) FOR DIRECT-ACCESS READ OPERATIONS,            40680013
*      INTERMIXED WITH FULL BUFFERS TO BE WRITTEN ONTO THE DASD.        40710013
*      STCB CHAIN--LIMITED TO THE STCB FOR THE DISK                     40740013
*      INPUT/OUTPUT SUBTASK.                                            40770013
DISK     DC    A(IECKSTOP)                                              40800013
         DC    A(0)                                                     40830013
         DC    A(DISKENQ)                                               40860013
         EJECT                                                          40890013
         SPACE                                                          40920013
* INACTIVE BUFFER REQUEST QUEUE                                         40950013
*      QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED AVREQ.           40980013
*      ELEMENT CHAIN--GENERATED IN THE PROB PROG ON                     41010013
*      EXPANSION OF THE BUFFER MACRO-INSTR, LABELED                     41040013
*      IECKAVRQ.  A CHAIN OF BRB'S OF WHICH THE THIRD AND               41070013
*      FOURTH FULLWORDS ARE EFFECTIVELY EMPTY.                          41100013
*      STCB CHAIN--MAY CONTAIN THE STCB FOR THE LINE'S                  41130013
*      RECEIVE-SCHEDULING SUBTASK AND/OR THE STCB FOR THE               41160013
*      LINE' SEND-SCHEDULING SUBTASK (OR MORE THAN ONE                  41190013
*      SEND-SCHEDULING STCB IF A SEPARATE QUEUE IS MAINTAINED           41220013
*      FOR EACH TERMINAL).  ALWAYS ENDS WITH THE                        41250013
*      STCB FOR THE QUEUE INSERT SUBTASK.                               41280013
AVREQ    DC    AL1(1)                                                   41310013
         DC    AL3(0)                                                   41340013
         DC    A(0)                                                     41370013
         DC    A(QLIFO)                                                 41400013
         SPACE                                                          41430013
* DESTINATION-DASD QUEUE                                                41460013
*      QCB--GENERATED IN THE PROB PROG ON EXPANSION                     41490013
*      OF A TERM MACRO-INSTR, LABELED QUEUEN, WHERE N                   41520013
*      IS A SEQ NUMBER REFLECTING THE NUMBER OF TERM                    41550013
*      AND/OR PROCESS MACRO-INSTR PREVIOUSLY ENCOUNTERED                41580013
*      DURING ASSEMBLY.                                                 41610013
*      ELEMENT CHAIN--THE ELEMENT CHAIN POINTER IN A DASD               41640013
*      DESTINATION QCB IS THE RELATIVE RECORD NUMBER OF THE             41670013
*      HDR SEG OF THE FIRST MSG IN THE QUE OF MESSAGES -- ON THE DASD-- 41700013
*      FOR THE DESTINATION.  IN THE MSG CHAIN EACH                      41730013
*      HDR SEG IS LINKED TO THE NEXT AND THE                            41760013
*      PRECEDING HDR SEG THROUGH INTERNAL CONTROL                       41790013
*      FIELDS.  TEXT SEGMENTS, WHICH ARE ALSO ON THE                    41820013
*      DASD ARE LINKED TO EACH OTHER, AND TO THE HDR SEG TO WHICH THEY  41850013
*      RELATE, THROUGH SELF-CONTAINED ACTUAL DASD ADDRESSES.            41880013
*           NOTE THAT THE RELATIVE RECORD NUMBER SIMPLY                 41910013
*      REFLECTS THE SEQ (1 THROUGH N) IN WHICH HDR                      41940013
*      SEGMENTS WERE ENCOUNTERED.  THIS NUMBER IS SUBSEQUENTLY          41970013
*      CONVERTED TO A RELATIVE DASD ADDR, WHICH                         42000013
*      IN TURN IS CONVERTED TO AN ACTUAL DASD ADDR.                     42030013
*      STCB CHAIN--MAY CONTAIN THE STCB FOR THE DESTINATION             42060013
*      LINE'S SEND-SCHEDULING SUBTASK. ALWAYS ENDS WITH                 42090013
*      THE STCB FOR THE DESTINATION-DASD SUBTASK.                       42120013
         SPACE                                                          42150013
* PROCESS-DASD QUEUE                                                    42180013
*      QCB--GENERATED IN THE PROB PROG ON EXPANSION                     42210013
*      OF THE PROCESS MACRO-INSTRUCTION, LABELED QUEUEN, WHERE N        42240013
*      IS A SEQUENCE NUMBER REFLECTING THE NUMBER OF TERM               42270013
*      AND/OR PROCESS MACRO-INSTRUCTIONS PREVIOUSLY                     42300013
*      ENCOUNTERED DURING ASSEMBLY.                                     42330013
*      ELEMENT CHAIN--REFER TO THE ELEMENT CHAIN DESCRIPTION            42360013
*      FOR THE DASD DESTINATION QCB.                                    42390013
*      STCB CHAIN--MAY CONTAIN THE STCB FOR THE PROCESS QUEUE'S         42420013
*      GET-SCHEDULING SUBTASK.  ALWAYS ENDS WITH THE STCB               42450013
*      FOR THE DESTINATION-DASD SUBTASK.                                42480013
         TITLE 'SUBTASK CONTROL BLOCKS'                                 42510013
* QUEUE INSERT BY PRIORITY STCB (TRUNCATED)                             42540013
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED QPRIRTY.        42570013
*      PROGRAM ENTRY--ENTERS THE QTAM NUCLEUS AT QPRIRTY+6              42600013
*      AN UNCONDITIONAL BRANCH TO THE PRIORITY SEARCH                   42630013
*      SUBROUTINE OF THE QTAM CONTROL PROGRAM.                          42660013
QPRIRTY  DC    AL1(ENQUE-NRET)   RETURN CODE                            42690013
         DC    FL4'255'                                                 42720013
         B     PRIORITY                                                 42750013
         SPACE                                                          42780013
* QUEUE INSERT STCB (TRUNCATED)                                         42810013
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED QLIFO.          42840013
*      PROGRAM ENTRY--ENTERS THE QTAM NUCLEUS AT QLIFO+6 --             42870013
*      AN UNCONDITIONAL BRANCH TO THE QUEUE INSERT SUBR                 42900013
*      (LIFO) IN THE QTAM CONTROL PROGRAM.                              42930013
QLIFO    DC    AL1(ENQUE-NRET)   RETURN CODE                            42960013
         DC    FL4'255'                                                 42990013
         B     LIFO                                                     43020013
         SPACE                                                          43050013
* QDISPATCH STCB (TRUNCATED)                                            43080013
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED QEVENT.         43110013
*      PROGRAM ENTRY--ENTERS THE QTAM NUCLEUS AT QEVENT+6               43140013
*      -- AN UNCONDITIONAL BRANCH TO THE DISPATCH SUBR                  43170013
*      OF THE QTAM CONTROL PROGRAM.                                     43200013
QEVENT   DC    AL1(ENQUE-NRET)   RETURN CODE                            43230013
         DC    FL4'255'                                                 43260013
         B     QEVENT1            CONTINUE OUTSIDE CONSTANT AREA   000A 43290015
         SPACE                                                          43320013
         TITLE '    '                                                   43350013
CNVT     DC    H'0'      INITIALIZED TO NO. BUFFERS LESS NO. BRBS       43380013
         SPACE                                                          43410013
DISKIOB  DS    0F                  SET UP FOR DISK IOB                  43440013
         DC    X'42000000'                                              43470013
         DC    A(LINEDECB)                                              43500013
         DC    X'000000000F000000'                                      43530013
         DS    XL1                                                      43560013
         DC    AL3(DISKCCW)                                             43590013
         DS    XL1                                                      43620013
         DC    AL3(0)              DCB ADDRESS FOR DISK STORED BY OPEN  43650013
         DS    A                                                        43680013
         DC    H'0'                                                     43710013
         DC    H'0'                                                     43740013
IOBSEEK  DC    XL8'0'                                                   43770013
         SPACE                                                          43800013
DISKCCW  CCW   49,IOBSEEK+3,64,5                                        43830013
         CCW   8,DISKCCW,0,1                                            43860013
         CCW   0,0,0,120           CCW FOR READ AND WRITE USING DISK    43890013
         SPACE                                                          43920013
*  POINTER TO APVECT STORED IN THE DEB BY OPEN DIRECT ACCESS MESSAGE Q  43950013
APVECT   DC    A(APNDGNRT)                                              43980013
         DC    A(APNDGNRT)                                              44010013
         DC    A(APNDGNRT)                                              44040013
         DC    A(DISKEND)                                               44070013
         DC    A(DISKABND)                                              44100013
         SPACE                                                          44130013
LNAPNDG  DC    A(APNDGNRT)                                              44160013
         DC    A(LINESIO)                                               44190013
         DC    A(LINEPCI)                                               44220013
         DC    A(LINEEND)                                               44250013
         DC    A(LINEEND)                                               44280013
         SPACE                                                          44310013
ADDRESS  DC    F'50'               RELATIVE RECORD NUMBER FOR THE DATA  44340013
*                                    SET ON THE DIRECT ACCESS DEVICE    44370013
         SPACE                                                          44400013
*  DESTINATION ERROR QUEUE                                              44430013
IECKERQ  DC    A(1)                                                     44460013
         DC    A(0)                                                     44490013
         DC    AL1(3)                                                   44520013
         DC    AL3(IECKMQ)                                              44550013
         DC    X'00'                                                    44580013
DESTERR  DC    AL3(IECKERQ)                                             44610013
         DC    A(0)                                                     44640013
         DC    H'0'                                                     44670013
         DC    AL3(1)                                                   44700013
         DC    AL3(IECKERQ+1)                                           44730013
         DC    A(0)                                                     44760013
*                                                                       44790013
*        THE FOLLOWING BRANCH TABLE IS ACCESSED BY 'B  N(0,REG)' WHERE  44820013
*        REG CONTAINS ADDR OF LPS QCB AND  N  IS A BRANCH OFFSET  AS    44850013
*        SHOWN BELOW--                                                  44880013
*                                                                       44910013
         B     IECKSU   LPS CONTROL RTN                 LPS+232         44940013
         B     IECKACT  ACTIVATE RTN                   LPS+236          44970013
         B     IECKRC   BUFFER RECALL                  LPS+240          45000013
         B     IECKPR   BUFFER CLEANUP                 LPS+244          45030013
         SPACE                                                          45060013
TTBASE   DC    FL1'1'                                                   45090013
         DC    AL3(0)                                                   45120013
DQADD    DC    AL3(DISK)                                                45150013
CURRDISK DS    0F                                                       45180013
         DC    X'09000000'                                              45210013
         SPACE                                                          45240013
QFIFO    DC    AL1(ENQUE-NRET)                                          45270013
         DC    X'000000FF00'                                            45300013
         MVI   FPRI,X'E0'                                               45330013
         B     PRIORITY                                                 45360013
         DC    A(GETSCH)                                       LPS+276  45390013
         DC    A(GETRET)                                       LPS+280  45420013
         DC    A(QMOVE)                                        LPS+284  45450013
MRCVSW   DC    X'FF'                   MASTER RECEIVE SWITCH   LPS+288  45480013
         DC    AL3(0)              MESSAGE CONTROL TCB ADDRESS          45510013
         DC    A(0)                    CHAIN OF PROCESS DEB    LPS+292  45540013
CLOSECON DC    A(CLOSEOUT)                                     LPS+296  45570013
         B     ENDINSRT                                        LPS+300  45600013
CPFLAG   DC    A(0)               CHECK/POINT ROUTINE ADDRESS  LPS+304  45630013
         B     CPENTRY                                         LPS+308  45660013
R15      EQU   15                                                       45690013
         L     R15,*+8             LOAD BRANCH ADDRESS          LPS+312 45720013
         B     0(R15)              BRANCH TO IECKPR OR IECKOPAW LPS+316 45750013
CPFLAG2  DC    X'00'          CHECKPOINT IN DISK Q FLAG    LPS+320 5645 45760016
         DC    AL3(IECKPR)    RECALL/CLEANUP ADDRESS       LPS+321 5645 45770016
*              MAY BE CHANGED TO A(IECKOPAW) IF OPCTL SPECIFIED    5645 45780016
CURUCB   DC    A(0)               CURRENT UCB ADDRESS                   45810013
ABCODE   DC    X'800A3000'                                              45840013
         DC    A(TIMEQ)                                                 45870013
QEVENT1  TM    LCBINCAM-LCB(FREG),2  IS DIAL LINE CONNECTED        000A 45873015
         BZ    DISPATCH            BRANCH IF NO                    000A 45876015
         LA    LCBREG,0(FREG)      LOAD BASE REGISTER              000A 45879015
         OI    LCBERCCW+2-LCB(FREG),X'80' THIS WILL INVOKE A WRITE 000A 45882015
*                                   NOT ACKNOWLEDGE CHANNEL PROGRAM000A 45885015
         MVI   LCBSTATE,0          INITIALIZE FOR RECEIVE SCHEDULER000A 45888015
         B     OUTONLY             FOR OUTPUT ONLY DIAL LINES      000A 45891015
         SPACE                                                          45900013
**************************** END OF CONSTANT AREA  *******************  45930013
         TITLE 'GET-SCHEDULER ROUTINE'                                  50910013
* GET-SCHEDULING STCB (TRUNCATED)                                       50940013
*      STCB--PRE-ASSEMBLED WITHIN THE QTAM NUCLEUS LABELED GETSCH.      50970013
*      PROGRAM ENTRY--ENTERS THE QTAM NUCLEUS AT GETSCH+6.              51000013
         SPACE 2                                                        51030013
GETSCH   DC    AL1(ENQUE-NRET)                                          51060013
         DC    AL4(255)                                                 51090013
*  UPON ENTRY QREG HAS THE ADDRESS OF THE DASD PROCESS QUEUE            51120013
         BAL   TREG,XCHECK         LINK TO DESTINATION DASD ROUTINE     51150013
*                                    IF NOT EXPEDITE                    51180013
*    RETURN TO HERE IF NOT EXPEDITE                                     51210013
         L     LCBREG,QTRAN+4      GET LCB POINTER FROM DASD PROCESS    51240013
*                                    QUEUE QCB (THE LCB IS A DUMMY LCB  51270013
*                                    CONTAINED IN THE DEB FOR MAIN      51300013
*                                    STORAGE PROCESS QUEUES)            51330013
*    ENTRY POINT FROM RETURN BUFFER ROUTINE                             51360013
GETTEST  LA    FREG,LCBCHDR        GET ADDRESS OF THE BRB FROM THE DEB  51390013
         TM    MSTIC+3,3           IS THE BUFFER ASSOCIATED WITH THE    51420013
*                                    BRB ELIGIBLE FOR THE DISK QUEUE    51450013
         BC    12,DISPATCH         BRANCH IF NO                         51480013
*      IF THE RIGHTMOST BITS OF MSTIC+3 ARE                             51510013
*            01 - THE BUFFER IS IN THE DISK QUEUE                       51540013
*            10 - THE CORE PROCESS QUEUE IS FILLED                      51570013
*            11 - THE BUFFER IS ELIGIBLE FOR THE DISK QUEUE             51600013
*                 THE BITS ARE SET TO 10 INITIALLY BY THE OPEN ROUTINE  51630013
         CLI   MSTATUS,9           IS THE BUFFER FOR A DISK OPERATION   51660013
         BE    DSKREQ              BRANCH IF YES                        51690013
         CLI   MSTATUS,4           IS THIS A PRIORITY MESSAGE           51720013
         BE    DISPATCH            BRANCH IF YES                        51750013
         MVI   MSTATUS,0                                                51780013
         L     QREG,MSTIC          ELSE GET ADDRESS OF DASD PROCESS QCB 51810013
         N     QREG,ADCLR          CLEAR LOW ORDER FOR ADDRESSABILITY   51840013
         LR    TREG,QREG           INITIALIZE FOR THE SEND SCHEDULER    51870013
         BAL   Y,MSGTEST           LINK TO THE SEND SCHEDULER ROUTINE   51900013
         MVC   MSLCB,LCBCSEG       LOAD PREFIX WITH DISK ADDRESS OF     51930013
*                                    SEGMENT                            51960013
         MVI   MSTATUS,9           INDICATE DISK OPERATION FOR BUFFER   51990013
DSKREQ   NI    MSTIC+3,253         SET TO SHOW BUFFER IS IN DISK QUEUE  52020013
         LA    TREG,DISK           GET ADDRESS OF DISK I/O QUEUE        52050013
         B     LPSDRCT+10          GO POST BUFFER TO DISK I/O QUEUE     52080013
         SPACE 2                                                        52110013
K4       DC    H'4'                                                     52140013
QQPTR    DS    A                   BASE FOR IECKQQ01                    52170013
ADCLR    DS    0F                                                       52200013
         DC    X'00FFFFFC'                                              52230013
         TITLE 'RETURN BUFFER ROUTINE'                                  52260013
* RETURN BUFFER STCB (COMBINED WITH QCB)                                52290013
*      STCB--PRE-ASSEMBLED WITHIN THE QTAM NUCLEUS, LOCATED AT          52320013
*      GETRET+8.                                                        52350013
*      PROGRAM ENTRY--ENTERS THE RETURN-BUFFER ROUTINE AT GETRET+14.    52380013
* RETURN-BUFFER QUEUE                                                   52410013
*      QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED GETRET.          52440013
*      ELEMENT CHAIN--LIMITED TO THE DUMMY LAST ELEMENT                 52470013
*      LABELED IECKSTOP.  BUFFERS RETURNED FROM A GET ARE               52500013
*      IMMEDIATELY TRANSFERRED TO THE AVAILABLE BUFFER QUEUE.           52530013
*      STCB CHAIN--LIMITED TO THE STCB FOR THE RETURN-BUFFER SUBTASK.   52560013
         SPACE 2                                                        52590013
LCBLAST  EQU   58                                                       52620013
*                                                                       52650013
*      THIS ORGIN IS TO PERMIT IGG0193N FINDING SYMBOL QQPTR            52680013
*                                                                       52710013
         ORG   QQPTR+8                                                  52740013
GETRET   DC    2A(0)                                                    52770013
         DC    AL1(ENQUE-NRET)                                          52800013
         DC    AL3(GETRET+8)                                            52830013
         DC    AL1(255)                                                 52860013
         L     LCBREG,MSLCB-1      GET MS PROCESS QUEUE LCB FROM PREFIX 52890013
         OI    MSTIC+3-FBLOCK+LCBCHDR,1 SET LOW ORDER BIT OF MSTIC IN   52920013
*                                    THE BRB IN THE MS PROCESS QUEUE    52950013
*                                    DEB TO INDICATE BUFFER IS IN       52980013
*                                    DISK QUEUE                         53010013
         CLI   MSTATUS,7           IS THIS TEXT EOM WITH PRIORITY       53040013
         BE    GETTEST             BRANCH IF YES TO GET SCHEDULER       53070013
         LR    X,LCBREG            TRANSFER THE LCB ADDRESS             53100013
         SH    X,K24               ADJUST WITH CONVENIENT CONSTANT      53130013
         TM    MSTATUS,X'01'       IS THIS A TEXT SEGMENT               53160013
         BO    TEXTSEG            BRANCH IF YES                   24957 53180018
         MVC   9(3,X),MSDLINK     PLACE DISK RELATIVE RECORD ADDR 24957 53200018
*                                 OF NEXT MESSAGE IN THE MS       24957 53220018
*                                 PROCESS QUEUE DEB               24957 53240018
TEXTSEG  TM    MSTATUS,X'02'      IS THIS END OF MESSAGE          24957 53260018
         BNO   GETRET1            BRANCH NO TO BYPASS MOVE        24957 53280018
         MVC   LCBLAST(3,X),9(X)  SAVE ADDRESS OF CURRENT MESSAGE 24957 53300018
GETRET1  EQU   *                                                        53340013
         L     Y,DEBDCBAD-DEB-8(0,X) GET DCB ADDRESS FROM MS PROCESS    53370013
*                                    QUEUE DEB                          53400013
         IC    TREG,DCBBUFRQ       GET NUMBER OF BUFFERS TO BE FILLED   53430013
*                                    FROM THE DASD QUEUE BEFORE         53460013
*                                    REQUESTED BY A GET MACRO           53490013
         LA    TREG,1(TREG)        BUMP BY ONE                          53520013
         STC   TREG,DCBBUFRQ       AND RESTORE                          53550013
         LA    TREG,BUFFER         GET AVAILABLE BUFFER QUEUE ADDRESS   53580013
* FOR CONVERSATION MODE MESSAGE POST BUFFER TO LPS TO TEST FOR REPLY    53610013
         TM    MSTATUS,X'02'       IS THIS THE LAST SEGMENT             53640013
         BZ    GETTESTX            BRANCH IF NOT LAST SEGMENT           53670013
         MVC   MSLCB,MSLINK        GET ADDRESS OF SOURCE LCB (SAVED IN  53700013
*                                    EXPEDITE SECTION OF GET SCHEDULER) 53730013
         L     X,MSLCB-1           TRANSFER LCB ADDRESS                 53760013
         TM   LCBSTATE-LCB(X),X'A8' ARE CLEANUP,CONVERSE,AND RECEIVE    53790013
*                                  SET IN SOURCE LCB                    53820013
         BNO   GETTESTX            BRANCH IF NOT ALL SETT               53850013
         NI    LCBSTATE-LCB(X),X'EF' TURN OFF INIT FLAG TO INDICATE     53880013
*                                  MESSAGE HAS BEEN PROCESSED           53910013
        CLI   LCBCPA-LCB(X),0     IS SOURCE LCB READY TO SEND REPLY     53940013
         BNZ   GETTESTX            BRANCH IF RECALL SET                 53970013
        MVI   LCBSTATE-LCB(X),X'F6' SET RECALL,CLEANUP,AND SEND TO      54000013
*                                    REENTER CONVERSE ROUTINE           54030013
         LA    TREG,LPS            GET ADDRESS OF LPS QUEUE             54060013
GETTESTX ST    TREG,FKEY           STORE ADDRESS OF QUEUE TO WHICH      54090013
*                                    BUFFER IS POSTED IN PREFIX (MAY BE 54120013
*                                    LPS QUEUE OR AVAILABLE BUFFER      54150013
*                                    QUEUE)                             54180013
         ST    FREG,READY          INSERT BUFFER ON READY QUEUE         54210013
         B     GETTEST             GO TO GET SCHEDULER ROUTINE          54240013
*    ENTRY FROM GET SCHEDULER ROUTINE                                   54300013
XCHECK   TM    QDCB+2,1            IS THIS FOR EXPEDITE                 54330013
         BZ    SCREEN              BRANCH IF NO                         54360013
*    THE FOLLOWING CODE IS PART OF THE GET SCHEDULER ROUTINE            54390013
*      FOR EXPEDITE QUEUES                                              54420013
         L    LCBREG,12(0,QREG)    GET ADDRESS OF LCB FROM DASD PROCESS 54450013
*                                    QUEUE QCB                          54480013
         MVC   MSLINK,MSLCB        SAVE SOURCE LCB ADDRESS              54510013
         MVC   MSLCB,QTRAN+5       PUT LCB POINTER FROM DASD PROCESS    54540013
*                                    QUEUE QCB INTO PREFIX OF SEGMENT   54570013
         LA    X,LPSDRCT+10        GET EXIT ADDRESS FROM INTERIM LPS    54600013
*    ENTRY POINT FROM DISK END APPENDAGE                                54630013
XCOUNT   LR    SPREG,LCBREG        TRANSFER THE LCB ADDRESS             54660013
         SH    SPREG,K24           ADJUST BY 24                         54690013
         L     SPREG,DEBDCBAD-DEB-8(0,SPREG)  GET THE ADDRESS OF THE    54720013
*                                    MS PROCESS QUEUE DCB               54750013
         SR    TREG,TREG           CLEAR WORKING REGISTER               54780013
         IC    TREG,DCBBUFRQ-IHADCB(0,SPREG)  GET NUMBER OF BUFFERS TO  54810013
*                                    BE FILLED FROM THE DASD QUEUE      54840013
*                                    BEFORE REQUESTED BY A GET MACRO    54870013
         BCT   TREG,*+8            BRANCH IF MORE THAN ONE REQUESTED    54900013
         NI    MSTIC+3-FBLOCK+LCBCHDR,254 TURN OFF INDICATOR SHOWING    54930013
*                                    BUFFER IS IN DISK QUEUE            54960013
         STC   TREG,DCBBUFRQ-IHADCB(0,SPREG)  RESET BUFFER COUNT IN DCB 54990013
         LA    TREG,LCBCECB        GET ADDRESS OF MS PROCESS QUEUE QCB  55020013
*                                    FROM THE DEB                       55050013
         LR    QREG,TREG           COPY MS-PROCESS Q ADDRESS     A33039 55056020
         LR    SPREG,LCBREG        COPY LCB ADDRESS              A33039 55062020
         SH    SPREG,K32           BACK UP TO DEB                A33039 55068020
         L     SPREG,0(SPREG)      GET TCB ADDRESS FOR           A33039 55074020
*                                    PROCESSING PROGRAM          A33039 55080020
         TM    TCBFLGS-TCB(SPREG),X'B6' APAR 33039 TESTED FOR X'B7'     55086021
*        ***   THE X'01' BIT DOES NOT ALWAYS IMPLY ABEND SO      A52243 55088021
*        ***   WE OMIT ITS INCLUSION IN THIS TEST.               A52243 55090021
*                                    ABENDING                    A33039 55092020
         BCR   8,X                 NO, EXIT TO                   A33039 55098020
*                                    A) INTERIM LPS ROUTINE TO POST     55110013
*                                       BUFFER TO MS PROCESS QUEUE OR   55140013
*                                    B) DISK END APPENDAGE              55170013
         NI    MSTIC+3-FBLOCK+LCBCHDR,254  ELSE SET INDICATOR    A33039 55173020
*                                    SHOWING MS-PROCESS QUEUE    A33039 55176020
*                                    IS FULL                     A33039 55179020
         LA    LGREG,PRIORITY      AND SET RETURN REGISTER TO    A33039 55182020
*                                    QUEUE BUFFER ON MS-PROCESS  A33039 55185020
*                                    QUEUE - CLOSE WILL DEQUEUE  A33039 55188020
*                                    THE BUFFER                  A33039 55191020
         BR    X                   AND RETURN TO INTERIM LPS OR  A33039 55194020
*                                    DISK END APPENDAGE          A33039 55197020
         TITLE 'DISK I/O ROUTINE'                                       56850013
* DISK I/O STCB (TRUNCATED)                                             56880013
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED DISKENQ.        56910013
*      PROGRAM ENTRY--ENTERS THE DISK INPUT/OUTPUT ROUTINE AT DISKENQ+6 56940013
* DISK I/O ROUTINE                                                      56970013
*      THIS ROUTINE IS ENTERED ON ACTIVATION OF THE DISK                57000013
* INPUT/OUTPUT SUBTASK.  THE ROUTINE CHAINS MESSAGE-FILLED              57030013
* BUFFERS (FOR DISK WRITES) AND BRBS (FOR DISK READS) ONTO              57060013
* THE ELEMENT CHAIN OF THE DISK INPUT/OUTPUT QUEUE AND                  57090013
* ISSUES THE SIO COMMAND (THROUGH AN SVC 0) TO WRITE ON OR READ         57120013
* FROM DISK.  BEFORE ISSUING THE SIO COMMAND,                           57150013
* THE ROUTINE CONVERTS THE RELATIVE RECORD NUMBER USED BY               57180013
* QTAM INTO A RELATIVE TRACK ADDR, THEN BRANCHES                        57210013
* (THROUGH A BALR) TO A MODULE OF BPAM TO CONVERT THE                   57240013
* RELATIVE TRACK ADDR TO AN ACTUAL DASD ADDR.                           57270013
         SPACE                                                          57300013
WKREG0   EQU   0                                                        57330013
DEBREG   EQU   1                                                        57360013
WKREG2   EQU   2                                                        57390013
WKREG3   EQU   3                                                        57420013
WKREG4   EQU   4                                                        57450013
WKREG5   EQU   5                                                        57480013
WKREG1   EQU   6                                                        57510013
EXTSN    EQU   16                                                       57540013
EXTSR    EQU   4                                                        57570013
         SPACE 2                                                        57600013
DISKENQ  DC    AL1(ENQUE-NRET)                                          57630013
         DC    FL4'255'                                                 57660013
*  ENTERED WHEN A FULL BUFFER IS POSTED TO THE DISK I/O QUEUE TO BE     57690013
*    WRITTEN ON THE DISK OR A BRB IS POSTED TO THE DISK I/O QUEUE TO    57720013
*    READ FROM THE DISK                                                 57750013
         BALR  15,0                SET UP BASE FOR THIS ROUTINE         57780013
         USING *,15                                                     57810013
         MVI   QKEY,2              SET DISK I/O QCB TO NOT WAITING      57840013
         LA    LGREG,POST          SET RETURN REGISTER IN CASE   A33039 57850020
*                                    RETURN IS TO SNDBUF         A33039 57860020
         CL    FREG,READY          IS THIS ITEM (BUFFER OR BRB) ALREADY 57870013
*                                    AT READY QUEUE HEAD                57900013
         BNE   DISKORD             BRANCH IF NO - DISK IDLE             57930013
*                                  IF EQUAL, THIS INDICATES THE DISK    57960013
*                                    HAS BEEN ACTIVATED PREVIOUSLY AND  57990013
*                                    DISPATCH HAS NOT REPLACED THE ECB  58020013
*                                    ON THE READY QUEUE WITH THE QCB.   58050013
         SPACE                                                          58080013
* TO HERE IF ITEM AT READY QUEUE HEAD.                                  58110013
         MVC   READY+1(3),FLINK    REMOVE ITEM FROM READY QUEUE         58140013
         CLI   FKEY,2              WAS SECOND ITEM (BUFFER OR BRB)      58170013
*                                    REMOVED                            58200013
         BNE   DISKORD             BRANCH IF YES TO PUT IT ON QUEUE     58230013
*                                  (NEW MSG, DISK NOT IDLE)             58260013
DISKSIO  L     FREG,DISK           GET POINTER TO HEAD OF DISK I/O QCBS 58290013
         LA    TREG,0(FREG)       PREPARE TO POST CHECK-POINT ELEMENT   58320013
         CLC   DISK+1(3),CPFLAG+1 IS THIS THE CHECK-POINT ELEMENT       58350013
         BNE   NOTCP              BRANCH NOT CHECK POINT ELEMENT        58380013
         MVC   DISK+1(3),FLINK    REMOVE CHECK POINT ELEMENT FROM QUEUE 58410013
         NI    CPFLAG2,X'7F'  TURN OFF CHECKPOINT IN DISK Q FLAG   5645 58420016
         MVI   FPRI,X'F4'         SET HIGH PRIORITY IN CHECK POINT ELEM 58440013
         B     SNDBUF+4                                                 58470013
NOTCP    CLI   FPRI,255           IS DUMMY LAST ELEMENT AT HEAD         58500013
*                                    (CHAIN EMPTY)                      58530013
         BNE   ACTREQ              BRANCH IF NO - OTHERWISE             58560013
         MVI   DISK,1              SET 'DISK IDLE' CODE IN QKEY FIELD   58590013
*                                    OF DISK QCB                        58620013
         B     DISPATCH            EXIT TO DISPATCH                     58650013
         SPACE 2                                                        58680013
ACTREQ   LA    X,5                 PREPARE 'WRITE' COMMAND CODE FOR CCW 58710013
         MVC   CURRDISK+1(3),MSLCB GET DISK RELATIVE RECORD NUMBER OF   58740013
*                                    SEGMENT                            58770013
         CLI   FPRI,X'EC'     DOES THIS HAVE EC PRIORITY           6990 58774016
         BE    OPCHECK        YES, OMIT SAVE                       6990 58778016
         TM    CPFLAG2,X'80'  IS CHECKPOINT IN DISK I/O QUEUE      6990 58782016
         BO    OPCHECK        YES, OMIT SAVE                       6990 58786016
         MVC   DISKONE,MSLCB  SAVE LAST NON-EC PRIORITY            6990 58790016
OPCHECK  EQU   *                                                   6990 58794016
         MVI   FPRI,X'EC'          SET HI-PRIORITY, FORCING NEW         58800013
*                                    REQUESTS TO LINK BELOW THIS        58830013
         CLI   MSTATUS,9           IS THIS A BRB ALREADY CONTAINING A   58860013
*                                    DISK ADDRESS                       58890013
         BNE   WRITE               BRANCH IF NO - ITS A FULL BUFFER FOR 58920013
*                                    A DISK WRITE                       58950013
         SPACE                                                          58980013
*  IF NEXT REQUEST IS FOR A READ, OBTAIN BUFFER FOR A BRB POINTED       59010013
*    TO BY FREG                                                         59040013
         MVC   DISK+1(3),FLINK     YES--REMOVE THIS BRB FROM DISK I/O   59070013
*                                    QCB'S ELEMENT CHAIN                59100013
         L     Y,BUFFER            POINT FREG TO FIRST AVAILABLE BUFFER 59130013
*                                    IN AVAILABLE BUFFER QUEUE          59160013
         CLI   FPRI-FBLOCK(Y),255  WAS A BUFFER AVAILABLE               59190013
         LA    TREG,BREQ           POINT TREG TO ACTIVE-BUFFER-REQUEST  59220013
         BE    SNDBUF+4           BRANCH TO POST THE BUFFER             59250013
*                                    ENQUEUE BRB AND DISK I/O QCB ON    59280013
*                                    READY QUEUE (DISK END APPENDAGE)   59310013
         MVC   DISK+1(3),BUFFER+1  BUFFER AVAILABLE - PUT EMPTY BUFFER  59340013
*                                    AT HEAD OF DISK I/O QUEUE ELEMENT  59370013
*                                    CHAIN                              59400013
         MVC   BUFFER+1(3),FLINK-FBLOCK(Y) REMOVE BUFFER FROM AVAILABLE 59430013
*                                    BUFFER QUEUE BY INSERTING 2ND      59460013
*                                    BUFFER AT TOP                      59490013
         ST    FREG,FPRI-FBLOCK(0,Y) SAVE BRB POINTER IN BUFFER ECB     59520013
         MVI   FPRI-FBLOCK(Y),X'EC'  SET HI-PRIORITY IN BUFFER ECB      59550013
         LR    FREG,Y          TRANSFER BUFFER ADDRESS FOR COMMON CODE  59580013
         LA    X,6                 PREPARE 'READ' COMMAND CODE FOR CCW  59610013
* SETUP IOB FOR NEXT REQUEST                                            59640013
WRITE    LA    FREG,8(FREG)    BUMP BUFFER ADDRESS TO START OF PREFIX   59670013
         ST    FREG,DISKCCW+16     INITIALIZE CCW WITH ADDRESS OF FULL  59700013
*                                    OR EMPTY BUFFER                    59730013
         STC   X,DISKCCW+16        INSERT READ OR WRITE COMMAND CODE    59760013
*                                    (COUNT SET AT OPEN)                59790013
         SPACE                                                          59820013
* CONVERT RELATIVE RECORD TO TTR AND ACTUAL DISK ADDRESS                59850013
* WKREG2 AND WKREG3 ARE EVEN-ODD PAIR                                   59880013
         USING DEB,DEBREG                                               59910013
         L     Y,DISKIOB+20        GET DCB ADDRESS FOR DISK             59940013
         L     DEBREG,DCBDEBAD     GET DEB BASE FROM THE DCB            59970013
         L     WKREG3,CURRDISK     GET RECORD NUMBER                    60000013
         LA    WKREG3,0(WKREG3)    CLEAR FIRST BYTE                     60030013
         SR    WKREG2,WKREG2                                            60060013
         SR    WKREG4,WKREG4                                            60090013
         SR    WKREG5,WKREG5                                            60120013
         IC    WKREG4,DEBNMEXT    COUNT OF EXTENTS ON THE DEB           60150013
         SLL   WKREG4,4           TIMES 16 EQUALS ACTUAL EXTENT SIZE    60180013
         IC    WKREG5,EXT1(WKREG4) COUNT OF RECORDS PER TRACK           60210013
         DR    WKREG2,WKREG5      DIVIDE INTO RELATIVE RECORD NUMBER    60240013
         SLL   WKREG3,8           POSITION TT PORTION OF THE TTR        60270013
         LA    WKREG0,1(WKREG2,WKREG3) COMBINE TT AND R PORTIONS OF TTR 60300013
         SLL   WKREG0,8           POSITION TTR FOR BPAM CONVERT ROUTINE 60330013
         SPACE                                                          60360013
* TRANSFER TO BPAM MODULE TO CONVERT TO ACTUAL DISK ADDRESS             60390013
         LA    2,IOBSEEK                                                60420013
         L     X,16            GET COMMUNICATIONS VECTOR TABLE ADDRESS  60450013
         L     15,28(X)            GET BPAM ADDRESS                     60480013
         BALR  14,15               LINK TO ROUTINE WHICH CONVERTS       60510013
*                                    RELATIVE TRACK ADDRESS TO ABSOLUTE 60540013
         USING *,14                                                     60570013
*                                                                       60600013
*      ABEND IF ALL SPACE USED ON THE DISK                              60630013
*                                                                       60660013
         L     Z,QTAMBASE         RESET BASE REGISTER FOR THIS MODULE   60690013
         L     BREG,QQPTR          RESTORE BASE FOR IECKQQ01            60720013
         LTR   15,15              TEST THE RETURN CODE FROM BPAM        60750013
         BZ    VALIDTTR           BRANCH IF SPACE LEFT ON THE DISK      60780013
         MVI   STARTIO+4,X'F0'    SET REQUEST ABEND PRIORITY            60810013
         B     POSTSIO                                                  60840013
*  THIS ROUTINE COULD HAVE BEEN ENTERED BY IOS THRU THE PCI APPENDAGE   60870013
*    AS THE RESULT OF A PCI WHEN SENDING SO THAT A BUFFER COULD BE      60900013
*    FILLED FROM THE DISK.                                              60930013
VALIDTTR SR    X,X                                                      60960013
         IC    X,IOBSEEK          LOAD M FROM NEW MBBCCHHR              60990013
         SLL   X,4                TIMES 16                              61020013
         LH    FREG,34(FREG,X)    ADDRESS OF THE UCB FOR THIS OPERATION 61050013
         CH    FREG,CURUCB+2      SAME UCB AS LAST OPERATION            61080013
         ST FREG,CURUCB           STORE THIS UCB ADDRESS AND ZERO THE   61110013
*                                 NO RESTART SWITCH                     61140013
         BE    TESTAPP            BRANCH IF THE SAME UCB                61170013
         MVI   CURUCB+1,255       SET THE NO RESTART SWITCH             61200013
TESTAPP  CLI   IOSSAVE,255        WAS ENTRY VIA AN SVC                  61230013
         BE    NOTAPP             BRANCH IF YES                         61260013
         CLC   DISKIOB+21(3),IOSSAVE+25 ENTRY THRU DISK END APPENDAGE   61290013
         BNE   POSTSIO            BRANCH NOT DISK APPENDAGE             61320013
         TM    CURUCB+1,255       IS THE NO RESTART SWITCH SET          61350013
         BZ    SETSIO             BRANCH NO TO RESTART IO               61380013
POSTSIO  LA    TREG,LPS           GET ADDRESS OF THE LPS QUEUE          61410013
         LA    FREG,STARTIO        AND START I/O ELEMENT ADDRESS        61440013
         B     POST                EXIT TO POST START I/O ELEMENT TO    61470013
*                                    LPS QUEUE                          61500013
NOTAPP   L     FREG,16            GET COMM REGION                       61530013
         L     FREG,0(0,FREG)     GET TCB POINTER                       61560013
         CLC   5(3,FREG),MRCVSW+1 TEST FOR MESSAGE CONTROL              61590013
         BNE   POSTSIO            IF NOT: BRANCH TO POST SIO REQUEST    61620013
         LA    1,DISKIOB           LOAD DISK START I/O PARAMETER        61650013
         SVC   0                   EXECUTE CHANNEL PROGRAM              61680013
         MVI   IOSSAVE,255         SET SVC ENTRY FLAG                   61710013
         B     DISPATCH            EXIT TO DISPATCH                     61740013
         DROP  14                                                       61770013
         SPACE 2                                                        61800013
         USING FBLOCK,FREG                                              61830013
         TITLE 'DISK-END APPENDAGE'                                     61860013
* DISK-END ROUTINE                                                      61890013
*      THIS ROUTINE IS AN I/O APPENDAGE, ENTERED FROM THE I/O           61920013
* SUPERVISOR FOLLOWING A DASD READ OR WRITE OPERATION.  IN              61950013
* A RECEIVE OPERATION, THE ROUTINE ROUTES THE EMPTY BUFFER              61980013
* REQUIRED FOR THE NEXT SEG TO BE RECEIVED TO THE                       62010013
* AVAILABLE-BUFFER QUEUE.  IN A SEND OPERATION, THE ROUTINE             62040013
* ROUTES THE MESSAGE-FILLED BUFFER TO THE LPS QUEUE,                    62070013
* INITIALIZES THE NEXT BRB IN THE RING TO READ THE NEXT                 62100013
* SEG OF THE MESSAGE AND, IF BUFFER HAS BEEN                            62130013
* ASSIGNED, ROUTES IT TO THE DISK INPUT/OUTPUT QUEUE.                   62160013
*                                                                       62190013
*                                  WRITES HAVE A BUFFER ON THE DISK I/O 62220013
*                                  QUEUE                                62250013
*                                  READS HAVE A BUFFER AND A BRB        62280013
*                                  A FULL BUFFER TO BE WRITTEN (I.E.,   62310013
*                                  FOR A WRITE) FOLLOWED ON THE DISK    62340013
*                                  I/O QUEUE BY A BRB FOR THAT SAME     62370013
*                                  RECORD (I.E., A BRB FOR THE SAME     62400013
*                                  DISK ADDRESS) LOOKS- TO THE DISK END 62430013
*                                  APPENDAGE-LIKE A READ.               62460013
         SPACE 2                                                        62490013
*  WHEN ENTERED AT DISKABND, REGISTER 2 POINTS TO THE IOB - X'41' IS    62520013
*    SET BY THE SYSTEM WHEN A 'HARD' ERROR OCCURS                       62550013
DISKABND CLI   4(2),X'41'          DID A 'HARD' ERROR OCCUR             62580013
         BCR   7,14                BRANCH IF NO TO IOS TO RETRY         62610013
         SPACE                                                          62640013
DISKEND  BALR  BREG,0  SET UP ADDRESSABILITY                       000D 62650016
         USING *,BREG                                              000D 62660016
         L     Z,QTAMBASE  LOAD ADDR OF IGG019NG                   000D 62670016
         L     15,BASE2            SET UP BASE REGISTER          A36503 62680020
         USING SVCBASE+2,BREG                                      000D 62690016
         L     BREG,QQPTR          GET BASE FOR IECKQQ01                62730013
         LA    LNKRG2,4(LNKRG2)    BUMP RETURN REGISTER                 62760013
         STM   14,9,IOSSAVE        SAVE LINKAGE FROM I/O FLIH           62790013
         L     FREG,DISK           FREG POINTS TO FIRST ELEMENT ON DISK 62820013
*                                    I/O QUEUE (EL1)                    62850013
         L     X,FLINK-1           X POINTS TO THE SECOND    (EL2)      62880013
         MVC   SAVELINK,MSLINK     SAVE MSLINK ADDRESS            19509 62890017
         SPACE                                                          62910013
* IF NO READ REQUEST, RELEASE BUFFER                                    62940013
         LA    TREG,BUFFER         GET AVAILABLE BUFFER QUEUE ADDRESS   62970013
         LA    LGREG,POST          SET RETURN REGISTER IN CASE   A33039 62980020
*                                    RETURN IS TO SNDBUF         A33039 62990020
         CLC   CURRDISK,MSTATUS-FBLOCK(X) IS EL2 A REQUEST TO READ EL1  63000013
         BNE   FRBUF               BRANCH IF NO TO RELEASE THE BUFFER   63030013
         MVI   FPRI-FBLOCK(X),X'EC'  PREVENT ELEMENT BEING CHAINED 00PS 63037018
*                                   BETWEEN TOP TWO ELEMENTS       00PS 63044018
*                                   DURING NEXT DISK ACCESS        00PS 63051018
         CLI   MSTIC-FBLOCK(X),8   DOES EL2 HOLD A TIC COMMAND          63060013
         BNE   RTRV                BRANCH IF NO (RETRIEVE IN PROGRESS)  63090013
         SPACE                                                          63120013
* FIND ADDRESS OF LCB FROM NEXT REQUEST IN LOOP                         63150013
         L     Y,MSTIC-FBLOCK(X)   ACCESS BRB (OR DASD PROCESS QUEUE    63180013
*                                    QCB IF FOR GET OPERATION) IN TIC   63210013
*                                    ADDRESS OF EL2                     63240013
         N     Y,ADCLR             MAKE BRB (OR QCB) ADDRESSABLE        63270013
*  AT THIS POINT EL2 CONTAINS THE NEXT SEGMENT DISK ADDRESS WHERE THE   63300013
*    LCB ADDRESS NORMALLY RESIDES.                                      63330013
         L     LCBREG,MSLCB-1-FBLOCK(Y) ACCESS THE LCB FROM THE BRB OR  63360013
*                                    THE DASD PROCESS QUEUE QCB         63390013
         TM    LCBSTATE,192        TEST FOR RECALL (64) AND CLEANUP     63420013
         BO    TXTRD+4             (128). BRANCH IF BOTH, THIS IS AN    63450013
*                                    EFFECTIVE REQUEST TO READ THIS     63480013
*                                    RECORD                             63510013
         TM    MSTATUS,1           IS EL1 A HEADER SEGMENT              63540013
         BC    7,TXTRD             BRANCH IF TEXT SEGMENT               63570013
         SPACE                                                          63600013
*  IF HEADER, DETERMINE IF SEQUENCE NUMBER HAS BEEN ASSIGNED            63630013
         LH    TREG,TTDKEY         GET OFFSET TO DESTINATION TERMINAL   63660013
*                                    TABLE ENTRY                        63690013
         STH   TREG,LCBTTIND       SAVE IT IN THE LCB                   63720013
         A     TREG,TTBASE         GET ADDRESS OF TERMINAL TABLE ENTRY  63750013
         L     QREG,0(TREG)        POINT QREG TO QCB FOR DESTINATION    63780013
         TM    MSTATUS,144         WAS MESSAGE CANCELLED OR SENT        63810013
         BZ    NOSRVC              BRANCH IF NO                         63840013
         SPACE                                                          63870013
* DECREASE QUEUE SIZE COUNTER AND UPDATE START POINTER                  63900013
         TM    MSTATUS,4         PRIORITY OR INTERCEPTED MSG     A64632 63910021
         BO    RELPEND           YES, CHECK RELEASE PENDING      A64632 63920021
         CLC   QFAC,CURRDISK+1     CHECK SEQUENCE                       63930013
         BNE   NOSEND              BRANCH IF OUT OF SEQUENCE            63960013
RELPEND  EQU   *                                                   00PS 63965017
         OC    LCBTTIND(2),LCBTTIND  IS DESTINATION VALID          5480 63970016
         BZ    NOTVALID            NO DON'T USE IT                 5480 63980016
         TM    8(TREG),8             IS A RELEASEM PENDING         5480 63990016
         BNO   NOTVALID              BRANCH IF NO                  5480 64000016
         OI    8(TREG),2             SET TSTATUS SEND BIT ON       5480 64010016
         NI    8(TREG),X'F3'         RESET INTERCPT AND RELEASE    5480 64020016
*                                     PENDING IN TSTATUS           5480 64030016
NOTVALID EQU   *                                                   5480 64040016
         CLC   QFAC,CURRDISK+1   CHECK SEQUENCE                  A64632 64080021
         BNE   NOSEND            BR., IF OUT OF SEQUENCE         A64632 64120021
         MVC   QFAC,MSDLINK        MOVE RELATIVE RECORD ADDRESS FROM    64170013
*                                    THE PREFIX TO THE QCB              64200013
         CLC   QLINK,QFAC          RETRANSMIT FOR CHECKPOINT      19198 64205017
         BL    ZEROQLNK            BRANCH IF NO                   19198 64210017
         MVI   DISKCCW+16,1    SET FLAG FOR RETRANSMIT           A59550 64213021
         BH     NOSEND     BRANCH IF RESTART NOT COMPLETE               64223021
ZEROQLNK XC    QLINK,QLINK         ELSE ZERO RESTART FIELD IN QCB 19198 64225017
         SPACE                                                          64230013
* IF MESSAGE HAS BEEN CANCELLED OR PREVIOUSLY SENT SET LPS TO POSTSEND  64260013
NOSEND   TM    MSTATUS,128        IS THE CANCEL FLAG ON                 64290013
         BO    CANCEL             BRANCH IF YES                    5123 64320016
         TM    DISKCCW+16,1       WRITE OPERATION OR RETRANSMIT         64350013
*                                 FOR CHECK POINT                       64380013
         BNO   CANCEL+4            BRANCH IF NO                    00PS 64385017
         LH    SPREG,6(TREG)       OBTAIN SEQUENCE OUT NUMBER     17543 64390017
         CH    SPREG,MSNUMOUT      SEQ. OUT NO. EQUAL TO TT NUMBER17543 64395017
         BNE   TXTRD           BRANCH IF NO - DO NOT UPDATE IT   A59550 64400021
***                                                                     64402021
         LA    SPREG,1(SPREG)      ADD ONE TO SEQUENCE NO.        17543 64405017
         STH   SPREG,6(TREG)       AND RESTORE IN TERM TABLE ENTRY17543 64410017
         B     TXTRD               CONTINUE PROCESSING            17543 64415017
CANCEL   EQU   *                                                   5123 64420016
         OI    LCBINCAM,4          SET INCAM TO DISCONNECT LINE    00PS 64430017
         MVI   LCBSTATE,128        TURN ON CLEANUP FLAG IN LCB IF READ  64440013
*                                    FROM DISK COMMAND IS IN CCW OR IF  64470013
*                                    WRITE AND MESSAGE CANCELLED        64500013
         SPACE                                                          64530013
* PREPARE BUFFER FOR LPS                                                64560013
TXTRD    NI    MSTATUS,X'DF'       TURN OFF EOB FLAG                    64590013
         NI    MSTATUS,X'6F'       CLEAR CANCEL AND SENT FLAGS          64620013
         MVC   DISK+1(3),5(X)      TAKE BRB AND BUFFER OUT OF DISK I/O  64650013
*                                    QUEUE BY MOVING LINK ADDRESS OF    64680013
*                                    EL2 INTO QCB                       64710013
         ST    LCBREG,MSLCB-1-FBLOCK(X)  PUT LCB POINTER BACK INTO BRB  64740013
*                                    REMOVED FROM QUEUE (EL2)           64770013
         MVC   MSLCB,MSLCB-FBLOCK(X)  ASSIGN BUFFER TO LINE (PUT LCB    64800013
*                                    POINTER IN BUFFER                  64830013
         CLI   MSTIC-FBLOCK(Y),8   IS THIS A DISK READ FOR A GET        64860013
         BNE   GETDEND             BRANCH IF YES - (Y WILL HAVE DASD    64890013
*                                    PROCESS QUEUE QCB ADDRESS)         64920013
         LA    TREG,LPS            NO--ROUTE BRB TO LPS QUEUE           64950013
         SPACE                                                          64980013
*  THE FOLLOWING BRANCHES TO PUT THE BUFFER ON THE READY QUEUE IF       65010013
*          1.  THE LINE IS NOT SENDING                                  65040013
*          2.  THE LINE IS IN CLEANUP                                   65070013
*          3.  THIS IS LAST SEGMENT AND READING OF NEXT SEGMENT IS      65100013
*                  TO BE INITIATED                                      65130013
         TM    LCBSTATE,4          IS THE LINE SENDING                  65160013
         BZ    SNDBUF              BRANCH IF NO                         65190013
         TM    LCBSTATE,192        ARE CLEANUP AND RECALL BOTH SET      65220013
         BM    SNDBUF              BRANCH IF EITHER-LINE IS IN CLEANUP  65250013
         NI    MSTIC+3-FBLOCK(X),253  RESET BRB STATUS CODE TO INDICATE 65280013
*                                    BRB IS INACTIVE                    65310013
         TM    MSTATUS,2           IS THIS LAST SEGMENT OF MESSAGE      65340013
         BC    7,SNDBUF            BRANCH IF YES                        65370013
         SPACE                                                          65400013
* TEST FOR NEXT SEGMENT NOT YET RECIEVED                                65430013
NEXTSEG  L     X,LCBSTATE          LOAD LCB ADDRESS FOR ORIGINATING     65460013
*                                    LINE                               65490013
         TM    LCBSORCE+2-LCB(X),1 IN INITIATE MODE (IN-SOURCE CHAIN    65520013
*                                    SET)                               65550013
         BNZ   SEGRDY              BRANCH IF NOT INITIATE (BIT IS SET)  65580013
         CLI   LCBSCHAD,X'12'     IS THIS PROCESS QUEUE LCB       21207 65585017
         BE    CHEKCHDR           NO,COMPARE LCBCHDR              21207 65590017
         CLC   LCBCHDR-LCB(3,X),LCBLAST-24+3(LCBREG)              21207 65595017
*                                 ELSE COMPARE SAVED HEADER FIELD 21207 65600017
         BNE   SEGRDY             BRANCH IF PUTTING ANOTHER MESSAGE1207 65605017
         B     WAITING            ELSE WAIT FOR NEXT SEGMENT      21207 65610017
CHEKCHDR  EQU  *                                                  21207 65615017
         CLC   LCBCHDR-LCB(3,X),LCBCHDR HAS THE RECEIVING LINE     00PSX65620015
                           STARTED ANOTHER MESSAGE                 00PS 65660015
         BNE   SEGRDY              BRANCH IF YES                        65700013
WAITING  EQU  *                                                   21207 65710017
         MVI MSTATUS-FBLOCK(Y),4   SET SPECIAL CODE IN BRB TO INDICATE  65730013
*                                    WAITING FOR NOT YET RECEIVED       65760013
*                                    SEGMENT (USED IN DESTINATION DASD) 65790013
         ST    Y,LCBSORCE-1-LCB(0,X) SAVE POINTER TO BRB TO BE USED TO  65820013
*                                    READ NEXT SEGMENT                  65850013
         MVC   LCBNASEG-LCB(3,X),SAVELINK  UPDATE NEXT AVAILABLE  19509 65870017
*                SEGMENT ADDRESS (FIRST SEGMENT NOT SENT)         19509 65890017
         CLC   LCBCSEG-LCB(3,X),SAVELINK  LCBCSEG IS FIRST SEGMENT19509 65910017
*                NOT RECEIVED - HAS NEXT SEG BEEN RECEIVED        19509 65930017
         BE    SNDBUF              BRANCH IF NO                    00PS 65970015
SEGRDY   MVI   MSTATUS-FBLOCK(Y),9 SET DISK ADDRESS ASSIGNED IN BRB     66000013
         MVC   MSLCB-FBLOCK(3,Y),SAVELINK  PUT DISK ADDRESS IN BRB19509 66030017
         TM    MSTIC+3-FBLOCK(Y),3 IS THIS AN IDLE BRB (BUFFER NOT      66060013
*                                    ASSIGNED)                          66090013
         BC    12,SNDBUF           BRANCH IF NO TO CHAIN BUFFER INTO    66120013
*                                    DISK I/O QUEUE                     66150013
         SPACE                                                          66180013
* PLACE DISK REQUEST IF BUFFER HAS BEEN ASSIGNED.                       66210013
         NI    MSTIC+3-FBLOCK(Y),253  RESET BRB STATUS CODE             66240013
         LA    X,DISK              GET DISK I/O QUEUE QCB ADDRESS       66270013
RESCHEDD MVC   FLINK-FBLOCK(3,Y),DQADD SET LINK ADDRESS IN BRB TO DISK  66300013
*                                    I/O QCB                            66330013
         MVI   FPRI-FBLOCK(Y),X'E4'  SET PRIORITY IN BRB                66360013
         MVC   DISK+5(3),READY+1   LINK ITEM AT READY QUEUE HEAD TO     66390013
*                                    DISK I/O QCB                       66420013
         ST    X,FKEY-FBLOCK(Y)    PUT RETURN BUFFER QCB INTO BUFFER OR 66450013
*                                    DISK I/O QCB INTO BRB              66480013
         ST    Y,READY             PUT BRB ON THE READY QUEUE OR        66510013
*                                    PUT BUFFER ON THE READY QUEUE      66540013
         B     LPSDRCT+10          BRANCH TO POST                       66570013
         SPACE                                                          66600013
* IF RETRIEVE QPOST BUFFER TO REQUEST BLOCK NOW CONVERTED TO QCB        66630013
RTRV     LA    TREG,0(0,X)         LOAD TREG AND CLEAR FIRST BYTE OF    66660013
*                                    BRB ADDRESS                        66690013
         MVC   QFAC-QBLOCK(3,X),DUMMY MOVE READY QUEUE ADDRESS TO BRB   66720013
*                                    FIRST WORD                         66750013
         MVC   FLINK,FLINK-FBLOCK(X) MOVE BRB LINK FIELD TO BUFFER      66780013
*                                    LINK FIELD                         66810013
FRBUF    MVC   DISK+1(3),FLINK     MOVE BUFFER LINK FIELD TO DISK QCB   66840013
*  ENTRY POINT FROM THE DISK I/O ROUTINE                                66870013
SNDBUF   MVI   FPRI,X'E0'         SET BUFFER PRIORITY                   66900013
         MVC   DISK+5(3),READY+1  READY ITEM TO THE DISK QUEUE          66930013
         MVC   READY+1(3),DQADD    PUT DISK I/O QCB ON READY QUEUE      66960013
         BR    LGREG               RETURN TO POST TO POST BUFFER A33039 66970020
*                                    OR PRIORITY TO QUEUE BUFFER A33039 66980020
*                                    ON MS-PROCESS QUEUE (IF     A33039 66990020
*                                    PROCESSING PROGRAM IS       A33039 67000020
*                                    CLOSING)                    A33039 67010020
         SPACE                                                          67020013
GETDEND  LA    TREG,BUFFER         GET AVAILABLE BUFFER QUEUE ADDRESS   67050013
         LR    Y,X                 SAVE THE BRB ADDRESS                 67080013
         OI    MSTIC+3-FBLOCK+LCBCHDR,3  SET FLAGS IN BRB IN MS PROCESS 67110013
*                                    QUEUE DEB INDICATING BUFFER IS     67140013
*                                    ELIGIBLE FOR DISK QUEUE            67170013
         CLI   LCBSTATE,128    WAS LCBSTATE SET EARLIER IN THIS ROUTINE 67200013
         BNE   *+8                 BRANCH IF NO                   18900 67220017
         OI    MSTATUS,X'82'       RESET CANCEL AND EOM           19563 67240017
         TM    MSTATUS,1          IS THIS A TEXT SEGMENT          21207 67292017
         BO    BYPASS             YES,BYPASS THE SAVE             21207 67294017
         MVC   LCBLAST-24+3(3,LCBREG),CURRDISK+1  SAVE HEADER ADDR21207 67296017
BYPASS   EQU   *                                                  21207 67298017
         MVC   MSLINK,LCBENDOP     SAVE SOURCE TO TEST REPLY      19509 67300017
         L     X,LCBENDOP-1        GET SOURCE LCB ADDRESS        A31036 67302020
         TM    LCBSTATE-LCB(X),X'20' IS SOURCE IN CONVERSE MODE  A31036 67304020
         BO    CVRS                YES, MSLINK OK                A31036 67306020
         MVC   MSLINK,LCBSORCE     SET UP MSLINK WITH PROCESS    A31036 67308020
*                                   QUEUE QCB ADDRESS            A31036 67310020
         NI    MSLINK+2,X'FC'      TURN OFF TIC FLAGS            A31036 67312020
CVRS     EQU   *                                                 A31036 67314020
         BAL   X,XCOUNT            LINK TO SPECIAL ENTRY IN      A33039 67315020
*                                    RETURN BUFFER ROUTINE FOR   A33039 67316020
*                                    LOOK AHEAD                  A33039 67317020
         TM    MSTATUS,2           IS END OF MESSAGE FLAG ON            67320013
         BZ    NEXTSEG             BRANCH IF NO TO PREPARE NEXT SEGMENT 67350013
GETEND   LA    X,GETRET            GET ADDRESS OF RETURN BUFFER QUEUE   67410013
         MVI   MSTATUS-FBLOCK(Y),7 INDICATE DUMMY BRB IN DEB FOR MS     67440013
*                                    PROCESS QUEUE                      67470013
         TM    MSTIC+3-FBLOCK(Y),3   IS THERE SPACE IN MS-PROCESS Q4982 67477016
         BNO   SNDBUF             NO, DO NOT SET UP FOR ANOTHER    4982 67484016
*                                 READ                             4982 67491016
         B     RESCHEDD            BRANCH TO ACTIVATE BRB               67500013
         SPACE                                                          67530013
* SET STATUS TO INDICATE MESSAGE SENT                                   67560013
NOSRVC   OI    MSTATUS,16          INDICATE MESSAGE SENT IN PREFIX 000D 67570018
         LH    X,QSIZE        GET NUMBER OF HEADERS IN QUEUE       5480 67597016
         BCTR  X,0            DECREMENT BY ONE                     5480 67604016
         STH   X,QSIZE        RESTORE QSIZE                        5480 67611016
         MVI   DISKCCW+16,5        SET TO REWRITE HEADER TO DISK        67620013
         TM    MSTATUS,4           IS PRIORITY SET IN PREFIX            67650013
         BC    7,SETSIO            BRANCH IF YES                        67680013
         SPACE                                                          67710013
* ASSIGN SEQUENCE NUMBER TO MESSAGE                                     67740013
         LH    X,6(TREG)           GET SEQOUT NUMBER FROM TERMINAL TBL  67770013
       CLC   MSNUMOUT(1),MSNUMOUT+1  IS SEQ OUT TO BE INSERTED IN HDR   67800013
         BE    NOOUTSEQ            BRANCH IF NO                         67830013
         TM    MSTATUS,X'40'       IS MESSAGE TO A SECONDARY DESTINATN  67860013
         BO    NOOUTSEQ            YES                                  67890013
         LH    Y,MSNUMOUT          ACCESS CHARACTER POSITION IN HEADER  67920013
*                                       FOR INSERTION OF SEQUENCE NUMBR 67950013
         AR    Y,FREG              CALCULATE ADDRESS OF SEQUENCE FIELD  67980013
*                                       IN THE BUFFER                   68010013
         MVC   0(2,Y),6(TREG)      MOVE IN OUTPUT SEQUENCE NUMBER       68040013
NOOUTSEQ  EQU  *                                                        68070013
         STH   X,MSNUMOUT          STORE IT IN PREFIX                   68100013
         LA    X,1(X)              INCREMENT THE SEQUENCE NUMBER        68130013
         STH   X,6(TREG)           AND RESTORE IN TERMINAL TABLE        68160013
         CLC   QFAC,CURRDISK+1     CHECK SEQUENCE                       68190013
         BE    SETSIO              BRANCH IF EXPECTED VALUE             68220013
         OI    MSTATUS,4           ELSE SET PRIORITY IN PREFIX          68250013
         SPACE                                                          68280013
*  ENTRY POINT FROM DISK I/O ROUTINE                                    68310013
* SET START IO EXIT FROM APPENDAGE                                      68340013
SETSIO   L     X,IOSSAVE           LOAD SAVED RETURN REGISTER           68370013
         LA    X,4(X)              BUMP BY FOUR                         68400013
         ST    X,IOSSAVE           AND RESTORE                          68430013
         MVI   DISKIOB,X'42'       REINITIALIZE IOB FOR FUTURE USE      68460013
         XC    DISKIOB+1(3),DISKIOB+1  ZERO THE FIVE BYTES INDICATED    68490013
         XC   DISKIOB+30(2),DISKIOB+30   IN THE DISK IOB                68520013
         B     DISPATCH            EXIT TO DISPATCH NEXT ITEM ON READY  68550013
         SPACE 2                                                        68580013
*  ENTRY POINT FROM DISK I/O ROUTINE WHEN DISK IDLE                     68610013
DISKORD  TM    CPFLAG2,X'80'  IS CHECKPOINT IN DISK QUEUE          5645 68640016
         BZ    STARTORD           BRANCH NO CHECK POINT                 68670013
         L     TREG,CPFLAG        RESET START ORD POINTER               68700013
         B     CSCAN                                                    68730013
*  THE FOLLOWING IS USED EXCLUSIVELY BY THE DISK I/O ROUTINE            68760013
* PLACE DISK REQUEST INTO PROPER POSITION IN DISK I/O QUEUE             68790013
SKIP     CLC   MSLCB-FBLOCK(3,TREG),DISKONE  IS DISK ADDRESS OF    6990 68820016
*                                    ELEMENT IN CHAIN LESS THAN         68850013
*                                    CURRENT ADDRESS                    68880013
         BC    4,ADD               BRANCH IF ENQUEUED ELEMENT LESS      68910013
CSCAN    LA    QREG,TPRI           ENABLE NEXT ELEMENT TO BE ACCESSED   68940013
STARTORD L     TREG,QKEY          ACCESS FIRST ELEMENT ON DISK I/O      68970013
*                                    QUEUE OR NEXT ELEMENT IN CHAIN     69000013
*                                    IF NOT FIRST TIME                  69030013
NOCPNT   CLI   TPRI,255           IS THIS THE LAST ELEMENT              69060013
         BE    LIFO              BRANCH IF YES TO QUEUE INSERT ROUTINE  69090013
         CLI   TPRI,X'EC'          DOES THE ELEMENT IN CHAIN HAVE HIGH  69120013
*                                    PRIORITY (BYPASS HIGH PRIORITY)    69150013
         BE    CSCAN               BRANCH IF YES                        69180013
         CLI   FPRI,X'EC'          DOES ELEMENT TO BE INSERTED (BUFFER  69210013
*                                    OR BRB) HAVE HIGH PRIORITY         69240013
         BE    LIFO                BRANCH IF YES TO INSERT THIS ELEMENT 69270013
*                                    AS LAST IN HIGH PRIORITY SECTION   69300013
*                                    OF CHAIN                           69330013
         SPACE                                                          69360013
*    IF THE NEW ELEMENT HAS 'EC' PRIORITY, IT IS INSERTED IN DISK I/O   69390013
*      QUEUE FOLLOWING ALL OTHER ELEMENTS WITH 'EC' PRIORITY            69420013
*      OTHERWISE IT IS INSERTED BY THE RELATIVE DISK ADDRESS TO BE      69450013
*      ACCESSED                                                         69480013
         CLC   MSLCB,DISKONE  IS DISK ADDRESS OF NEW ELEMENT LESS  6990 69510016
*                                    THAN CURRENTLY ASSIGNED ADDRESS    69540013
         BL    SKIP                BRANCH IF YES                        69570013
         CLC   MSLCB-FBLOCK(3,TREG),DISKONE  IS DISK ADDRESS OF    6990 69600016
*                                    ELEMENT IN THE CHAIN LESS THAN THE 69630013
*                                    CURRENT ADDRESS                    69660013
         BL    LIFO                BRANCH IF YES TO INSERT NEW ELEMENT  69690013
ADD      CLC   MSLCB,MSLCB-FBLOCK(TREG)  IS DISK ADDRESS OF NEW ELEMENT 69720013
*                                    LESS THAN ELEMENT IN CHAIN         69750013
         BL    LIFO                BRANCH IF YES TO INSERT NEW ELEMENT  69780013
         B     CSCAN               ELSE GO ACCESS NEXT ELEMENT IN CHAIN 69810013
DISKONE  DC    AL3(0)                                              6990 69820016
SAVELINK DC    AL3(0)                                             19509 69825017
         DS    0H                                                  6990 69830016
         TITLE 'LINE-SIO APPENDAGE'                                     69840013
*      THIS ROUTINE IS ENTERED FROM THE SUPERVISOR'S EXCP               69870013
* HANDLER AFTER AN EXCP MACRO-INSTR HAS BEEN ISSUED                     69900013
* BY BTAM, BUT BEFORE AN SIO COMMAND HAS BEEN ISSUED.  THE              69930013
* ROUTINE MODIFIES THE BTAM-GENERATED CHANNEL PROGRAM TO                69960013
* MEET QTAM'S REQUIREMENTS.                                             69990013
*      WHEN THIS ROUTINE IS ENTERED, BTAM HAS GENERATED A               70020013
* CHANNEL PROGRAM CONSISTING OF SEVERAL CHANNEL COMMANDS                70050013
* INCLUDING A 'WRITE DATA' OR 'READ DATA' CCW.                          70080013
* QTAM HAS CREATED A RING OF BRB/CCWS,                                  70110013
* EACH CONTAINING THE PCI FLAG AND A TIC                                70140013
* COMMAND TO THE FOLLOWING BRB/CCW.  THE ROUTINE LINKS                  70170013
* THESE TWO CHANNEL PROGRAMS TO GETHER BY ALTERING THE FLAGS            70200013
* IN BTAM'S READ OR WRITE DATA CCW AND ADDING A TIC                     70230013
* COMMAND TO THE SECOND QTAM BRB/CCW.                                   70260013
*      WHEN THE CHANNEL PROGRAM IS EXECUTED, THE FIRST BUFFER           70290013
* IS TRANSMITTED UNDER BTAM'S READ- OR WRITE-DATA CCW.  IF              70320013
* QTAM HAS ALREADY SCHEDULED A SECOND BUFFER (USUALLY THE               70350013
* CASE), A TIC TO QTAM'S CCW TAKES PLACE AND THE SECOND BUFFER          70380013
* BEGINS TO FILL.  THE PCI FLAG IN THE QTAM CCW CAUSES THE LINE-PCI     70410013
* ROUTINE TO BE ENTERED AS FILLING OF THE SECOND BUFFER BEGINS.         70440013
* (IF A SECOND BUFFER IS NOT AVAILABLE, QTAM SETS THE PCI FLAG IN       70470013
* BTAM'S CCW.)                                                          70500013
*      IF THE CHANNEL PROGRAM INVOLVED IS FOR AN INITIAL                70530013
* READ, THE LINE-SIO ROUTINE ALSO REPLACES THE POLLING                  70560013
* CHARACTER POINTER IN BTAM'S 'WRITE POLLING CHARACTERS'                70590013
* CCW WITH A POINTER COMPATIBLE WITH QTAM'S POLLING TECHNIQUE.          70620013
*      WHEN THE REQUIRED ADJUSTMENTS HAVE BEEN MADE, QTAM               70650013
* BRANCHES BACK TO THE EXCP HANDLER TO CAUSE THE SIO                    70680013
* COMMAND TO BE ISSUED.                                                 70710013
* SET TRANSFER IN CHANNEL                                               70740013
         SPACE 2                                                        70770013
         USING *,15                                                     70800013
LINESIO  L     15,BASE                                             00PS 70830018
         USING TTBASE,15                                                70860013
         CLI   LCBCPA-LCB-48+32(2),X'FE' ENTRY FOR SAD/ENABLE COMMANDS  70890013
         BL    NOTSAD             BRANCH NOT SAD/ENABLE COMMANDS        70920013
         MVI   X'1F'(2),X'0C'     SET FLAGS FOR ERP                     70950013
         MVI   0(2),X'E6'         INDICATE ERP IN CONTROL               70980013
         BR    14                 RETURN TO IOS                         71010013
NOTSAD   EQU   *                                                        71040013
*                                    UPON ENTRY. THIS SETS UP THE       71070013
*                                    POINTER TO IECKQQ01 IN REGISTER 15 71100013
         DROP  BREG                                                     71130013
         L     15,QQPTR                                                 71160013
         USING SVCBASE+2,15                                             71190013
         STM   10,13,IOSSAVE+48    SAVE REGISTERS 10-13                 71220013
         BALR  13,0                                                     71250013
         USING *,13                                                     71280013
LINEX    L     13,BASE                                             00PS 71310018
         USING TTBASE,13                                                71340013
         LR    10,2                REGISTER 2 HAS THE IOB ADDRESS       71370013
         SH    10,LCBSZ            ADJUST TO START OF LCB               71400013
         TM    LCBCPA-LCB(10),X'FF'    TEST FOR TERMINAL TEST ACTIVE    71430013
         BNO   *+12               BRANCH NO                        2936 71440016
         MVI   LCBPTEMP-LCB(10),X'FF'  SET SWITCH FOR RCV SCHEDULER2936 71450016
         B     NOSTAT             RETURN TO IOS IF TEST ACTIVE     2936 71460016
         CLI   LCBCECB-LCB(10),X'0A' IS THIS A WRITE NOT ACK       000A 71470015
         BE    LEAVE              BRANCH IF YES                    000A 71480015
         L     11,LCBSTART-1-LCB(10) GET ADDRESS OF STARTING CCW   7766 71481017
         CLI   0(11),X'41'         IS IT 2848 RESET CHANNEL PROGRAM7766 71482017
         BNL   *+12               YES, 2260 BREAKOFF               7766 71482518
         CLI   0(11),X'0D'        IS IT TWX, 115A, OR 83B3 BREAKOFF7766 71483018
         BNE   *+16               NO, CONTINUE NORMAL FLOW         7766 71483518
         MVI   LCBERRCT+1-LCB(10),X'40' SET DISABLE RETURN FOR ERP 7766 71484017
         OI    LCBFLAG1-LCB(10),X'24'  SET FOR ERP TO HANDLE BREAK 7766 71485017
         B     LEAVE               RETURN TO IOS                   7766 71486017
         L     11,LCBCLPCI-1-LCB(0,10) GET THE QTAM CCW POINTER IN R11  71490013
         SR    12,12                   GET THE BTAM CCW PTR IN 12       71520013
         IC    12,LCBERCCW+3-LCB(0,10)   OFFSET TO DATA CCW             71550013
         LA    12,LCBCPA-LCB(12,10)    ADDRESS OF DATA CCW              71580013
         NI    4(11),247       TURN OFF PCI FLAG IN QTAM'S INITIAL CCW  71610013
         MVC   8(4,12),8(11)   MOVE TIC COMMAND FROM QTAM TO BTAM CCW   71640013
         MVC   4(1,12),4(11)       MOVE FLAGS FROM QTAM TO BTAM CCW     71670013
         CLI   12(11),128          IS QTAM CCW FROM AN INSERT BLOCK     71700013
         BNE   NOSTINS             BRANCH IF NO                         71730013
         SPACE                                                          71760013
* IF FIRST CCW IS INSERT,SET TIC TO CCW FOR INSERTED CHARACTERS         71790013
         LA    11,8(11)            GET ADDRESS OF WRITE IDLES CCW       71820013
         ST    11,MSTIC-FBLOCK(0,12) STORE FOR TIC IN BTAM'S CCW        71850013
         MVI    MSTIC-FBLOCK(12),8 MOVE TIC COMMAND (08) TO BTAM'S CCW  71880013
NOSTINS  TM    MSTIC+3-FBLOCK(12),3 HAS READ BEEN REQUESTED BUT NEXT    71910013
*                                    BUFFER NOT ASSIGNED TO QTAM BRB    71940013
         BC    12,OK               BRANCH IF BUFFER ASSIGNED            71970013
         CLI   LCBCECB-LCB(10),7   IS THIS A READ REPEAT          22423 71980018
         BE    *+8                 YES, SKIP PCI SETTING          22423 71990018
         OI    4(12),8             ELSE SET PCI FLAG IN BTAM'S CCW      72000013
         NI    MSTIC+3-FBLOCK(12),253 CLEAR SWITCH INDICATING BRB IS IN 72030013
*                                    BUFFER REQUEST QUEUE               72060013
         SPACE                                                          72090013
* FOR READ INITIAL SET POLL CHARACTERS                                  72120013
OK       CLI   LCBCECB-LCB(10),2  IS THIS A WRITE INITIAL        A26763 72130019
         BNE   OK2                BRANCH IF NO                   A26763 72140019
         LA    11,LCBCPA-LCB(10)  GET STARTING CCW ADDRESS       A26763 72150019
TICLOOP  LA    11,8(11)           BUMP TO NEXT CCW               A26763 72160019
         CLI   0(11),8            IS THIS TIC CCW                A26763 72170019
         BE    OK2                YES, NO WRITE (D) FOUND        A26763 72180019
         CLI   5(11),8            IS THIS WRITE (D) CCW          A26763 72190019
         BNE   TICLOOP            NO,RELOOP                      A26763 72200019
         NI    4(11),X'3F'        TURN OFF CHAINING FLAGS IN CCW A26763 72210019
OK2      CLI   LCBCECB-LCB(10),1  IS THIS A READ INITIAL         A26763 72220019
         BNE   LEAVE+4             BRANCH IF NO                    00PS 72250018
         TM    LCBERRST+1-LCB(10),X'10' TEST FOR INSUFF. BUFFERS A26776 72280019
         BO    LEAVE+4            BRANCH IF YES                  A26776 72310019
         CLI   LCBINCAM-LCB(10),2      WAS THERE A POLLING ERROR        72360013
         BNE   DISABLEC-4              BRANCH IF NO                     72390013
         MVI   LCBCPA-LCB(10),3        NOP THE DISABLE                  72420013
         B     DISABLEC                                                 72450013
         MVI   LCBINCAM-LCB(10),0  TURN OFF THE DON'T DIAL FLAG         72480013
DISABLEC L     11,LCBSTART-1-LCB(10) GET ADDRESS OF STARTING CCW   00PS 72490018
         CLI   5(11),X'11'         DOES TP OP CODE INDICATE TEXT   00PS 72500018
         BNL   LEAVE               YES, DO NOT BUMP POLL POINTER   00PS 72510018
         CLI   LCBCPA+13-LCB(10),3 DOES 2ND CCW HAVE RESTRT TP CODE00PS 72520018
*                                    THE RESTART CCW IS WRITE POLLING   72540013
*                                    OR ADDRESSING CHARACTERS FOLLOWING 72570013
*                                    A WRITE CIRCLE C. THE WRITE CIRCLE 72600013
*                                    C CCW HAS TO BE ISSUED ONLY ONCE   72630013
*                                    FOR THE LINE. A NON DIAL LINE HAS  72660013
*                                    THE 2ND CCW AS THE RESTART CCW     72690013
*                                    WHILE A DIAL LINE HAS THE 3RD CCW  72720013
*                                    AS RESTART.                        72750013
         BNE   TEST1               BRANCH IF NO                    3727 72780016
         TM    LCBFLAG2-LCB(10),X'01' IS THIS AN AUTOPOLL LINE          72810013
         BZ    LSIOUT              BRANCH IF NO                         72840013
         CLI   LCBCPA+8-LCB(10),X'03' FIRST SIO AFTER CONVERSE MODE     72870013
         BE    LEAVE               BRANCH IF YES                        72900013
         OI    LCBERCCW-LCB(10),X'40'  IDENTIFY HEADER BUFFER ON        72930013
*                                      AUTOPOLL LINE                    72960013
         B     LEAVE               DO NOT ADJUST POINTER TO POLING CHRS 72990013
TEST1    CLI   LCBCPA+8-LCB(10),X'06'  IS CCW A PREPARE            3727 73000016
         BNE   LEAVE               BRANCH NO, NOT 2740 BASIC       3727 73010016
LSIOUT   EQU   *                                                        73020013
         L     11,LCBPOLPT-1-LCB(0,10) ELSE INITIALIZE WITH POINTER TO  73050013
*                                    POLLING CHARACTER FOR FIRST PASS   73080013
*                                    THRU LOOP.                         73110013
NEXT     ST    11,LCBPOLPT-1-LCB(0,10) STORE ACTIVE POLLING ENTRY       73140013
*                                    POINTER IN LCB                     73170013
         LH    12,0(11)      ACCESS POINTER TO TERMINAL TABLE ENTRY TO  73200013
         STH   12,LCBTTIND-LCB(0,10)  CONFORM WITH QTAM POLL TECHNIQUE  73230013
         LTR   12,12               IS THIS THE END OF THE POLLING LIST  73260013
*                                    (THERE IS A HALFWORD OF ZERO       73290013
*                                    DEFINING THE END OF POLLING LIST)  73320013
         BE    ENDLIST             BRANCH IF YES                        73350013
         A     12,TTBASE           ADD TERMINAL TABLE ADDRESS TO OFFSET 73380013
         LA    11,2(0,11)          BUMP TO NEXT LIST ENTRY              73410013
         TM    8(12),1             CAN THE TERMINAL BE POLLED (IS THE   73440013
*                                    RECEIVE BIT ON IN TERMINAL TABLE   73470013
*                                    ENTRY)                             73500013
         BZ    NEXT                BRANCH IF NO                         73530013
         CLI   LCBCPA+8-LCB(10),X'06'  IS THIS 2740 BASIC          3727 73540016
         BE    LEAVE               BRANCH IF YES                   3727 73550016
*  THE RECEIVE BIT IS BIT 7 OF THE TSTATUS BYTE IN THE TERMINAL TABLE   73560013
*  ENTRY FOR THE TERMINAL.  THE BIT IS INITIALIZED TO 1 AND CAN BE SET  73590013
*  TO ZERO BY THE CHNGT MACRO INSTRUCTION TO PREVENT POLLING.           73620013
         SR    11,11               CLEAR WORKING REGISTER               73650013
         L     13,TTBASE          ADDRESS OF THE TERMINAL TABLE         73680013
         IC    11,4(13)           LENGTH OF THE TERMINAL NAMES          73710013
         IC    11,9(11,12)        OFFSET TO ADDRESSING CHARACTERS IN    73740013
*                                 THIS TERM ENTRY                       73770013
         LA    11,2(0,11)          BUMP BY 2 TO GET TO POLL CHARACTERS  73800013
         AR    12,11             ADD INTO TERMINAL TABLE ENTRY ADDRESS  73830013
         ST    12,LCBCPA+8-LCB(0,10) AND STORE WRITE CHANNEL COMMAND    73860013
*                                    CODE AND POLLING CHARACTERS        73890013
*                                    ADDRESS INTO BTAM'S 2ND CCW. THE   73920013
*                                    WRITE CHANNEL COMMAND CODE (01) IS 73950013
*                                    THE FIRST BYTE OF TTBASE.          73980013
LEAVE    MVI   LCBPTEMP-LCB(10),C' ' SET SWITCH USED BY RECEIVE         74010013
*                                    SCHEDULER TO DETERMINE IF ANY      74040013
*                                    TERMINAL WAS POLLED.  (RESET IN    74070013
*                                    'END OF POLL TIME DELAY ROUTINE')  74100013
*  THE FOLLOWING CODE UPDATES THE TRANSMISSION THRESHOLD COUNTER   2936 74102016
*  AND CHECKS IT AGAINST THE THRESHOLD VALUE IN THE DCB. IF EQUAL, 2936 74104016
*  ALL THRESHOLD COUNTERS ARE ADDED TO THE CUMULATIVE COUNTERS AND 2936 74106016
*  THE THRESHOLD COUNTERS ARE THEN CLEARED.                        2936 74108016
         BALR  13,0                                                2936 74110016
         USING *,13                                                2936 74112016
         L     12,LCBDCBPT-LCB(10)     DCB ADDRESS                 2936 74114016
         SR    11,11                                               2936 74116016
         IC    11,DCBEIOBX-IHADCB(12)  LCB SIZE                    2936 74118016
         AR    11,10              11 NOW POINTS 1 BYTE BEYOND LCB  2936 74120016
         SH    11,H16                  BACK UP TO LER ACTR         2936 74122016
         CLI   10(11),255         IS THRESH COUNTER AT MAX (X'FF') 2936 74124016
         BE    ADDCUM             YES, BYPASS UPDATE               2936 74126016
         SR    10,10                   LCB ADDRESS NO LONGER NEEDED2936 74128016
         IC    10,10(0,11)             THRESHOLD TRANSMISSION CNTR 2936 74130016
         LA    10,1(0,10)                ADD ONE                   2936 74132016
         STC   10,10(0,11)               STORE BACK                2936 74134016
         CLI   14(11),0                IS THRESHOLD MESSAGE WAITING2936 74136016
         BE    NOADD                     GO BRANCH NO              2936 74138016
ADDCUM   L     10,0(0,11)              CUMULATIVE THRESHOLD COUNTER2936 74140016
         LA    10,1(0,10)                ADD ONE                   2936 74142016
         ST    10,0(0,11)                STORE BACK                2936 74144016
         B     NOSTAT                                              2936 74146016
NOADD    CLC   10(1,11),DCBKSTAT-IHADCB(12) HAS TRANSMISSION CNTR  2936 74148016
*                                        REACHED ITS THRESHOLD     2936 74150016
         BL    NOSTAT                   BRANCH NO                  2936 74152016
         MVI   10(11),0                CLEAR THRESHOLD COUNTER     2936 74154016
         AL    10,0(0,11)              ADD CUMULATIVE TO THRESHOLD 2936 74156016
         ST    10,0(0,11)              STORE TOTAL                 2936 74158016
         LA    12,3                    INITIALIZE LOOP             2936 74160016
LOOPST   SR    10,10                                               2936 74162016
         IC    10,13(0,11)             THRESHOLD COUNTER           2936 74164016
         MVI   13(11),0                CLEAR                       2936 74166016
         BCTR  11,0                    DECREMENT FOR THRESHOLD CNTR2936 74168016
*                                        AND HALF FOR CUMULATIVE   2936 74170016
         AH    10,6(12,11)             ADD CUMULATIVE              2936 74172016
         STH   10,6(12,11)             STORE TOTAL                 2936 74174016
         BCT   12,LOOPST               DECREMENT OTHER HALF ANO    2936 74176016
*                                        TERMINATE LOOP            2936 74178016
         DROP  13                                                  2936 74180016
NOSTAT   LM    10,13,IOSSAVE+48        RELOAD REGISTERS            2936 74182016
APNDGNRT BR    14                 RETURN TO EXCP SUPERVISOR TO SIO 2936 74184016
H16      DC    AL2(16)                                             2936 74186016
         SPACE                                                          74190013
         USING IGG019NG,13                                              74220013
LCBSZ    DC    H'48'                                                    74250013
         TITLE 'LINE PCI APPENDAGE'                                     74280013
* LINE-PCI ROUTINE                                                      74310013
*      THIS ROUTINE IS ENTERED WHEN A PCI OCCURS DURING THE             74340013
* EXECUTION OF A QTAM CHANNEL COMMAND FOR THE LINE.  THE FUNCTION       74370013
* OF THE ROUTINE IS TO DISPOSE OF THE BUFFER FILLED OR EMPTIED BY THE   74400013
* CHANNEL COMMAND PRECEDING THAT WHICH CAUSED THE PCI, AND TO PLACE     74430013
* A REQUEST FOR THE BUFFER THAT IS TO BE EMPTIED OR FILLED              74460013
* BY THE CCW WHEN IT IS AGAIN ENCOUNTERED IN THE RING.                  74490013
         SPACE 2                                                        74520013
         USING LINEPCI,15                                               74550013
LINEPCI  L     15,BASE            ADJUST BASE REGISTER             00PS 74580018
         SR    BREG,BREG           THIS SETS THE CONDITION CODE SO THAT 74610013
         USING TTBASE,15                                                74640013
*                                    THE FOLLOWING BRANCH WILL NOT      74670013
*                                    OCCUR ON NORMAL ENTRY              74700013
         L     BREG,QQPTR          SET BASE IECKQQ01 (ENTRY POINT FROM  74730013
         USING SVCBASE+2,BREG                                           74760013
*                                    TIME EXIT IN THE END-OF-POLL-TIME- 74790013
*                                    DELAY ROUTINE SO THAT QTAMBASE CAN 74820013
*                                    BE ADDRESSED. THIS ENTRY TAKES     74850013
*                                    ADVANTAGE OF COMMON CODE)          74880013
         STM   14,9,IOSSAVE        SAVE REGISTERS FOR IOS               74910013
         BALR  14,0      MAKE QTAMBASE ADDRESSABLE                 000D 74915016
         USING ADDRFIX,14                                          000D 74920016
ADDRFIX  DS    0H                                                  000D 74925016
         L     Z,QTAMBASE   SET UP BASE OF IGG019NG                000D 74930016
         L     14,IOSSAVE  RESTORE 14                              000D 74935016
         DROP  14                                                  000D 74940016
         BZ    NOTTIME       THIS BRANCH IS EFFECTIVE WHEN ENTRY   2937 74950015
*                                 IS NOT FROM TIMEEXIT ROUTINE. THE2937 74960015
*                                 CONDITION CODE ON ENTRY FROM THAT2937 74970015
*                            ROUTINE IS SET BY AN LTR INSTRUCTION  2937 74980015
*                                 TO INSURE NO BRANCH              2937 74990015
         CLC   DUMMYTME+1(3),1(Z) IS TIME ELEMENT ALREADY ON LPS Q.2937 75000015
         BE    DISPATCH           BRANCH IF YES                    2937 75010015
         CLI   DUMMYTME,1         IS TIME ELEMENT ON READY QUEUE A28771 75013019
         BH    DISPATCH           YES, DISPATCH TIME ELEMENT     A28771 75016019
         B     POST               IF NO GO PUT IT ON               2937 75020015
NOTTIME  EQU   *                                                   2937 75030015
         LR    LCBREG,2            GET THE POINTER TO THE IOB           75120013
*                                (IOS STORES THE POINTER IN REGISTER 2) 75150013
         SH    LCBREG,LCBSZ        RESET TO POINT TO LCB HEAD           75180013
         TM    69,X'20'           DID PROGRAM CHECK ALSO OCCUR     00PS 75190015
         BO    DISPATCH                  YES, LEAVE PCI APPENDAGE  00PS 75200015
         L     Y,64                IOS DOES NOT PLACE CSW IN IOB. GET   75210013
*                                    FIRST FULL WORD OF CSW FROM        75240013
*                                    LOCATION 64. THE CSW POINTS TO THE 75270013
*                                    TIC FOLLOWING THE CCW FOR WHICH    75300013
*                                    THE PCI OCCURRED                   75330013
         SH    Y,K24               BACK UP 3 DOUBLE WORDS               75360013
         LA    Y,8(0,Y)            STEP TO NEXT CCW                     75390013
         CLI   8(Y),8              TEST FOR TIC COMMAND CODE            75420013
         BNE   *-8                 LOOP IF NOT FOUND                    75450013
*FIND CCW PRECEDING THE FIRST ONE CONTAINING A TIC COMMAND              75480013
         SPACE                                                          75510013
*  REGISTER Y HAS POINTER TO CCW CONTAINING THE CURRENT PCI             75540013
*  REGISTER X WILL HAVE POINTER TO CCW CONTAINING THE FIRST PCI WHICH   75570013
*                            WAS NOT SERVICED                           75600013
         SPACE                                                          75630013
* TEST STATUS OF BUFFER PREVIOUSLY ASSIGNED TO REQUEST                  75660013
         L     X,LCBCLPCI-1        GET BRB/CCW ADDRESS CONTAINING THE   75690013
*                                    FIRST PCI NOT SERVICED             75720013
         CLI   MSTATUS-FBLOCK(X),128 IS THIS AN INSERT BLOCK OR A BRB   75750013
*                                    BRB+12 IS 0 IN A BRB (FIRST BYTE   75780013
*                                    OF LCB ADDRESS) AND IS THE FLAGS   75810013
*                                    BYTE OF THE WRITE IDLES CCW IN     75840013
*                                    AN INSERT BLOCK                    75870013
         LA    FREG,LCBCLPCI-5    INITIALIZE FOR FOLLOWING BRANCH  00PS 75900015
         BE    INSLOOP            BRANCH IF INSERT BLOCK                75930015
         TM    MSTIC+3-FBLOCK(X),3 HAS A BUFFER BEEN ASSIGNED TO NEXT   75960013
*                                    BRB                                75990013
         BO    NOBUFY              BRANCH IF NO (FREG HAS ADDRESS       76020013
*                                    OF LCBCLPCI-5)                     76050013
         B     PCITEST+4                                           00PS 76060015
         SPACE                                                          76080013
* DISPOSE OF PREVIOUS BUFFER                                            76110013
*  ENTRY POINT FROM LINE END APPENDAGE                                  76140013
NOTINQ   TM    LCBERCCW,X'40'      IS THIS HEADER BUFFER ON AUTOPOLINE  76170013
         BO    PCIAP               IF YES BRANCH                        76200013
PCIRT    L     FREG,0(X)           GET BUFFER ADDRESS FROM THE BRB      76230013
         SH    FREG,DSTART         SUBTRACT TO GET START OF PREFIX      76260013
         ST    FREG,4(X)           LINK BUFFER ADDRESS INTO BRB (CHAIN  76290013
*                                    BUFFERS AND BRB'S TOGETHER SO THAT 76320013
*                                    ALL CAN BE PUT ON READY QUEUE      76350013
*                                    SIMULTANEOUSLY                     76380013
         SPACE                                                          76410013
* IF LINE IS RECEIVING BUFFER GOES TO LPS                               76440013
         MVI   FPRI-FBLOCK(X),X'E4'  SET PRIORITY IN BRB                76470013
         LA    TREG,INTERM         GET ADDRESS OF INTERIM LPS QUEUE     76500013
         NI    MSTATUS,253         CLEAR END OF MESSAGE FLAG IN PREFIX  76530013
         SPACE                                                          76560013
* IF LINE IS SENDING BUFFER GOES TO AVAILABLE BUFFER QUEUE              76590013
         TM    MSTATUS,16          IS THIS AN OUTPUT MESSAGE            76620013
         BZ    PCIENT              BRANCH IF LINE IS NOT SENDING        76650013
         MVC   LCBCSEG,MSLINK      SAVE POINTER TO NEXT SEGMENT AS      76680013
*                                    CURRENT SEGMENT                    76710013
         LA    TREG,BUFFER       GET ADDRESS OF AVAILABLE BUFFER QUEUE  76740013
         MVI   FPRI-FBLOCK(X),X'E8' SET PRIORITY IN BRB                 76770013
PCIENT   ST    TREG,FKEY           PUT QCB ADDRESS INTO PREFIX          76800013
         LH    QREG,CNVT           GET COUNT OF 'BUFFERS LESS BRB'S'    76830013
         AH    QREG,ONE       ADD ONE                              00PS 76860016
         STH   QREG,CNVT           AND RESTORE                          76890013
         SPACE                                                          76920013
* PUT REQUEST FOR NEXT BUFFER INTO REQUEST QUEUE                        76950013
*  ENTRY POINT FROM LINE END APPENDAGE                                  76980013
NOBUF    NI    MSTIC+3-FBLOCK(X),252 MAKE NEXT BRB ADDRESSABLE TO       77010013
*                                      INDICATE BUFFER ASSIGNED         77040013
         LA    TREG,BREQ     GET ADDRESS OF ACTIVE BUFFER REQUEST QUEUE 77070013
         ST    TREG,0(X)           STORE ADDRESS IN FIRST WORD OF BRB   77100013
NOBUFY   XI    MSTIC+3-FBLOCK(X),2 SET FLAG IN TIC ADDRESS TO INDICATE  77130013
*                                    BRB IN ACTIVE BRB QUEUE            77160013
         SPACE                                                          77190013
*  ENTRY POINT FROM LINE END APPENDAGE                                  77220013
NOBUFX   MVC   FLINK,MSTIC+1-FBLOCK(X) MOVE TIC ADDRESS TO NEXT BLOCK   77250013
*                                    TO LCBCLPCI IF NO BUFFER HAS BEEN  77280013
*                                    ASSIGNED TO NEXT BRB. ELSE LINK    77310013
*                                    NEXT BRB INTO PREVIOUS BUFFER OR   77340013
*                                    BRB IN CHAIN                       77370013
         NI    FLINK+2,252         CLEAR STATUS BITS IN ADDRESS         77400013
         SPACE                                                          77430013
*  IF NEXT BLOCK IS AN INSERT BLOCK, REMOVE FROM BRB RING               77460013
         L     TREG,FLINK-1        GET ADDRESS OF NEXT BLOCK            77490013
CLOSE    CLI   MSTATUS-FBLOCK(TREG),128  IS IT AN INSERT BLOCK          77520013
         BNE   PCITEST             BRANCH IF NO                         77550013
         L     TREG,16(0,TREG)     ELSE ACCESS NEXT BLOCK FROM INSERT   77580013
*                                    BLOCK                              77610013
         ST    TREG,MSTIC-FBLOCK(X) AND REMOVE INSERT BLOCK FROM CHAIN  77640013
         OI    MSTIC+3-FBLOCK(X),2 INDICATE NEW BRB IS IN THE BUFFER    77670013
*                                    REQUEST QUEUE                      77700013
         B     CLOSE               BRANCH TO LOOK AT NEXT BLOCK         77730013
         SPACE                                                          77760013
*                        RETURN INSERT-CCW TO INSERT POOL               77790013
INSLOOP  CLC   17(3,X),MSTIC+1-FBLOCK(Y) WAS A CCW CONTAINING A PCI     77820013
*                                          MISSED                       77850013
         BE    PCIEXIT             BRANCH IF NO, THERE ARE NO FINISHED  77880013
*                                    INSERT BLOCKS TO BE RELEASED       77910013
RLSINSP  LR    FREG,X              GET FIRST PCI CCW ADDRESS            77940013
         L     X,16(FREG)          GET TIC ADDRESS TO NEXT BLOCK        77970013
         MVC   1(3,X),1(FREG)      LINK BUFFER INTO NEXT BLOCK          78000013
         LH    TREG,6(FREG)        GET DATA COUNT FROM INSERT BLOCK     78030013
         AH    TREG,6(X)           ADD IN DATA COUNT FROM NEXT BLOCK    78060013
         STH   TREG,6(X)           STORE IN NEXT BLOCK                  78090013
         MVC   FKEY(4),20(FREG)    MOVE QCB FOR INSERT QUEUE INTO FIRST 78120013
*                                    WORD OF INSERT BLOCK               78150013
         ST    X,FLINK-1           STORE ADDRESS OF NEXT BLOCK INTO     78180013
*                                    SECOND WORD OF INSERT BLOCK TO     78210013
*                                    CHAIN BLOCK TO NEXT BLOCK          78240013
         MVI   FPRI,X'E0'          SET PRIORITY IN INSERT BLOCK    8514 78270016
         SPACE                                                          78300013
* SCAN FOR BUFFERS USED SINCE LAST PCI                                  78330013
PCITEST  L     X,FLINK-1           GET THE ADDRESS OF THE NEXT BLOCK    78360013
         CLI   MSTATUS-FBLOCK(X),128 IS NEXT BLOCK AN INSERT BLOCK      78390013
         BE    INSLOOP             BRANCH IF YES                        78420013
         L     REG0,MSTIC-FBLOCK(0,X)   COMPARE FOR END OF LOOP   00PS  78430018
         X     REG0,MSTIC-FBLOCK(0,Y)    HAS BEEN REACHED          00PS 78440015
         BZ    PCIEXIT                 END OF LOOP                 00PS 78450015
         BCT   REG0,PKRCVR             NOT END OF LOOP,REPEAT LOOP 00PS 78460015
* THE SECOND BRANCH (BCT) DECREMENTS REG0 FIRST TO ACCOUNT FOR THE 00PS 78470015
* CASE WHERE MSTIC+3 HAS BITS SIX AND SEVEN 01.  THIS OCCURS WHEN  00PS 78480015
* PCI INTERRUPTS ACTIVATE BEFORE IT RESETS THE TWO BIT TO 00 .     00PS 78490015
         SPACE                                                          78510013
* UPDATE LCBCLPCI AND PUT BUFFER REQUEST                                78540013
*             BLOCKS AND BUFFERS ON THE READY QUEUE                     78570013
PCIEXIT  MVC   FLINK,READY+1       LINK ITEM AT TOP OF READY QUEUE INTO 78600013
*                                    THIS CHAIN                         78630013
         MVC   READY+1(3),LCBCLPCI LINK CURRENT CHAIN INTO READY QUEUE  78660013
         ST    X,IOSSAVE+4         STORE BRB ADDRESS                    78690013
         MVC   LCBCLPCI,IOSSAVE+5  MOVE 3 BYTE BRB ADDRESS TO LCB       78720013
         B     DISPATCH            BRANCH TO IECKQQ01                   78750013
         SPACE                                                          80610013
         TITLE 'LINE END APPENDAGE'                                     80640013
* LINE-END ROUTINE                                                      80670013
*      THIS ROUTINE IS AN I/O APPENDAGE ENTERED ON CHANNEL              80700013
* END DURING LINE I/O OPERATIONS.  NORMALLY THE ROUTINE                 80730013
* ROUTES A MESSAGE-FILLED BUFFER TO THE LPS QUEUE OR EXITS              80760013
* TO THE SUPERVISOR TO RESTART THE CHANNEL PROGRAM.                     80790013
*      WHEN ENTERED BECAUSE OF A NEGATIVE RESPONSE TO                   80820013
* POLLING, THE ROUTINE RESETS THE POLLING LIST POINTER TO               80850013
* THE NEXT ENTRY IN THE POLLING LIST BEFORE INITIATING                  80880013
* RESTART.  IF THE END OF THE POLLING LIST HAS BEEN                     80910013
* REACHED,  THE ROUTINE SETS THE 'CLEANUP' CODE IN THE LCB              80940013
* (LCBSTATE = 128).                                                     80970013
*      THIS ROUTINE MAY ALSO BE ENTERED AS A RESULT OF A                81000013
* PROGRAM CHECK OCCURRING BECAUSE A BUFFER WAS NOT PROVIDED             81030013
* ON TIME, OR BECAUSE A CCW WITH A ZERO DATA COUNT WAS                  81060013
* ACCESSED.  THE TWO LOW-ORDER BITS OF THE TIC COMMAND IN               81090013
* EACH BRB/CCW ARE USED TO INDICATE BRB STATUS.  WHEN A                 81120013
* BUFFER HAS BEEN ALLOCATED, THESE BITS ARE SET TO ZERO.                81150013
* BECAUSE OF TIMING CONSIDERATIONS, A PCI FLAG IN THE CCW               81180013
* PRECEDING A CCW CONTAINING A TIC MAY NOT INTERRUPT THE                81210013
* CHANNEL PROGRAM BEFORE THE TIC COMMAND IS                             81240013
* ACCESSED.  IF THIS HAPPENS BEFORE THE REQUIRED BUFFER HAS             81270013
* BEEN ALLOCATED AND THE BRB STATUS CODE HAS BEEN CLEARED,              81300013
* THE REQUIREMENT THAT THE TIC ADDRESS BE ON A DOUBLEWORD               81330013
* BOUNDARY IS VIOLATED BY THE NON-ZERO LOW ORDER BITS AND A             81360013
* PROGRAM CHECK OCCURS. FOUR POSSIBILITIES ARISE--                      81390013
*  1.  THE CHECK OCCURRED ON THE TIC FOLLOWING THE CCW FOR              81420013
*      THE LAST SEG OF AN OUT-GOING MSG.  THIS IS A                     81450013
*      NORMAL SITUATION AND IS IGNORED.  (THE MISSING                   81480013
*      BUFFER IS FOR THE 'NEXT' SEGMENT AND THERE IS NO                 81510013
*      NEXT SEG.)  IF THIS IS NOT THE CASE, THE 'START                  81540013
*      CHANNEL PROGRAM' POINTER  (LCBSTART) IS RESET TO THE             81570013
*      CCW TO WHICH THE TIC COMMAND WAS TO HAVE TRANSFERRED             81600013
*      CONTROL. THIS ANTICIPATES CORRECTION OF THE CONDITION.           81630013
*  2.  IT IS POSSIBLE THAT THROUGH ASYNCHRONOUS OPERATIONS              81660013
*      A BUFFER WAS ALLOCATED, AND THE TIC ADDRESS MADE                 81690013
*      VALID, IN THE PERIOD BETWEEN THE PROGRAM CHECK'S                 81720013
*      GENERATION AND ITS DETECTION BY THE PROG.  IF                    81750013
*      THIS IS TRUE, THE CHANNEL PROGRAM IS SIMPLY RESTARTED.           81780013
*                                                                       81810013
*  3.  THE PROCESS OF ALLOCATING A BUFFER MAY ALREADY HAVE              81840013
*      BEEN INITIATED. IF SO, THE ROUTINE EXITS TO THE I/O              81870013
*      SUPERVISOR TO ALLOW TIME FOR THE PROCESS TO COMPLETE.            81900013
*  4.  IF THE PROCESS OF ALLOCATING A BUFFER HAS NOT                    81930013
*      ALREADY BEEN INITIATED, THE ROUTINE BRANCHES TO THE              81960013
*      LINE-PCI ROUTINE (AT NOTINQ) TO RELEASE THE BUFFER               81990013
*      FILLED BY THE CCW IMMEDIATELY PRECEDING THE TIC THAT             82020013
*      CAUSED THE PROGRAM CHECK.                                        82050013
         SPACE                                                          82080013
*  ENTRY POINT FROM LINE SIO APPENDAGE                                  82110013
ENDLIST  MVI   LCBSTATE-LCB(10),X'80'  SET CLEANUP CODE IN LCBSTATE     82140013
         OI    LCBECBPT-LCB(10),X'F0'  SET TO INDICATE FROM LINE SIO    82170013
         DROP  15                                                       82200013
         USING TTBASE,13                                                82230013
         LA    11,RESPCCW+8                  SET CSW IN LCB TO POINT    82260013
         DROP  13                                                       82290013
         ST    11,LCBCSW-LCB(0,10)             TO CCW FOLLOWING RESPCCW 82320013
         BALR  15,0                SET UP BASE REGISTER                 82350013
         SPACE 2                                                        82380013
*                        ENTER HERE FROM I/O FLIH.                      82410013
         SPACE  2                                                  000C 82416017
*              ENTER HERE FROM WTTA LINE APPENDAGE(IGG019QB)       000C 82422017
*              THE REGISTER 10 CONTAINS THE RETURN ADDRESS         000C 82428017
         SPACE  2                                                  000C 82434017
         USING LINEEND,15                                               82440013
LINEEND  L     Z,QTAMBASE   GASE FOR IGG019NG                      000D 82460016
         L     15,BASE            ADJUST BASE REGISTER             00PS 82480018
         USING TTBASE,15                                                82500013
         LA    14,4(14)            BUMP RETURN REGISTER BY 4            82530013
         USING IGG019NG,Z                                               82590013
         L     BREG,QQPTR               GET ADDRESS OF QQPTR            82620013
         STM   14,9,IOSSAVE        SAVE FOR REENTRY TO I/O FLIH         82650013
         LR    LCBREG,2            GET POINTER TO IOB PASSED BY IOS     82680013
         SH    LCBREG,LCBSZ        RESET TO POINT TO LCB HEAD           82710013
         CLI   LCBCPA-LCB-48+1(2),254 ENTRY DUE TO SAD/ENABLE COMMANDS  82740013
         BNH   TRYEXIT            BRANCH NOT SAD ENABLE OR IS SAD       82770013
         MVI   LCBCECB,X'E4'      RESET TO LOWER PRIORITY          00PS 82771020
         MVI   LCBCPA+1,0          RESET STARTLN FLAG            A35209 82772020
         TM    LCBCPA+44,X'FE'     IS THIS OPEN TIME             A28763 82773019
         BO    *+14                    NO                          000C 82776017
         LA    FREG,0(LCBREG)          LOAD FREG FOR QPOST         000C 82779017
         LR    TREG,FREG               POST LCB TO ITSELF          000C 82782017
         B     POST                                                000C 82785017
         MVC   FLINK-FBLOCK(3,LCBREG),READY+1  QUEUE SIO REQUEST   7814 82790016
         LA    LCBREG,0(LCBREG)   ENSURE FIRST BYTE IS ZERO        7814 82810016
         ST    LCBREG,READY       PLACE REQUEST ON READY QUEUE     7814 82830016
         ST    LCBREG,LCBENDOP-1  POST LCB TO ITSELF               7814 82850016
         BR    14                 RETURN TO  IOS                   7814 82870016
TRYEXIT  BCR   8,14               RETURN TO IOS IF ENTRY FOR SAD/ENABLE 82890013
         L     TREG,LCBCSW         GET CCW ADDRESS + 8             000D 82900018
         SH    TREG,K8             BACK UP TO FAILING CCW          000D 82910018
         TM    LCBCPA,X'FF'            TERMINAL TEST ACTIVITY           82920013
         BC    12,NOTEST           BRANCH IF NO                    000D 82950018
         L     FREG,LCBCPA+4           LOAD TEST BUFFER ADDRESS         82980013
         CLI   0(TREG),2           READ COMMAND                    000D 82983018
         BNE   LPSDRCT+6           BRANCH IF NO                    000D 82986018
         CLI   7(TREG),2           TWO CHARACTER RESPONSE          000D 82989018
         BNE   LPSDRCT+6           BRANCH IF NO                    000D 82992018
         CLI   LCBCSW+7,1          IS RESIDUAL COUNT ONE           000D 82995018
         LA    TREG,8(TREG)        SET TO RESTART CHANNEL PROGRAM  000D 82998018
         BE    LNRESTR             GO TO RESTART CHANNEL PROGRAM   000D 83001018
         B     LPSDRCT+6               GO TO POST BUFFER TO LPS QUEUE   83010013
NOTEST   EQU   *                                                   000D 83020018
         L     X,LCBCLPCI-1        GET BRB/CCW ADDRESS FOR WHICH THE    83040013
*                                    THE LAST PCI WAS SERVICED (POINTS  83070013
*                                    TO CURRENT BRB/CCW AT THIS TIME    83100013
*                                    SINCE THIS ROUTINE WAS ENTERED     83130013
*                                    AFTER LCBCLPCI HAD BEEN UPDATED    83160013
*                                    BY LINE PCI APPENDAGE)             83190013
         B     LECT               CONTINUE CHECKS                A39104 83250020
CHECK0   L     TREG,LCBSTART-1    GET CCW ADDRESS TO RESTART ON    00PS 83316018
         CLC   5(3,TREG),TXTRANS  IS THIS A TEXT TRANSFER WITH     00PS 83322018
*                                 WITH ZERO COUNT                  00PS 83328018
         BNE   LNRESTR+4          NO RESTART CHANNEL PROGRAM       00PS 83334018
LECT     L     FREG,0(X)           GET THE BUFFER ADDRESS FROM THE BRB  83340013
         SH    FREG,DSTART         ADJUST TO START OF BUFFER FOR BASE   83370013
         LH    Y,6(X)              GET THE BUFFER COUNT                 83400013
         LA    Y,TXSTRT-MSEGSZE(Y) BUMP COUNT BY AMOUNT EQUAL TO TEXT   83430013
*                                    PREFIX MINUS ECB                   83460013
         L     SPREG,LCBDCBPT          GET DCB ADDRESS             000C 83520717
         TM    DCBCPOLL-IHADCB(SPREG),X'68'  IS IT A WTTA LINE     000C 83521417
         BNO   NOTWTTA                 NO                          000C 83522117
         TM    LCBECBPT,X'F0'          WAS ENTRY FROM LINE SIO     000C 83522817
         BO    NOTWTTA                  YES,CONTIMUE PROCESSING    000C 83523517
         BAL   5,4(10)                  EXIT  TO WTTA LINE APPEND. 000C 83524217
*                             RETURNS FROM WTTA APPENDAGE          000C 83524917
         B     LPSDRCT               ...POSTS TO INTERIM LPS       000C 83525617
         B     LPSDRCT+6            ...POSTS TO LPS                000C 83526317
         B     LNRESTR              ...RESTART CHANNEL PROGRAM     000C 83527017
         B     ERP                  ...GO TO ERP                   000C 83527717
NOTWTTA  EQU   *                                                   000C 83528417
         CLI   LCBECBPT,X'48'          IS THIS INTERRUPT FROM HIO  00PS 83530015
         BE    AGAIN2                  BRANCH IF YES               00PS 83540015
         CLI   LCBECBPT,X'7F'          CHECK COMPLETION CODE            83550013
         BNE       PERMERR             NOT NORMAL                       83580013
         TM    LCBCSW+5,X'20'          PROGRAM CHECK                    83610013
         BO    AGAINRET           YES, CAUSED BY QTAM TIC BUT    A39104 83630020
*                                 CHECK FOR AUTOPOLL             A39104 83650020
         TM    LCBCSW+4,X'F2'          CHECK STATUS                     83670013
         BNZ   ERP                     ABNORMAL                         83700013
         TM    LCBCSW+5,X'1F'          SECOND STATUS BYTE               83730013
         BNZ   ERP                     ABNORMAL                         83760013
         TM    LCBCSW+4,X'0D'          UNIT EXCEPTION                   83790013
         BNO   AGAINRET                 NO, NORMAL END                  83820013
         CLI   0(TREG),X'27'       ENABLE CCW HALTED               00PS 83840015
        BE    AGAIN2              BRANCH IF YES                    00PS 83860015
         CLI   0(TREG),6          PREPARE CCW HALTED               6646 83866016
         BE    AGAIN2               BRANCH YES                     6646 83872016
        CLI   0(TREG),2           READ CCW                         00PS 83880015
        BNE   ERP                 BRANCH IF NO                     00PS 83900015
        CLI   5(TREG),32          READ RESPONSE TO POLLING         00PS 83920015
        BNE   AGAINRET            BRANCH IF NO                     00PS 83940015
ERP      OI    LCBFLAG1,4          SET FLAG TO CALL ERP            000D 83960018
         LM    14,9,IOSSAVE        RESTORE REGISTERS               000D 83980018
         SH    14,FOUR                 RETURN TO IOS+0                  84000013
         BR    14                      TO IOS TO CALL ERP               84030013
PERMERR  BH    LNSIOENT                FROM LINE SIO                    84060013
         CLI   LCBCPA+4,255            SPECIAL FLAG FOR SIO CC 3        84090013
         BE    LPSDRCT+6               FREE BUFFERS AND                 84120013
*                                        DO NOT USE LINE TILL A         84150013
*                                        STARTLN IS ISSUED              84180013
         TM    LCBCECB,X'03'      READ CONTINUE OR READ REPEAT?    4391 84210016
         BO    NEGRESPX      IF YES, TEXT SEGMENT , SO SEND TO LPS 4391 84240016
         OI    LCBINCAM,4          SET POLLING/ADDRESSING ERROR   22743 84260018
AGAINRET EQU   *                                                   2202 84290015
         TM    LCBERCCW,X'40'     IS THIS A HEADER BUFFER ON     A39104 84290620
*                                 AUTOPOLL LINE                  A39104 84291220
         BZ    NOTAUTO            IF NOT, CONTINUE               A39104 84291820
         XI    LCBERCCW,X'40'     CLEAR HEADER BUFFER INDICATOR  A39104 84292420
         B     PCIAP              SET UP FOR AUTOPOLL            A39104 84293020
NOTAUTO  TM    LCBCSW+5,X'20'     RECHECK FOR PROGRAM CHECK      A39104 84293620
         BO    PGMCHK             HANDLE CHANNEL PROGRAM CHECK   A39104 84294220
         CLI   5(TREG),8          IS THIS WRITE (D) CCW          A26763 84295019
         BNE   LOADPCI            NO, CONTINUE NORMAL PROCESSING A26763 84300019
         OI    4(TREG),X'80'      TURN ON CHAINING FOR LATER TESTA26763 84305019
         CLI   LCBECBPT,X'7F'     IS THIS NORMAL COMPLETION      A26763 84310019
         MVC   LCBSTART(3),LCBCSW+1      SET RESTART ADDRESS     A26763 84315019
         BE    RESREG             YES, RESTART ON WRITE DATA     A26763 84320019
LOADPCI  EQU  *                                                  A26763 84325019
         TM    LCBFLAG2,X'01'      IS THIS AN AUTOPOLL LINE             84330013
         BO    APTST               IF YES BRANCH                        84360013
AGNRT    CLC   4(2,TREG),H6        ANY CHAINING FLAGS ON IN READ   000D 84360918
*                                   RESPONSE TO ADDRESSING CCW     000D 84361818
         BNE   AGNRT2              BRANCH IF YES                   000D 84362718
         L     SPREG,0(TREG)      PREPARE TO LOOK AT RESPONSE      000D 84363618
*                                   CHARACTER                      000D 84364518
*                                                                  000D 84367218
*   CHECK RESPONSE CHARACTERS TO DETERMINE IF SENDING IS POSSIBLE  000D 84368118
*                                                                  000D 84369018
         NI    0(SPREG),X'7F'     TURN OFF PARITY BIT              000D 84369918
*                                                                  000D 84371920
*   FOR POSITIVE RESPONSE, RE-CHAIN SEND SCHEDULER TO PREVENT      000D 84373920
*  UNPRODUCTIVE ADDRESSING OPERATION ON NEXT MESSAGE.              000D 84375920
*                                                                  000D 84378018
SENSE    CLI   0(SPREG),8         BUFFER PRINT,BID,OR ENTER MODE   000D 84378918
         BH    ERP                 BRANCH IF NO                    000D 84379818
*                                                                  000D 84380718
*   RESCHEDULE WRITE OPERATION FOR FOLLOWING SENSE CHARACTERS      000D 84381618
*        X'02' - ENTER MODE, COMMUNICATE MODE                      000D 84382518
*        X'04' - BID MODE                                          000D 84383418
*        X'08' - BUFFER PRINT, COMMUNICATE MODE                    000D 84384318
*                                                                  000D 84385218
*   PLACE SEND SCHEDULER AT END OF STCB CHAIN TO ALLOW RECEIVING   000D 84386118
*                                                                  000D 84387018
RMVSTCB  LA    X,4(LCBREG)         INITIALIZE FOR LOOP             000D 84387918
STCBLOOP L     Y,4(X)              GET ADDRESS OF NEXT WAITING     000D 84388818
*                                   SUBTASK IN CHAIN               000D 84389718
         CLI   0(Y),X'68'          IS THIS THE SEND SCHEDULER      000D 84390618
         BE    REMOVE              BRANCH IF YES                   000D 84391518
         CLI   4(Y),X'FF'          IS THIS THE DUMMY END ELEMENT   000D 84392418
         BE    SETCLEAN            EXIT TO ALLOW CLEANUP           000D 84393318
         LR    X,Y                 ELSE RETURN TO LOOK             000D 84394218
         B     STCBLOOP             AT NEXT ENTRY                  000D 84395118
REMOVE   MVC   5(3,X),5(Y)         REMOVE SEND SCHEDULER FROM STCB 000D 84396018
*                                   CHAIN                          000D 84396918
ENDLOOP  L     TREG,4(X)           GET LINK ADDRESS TO NEXT STCB   000D 84397818
         CLI   4(TREG),X'FF'       IS THIS THE DUMMY END ELEMENT   000D 84398718
         BE    SETSEND             BRANCH IF YES                   000D 84399618
         CLI   0(SPREG),4         IS THIS BID MODE                 000D 84399718
         BE    CLOSEPRI           YES,BYPASS PRIORITY CHECK        000D 84399818
         CLC   4(1,TREG),4(Y)     IS THIS PRIORITY INSERTION POINT29193 84399919
         BL    SETSEND            YES, CHAIN SEND SCHEDULER        000D 84400018
CLOSEPRI  EQU  *                                                        84400118
         CLI   4(TREG),0           IS THIS STCB FOR CLOSEDOWN      000D 84400518
         BE    SETSEND             YES, CHAIN SEND SCHEDULER BEFORE000D 84401418
*                                    STCB FOR CLOSEDOWN            000D 84402318
         LR    X,TREG              ELSE RETURN TO LOOK             000D 84403218
         B     ENDLOOP              AT NEXT ENTRY                  000D 84404118
SETSEND  IC    REG0,4(Y)           SAVE PRIORITY OF SEND SCHEDULER 000D 84405020
         ST    TREG,4(Y)           POINT SEND SCHEDULER STCB TO    000D 84405918
*                                   DUMMY END ELEMENT              000D 84406818
         STC   REG0,4(Y)           RESTORE PRIORITY OF SEND        000D 84407720
*                                   SCHEDULER                      000D 84408618
         IC    REG0,4(X)           SAVE PRIORITY OF NEXT-LAST      000D 84409520
*                                   ELEMENT                        000D 84410418
         ST    Y,4(X)              PLACE SEND SCHEDULER AT END     000D 84411318
*                                   OF CHAIN                       000D 84412218
         STC   REG0,4(X)           RESTORE PRIORITY OF ELEMENT     000D 84412420
         MVC   LCBSTART,LCBCSW+1   RESET LCBSTART TO START ON      000D 84412620
*                                   WRITE DATA CCW                 000D 84412820
         TM    1(SPREG),X'76'      IS SECOND RESPONSE CHARACTER    000D 84413020
*                                   A CIRCLE Y                     000D 84413220
         BO    RESREG              YES, RESTART ON WRITE COMMAND   000D 84413420
         MVI   LCBCPA+29,X'FF'     SET CODE FOR RETRANSMITION TO   000D 84414018
*                                  2740 MODEL 2                    000D 84414221
         L     X,LCBENDOP-1       GET ORIGINATING LCB ADDRESS    A46042 84414421
         CLI   0(X),X'03'         IS IT A QCB OR LCB             A46042 84414621
         BE    ADERR              BRANCH IF QCB                  A46042 84414821
         TM    LCBSORCE+2-LCB(X),3  IS NEXT SEG NOT RECEIVED     A46042 84415021
         BNZ   ADERR              NO, NOT IN INITIATE MODE       A46042 84415221
         OI    LCBSORCE+2-LCB(X),2   SET FLAG FOR DEST. DASD     A46042 84415421
         B     ADERR               EXIT TO SEND BUFFER TO LPS      000D 84415818
AGNRT2   CLC   0(4,TREG),0(X)      CCW = LAST SERVICED PCI         000D 84416718
         BE    NEGRESPX                YES                              84420013
         CLI   8(TREG),8               NEXT CCW A TIC.  DATA TRANSFER   84510013
         BNE   CDCHAIN            NO                             A27524 84520019
         CLI   LCBCECB,1          READ INITIAL?                  A27524 84530019
         BNE   NEGRESPX           BRANCH IF NO                   A27524 84540019
         CLC   6(2,TREG),LCBCSW+6 COUNT=RESIDUAL COUNT           A27524 84550019
         BNE   NEGRESPX           BRANCH NO                      A27524 84560019
CDCHAIN  TM    4(TREG),X'C0'      COMMAND OR DATA CHAINING       A27524 84570019
         BNZ   POLRESTR                YES                              84600013
AGAIN2   SH    Y,MSEGSZE       NOW Y = COUNT+PREFIX SIZE-SEGMENT SIZE   84630013
         CLI   LCBCPA+16,4        SENSE CCW FOR 2740 BASIC         6646 84640016
         BE    POLLZERO-4          BRANCH YES (HALTED PREPARE)    18930 84650017
         CLI   LCBCPA+8,X'27'          ENABLE CCW                       84660013
         BNE   TWXID                   NO CHECK FOR TWX                 84690013
         OI    LCBINCAM,2      SET FLAG INDICATING LINE IS UNAVAILABLE  84720013
         BAL   SPREG,SETPP         BRANCH WITH POINTER TO POLLZERO      84750013
POLLZERO DC    H'0'                                                     84780013
         SPACE                                                          84810013
TWXID    CLI   5(TREG),7               TWX ID RESPONSE CCW              84840013
         BNE   CTREST                  NO                               84870013
         L     SPREG,0(TREG)       GET BUFFER ADDRESS FROM BTAM CCW     84900013
         LH    LGREG,6(TREG)       GET COUNT FROM CCW                   84930013
         LA    QREG,0(SPREG,LGREG) GET BUFFER ADDRESS PLUS COUNT        84960013
         BCTR  LGREG,0             DECREMENT COUNT FOR EXECUTE          84990013
         EX    LGREG,IDCOMP        CAUSE TWX ID RECEIVED FROM TERMINAL  85020013
*                                    TO BE COMPARED WITH EXPECTED VALUE 85050013
         BE    SETPP+4                                                  85080013
ADERR    OI    MSTATUS,X'70'       SET TO BYBASS HEADER ROUTINES        85110013
*                      X'40'     PREVENTS SENDING A RESPONSE IN         85140013
*                                THE EOB MACRO                          85170013
*                      X'20'     TESTED IN THE RECEIVE HEADER           85200013
*                                MACRO TO PREVENT PROCESSING            85230013
*                                THE HEADER ROUTINES                    85260013
*                      X'10'     TESTED IN POSTRCVE SO THAT THE         85290013
*                                MESSAGE WILL BE POSTED TO THE          85320013
*                                EMPTY BUFFER QUEUE RATHER THAN         85350013
*                                THE DESTINATION QUEUE                  85380013
         OI    LCBERRST+1,8        SET DATA CHECK, TIME OUT, OR         85410013
*                                    NEGATIVE RESPONSE                  85440013
         OI    LCBINCAM,4          SET POLLING/ADDRESSING ERROR FLAG    85470013
NOTSEND  SR    Y,Y                CLEAR WORKING REGISTER           00PS 85510018
CTREST   STH   Y,LCBCSW+6          ZERO COUNT                           85530013
         CLI   LCBECBPT,X'7F'          WAS ENTRY FROM LINE SIO          85560013
         BH    NEGRESPX-4              YES, BYPASS COMPARE              85590013
         CLC   LCBCSW+1(3),RESPAD  EOB RESPONSE                         85620013
         BNE   NOEOB               NO, SKIP CHECK FOR BUFFER       000D 85627018
*                                    OVERFLOW                      000D 85634018
         TM    LCBCSW+4,X'0D'      UNIT EXCEPTION ON READ RESPONSE 000D 85641018
         BNO   LPSDRCT+6           NO, POST BUFFER TO LPS          000D 85648018
         OI    LCBERRST,8          ELSE SET BUFFER OVERFLOW        000D 85655018
         B     LPSDRCT+6           AND POST BUFFER TO LPS          000D 85662018
NOEOB    EQU   *                                                   000D 85669018
         LH    Y,LCBTRST           GET OFFSET OF FIRST CHARACTER        85680013
         SPACE                                                          85710013
NEGRESPX SH    Y,LCBCSW+6          SET OFFSET IN BUFFER OF NEXT         85740013
         STH   Y,MSEGSZE             UNTRANSMITTED OR AVAILABLE         85770013
*                                      CHARACTER POSITION               85800013
         TM    LCBSTATE,4          IS LINE SENDING                      85830013
         BZ    LPSDRCT             BRANCH IF NO                         85860013
         LA    TREG,RESPCCW        ACCESS RESPCCW FOR WRITE EOB         85890013
         OC    LCBCSW+6(2),LCBCSW+6    IS RESIDUAL COUNT ZERO     21858 85910018
         BE    AAA                 BRANCH IF YES                   00PS 85930015
         CLI   LCBECBPT,X'41'      WAS PERMANENT ERROR POSTED      00PS 85940015
         BNE   LNRESTR-4           BRANCH IF NO                         85950013
         TM    LCBSENSE,X'40'      IS THIS INTERVENTION REQUIRED   00PS 85957015
         BO    LPSDRCT+6     BRANCH IF YES TO AVOID READ RESPONSE  00PS 85964015
AAA      EQU   *                                                   00PS 85971015
         TM    MSTATUS,X'70'      HERE FOR AN EOB                A29182 85973019
         BO    LPSDRCT+6          BRANCH IF NO -A POLLING OR     A29182 85975019
*                                 ADDRESSING ERROR               A29182 85977019
         AR    Y,FREG              ELSE GET ADDRESS IN BUFFER OF LAST   85980013
*                                    CHARACTER PLUS ONE                 86010013
         L     X,IOSSAVE+36        LOAD UCB ADDRESS               21856 86017018
         TM    19(X),X'40'         DOES UNIT HAVE IBM ADAPTER      00PS 86024016
         BO    LPSDRCT+6           BRANCH NO TO AVOID READ RESPONSE00PS 86031016
         TM    MSEGSZE-1-FBLOCK(Y),X'3D' IS LAST CHARACTER AN EOB       86040013
*                                    ('MSEGSZE-1-FBLOCK' ADJUSTS FOR    86070013
*                                    THE ECB PRECEDING THE PREFIX)      86100013
         BC    3,ANDOUT                BRANCH IF YES                    86130013
         CLI   MSEGSZE-1-FBLOCK(Y),X'03' NOT ETX                        86160013
         BNE   LPSDRCT+6               BRANCH IF NO                     86190013
         L     Y,LCBDCBPT          LOAD ADDRESS OF DCB                  86220013
         TM    DCBCPOLL,X'70'      TEST FOR 2260                        86250013
         BC    7,LPSDRCT+6         BRANCH IF NOT 2260 TO INTERIM LPS    86280013
ANDOUT   NI    LCBERRST+1,127          CLEAR DATA CHK,TIMEOUT, OR       86310013
*                                    NEGATIVE RESPONSE                  86340013
LNRESTR  ST    TREG,LCBSTART-1     SET CHANNEL PROGRAM RESTART ADDRESS  86370013
RESREG   NI    LCBFLAG1,X'FB'          TURN OFF IOB EXCEPTION FLAG 00PS 86400015
         LM    14,9,IOSSAVE            RESTORE REGISTERS           00PS 86430015
         B     4(14)  RETURN TO I/O FLIH TO RESTART CHANNEL PROGRAM     86460013
LNSIOENT SH    Y,MSEGSZE      Y = COUNT+PREFIX SIZE-SEGMENT SIZE        86490013
         B     CTREST                  CONTINUE NORMAL FLOW             86520013
         SPACE                                                          86550013
* CHANNEL PROGRAM CHECK - BUFFER NOT PROVIDED ON TIME                   86580013
PGMCHK   XC    LCBCSW+6(2),LCBCSW+6  ZERO THE COUNT IN LCBCSW           86610013
         CLI   0(TREG),X'08'           IS THE CCW A TIC            00PS 86620015
         BE    ITSATIC                   BRANCH IF YES             00PS 86630015
         TM    4(TREG),128   IS THE CHAIN DATA FLAG ON IN THE CCW  00PS 86640015
*                                    FOR WHICH THERE WAS A PROGRAM      86670013
*                                    CHECK - IF NO, IT HAS BEEN TURNED  86700013
*                                    OFF AS A RESULT OF DETECTING THE   86730013
*                                    LAST SEGMENT OF THE MESSAGE IN THE 86760013
*                                    ACTIVATE ROUTINE.  IF THIS IS THE  86790013
*                                    LAST SEGMENT OF AN OUTGOING        86820013
*                                    MESSAGE, IGNORE THE PROGRAM CHECK  86850013
*                                    CAUSED BY AN INVALID TIC ADDRESS.  86880013
         BZ    NEGRESPX            BRANCH IF NO TO IGNORE PROGRAM CHECK 86910013
ITSATIC  EQU   *                                                   00PS 86920015
         TM    LCBSTATE,4          IS THE SEND BIT ON FOR THE LINE      86940013
         BNZ   NOERROR             BRANCH IF YES                        86970013
         TM    LCBSTATE,8          IS THE RECEIVE BIT ON FOR THE LINE   87000013
         BZ    NEGRESPX            BRANCH IF NO                         87030013
         OI    LCBERRST+1,144      SET INSUFFICIENT BUFFERS FLAG ON IN  87060013
*                                    LCB ALONG WITH TRANSMISSION ERROR  87090013
*                                    SET PREVIOUSLY                     87120013
NOERROR  LR    FREG,TREG               ACCESS FAILING CCW          00PS 87130015
         SH    FREG,K16           INITIALIZE LOOP TO LOCATE START  00PS 87140015
*                                        OF BRB THAT PROGRAM CHECK 00PS 87150015
*                                       OCCURRED IN                00PS 87160015
FINDTIC  LA    FREG,8(0,FREG)          INCREMENT TO NEXT CCW       00PS 87170015
         CLI   8(FREG),8               IS SECOND-NEXT CCW A TIC    00PS 87180015
         BNE   FINDTIC                   NO,LOOP                   00PS 87190015
         MVC   LCBSTART,MSTIC+1        GET TIC ADDRESS OF NEXT BRB 00PS 87200015
         TM    LCBSTART+2,3            WAS BUFFER ACTUALLY ASSIGNED00PS 87210015
*                             SINCE PROGRAM CHECK OCCURRED         00PS 87220015
         BZ    CHECK0              YES, RESTART CHANNEL PROGRAM    00PS 87230018
         LR    Y,FREG             INITIALIZE WITH CCW PRECEDING    00PS 87250015
*                                        THE FAILING TIC           00PS 87260015
         LA    FREG,LCBCLPCI-5    INITIALIZE FOR FOLLOWING BRANCH  00PS 87270015
         CLI   MSTATUS-FBLOCK(X),128 IS THIS AN INSERT BLOCK OR BRB6497 87273016
         BE    INSLOOP               BRANCH IF INSERT BLOCK        6497 87276016
         NI    MSTIC+3,X'FE'       MAKE NEXT BRB ADDRESSABLE      M3140 87278018
         TM    MSTIC+3-FBLOCK(X),2     HAS A BUFFER BEEN REQUESTED 00PS 87280015
*                                    FOR THE NEXT BRB              00PS 87290015
         BO    NOBUFY                  NO                          00PS 87300015
* IF BRB IN FREG WAS FIRST BRB IN THE RING, AND NO BUFFER WAS RE-  00PS 87310015
* QUESTED FOR SECOND BRB, BRANCH TO AVOID RELEASING FIRST BRB'S    00PS 87320015
*   BUFFER                                                         00PS 87330015
          SPACE                                                         87340015
NOT1ST   L     Y,MSTIC-FBLOCK(Y)  GET ADDRESS OF NEXT BRB'S CCW    00PS 87350015
         N     Y,ADCLR        CLEAR LOW ORDER BITS OF ADDRESS      6482 87355016
         CLI   MSTATUS-FBLOCK(Y),128   IS THIS INSERT BLOCK      A65111 87356021
         BNE   NOT1STCN          NO, IT'S BRB, CONTINUE          A65111 87357021
         LA    Y,8(0,Y)          ADJUST POINTER FOR INSERT BLK   A65111 87358021
         B     NOT1ST            GO LOOK FOR NEXT BRB            A65111 87359021
NOT1STCN TM    MSTIC+3-FBLOCK(Y),1  DOES SECOND-NEXT BRB HAVE A  A65111 87365021
*                                  BUFFER IN LPS OR DISK QUEUE     00PS 87370015
         BZ    RLPREV                    NO                        00PS 87380015
         CLI   MSTATUS-FBLOCK(Y),9     IS BUFFER IN DISK OPERATION 00PS 87390015
         BNE   REENT               NO,BRANCH TO EXIT INTERFACE RTNE00PS 87400015
* BUFFER WAS NOT FOUND.  IF ONE IS ON ITS WAY,WAIT FOR IT TO       00PS 87410015
* BE ASSIGNED.                                                     00PS 87420015
         SPACE                                                          87430015
RLPREV   LA    TREG,LCBCLPCI-9     SET TIC POINTER FOR FIRST TIME       87570013
         ST    TREG,LCBCLCCW         (SEE BRB RING ROUTINE)             87600013
         SPACE                                                          87630013
*  ENTRY POINT FROM LINE PCI APPENDAGE WHEN A PCI WAS MISSED            87660013
PKRCVR   TM    MSTIC+3-FBLOCK(X),2     IS BUFFER ALREADY ASSIGNED  00PS 87690015
*                                        TO THE BRB                00PS 87720015
         BZ    NOTINQ             BRANCH TO FREE BUFFER AND GET    00PS 87750015
*                                        ANOTHER FOR SAME BRB      00PS 87780015
         SPACE                                                          87810015
* PUT BRB IN ACTIVE BUFFER REQUEST QUEUE WITH HIGH PRIORITY        00PS 87840015
         TM    MSTIC+3-FBLOCK(X),1  IS BRB IN ACTIVE BUFFER REQ. Q.00PS 87870015
         BZ    NOBUFX                  BRANCH TO LINE PCI TO AVOID 00PS 87900015
*                                        PUTTING IT IN QUEUE       00PS 87930015
         LR    FREG,X              PUT BRB ADDRESS IN FREG              87960013
         MVI   FPRI,X'EC'          MOVE HIGH PRIORITY INTO BRB          87990013
         B     NOBUF               BRANCH TO LINE PCI ROUTINE           88020013
         SPACE                                                          88050013
IDCOMP   CLC   0(1,SPREG),0(QREG)  COMPARE RECEIVED TWX ID              88080013
         SPACE                                                          88110013
         SPACE                                                          88140013
POLRESTR SH    TREG,K16                SET UP CCW ADDR FOR RESTART      88170013
         TM    LCBCECB,X'01'      IS THIS A RECEIVE OPERATION      3368 88200015
         BZ    ADERR              BRANCH IF NO                     3368 88230015
         CLI   LCBCPA+8,X'27'     IS THIS A DIAL LINE              3368 88260015
         BE    ADERR              BRANCH IF YES                    3368 88290015
         TM    LCBINCAM,1          IS LINE TRYING TO SEND (SET IN 21849 88296018
*                                   SEND SCHEDULER SO ANOTHER     21849 88302018
*                                   POLL WILL NOT TAKE PLACE)     21849 88308018
         BO    SETCLEAN            YES, FREE BUFFERS              21849 88314018
LOOPSET  LA    Y,0(0,TREG)        LOAD ADDRESS OF CCW              4778 88320016
         LA    TREG,LCBCPA-8             TO INDICATE               3368 88350015
LOOPW1   LA    TREG,8(0,TREG)     WRITE POLLING CHARACTERS CCW     3368 88380015
         CLI   13(TREG),X'03'            TO RESTART ON             3368 88410015
         BE    OUTW1                     IS IT FOUND--YES          3368 88440015
         CR    TREG,Y                  NO--IS LOOP DONE            3368 88470015
         BL    LOOPW1                   NO--LOOP AGAIN                  88500013
OUTW1    L     Y,LCBDCBPT              ACCESS DCB                       88530013
         TM    DCBCPOLL,X'70'          IS THIS A 2260 LINE              88560013
         BNE   INCRPPTR                 NO                              88590013
         LA    TREG,LCBCPA-8            YES, RESTART ON WRITE EOT CCW   88620013
*             PREPARE TO RESTART WITH NEW POLL ENTRY                    88650013
INCRPPTR L     SPREG,LCBPOLPT-1    * INCREMENT                          88680013
         LA    SPREG,2(0,SPREG)   *          POLL                       88710013
         TM    LCBFLAG2,1          IS THIS AN AUTOPOLLED LINE     23159 88720018
         BO    SETPP+4             YES, DON'T INCREMENT POLL PTR. 23159 88730018
SETPP    ST    SPREG,LCBPOLPT-1                                         88740013
         LA    TREG,8(TREG)            BUMP TO NEXT CCW                 88770013
         CLI   LCBECBPT,X'7F'     WAS A PERMANENT ERROR POSTED     00PS 88780015
         BE    LNRESTR            BRANCH IF NO                     00PS 88790015
         CLI   LCBECBPT,X'48'      INTERRUPT FROM HIO             19663 88798017
         BNE   ADERR               BRANCH IF NO                   19663 88806017
SETCLEAN MVI   LCBSTATE,X'80'      SET CLEANUP CODE IN LCBSTATE   19663 88814017
         B     ADERR               GO TO FREE BUFFERS             19663 88822017
*                                                                       88830013
* PERMIT A SEND OPERATION ON AN AUTOPOLL LINE                           88860013
*                                                                       88890013
APTST    TM    LCBSTATE,X'08'     IS LINE IN RECEIVE STATE         4989 88920016
         BZ    AGNRT              IS NO RETURN                     4989 88950016
         TM    LCBECBPT,X'7F'     IS THIS A PERMANENT ERROR        4989 88980016
         BO    APCONV              BRANCH IF NO                    00PS 89010017
         CLI   5(TREG),17         IS THIS A TEXT MODE ERROR       20401 89030017
         BNL   AGNRT              BRANCH IF YES                   20401 89050017
         MVI   LCBERRCT,3         ELSE SET ERRCT SO READ WRITE    20401 89070017
*                            WILL RESTART POLLING ON NEXT ENTRY   20401 89090017
         MVC   LCBPOLPT(3),LCBCPA+9                                4989 89130016
         B     ADERR               GO SEND CONTROL MODE ERROR THRU 4989 89160016
*                                       LPS WITH SERVICED BIT SET  4989 89190016
APCONV   EQU   *                                                   00PS 89200017
         CLI   LCBCPA+8,X'03'      FIRST INTERRUPT AFTER CONVERSE       89220013
         BE    SETCLEAN            BRANCH IF YES                  22436 89250018
         TM    LCBCSW+7,X'FE'      END OF POLLING LIST REACHED          89280013
         BNO   AGNRT               RETURN IF NO                 22436   89380018
APRSET   LA    SPREG,POLLZERO      PREPARE TO INITIATE POLLING          89490013
         ST    SPREG,LCBPOLPT-1    AT START OF AUTOPOLL POLLING LIST    89520013
APMSG    CLI   LCBCPA+40,X'03'     IS THE TIC FOLLOWING THE 2ND POLL    89550013
*                                   CCW NOW A NOP                       89580013
         BNE   AGNRT               IF NO RETURN (NO MESSAGES TO SEND)   89610013
         B     SETCLEAN            ELSE ALLOW CLEANUP             22436 89650018
TXTRANS  DC    X'110000'                                           00PS 89670018
         SPACE 2                                                        89700013
         SPACE 2                                                        89730013
BASE     DC    A(TTBASE)                                           00PS 89800018
BASE2    DC    A(DISKENQ+8)        BASE FOR DISK-END             A36503 89840020
FOUR     DC    H'04'                                                    89880013
K16      DC    H'16'                                                    89910013
ONE      DC    H'01'                                               00PS 89920016
H6       DC    H'6'                                                000D 89930018
         DS    0D                                                       89940013
RESPCCW  DC    X'02'                                                    89944018
         DC    AL3(RESPCHAR)                                            89948018
         DC    X'00200001'                                              89952018
RESPCHAR DS    XL1                                                      89956018
RESPAD   DC    AL3(RESPCCW+8)                                           89960018
         EJECT                                                          89964018
*                                                                       89966018
* THIS ROUTINE ENABLES AN AUTOPOLLED TERMINAL WHICH HAS MESSAGES TO     89968018
* SEND TO BE REPEATEDLY POLLED UNTIL IT HAS NO MORE MESSAGES TO SEND    89970018
* (OR UNTIL THE LIMIT SET BY THE POLLIMIT MACRO HAS BEEN REACHED)       89972018
*                                                                       89974018
*                                                                       89976018
PCIAP    STM   SPREG,TCREG,LCBCPA+72   SAVE REGISTERS            A39104 89980020
*                                                                       89984018
* FIND START OF POLLING LIST                                            89986018
*                                                                       89988018
         L     SPREG,LCBPOLPT-1    LOAD ADDRESS OF POLLING CHARACTERS   89990018
*                                  LAST USED TO START AUTOPOLL          89992018
PCLOOP   CLI   0(SPREG),X'FE'      LOOK FOR SCAN STOP BYTE              89994018
         LA    SPREG,1(SPREG)      INCREMENT BY 1                       89996018
         BNE   PCLOOP              IF NOT SCAN STOP BYTE LOOP           89998018
         MVC   LCBERCCW+4(2),0(SPREG) MOVE POINTER TO START OF LIST TO  90000018
*                                  A HALF WORD BOUNDRY                  90002018
         LR    REG0,SPREG          SAVE POINTER TO END OF LIST   A29210 90003020
         SH    SPREG,LCBERCCW+4    SET SPREG TO START OF POLLING LIST   90004018
*                                                                       90006018
* FIND   NUMBER OF POLLING CHARACTERS IN EACH ENTRY                     90008018
*                                                                       90010018
         SR    LGREG,LGREG                                              90012018
         IC    LGREG,4(SPREG)      GET BYTE CONTAINING WIDTH            90014018
         SRL   LGREG,5             SHIFT OUT OTHER INFORMATION          90016018
         BCTR  LGREG,0             DECREMENT BY 1                       90018018
*                                                                       90020018
* POINT X TO THE INDEX BYTE IN THE FIRST BUFFER                         90022018
*                                                                       90024018
         L     X,LCBCPA+48                                              90026018
*                                                                       90028018
* FIND POLLING CHARACTERS THAT HAVE SAME INDEX BYTE AS IN FIRST BUFFER  90030018
*                                                                       90032018
         LA    SPREG,5(SPREG)      INITIALIZE FOR FIRST TIME            90034018
         B     *+8                                                      90036018
PCILOOP  LA    SPREG,1(SPREG,LGREG) INCREMENT SPREG TO NEXT POLL CHARS  90038018
         CLI   0(SPREG),X'FE'      TEST FOR SCAN STOP BYTE              90040018
         BE    FINDSRCE            IF FOUND, NON SERIOUS ERROR   A29210 90042020
*                                    RETURN WILL SIMPLY CAUSE POLLING   90044018
*                                  TO BE RESTARTED AT THE SAME          90046018
*                                  TERMINAL AS THE LAST TIME            90048018
         LA    TCREG,0(SPREG,LGREG) SET TCREG TO INDEX BYTE             90050018
         CLC   0(1,TCREG),0(X)     COMPARE INDEX BYTES                  90052018
         BNE   PCILOOP             BYTE. IF NOT EQUAL LOOP              90054018
*                                                                       90056018
* ADJUST POLL POINTER                                                   90058018
*                                                                       90060018
         IC    TCREG,LCBPOLCT      STORE POLL COUNT                     90062018
         ST    SPREG,LCBPOLPT-1    STORE NEW POLL POINTER               90064018
         STC   TCREG,LCBPOLCT      RESTORE POLL COUNT                   90066018
FINDSRCE L     X,LCBPOLPT-1        GET POLL POINTER              A29210 90066220
         SR    TCREG,TCREG         ZERO REGISTER FOR IC          A29210 90066420
         IC    TCREG,0(X,LGREG)    GET INDEX BYTE                A29210 90066620
         SLL   TCREG,1             MULTIPLY BY TWO               A29210 90066820
         AR    TCREG,REG0          GET POLLING LIST ENTRY        A29210 90067020
         MVC   LCBTTIND(2),0(TCREG) PLACE OFFSET IN TTIND        A29210 90067220
*                                                                       90068018
* RETURN TO CALLING ROUTINE.                                            90070018
*                                                                       90072018
PCGB     LM    SPREG,TCREG,LCBCPA+72 RESTORE REGISTERS                  90074018
         TM    LCBERCCW,X'40'      IS INDICATOR STILL ON                90076018
         BZ    NOTAUTO            RETURN TO LINE END             A39104 90078020
         XI    LCBERCCW,X'40'      CLEAR HEADER BUFFER INDICATOR        90080018
         B     PCIRT               RETURN TO PCI ROUTINE                90082018
         USING FBLOCK,FREG                                              90084018
         TITLE 'CROSS PARTITION MOVE ROUTINE'                           90091018
*  MOVE DATA STCB  (COMBINED WITH QCB)                                  90092018
*        QCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS LABELED QMOVE           90093018
*        STCB--PRE-ASSEMBLED WITHIN THE QTAM NUCLEUS LABELED QMOVER     90094018
*        PROGRAM ENTRY--ENTERS THE QTAM NUCLEUS AT QMOVER+6.            90095018
QMOVE    DC    A(QMOVE)                                                 90096018
         DC    X'FE'                                                    90097018
         DC    AL3(QMOVE)                                               90098018
QMOVER   DC    X'02'                                                    90099018
         DC    AL3(QMOVER)                                              90100018
         DC    X'0000'                                                  90101018
         BALR  15,0                     SET UP BASE                000C 90102018
         USING *,15                                                000C 90103018
         L     Y,16                    LOAD ADDRESS OF CVT              90104018
         L     Y,0(Y)                  LOAD ADDRESS OF TCB LIST         90105018
         L     Y,4(Y)                  LOAD CALLERS TCB ADDRESS         90106018
         L     Y,TCBRBP-TCB(Y)         LOAD SVRB ADDRESS                90107018
         LM    Y,5,XRBREG+12-TBLOCK(Y) LOAD PASSED REGISTERS FOR MOVE   90108018
         LTR   Y,Y                     TEST LENGTH OF REQUESTED MOVE    90111018
         MVN   1(1,4),0(5)             MOVE NEW POLL LIST STATUS        90112018
         BZ    DISPATCH                GO IF REQUEST WAS TO CHANG POLL  90113018
*                                                               STATUS  90114018
         EX    Y,MOVE-QMOVER(TREG) MOVE REQUESTED DATA                  90115018
         B     DISPATCH                                                 90116018
         SPACE 2                                                        90117018
MOVE     MVC   1(1,4),1(5)                                              90133018
         TITLE 'ACTIVE BUFFER REQUEST ROUTINE'                          90133220
* ACTIVE-BUFFER-REQUEST SUBTASK                                         90133420
*      STCB--PRE-ASSEMBLED IN THE QTAM NUCLEUS, LABELED BREQENQ.        90133620
*      PROGRAM ENTRY--ENTERS THE ACTIVE-BUFFER-REQUEST                  90133820
*      ROUTINE AT BREQENQ+6.                                            90134020
* ACTIVE-BUFFER-REQUEST ROUTINE                                         90134220
*      THIS ROUTINE IS ENTERED ON ACTIVATION OF THE                     90134420
* ACTIVE-BUFFER-REQUEST SUBTASK.  THE ELEMENT PASSED TO THE             90134620
* ROUTINE IS AN ACTIVE BRB, THE ROUTINE DETERMINES WHETHER              90134820
* A BUFFER TO SATISFY THE REQUEST IS AVAILABLE AND SHOULD               90135020
* BE ASSIGNED, OR WHETHER THE ACTIVE BRB SHOULD BE ENQUEUED             90135220
* FOR LATER SERVICING.                                                  90135420
*      IF THE ACTIVE BRB REPRESENTS THE BEGINNING OF A BRB              90135620
* RING TO BE USED FOR A RECEIVE OPERATION, THE ROUTINE                  90135820
* REMOVES A BUFFER FROM THE ELEMENT CHAIN OF THE AVAILABLE-BUFFER QCB   90136020
* AND EXITS TO THE BUFFER-BRB ROUTINE.  PARAMETERS PASSED TO            90136220
* THAT ROUTINE ARE THE ADDR OF THE ACTIVE BRB, THE ADDRESS OF THE       90136420
* REMOVED BUFFER, AND THE ADDRESS OF THE AVAILABLE-BUFFER QCB.          90136620
*      IF THE ACTIVE BRB IS NOT THE FIRST OF A RING FOR A               90136820
* RECEIVE OPERATION, OR IF IT IS THE FIRST BUT NO BUFFER IS             90137020
* AVAILABLE, THE ROUTINE BRANCHES TO THE QUEUE INSERT BY                90137220
* PRIORITY (PRIORITY) SUBROUTINE TO CAUSE THE ACTIVE BRB TO             90137420
* BE ENQUEUED ON THE ELEMENT CHAIN OF THE ACTIVE-BUFFER-REQUEST QUEUE.  90137620
* BUFFER REQUEST QUEUE HANDLER     (FREG POINTS TO A BRB)               90137820
         SPACE 2                                                        90138020
BREQENQ  DC    AL1(ENQUE-NRET)                                          90138220
         DC    AL4(255)                                                 90138420
*                                  ACTIVE-BUFFER-REQUEST ROUTINE        90138620
         DROP  15                                                A39114 90138820
         USING  IGG019NG,Z                                       A39114 90139020
         CLI   FPRI,X'EC'          DOES THIS REQUEST HAVE HIGH PRIORITY 90139620
*        (FIRST BRB FOR A RECEIVE OPERATION HAS HIGH PRIORITY OF 'EC')  90140220
         BNE   PRIORITY            BRANCH IF NOT HIGH PRIORITY TO       90140820
*                                    PRIORITY SEARCH ROUTINE TO ENQUEUE 90141420
*                                    THE BRB RATHER THAN PROVIDE        90142020
*                                    IMMEDIATE BUFFER ASSIGNMENT        90142620
         L     Y,BUFFER            ELSE GET ADDRESS OF FIRST BUFFER IN  90143220
*                                    AVAILABLE BUFFER QUEUE CHAIN       90143820
         MVC   BUFFER+1(3),FLINK-FBLOCK(Y) REMOVE BUFFER FROM CHAIN     90144420
         CL    Y,BUFFER            COMPARE EQUAL WHEN CHAIN EXHAUSTED   90145020
         BE    PRIORITY            IF NO BUFFER,BRANCH TO ENQUEUE BRB   90145620
         LR    X,FREG              IF AVAILABLE BUFFER SAVE BRB ADDRESS 90146220
         LR    FREG,Y              GET BUFFER ADDRESS IN FREG           90146820
         LA    QREG,BUFFER         POINT QREG TO AVAILABLE-BUFFER QCB   90147420
*                                  (WHICH NOW HAS A NEW FIRST BUFFER)   90148020
         B     BFRSCH+6            AND BRANCH TO BUFFER BRB ROUTINE     90148620
         ORG   IGG019NG+X'1E10'                                  A65111 90149221
QTAMBASE DC    A(IGG019NG)                                              90150013
         TITLE   'BASIC CONTROL BLOCK DEFINITIONS'                      90180013
         DCBD  DSORG=(QX),DEVD=WT                                  000C 90210017
* DCBBUFRQ  EQU  IHADCB+20 (14) NO. OF BUFFERS FOR EACH TRANSMISSION    90240013
* DCBCLPS   EQU  IHADCB+20 (14) ADDR OF LPS ASSOC. WITH THIS DCB        90270013
* DCBACLOC  EQU  IHADCB+25 (19) REL. ADDR TERMTBL ENTRY DEVICE-ADDR     90300013
* DCBLCBAD  EQU  IHADCB+32 (20) ADDR OF LCB FOR THIS LINE               90330013
* DCBEIOBX  EQU  IHADCB+36 (24) SIZE OF LCB                             90360013
         EJECT                                                          90390013
* COMMUNICATIONS-LINE QUEUE                                             90420013
*      QCB--FORMED BY THE FIRST 12 BYTES OF THE LCB,                    90450013
*      WHICH IS CREATED DURING OPEN.                                    90480013
*      ELEMENT CHAIN--LIMITED TO A POINTER TO THE LCB ITSELF.           90510013
*      STCB CHAIN--MAY CONTAIN THE STCB FOR THE LINE'S                  90540013
*      RECEIVE-SCHEDULING SUBTASK AND/OR THE STCB FOR THE               90570013
*      LINE'S SEND-SCHEDULING SUBTASK (OR MORE THAN ONE                 90600013
*      SEND-SCHEDULING STCB IF SEPARATE QUEUES ARE MAINTAINED           90630013
*      FOR EACH TERMINAL).  ALWAYS ENDS WITH THE                        90660013
*      QDISPATCH STCB (QEVENT).                                         90690013
         LCBD  QTAM=3                                                   90720013
         EJECT                                                          90750013
         TCBD                                                           90780013
         EJECT                                                          90810013
         STCBD                                                          90840013
         EJECT                                                          90870013
         QCBD                                                           90900013
         EJECT                                                          90930013
         PREFIXD                                                        90960013
         EJECT                                                          90990013
DEB      DSECT                                                          91020013
         DS    XL16                                                     91050013
DEBNMEXT DS    FL1                                                      91080013
         DS    7X                                                       91110013
DEBDCBAD DS    A                                                        91140013
         DS    4X                                                       91170013
EXT1     DS    XL16                                                     91200013
         SPACE                                                          91230013
         USING TCB,TCBREG         TASK CONTROL BLOCK BASE REG           91260013
         DROP  TREG                                                     91290013
         USING TBLOCK,Y           SVRB/STCB BASE REG                    91320013
SVCBASE  DSECT                                                          91350013
         CTLPROGD                                                       91380013
         END                                                            91410013
