         TITLE ' QTAM CHECK/POINT ROUTINE IGG019NH '                    00200013
IGG019NH START                                                          00400013
*********************************************************************** 00400621
*                                                                     * 00401221
*                                                                     * 00401821
* STATUS  CHANGE LEVEL=180         JANUARY 1970                       * 00402421
*                                                                     * 00403021
* FUNCTION- THIS ROUTINE MAY BE ENTERED AT 'DISKEND' AS A DISK END    * 00403621
*    APPENDAGE.  IF THE ENDREADY MACRO HAS NOT BEEN EXECUTED, RETURN  * 00404221
*    IS MADE TO IOS VIA A BRANCH ON REGISTER 14 MINUS 8.  (ENDREADY   * 00404821
*    WILL POST ELEMENT TO GIVE ROUTINE CONTROL AND DISK INTERRUPT WILL* 00405421
*    THEN BE HANDLED.)  IF ENDREADY MACRO HAS BEEN EXECUTED, THE CHECK* 00406021
*    POINT ELEMENT IS POSTED TO THE LPS QUEUE TO BE ENTERED VIA A SVC.* 00406621
*         THIS ROUTINE MAY BE ENTERED AT WAITQ + 10 WHEN A CHECK      * 00407221
*    REQUEST (CKREQ) MACRO IS EXECUTED. THE FIRST ELEMENT IS REMOVED  * 00407821
*    FROM THE WAIT QUEUE WHICH IS AT LABEL WAITQ.  IF CHECKPOINT IS   * 00408421
*    IN PROGRESS, A BRANCH IS TAKEN TO DISPATCH TO RETURN.  IF THE    * 00409021
*    REQUIRED NUMBER OF CKREQ MACROS HAVE BEEN ISSUED, 'CPFLAG' IS SET* 00409621
*    TO INDICATE CHECKPOINT IN PROGRESS (8) AND THE CHECKPOINT ELEMENT* 00410221
*    IS POSTED TO ITSELF TO GAIN CONTROL UNDER THE MCP TCB.  IF THE   * 00410821
*    REQUIRED NUMBER IS NOT MET, 1 IS SUBTRACTED FROM THE 'NUMBER TO  * 00411421
*    GO';  A BRANCH IS TAKEN TO DISPATCH TO RETURN.                   * 00412021
*         THIS ROUTINE MAY BE ENTERED AT QUEUEST + 10 WHEN THE CHECK- * 00412621
*    POINT ELEMENT (AT THE BEGINNING OF THE CONSTANT AREA) IS DIS-    * 00413221
*    PATCHED FROM THE READY QUEUE.  THE ELEMENT IS REMOVED FROM THE   * 00413821
*    READY QUEUE. IF THE ROUTINE WAS ENTERED AS A RESULT OF ENTERING  * 00414421
*    AN APPENDAGE (BRANCH TO DISPATCH OR POST FROM APPENDAGE), THE    * 00415021
*    CHECKPOINT ELEMENT IS POSTED TO THE LPS QUEUE TO ENTER THE       * 00415621
*    ROUTINE VIA A SVC. IF THE ROUTINE IS NOT UNDER THE CONTROL OF THE* 00416221
*    MESSAGE CONTROL TCB, THE CHECKPOINT ELEMENT IS POSTED TO THE LPS * 00416821
*    QUEUE TO GAIN CONTROL UNDER MCP TCB.  THIS ENTRY POINT IS USED:  * 00417421
*    (1) FOR A DISK OPERATION, (2) WHEN CHECKPOINT ELEMENT IN DISK I/O* 00418021
*    QUEUE, (3) AT ENDREADY TIME, AND (4) TO TAKE A CHECKPOINT.       * 00418621
*         (1) FOR A DISK OPERATION (DISKFLAG=3), A TEST IS MADE FOR   * 00419221
*    DISK ERRORS.  IF A WRITE WAS NOT SUCCESSFUL A WTO IS ISSUED FOR  * 00419821
*    'I/O ERROR-CHECK POINTS TERMINATED.'  THE CHECKPOINT FLAGS       * 00420421
*    (CPFLAG) IS SET TO INDICATE CHECK REQUESTS.  THE CHECKPOINT      * 00421021
*    ELEMENTS FOR ALL OTHER WAITING PARTITIONS ARE POSTED COMPLETE VIA* 00421621
*    OS POST ROUTINE.  THE CHECKPOINT FLAGS ARE SET TO 'WAITING' AND  * 00422221
*    EXIT IS MADE TO DISPATCH.                                        * 00422821
*         IF THERE WERE NO DISK ERRORS, THE STATUS OF DISKFLAG IS     * 00423421
*    CHECKED.  IF A CONTROL RECORD WAS WRITTEN, THE DISKFLAG FIELD IS * 00424021
*    ZEROED, AND A 'FREEMAIN' IS ISSUED FOR CORE WHOSE ADDRESS IS IN  * 00424621
*    'WKAREA'. A X'FF' IS SET IN 'WKAREA' TO INDICATE THE CORE HAS    * 00425221
*    BEEN FREED.  IF CHECK REQUEST MACROS ARE BEING USED, THE WAITING * 00425821
*    ECB IN ALL PARTITIONS ARE POSTED COMPLETE, AND EXIT IS MADE TO   * 00426421
*    DISPATCH.  IF THE INTERVAL TIMER IS BEING USED, EXIT IS MADE TO  * 00427021
*    THE TIME DELAY ROUTINE TO PLACE THE CHECKPOINT ELEMENT IN THE    * 00427621
*    TIME QUEUE.                                                      * 00428221
*         IF WRITING A CHECK POINT RECORD, THE RESIDUAL COUNT IS      * 00428821
*    CHECKED FOR ZERO.  IF ZERO, THE CHECKPOINT RECORD HAS BEEN       * 00429421
*    WRITTEN AND THE CONTROL RECORD IS TO BE WRITTEN.  THE CONTROL    * 00430021
*    RECORD IS WRITTEN WITH THE MORE CURRENT BIT FLIPPED AND WITH A   * 00430621
*    LENGTH OF 4 AND TTR OF 1.  DISKFLAG FIELD IS SET TO INDICATE     * 00431221
*    CONTROL RECORD IS BEING WRITTEN.  IF THE COUNT IS NONZERO, THE   * 00431821
*    ADDRESS AND TTR FOR THE NEXT RECORD ARE COMPUTED FOR THE NEXT    * 00432421
*    WRITE.                                                           * 00433021
*         (2) IF THE 'CPFLAG' INDICATES THAT THE CHECKPOINT ELEMENT IS* 00433621
*    IN THE DISK QUEUE (4), PREPARATION IS MADE FOR WRITING THE CHECK-* 00434221
*    POINT DATA SET.  THE SIZE AND ADDRESS OF THE WORKAREA FROM THE   * 00434821
*    CONSTANT AREA AND WRITE OP CODE ARE STORED IN CCW IN THE CONSTANT* 00435421
*    AREA.  THE CPFLAG IS SET TO INDICATE 'DISK IN OPERATION', AND    * 00436021
*    DISKFLAG IS SET TO INDICATE 'CHECKPOINT RECORD'.  THE TTR OF 2 IS* 00436621
*    SET FOR THE FIRST RECORD OR OBTAINED FROM 'CONTROL' FIELD FOR    * 00437221
*    NEXT RECORD.  THE CONVERT ROUTINE IS USED TO CONVERT THE TTR TO  * 00437821
*    DISK ADDRESS.  EXCP IS ISSUED TO WRITE THE RECORD.  IOSSAVE IN   * 00438421
*    THE NUCLEUS IS SET TO X'FF' TO INDICATE SVC ENTRY, AND A BRANCH  * 00439021
*    IS TAKEN TO DISPATCH.                                            * 00439621
*         (3) IF THE 'CPFLAG' FIELD INDICATES THAT IT IS ENDREADY TIME* 00440221
*    WITH RESTART (2 OR 1), CORE OBTAINED FOR THE WORKAREA IS FREED   * 00440821
*    VIA A FREEMAIN. THE DISKFLAG IS SET TO ZERO AND WKAREA IS SET TO * 00441421
*    X'FF' TO INDICATE WORKAREA FREED.  IF CHECK REQUESTS ARE BEING   * 00442021
*    USED, THE WAITING ECB'S FOR EACH PARTITION ARE POSTED. IF CPFLAG * 00442621
*    INDICATES THAT IT IS ENDREADY WITH OR WITHOUT RESTART, THE CPFLAG* 00443221
*    ARE CHECKED FOR CHECK REQUEST USAGE (X'10').  FOR CHECK REQUESTS,* 00443821
*    THE CPFLAG IS SET TO 'ELEMENT WAITING' BEFORE A BRANCH IS TAKEN  * 00444421
*    TO DISPATCH TO RETURN TO ENDREADY.  OTHERWISE CPFLAG IS SET TO   * 00445021
*    'ELEMENT WAITING'.  THE ELEMENT ADDRESS AND INTERVAL IN SECONDS  * 00445621
*    ARE OBTAINED FOR THE TIME ROUTINE BEFORE A BRANCH TO THE TIME    * 00446221
*    DELAY ROUTINE TO PLACE THE CHECKPOINT ELEMENT IN THE TIME QUEUE. * 00446821
*         (4) IF THE ROUTINE WAS ENTERED TO TAKE CHECKPOINTS (EITHER  * 00447421
*    A TIMER INTERRUPT OR NUMBER OF CKREQ MACROS HAVE BEEN EXECUTED), * 00448021
*    REGISTERS 12 AND 13 (BASE REGISTER FOR IECKQQ01 AND IGG019NG) ARE* 00448621
*    SAVED IN CONSTANT AREA.  IF CONTROL IS NOT UNDER MESSAGE CONTROL * 00449221
*    TCB, THE CHECKPOINT ELEMENT IS POSTED TO THE LPS Q TO RETURN CON-* 00449821
*    TROL UNDER MCP. THE SIZE OF CHECKPOINT ELEMENT AND SUBPOOL ARE   * 00450421
*    OBTAINED FROM CONSTANT AREA AND PASSED TO GETMAIN TO OBTAIN CORE * 00451021
*    FOR WORKAREA. THE ADDRESS OF THE CORE IS STORED IN WKAREA, THERE-* 00451621
*    BY ZEROING THE CORE FREE SWITCH.                                 * 00452221
*         THE FOLLOWING DATA IS MOVED TO THE CHECKPOINT WORKAREA; THE * 00452821
*    ENTIRE TERMINAL TABLE BY ENTRY; DATA FROM EACH DESTINATION QCB   * 00453421
*    (QSIZE,QNAGSEG,QBACK, AND QFAC FIELDS); DATA FROM EACH PROCESS   * 00454021
*    QCB (QSIZE,QNAGSEG, QBACK, QFAC, AND IF OPEN, THE DISK ADDRESS OF* 00454621
*    LAST HEADRER OBTAINED FROM THE DEB + 66.  THE QSIZE DATA IS AD-  * 00455221
*    JUSTED ACCORDING TO THE MESSAGES IN THE M-S PROCESS QUEUE.); THE * 00455821
*    POLLING LISTS EXCEPT FOR THE LENGTH BYTE; DATA FROM THE LCB      * 00456421
*    (LCBHDR,LCBTTIND, LCBSTATE, LCBNASEG, AND UNIT ADDRESS FROM THE  * 00457021
*    UCB); AND DISK POINTERS IN THE DEAD LETTER QUEUE.                * 00457621
*         THE CHECKPOINT ELEMENT IN IGG019NH IS PLACED AT THE END OF  * 00458221
*    THE DISK I/O QUEUE.  A BRANCH IS TAKEN TO DISPATCH TO WAIT ON    * 00458821
*    I/O.                                                             * 00459421
*                                                                     * 00460021
* ENTRY POINTS- ENTRY MAY BE MADE AT QUEUEST + 10 WHEN SUBTASK FOR THE* 00460621
*         CHECK POINT ELEMENT IS DISPATCHED.                          * 00461221
*               ENTRY MAY BE MADE AT WAITQ + 10 WHEN THE SUBTASK FOR  * 00461821
*         CHECK REQUEST IS DISPATCHED.                                * 00462421
*               ENTRY MAY BE MADE AT DISKEND FOR A DISK END APPENDAGE.* 00463021
*                                                                     * 00463621
* INPUT-                                                              * 00464221
*    REGISTER 1 - ELEMENT ADDRESS                                     * 00464821
*    REGISTER 2 - STCB ADDRESS                                        * 00465421
*    REGISTER 9 - QCB ADDRESS                                         * 00466021
*    REGISTER 12- BASE FOR IECKQQ01                                   * 00466621
*    REGISTER 13- BASE FOR IGG019NG                                   * 00467221
*                                                                     * 00467821
* OUTPUT- EXIT VIA BRANCH TO POST                                     * 00468421
*    REGISTER 1 - ELEMENT ADDRESS                                     * 00469021
*    REGISTER 2 - QCB ADDRESS                                         * 00469621
*    REGISTER 12- BASE FOR IECKQQ01                                   * 00470221
*    REGISTER 13- BASE FOR IGG019NG                                   * 00470821
*                                                                     * 00471421
* EXTERNAL REFERENCES- THE CONVERT ROUTINE IS USED VIA THE ADDRESS IN * 00472021
*         THE CVT.                                                    * 00472621
*         WTO MACRO (SVC 35)                                          * 00473221
*         FREEMAIN MACRO (SVC 10)                                     * 00473821
*         GETMAIN MACRO (SVC 10)                                      * 00474421
*                                                                     * 00475021
* EXITS,NORMAL- THIS ROUTINE EXITS VIA A BRANCH TO DISPATCH OR POST IN* 00475621
*    IECKQQ01 OR VIA A BRANCH ON REGISTER 14 TO RETURN TO IOS.        * 00476221
*                                                                     * 00476821
* EXITS,ERROR - NONE                                                  * 00477421
*                                                                     * 00478021
* TABLES & WORKAREAS- THE FIRST 122 BYTES OF IGG019NH CONTAIN A       * 00478621
*    CONSTANT AREA THAT CAN BE ADDRESSED BY A DSECT, IGG019NH.        * 00479221
*    THE FIRST 16 BYTES CONTAIN THE CHECKPOINT ELEMENT,QCB,AND STCB.  * 00479821
*    NEXT ARE VARIOUS OFFSETS INTO THE WORKAREA, COUNTERS, AND        * 00480421
*    ADDRESSES.                                                       * 00481021
*    AT OFFSET 48 INTO THE CONSTANT AREA IS AN IOB FOR THE CHECKPOINT * 00481621
*    DATA SET FOLLOWED BY THE DISK CCWS.                              * 00482221
*                                                                     * 00482821
* ATTRIBUTES- REUSABLE, ONLY LOADABLE                                 * 00483421
*                                                                     * 00484021
* CHARACTER CODE DEPENDENCY- NONE                                     * 00484621
*                                                                     * 00485221
* NOTES-                                                              * 00485821
*      CHECK POINT FLAG STATUS WHEN USING CHECK POINT INTERVAL          00488821
*                                                                       00491821
*            E0    CHECK POINT ELEMENT IS IN THE TIME QUEUE             00494821
*            E1    ENDREADY TIME RESTART NOT INITIATED                  00497821
*            E2    ENDREADY WITH RESTART                                00500821
*            E4    CHECK POINT ELEMENT IS IN THE DISK QUEUE             00503821
*                                                                       00506821
*                                                                       00509821
*      CHECK POINT FLAG STATUS WHEN USING CKREQ MACROS                  00512821
*                                                                       00515821
*                                                                       00518821
*            F0    WAITING FOR REQUIRED NUMBER OF CKREQ MACROS          00521821
*            F1    ENDREADY TIME RESTART NOT INITIATED                  00524821
*            F2    ENDREADY WITH RESTART                                00527821
*            F4    CHECK POINT ELEMENT IN THE DISK QUEUE                00530821
*                                                                     * 00533821
*********************************************************************** 00536821
*3411279000                                                        8918 00550017
*3411272000                                                       20397 00570017
*1201749000-750000                                                18035 00580018
*1201954000                                                        000D 00590018
*A311000,605000,751000                                           A39110 00593021
*C954000                                                         A39110 00596021
*A004006-005368                                                  S21016 00598021
*A400600,401200                                                  A54000 00599021
*A728500,734500,C954000                                        A65129   00599421
*                                                                       00600013
*      REGISTER EQUATES                                                 00800013
*                                                                       01000013
R0       EQU   0                                                        01200013
FREG     EQU   1                                                        01400013
LPS      EQU   2                                                        01600013
LASTQ    EQU   3                                                        01800013
QUE      EQU   4                                                        02000013
LCBR     EQU   5                                                        02200013
TERM     EQU   6                                                        02400013
LINK     EQU   7                                                        02600013
POLL     EQU   8                                                        02800013
CPBASE   EQU   9                                                        03000013
WK10     EQU   10                                                       03200013
WK11     EQU   11                                                       03400013
CTLBASE  EQU   12                                                       03600013
NGBASE   EQU   13                                                       03800013
WK14     EQU   14                                                       04000013
SIZE     EQU   15                                                       04200013
         EJECT                                                          04400013
RCDSTART EQU   0                                                        04600013
POLLLEN  EQU   0                                                        04800013
EXCP     EQU   0                                                        05000013
CVTTCB   EQU   0                                                        05200013
HDR      EQU   1                                                        05400013
QPRIBY   EQU   4                                                        05600013
OLDQUES  EQU   4                                                        05800013
UCBAD    EQU   4                                                        06000013
CURTCB   EQU   5                                                        06200013
LINKF    EQU   5                                                        06400013
TCBAD    EQU   8                                                        06600013
QRET     EQU   8                                                        06800013
RCDFIX   EQU   8                                                        07000013
QLEN     EQU   11                                                       07200013
LCBSIZE  EQU   11                                                       07400013
MSTATUS  EQU   12                                                       07600013
PROLCB   EQU   12                                                       07800013
CVT      EQU   16                                                       08000013
NMEX     EQU   16                                                       08200013
CVTCVR   EQU   28                                                       08400013
DCBS     EQU   28        OFFSET TO DCBSEGAD                             08600013
DEBUCB   EQU   32                                                       08800013
DCBLCBAD EQU   32                                                       09000013
PROEXTRA EQU   34                 TO THE QUEUE WORK AREA                09200013
DISK     EQU   36                                                       09400013
DCBLCBSZ EQU   36                                                       09600013
DCBDEB   EQU   44                                                       09800013
DCBOFLGS EQU   48                                                       10000013
DCBPOLL  EQU   56                                                       10200013
READY    EQU   80                                                       10400013
ADDRESS  EQU   196                                                      10600013
ERRORQUE EQU   200                                                      10800013
CTLTCB   EQU   289                                                      11000013
CPFLAG   EQU   304                                                      11200013
CPFLAG2  EQU   320                                                 5645 11300016
TIMEENT  EQU   308                                                      11400013
POST     EQU   X'82'                                                    11600013
DISPATCH EQU   X'F8'                                                    11800013
IOSSAVE  EQU   X'1DC'                                                   12000013
         EJECT                                                          12200013
*                                                                       12400013
*            F8    BUILDING THE CHECK POINT RECORD                      15600013
*                                                                       15800013
*                                                                       16000013
         EJECT                                                          16200013
         USING IECKLCB0,SIZE                                            16400013
         USING QBLOCK,LASTQ                                             16600013
         USING *,CPBASE                                                 16800013
START    DC    X'1D'              WRITE COUNT/KEY/DATA COMMAND          17000013
         DC    AL3(START)         WRITE ADDRESS                         17200013
LCBP     DC    X'80'              DATA CHAINING FLAG                    17400013
LCBLINK  DC    AL3(8)             LENGTH                                17600013
COUNTSW  DC    X'80'                                                    17800013
         DC    AL3(TERMTBL)       STCB ADDRESS                          18000013
TIMELINK DC    A(0)               LINK FIELD WHEN IN THE TIME QUEUE     18200013
TERMSZ   DC    H'0'               STORAGE FOR THE TERMINAL TABLE SIZE   18400013
POLLOFF  DC    H'0'               POLLING LIST OFFSET IN THE CP RECORD  18600013
QOFF     DC    H'0'               QUEUE DATA OFFSET IN THE C/P RECORDS  18800013
LCBOFF   DC    H'0'               LCB DATA OFFSET IN THE C/P RECORDS    19000013
WKAREA   DC    A(0)               ADDRESS OF THE C/P RECORD IN CORE     19200013
CKRQPT   DC    A(CKQUE)           ADDRESS OF THE CKREQ QUEUE            19400013
SUBPOOL  DC    H'0'               SUBPOOL FOR GETMAIN                   19600013
CPSIZE   DC    H'0'               SIZE OF THE CHECK POINT OUTPUT        19800013
OVERHEAD DC    H'0'               SPACE OVERHEAD PER RECORD ON THE DISK 20000013
TRKLN    DC    H'0'               TRACK LENGTH ON THE CHECK PT. DEVICE  20200013
CPINT    DC    H'0'               CHECK/POINT INTERVAL IN SECONDS       20400013
TIMEQ    DC    H'0'               USED BY TIME DELAY ROUTINE            20600013
DECB     DC    A(0)               DECB TO BE USED FOR READ AND WRITE    20800013
DISKIOB  DC    X'42'              START OF THE DISK IOB                 21000013
         DC    AL3(0)                                                   21200013
         DC    A(DECB)            IOBDECB ADDRESS                       21400013
         DC    A(0)                                                     21600013
         DC    X'0F00'                                                  21800013
RSDCOUNT DC    H'0'                                                     22000013
IOBCCWAD DC    A(DISKCCWS)        IOBCCW ADDRESS                        22200013
DISKDCB  DC    A(0)               ADDRESS OF THE DISK DCB               22400013
         DC    2A(0)                                                    22600013
SEEKAD   DC    2A(0)              DISK SEEK ADDRESS                     22800013
DISKCCWS DC    X'31'              SEARCH COMMAND                        23000013
         DC    AL3(SEEKAD+3)      SEARCH ADDRESS                        23200013
         DC    X'40000005'        FLAGS AND LENGTH                      23400013
DISKTIC  DC    X'08'              TIC COMMAND                           23600013
         DC    AL3(DISKCCWS)      TIC ADDRESS                           23800013
CONTROL  DC    X'00'              INPUT AREA FOR THE CONTROL RECORD     24000013
         DC    AL3(0)             TTR OF THE SECOND SET OF RECORDS      24200013
DISKRW   DC    X'06'              READ DATA COMMAND                     24400013
         DC    AL3(CONTROL)       INPUT ADDRESS                         24600013
         DC    A(2)               LENGTH                                24800013
QUEUEST  DC    A(0)               START OF QUEUE AREA                   25000013
         EJECT                                                          25200013
TERMTBL  DC    A(DISKEND)         AFTER OPEN POINTER TO THE TERM TABLE  25400013
CON3     DC    H'3'                                                     25600013
*                                                                       25800013
*      POST TO LPS IF ENTERED WHILE IN AN APPENDAGE                     26000013
*                                                                       26200013
         L     LPS,0(NGBASE)      LOAD ADDRESS OF THE LPS QUEUE         26400013
         MVC   READY+1(3,NGBASE),LCBLINK REMOVE LCB FROM READY QUEUE    26600013
         XC    TIMELINK(4),TIMELINK ASSURE FULL WORD OF ZEROS           26800013
         CLI   IOSSAVE-2(CTLBASE),255 WAS ENTRY VIA AN SVC              27000013
         BNE   POSTLPS                                            20397 27200017
*                                                                       27400013
*      DETERMINE REASON FOR ACTIVATION OF THIS ROUTINE                  27600013
*                                                                       27800013
         BAL   LINK,PARTCK        GO ASSURE MESSAGE CONTROL PART   8918 27900017
         TM    DISKFLAG,3         WAS A DISK OPERATION IN PROGRESS      28000013
         BC    7,TESTERR          GO TEST FOR ERROR ON LAST WRITE       28200013
         TM    CPFLAG(LPS),4      WAS CHECK POINT ELEMENT IN THE DISK Q 28400013
         BO    DISKWRT            BRANCH IF YES                         28600013
         TM    CPFLAG(LPS),2      ENDREAD TIME WITH RESTART             28800013
         BO    RESTART            BRANCH IF YES                         29000013
         TM    CPFLAG(LPS),1      ENDREADY WITH OUT RESTART             29200013
         BO    STARTUP            BRANCH IF YES                         29400013
         STM   CTLBASE,NGBASE,QQCON STORE BASE REGISTERS                29600013
*                                                                       29800013
*      EITHER A TIME INTERRUPT JUST OCCURED OR THE REQUIRED NUMBER OF   30000013
*      CKREQ MACROS HAVE BEEN EXECUTED.-GET MAIN FOR THE WORK AREA      30200013
*                                                                       30400013
         BAL   LINK,PARTCK        GO ASSURE MESSAGE CONTROL PART.       30600013
         L     R0,SUBPOOL         SIZE AND SUBPOOL FRO GET MAIN         30800013
         GETMAIN R,LV=(0)                                               31000013
         MVI   IOSSAVE-2(CTLBASE),255  FLAG AS SVC ENTRY AGAIN   A39110 31100021
         ST    FREG,WKAREA        STORE ADDRESS OF THE WORK AREA        31200013
*                                                                       31400013
*      NOW SET REGISTERS TO START OF EACH FIELD IN THE WORK AREA        31600013
*                                                                       31800013
         MVC   RCDSTART(4,FREG),ADDRESS(LPS) SAVE LAST DISK ADDRESS     32000013
         MVC   OLDQUES(4,FREG),QUEUEST SAVE ADDRESS OF THE FIRST QUEUE  32200013
         LR    QUE,FREG           COPY ADDRESS OF THE WORK AREA         32400013
         LR    POLL,FREG          COPY ADDRESS OF THE WORK AREA         32600013
         LR    LCBR,FREG          COPY ADDRESS OF THE WORK AREA         32800013
         AH    QUE,QOFF           ADDRESS OF QUEUE WORK AREA            33000013
         AH    POLL,POLLOFF       ADDRESS OF POLLING LIST WORK AREA     33200013
         AH    LCBR,LCBOFF        ADDRESS OF LCB WORK AREA              33400013
         LH    R0,TERMSZ          SIZE OF THE TERMINAL TABLE            33600013
         L     TERM,TERMTBL       ADDRESS OF THE TERMINAL TABEL         33800013
*                                                                       34000013
*      SAVE NEXT TERM ENTRY AND ADJUST QUEUE POINTER                    34200013
*                                                                       34400013
TERMLOOP SR    WK11,WK11                                                34600013
         SR    SIZE,SIZE                                                34800013
         IC    SIZE,8(TERM)       LOAD LENGTH OF THIS TERM ENTRY        35000013
         EX    SIZE,MOVETERM      MOVE TERM ENTRY PLUS ONE BYTE         35200013
         L     WK10,8(TERM)       LOAD ADDRESS OF THE QUEUE             35400013
         LA    WK10,0(WK10)       CLEAR THE HIGH ORDER BYTE             35600013
         ALR   FREG,SIZE          UPDATE TERM WORK AREA POINTER         35800013
         ALR   TERM,SIZE          UPDATE TERM TABLE POINTER             36000013
         SLR   R0,SIZE            REDUCE SIZE OF TERM TABLE             36200013
*                                                                       36400013
*      MOVE QUEUE FIELDS TO WORK AREA IF DIFFERENT QUEUE THEN LAST      36600013
*                                                                       36800013
         CLI   QRET(WK10),X'02'   IS THIS A DISTRIBUTION LIST           37000013
         BE    ENDTEST            BRANCH IF YES                         37200013
         CR    WK10,LASTQ         COMPARE QUEUE ADDRESS OF LAST QUEUE   37400013
         LR    LASTQ,WK10         SAVE THIS QUEUE ADDRESS AS LAST QUEUE 37600013
         BE    ENDTEST            BRANCH IF QUEUES ARE THE SAME         37800013
         BAL   LINK,MOVEQUE                                             38000013
*                                                                       38200013
*      MOVE EXTRA DISK POINTER IF THIS IS A PROCESS QUEUE               38400013
*                                                                       38600013
         CLI   QRET(LASTQ),X'68'  TEST TYPE OF QUEUE FOR DEST. QUEUE    38800013
         BE    DEST               BRANCH IF DESTINATION QUEUE           39000013
         L     WK14,PROLCB(WK10)  LOAD ADDRESS OF THE DUMMY LCB LOCATED 39200013
*                                 IN THE PROCESS QUEUE DEB              39400013
         MVC   QLEN(3,QUE),QFAC   IN CASE DCB NOT OPEN                  39600013
         TM    QPRI,1             IS THIS QCB OPEN                      39800013
         BZ    NOTOPEN            BRANCH NOT OPEN                       40000013
         TM    QRLN+3,X'01'        IS THIS EXPEDITE PROCESS Q?   A54000 40060021
         BO    NOTOPEN             YES, DO NOT CHANGE QLEN       A54000 40120021
         MVC   QLEN(3,QUE),PROEXTRA(WK14) DISK ADDRESS CURRENT MESSAGE  40200013
*                                                                       40400013
*      ADJUST QSIZE FOR MESSAGES IN THE CORE PROCESS QUEUE              40600013
*                                                                       40800013
         LR    WK11,WK14          SAVE ADDRESS OF THE LCB               41000013
         LH    LINK,QSIZE         PRESENT VALUE OF QSIZE                41200013
         LA    LINK,1(LINK)       ADD ONE FOR CURRENT MESSAGE           41400013
LOOPX    L     WK14,4(WK14)       ADDRESS OF NEXT BUFFER IN THE QUEUE   41600013
         CLI   4(WK14),255        IS THIS THE DUMMY END ELEMENT         41800013
         BE    ENDLOOPX           BRANCH IF YES                         42000013
         TM    MSTATUS(WK14),HDR  IS THIS A HEADER SEGMENT              42200013
         LA    LINK,1(LINK)       ADD ONE ASSUMING HEADER               42400013
         BZ    LOOPX              BRANCH IF HEADER                      42600013
         BCT   LINK,LOOPX         SUB ONE AND BRANCH IF NOT HEADER      42800013
ENDLOOPX SH    WK11,CON8          BACK UP TO THE DCB ADDRESS            43000013
         LA    WK14,24(WK11)      DUMMY BRB ADDRESS DEB+84              43200013
         L     WK11,0(WK11)       ADDRESS OF THE DCB                    43400013
         C     WK14,DCBS(WK11)    COMPARE TO DCB SEG ADDR OT DETERMINE  43600013
*                                 IF A BUFFER HAS EVER BEEN GOTTEN      43800013
         BNE   BUFGOT             BRANCH IF BUFFER GOTTEN               44000013
         BCTR  LINK,0             SUB ONE FROM QSIZE                    44200013
BUFGOT   STC   LINK,1(QUE)        SAVE FIRST QSIZE BYTE                 44400013
         SRL   LINK,8             POSITION SECOND QSIZE BYTE            44600013
         STC   LINK,0(QUE)        STORE SECOND QSIZE BYTE               44800013
NOTOPEN  LA    QUE,QLEN+3(QUE)    INCREMENT QUEUE WORK AREA POINTER     45000013
         B     ENDTEST                                                  45200013
*                                                                       45400013
*      MOVE POLLING LIST TO THE WORK AREA                               45600013
*                                                                       45800013
DEST     LA    QUE,QLEN(QUE)      INCREMENT QUEUE WORK AREA POINTER     46000013
         IC    LINK,COUNTSW       LOAD SWITCH FOR EXECUTE OF BRANCH     46200013
         IC    WK11,QRLN          LOAD RELATIVE LINE NUMBER FROM THE Q. 46400013
         LR    WK14,WK11          SAVE RELATIVE LINE NUMBER             46600013
         SLL   WK11,2             MULTIPLY BY FOUR                      46800013
         L     WK10,QDCB-1        LOAD ADDRESS OF THE DCB               47000013
         ALR   WK11,WK10          COMPUTE ADDRESS OF POLLING LIST PT.   47200013
         TM    DCBPOLL-4(WK11),1  TEST PREVIOUSLY SAVED FLAG            47400013
         EX    LINK,BRANCH        INSTRUCTION WILL BRANCH IF THIS POLL  47600013
*                                 LIST WAS PREVIOUSLY SAVED             47800013
         XI    DCBPOLL-4(WK11),1  INDICATE POLL LIST PREVIOUSLY SAVED   48000013
         L     WK11,DCBPOLL-4(WK11) LOAD ADDRESS OF THE POLLING LIST    48200013
         IC    SIZE,POLLLEN(WK11)   LOAD SIZE OF THE POLLING LIST       48400013
         BCTR  SIZE,0             SUB ONE FOR LENGTH BYTE NOT MOVED     48600013
         BCTR  SIZE,0             SUB ONE FOR MOVE CHARACTER INST.      48800013
         EX    SIZE,MOVEPOLL        POLLING LIST TO THE WORK AREA       49000013
         LA    POLL,1(SIZE,POLL)  INCREMENT POLL WORK AREA POINTER      49200013
*                                                                       49400013
*      NOW SAVE FIELDS ASSOCIATED WITH THE LCB                          49600013
*                                                                       49800013
         TM    DCBOFLGS(WK10),X'10' HAS THIS DCB BEEN OPENED            50000013
         BZ    ENDTEST            BRANCH DCB NOT OPEN                   50200013
         L     WK11,DCBDEB(WK10)  ADDRESS OF THE DEB                    50400013
         CLC   NMEX(1,WK11),QRLN  IS RELATIVE LINE TOO LARGE            50600013
         BL    ENDTEST            BRANCH IF YES                         50800013
         IC    SIZE,DCBLCBSZ(WK10)  LOAD SIZE OF LCB/IOB                51000013
         LR    WK11,WK14            SAVE THE RELATIVE LINE NUMBER       51200013
         MR    WK14,WK14          SIZE TIMES RELATIVE LINE NUMBER       51400013
         AL    SIZE,DCBLCBAD(WK10)  COMPUT ADDRESS OF THE LCB           51600013
         MVC   0(9,LCBR),LCBCHDR    SAVE LCBCHDR AND LCBNASEG           51800013
         MVC   3(2,LCBR),LCBTTIND   SAVE LCBTTIND                       52000013
         MVC   5(1,LCBR),LCBSTATE   SAVE LCB STATE                      52200013
         SLL   WK11,2             RELATIVE LINE NUMBER TIMES FOUR       52400013
         L     WK10,DCBDEB(WK10)  ADDRESS OF THE DEB                    52600013
         L     WK10,DEBUCB-4(WK10,WK11) ADDRESS OF THE UCB FOR THIS LN. 52800013
         MVC   9(2,LCBR),UCBAD(WK10) SAVE UNIT ADDRESS FROM THE UCB     53000013
         LA    LCBR,LCBSIZE(LCBR)    UPDTAE WORKAREA LCB POINTER        53200013
         XC    0(LCBSIZE,LCBR),0(LCBR) ZERO IN CASE THIS IS THE LAST    53400013
*                                                                       53600013
*      TEST FOR MORE TERM TABLE ENTRIES                                 53800013
*                                                                       54000013
ENDTEST  LTR   R0,R0              MORE TERM TABLE ENTRIES               54200013
         BP    TERMLOOP           BRANCH IF MORE                        54400013
*                                                                       54600013
*      SAVE ERROR QUE POINTERS                                          54800013
*                                                                       55000013
         LA    LASTQ,ERRORQUE(LPS) ADDRESS OF THE DEAD LETTER QUEUE     55200013
         BAL   LINK,MOVEQUE        GO SAVE DEAD LETTER QUEUE POINTERS   55400013
         XI    COUNTSW,X'90'       FLIP COUNT SWITCH FOR NEXT ENTRY     55600013
*                                                                       55800013
*      NOW PUT LCB IN THE DISK QUEUE                                    56000013
*                                                                       56200013
         MVN   CPFLAG(1,LPS),CON4 FLAG CHECK POINT ELEMENT AS IN DISK Q 56400013
*                                 DISK QUE                              56600013
         LA    LASTQ,DISK(LPS)    LOAD ADDRESS OF THE LPS QUEUE         56800013
         L     WK10,QKEY          LOAD ADDRESS OF FIRST ELEMENT         57000013
         CLI   QPRIBY(WK10),255   END OF DISK QUEUE ELEMENT CHAIN       57200013
         BE    DISKWRT            BRANCH NO ELEMENT IN THE DISK QUEUE   57400013
         OI    CPFLAG2(LPS),X'80'  FLAG FOR DISK I/O TO RECOGNIZE  5645 57460016
*                                   CHECK POINT ELEMENT IN DISK Q  5645 57520016
QINLOOP  LR    LASTQ,WK10         SAVE ADDRESS OF THIS ELEMENT          57600013
         L     WK10,QPRI          LOAD POINTER TO NEXT ELEMTNT          57800013
         CLI   QPRIBY(WK10),255   END OF DISK QUEUE CHAIN               58000013
         BNE   QINLOOP            BRANCH NOT LAST ELEMENT               58200013
         MVC   LCBLINK(3),QLINK   END CHAIN ADDRESS IN DUMMY LCB        58400013
         MVC   QLINK(3),CPFLAG+1(LPS) DUMMY LCB TO DISK ELEMENT CHAIN   58600013
         B     DISPATCH-2(CTLBASE) GO WAIT FOR DISK I/O                 58800013
*                                                                       59000013
*      FREE CORE GOTTEN FOR THE WORK AREA                               59200013
*                                                                       59400013
RESTART  BAL   LINK,PARTCK        GO ASSURE MESSAGE CONTROL PART.       59600013
         MVI   DISKFLAG,0         RESET THE DISK FLAG                   59800013
         L     R0,SUBPOOL         SIZE AND SUBPOOL FRO FREE MAIN        60000013
         L     FREG,WKAREA        LOAD ADDRESS FOR FREE MAIN            60200013
         FREEMAIN R,LV=(0),A=(1)                                        60400013
         MVI   IOSSAVE-2(CTLBASE),255  FLAG AS SVC ENTRY AGAIN   A39110 60500021
         MVI   WKAREA,255         SET INDICATOR CORE FREE               60600013
         TM    CPFLAG(LPS),X'10'  ARE CKREQ MACROS BEING USED           60800013
         BO    POSTECBS           BRANCH IF YES                         61000013
*                                                                       61200013
*      EXIT TO DISPATCH IF CKREQ MACROS ARE BEING USED                  61400013
*                                                                       61600013
STARTUP  NI    CPFLAG(LPS),X'F0' FLAG ELEMENT AS WAITING                61800013
         TM    CPFLAG(LPS),X'10'  ARE CKREQ MACROS BEING USED           62000013
         BO    DISPATCH-2(CTLBASE) BRANCH IF YES TO WAIT FOR NEXT REQ.  62200013
*                                                                       62400013
*      PLACE CHECK-POINT LCB IN THE TIME QUEUE                          62600013
*                                                                       62800013
         LH    TERM,CPINT         CHECK POINT INTERVAL IN SECONDS       63000013
         LR    QUE,CPBASE         LOAD ELEMENT ADDRESS FOR TIME ROUTINE 63200013
         B     TIMEENT(LPS)       TO CHECK-POINT ENTRY IN DELAY RT.     63400013
         DS    0F                                                       63600013
CKQUE    DC    X'0300'            QKEY AND FILLER                       63800013
TOGO     DC    H'0'               COUNT OF CKREQ MACROS YET REQUIRED    64000013
WAITQ    DC    A(CKSTCB)          QUEUE OF PARTITIONS WAITING FOR CKPT  64200013
CKSTCB   DC    X'02'              RETURN CODE                           64400013
         DC    AL3(CKSTCB)                                              64600013
         DC    X'FF'              PRIORITY BYTE                         64800013
DISKFLAG DC    X'00'              FLAGS USED FOR DISK WRITE             65000013
         USING CKQUE,CPBASE                                             65200013
         L     CPBASE,STARTPT     LOAD COMMON BASE REGISTER             65400013
         USING START,CPBASE                                             65600013
*                                                                       65800013
*      PLACE REQUEST ELEMENT IN THE WAIT QUEUE                          66000013
*                                                                       66200013
         MVC   LINKF(3,FREG),WAITQ+1 NEXT ELEMENT ADDRESS TO THIS ONE   66400013
         ST    FREG,WAITQ         ELEMENT ADDRESS TO THE WAIT QUEUE     66600013
*                                                                       66800013
*      EXIT TO DISPATCH IF CHECK POINT ALREADY IN PROGRESS              67000013
*                                                                       67200013
         L     LPS,0(NGBASE)      ADDRESS OF THE LPS QUEUE IN IGG019NG  67400013
         CLI   CPFLAG(LPS),240    TEST THE CHECK POINT FLAGS            67600013
         BNE   DISPATCH-2(CTLBASE) TO DISPATCH IF CK-PT IN PROGRESS     67800013
*                                                                       68000013
*      DETERMINE IF THE REQUIRED NUMBER OF CKREQ'S HAVE BEEN ISSUED     68200013
*                                                                       68400013
         LH    TERM,TOGO          LOAD REMAINING VALUE                  68600013
         BCT   TERM,NOTNOW        BRANCH IF MORE REQUIRED               68800013
*                                                                       69000013
*      POST THE CHECK POINT ELEMENT TO INITIATE A CHECK POINT           69200013
*                                                                       69400013
         OI    CPFLAG(LPS),8      FLAG AS CHECK POINT IN PROGRESS       69600013
         B     POSTLCB            GO POST THE LCB TO IT SELF            69800013
*                                                                       70000013
*      MORE CKREQ'S REQUIRED-EXIT TO DISPATCH                           70200013
*                                                                       70400013
NOTNOW   STH   TERM,TOGO          STORE REMAING VALUE                   70600013
         B     DISPATCH-2(CTLBASE)                                      70800013
*                                                                       71000013
*      CHECK POINT IS COMPLETE POST ALL WAITING PARTITIONS              71200013
*                                                                       71400013
POSTECBS L     WK11,WAITQ         ADDRESS OF THE NEXT PARTITION ELEMENT 71600013
         CLI   LINKF-1(WK11),255  IS THIS THE DUMMY END ELEMENT         71800013
         BE    STARTUP            BRANCH IF YES                         72000013
         MVC   WAITQ+1(3),LINKF(WK11) REMOVE ELEMENT FROM THE WAIT QUE  72200013
         USING QQD+2,CTLBASE                                            72400013
         L     SIZE,POSTAD        ADDRESS OF THE POST ROUTINE           72600013
         L     CTLBASE,TCBAD(WK11) ADDRESS OF THE TCB FOR THIS PART.    72800013
         LA     WK11,0(WK11)       CLEAR HI-ORDER BYTE          A65129  72850021
         BALR  14,SIZE            LINK TO THE POST ROUTINE              73000013
         USING *,14                                                     73200013
         LM    CPBASE,NGBASE,STARTPT LOAD BASE REGISTERS                73400013
         MVI   IOSSAVE-2(CTLBASE),255  FLAG AS SVC AGAIN        A65129  73450021
         DROP  14                                                       73600013
         B     POSTECBS           GO TEST FOR MORE PARTITIONS           73800013
*                                                                       74000013
*      TEST FOR ERROR ON LAST WRITE IF NOT NEW REQUEST                  74200013
*                                                                       74400013
TESTERR  TM    DISKIOB+4,X'7F'    TEST THE COMPLECTION CODE             74600013
         BO    NOERROR            BRANCH IF NO ERROR                    74800013
         WTO   'IEC805I   I/O ERROR - CHECK POINTS TERMINATED',   18035C74900018
               ROUTCDE=(4,10),DESC=(4)                            18035 75000018
         MVI   IOSSAVE-2(CTLBASE),255  FLAG AS SVC ENTRY AGAIN   A39110 75100021
         MVI   CPFLAG(LPS),X'10'  SET CKREQ FLAG                        75200013
         B     POSTECBS                                                 75400013
*                                                                       75600013
*      NEW DISK REQUEST PREPARE TO WRITE DATA                           75800013
*                                                                       76000013
DISKWRT  L     WK10,WKAREA        ADDRESS OF THE WORK AREA              76200013
         LH    WK11,CPSIZE        SIZE OF THE WORK AREA                 76400013
         MVN   CPFLAG(1,LPS),CON3+1 FLAG AS DISK OPERATION IN PROGRESS  76600013
         OI    DISKFLAG,2         SET DISK FLAGS TO INDICATE DATA REC.  76800013
*                                 BEING WRITTEN                         77000013
         LA    R0,2               TTR OF FIRST SET OF RECORDS           77200013
         TM    CONTROL,2          IS FIRST RECORD TO BE WRITTEN         77400013
         BO    WRTFIRST           BRANCH IF YES                         77600013
         L     R0,CONTROL         TTR OF THE SECOND SET OF RECORDS      77800013
WRTFIRST ST    R0,TTRSAVE         SAVE THIS TTR                         78000013
         ST    WK10,DISKRW        WRITE ADDRESS TO WRITE COMMAND        78200013
         STH   WK11,DISKRW+6      LENGTH TO THE WRITE COMMAND           78400013
         MVI   DISKRW,5           MOVE IN WRITE COMMAND                 78600013
*                                                                       78800013
*      LINK TO THE TTR CONVERT FOR ACTUAL DISK ADDRESS                  79000013
*                                                                       79200013
         SLL   R0,8               POSITION THE TTR                      79400013
         L     FREG,DISKDCB       LOAD ADDRESS OF THE DCB               79600013
         L     FREG,DCBDEB(FREG)  ADDRESS OF THE DEB FROM THE DCB       79800013
         LA    LPS,SEEKAD         RETURN LOCATION FOR THE DISK ADDRESS  80000013
         L     SIZE,16            ADDRESS OF THE CVT                    80200013
         L     SIZE,CVTCVR(SIZE)  ADDRESS OF TTR CONVERT ROUTINE        80400013
         BALR  WK14,SIZE          LINK TO THE CONVERT ROUTINE           80600013
         USING *,14                                                     80800013
         LM    CPBASE,NGBASE,STARTPT LOAD BASE REGISTERS                81000013
         DROP  14                                                       81200013
*                                                                       81400013
*      NOW ISSUE EXCP FOR THE DISK WRITE                                81600013
*                                                                       81800013
         LA    FREG,DISKIOB       PARAMETER FOR IOS                     82000013
         SVC   EXCP                                                     82200013
         MVI   IOSSAVE-2(CTLBASE),255 FLAG AS SVC ENTRY AGAIN           82400013
         B     DISPATCH-2(CTLBASE) GO DISPATCH NEXT READY ITEM          82600013
*                                                                       82800013
*      PREPARE FOR NEXT WRITE IF RESID. COUNT NOT ZERO                  83000013
*                                                                       83200013
NOERROR  TM    DISKFLAG,3         WHAT WRITE WAS THIS                   83400013
         BO    RESTART            BRANCH IF CONTROL RECORD WRITE        83600013
         LH    WK11,RSDCOUNT      LOAD RESID. COUNT FROM THE IOB        83800013
         LTR   WK11,WK11          TEST FOR ZERO                         84000013
         BZ    WRTCONTR           BRANCH IF ZERO TO GO WRITE CONTROL    84200013
         LH    WK10,DISKRW+6      LENGTH FROM THE WRITE COMMAND         84400013
         SR    WK10,WK11          COMPUTE NUMBER OF BYTES WRITTEN       84600013
         AL    WK10,DISKRW        ADDRESS FOR THE NEXT WRITE            84800013
         L     FREG,TTRSAVE       TTR OF THE LAST RECORD                85000013
         IC    FREG,DISKRW        SET RECORD NUMBER TO KNOWN VALUE      85200013
         LA    R0,252(FREG)       TTR OF THE NEXT RECORD                85400013
         B     WRTFIRST           GO WRITE THE NEXT RECORD              85600013
*                                                                       85800013
*      PREPARE TO WRITE THE CONTROL RECORD                              86000013
*                                                                       86200013
WRTCONTR LA    WK10,CONTROL       CONTROL RECORD OUTPUT ADDRESS         86400013
         XI    CONTROL,3          FLIP THE MOST CURRENT FLAG            86600013
         MVC   TOGO(2),CPINT      RESET VARIABLE CKREQ MACRO COUNT      86800013
         LA    WK11,4             LENGTH OF THE CONTROL RECORD          87000013
         LA    R0,1               TTR OF THE CONTROL RECORD             87200013
         OI    DISKFLAG,1         SET TO INDICATE CONTROL RECORD        87400013
*                                 IS BEING WRITTEN                      87600013
         B     WRTFIRST           GO WRITE THE CONTROL RECORD           87800013
*                                                                       88000013
*      SAVE QCB FIELDS                                                  88200013
*                                                                       88400013
MOVEQUE  MVC   0(5,QUE),QSIZE     SAVE QSIZE AND QNASEG                 88600013
         MVC   5(3,QUE),QBACK     SAVE QBACK                            88800013
         MVC   8(3,QUE),QFAC      SAVE QFAC                             89000013
         BR    LINK                                                     89200013
*                                                                       89400013
*      SUB ROUTINE TO ASSURE MESSAGE CONTROL PART                       89600013
*                                                                       89800013
PARTCK   L     WK10,CVT           ADDRESS OF THE CVT                    90000013
         L     WK10,CVTTCB(WK10)  ADDRESS OF THE TCB LIST               90200013
         CLC   CURTCB(3,WK10),CTLTCB(LPS) CURRENT TCB ADDRESS TO        90400013
*                                 ADDRESS OF MSGCTL TCB                 90600013
         BCR   8,LINK             RETURN GET OR FREE MAIN VALID         90800013
         B     POSTLPS            POST TO LPS TO CAUSE SWITCH           91000013
*                                                                       91200013
*      DISK END APPENDAGE TO POST LCB AFTER WRITE COMPLETES             91400013
*                                                                       91600013
         USING *,15                                                     91800013
DISKEND  LM    CTLBASE,NGBASE,QQCON LOAD BASE FOR QQ01 AND IGG019NG     92000013
         LTR   CTLBASE,CTLBASE    HAS ENDREADY TIME BEEN REACHED YET    92200013
         BCR   8,14               NO RETURN TO IOS                      92400013
         STM   14,9,IOSAVE        SAVE REGISTERS FOR LATER IOS RETURN   92600013
         L     CPBASE,STARTPT     LOAD CHECK POINT BASE                 92800013
POSTLCB  LR    LPS,CPBASE         LOAD REGISTER FOR POST                93000013
POSTLPS  LR    FREG,CPBASE        LOAD REGISTER FOR POST                93200013
         MVI   LCBP,X'E0'         SET ELEMENT PRIORITY FOR POST         93400013
         B     POST-2(CTLBASE)    GO POST THE CHECK POINT ELEMENT       93600013
MOVETERM MVC   RCDFIX(0,FREG),8(TERM)                                   93800013
MOVEPOLL MVC   0(0,POLL),1(WK11)                                        94000013
BRANCH   BC    0,ENDTEST                                                94200013
STARTPT  DC    A(START)                                                 94400013
         DC    H'0'               FILLER                                94600013
CON8     DC    H'8'                                                     94800013
TTRSAVE  DC    A(0)                                                     95000013
QQCON    DC    2A(0)                                                    95200013
         ORG   IGG019NH+X'48F'                                   A65129 95400021
CON4     DC    X'04'                                                    95600013
         LCBD                                                           95800013
         QCBD                                                           96000013
QQD      DSECT                                                          96200013
         DS    118A                                                     96400013
POSTAD   DS    A                                                        96600013
IOSAVE   DS    A                                                        96800013
         END                                                            97000013
