         MACRO                                                          00100013
         IECTDECB                                                       00200013
IECTDECB DSECT          DECB DUMMY SECTION                              00300013
*        ------------------------------------------                     00400013
*        +                                        +                     00500013
*     0  +      STANDARD EVENT CONTROL BLOCK      +                     00600013
*        +                                        +                     00700013
*        +----------------------------------------+                     00800013
*        +                   +                    +                     00900013
*     4  +  OPERATION TYPE   +    AREA LENGTH     +                     01000013
*        +                   +                    +                     01100013
*        +----------------------------------------+                     01200013
*        + ON-LINE +                              +                     01300013
*     8  +TERMINAL +        ADDRESS OF DCB        +                     01400013
*        +  TEST   +                              +                     01500013
*        +----------------------------------------+                     01600013
*        +         +                              +                     01700013
*    12  +RESERVED +        ADDRESS OF AREA       +                     01800013
*        +         +                              +                     01900013
*        +----------------------------------------+                     02000013
*        +                   +                    +                     02100013
*    16  +    SENSE BYTES    +   RESIDUAL COUNT   +                     02200013
*        +    1    &    2    +                    +                     02300013
*        +----------------------------------------+                     02400013
*        +         +                              +                     02500013
*    20  + COMMAND    ADDRESS OF TERMINAL LIST   +                     02600013
*        +   CODE  +                              +                     02700013
*        +----------------------------------------+                     02800013
*        +         + RELATIVE+         +          +                     02900013
*    24  +  STATUS +   LINE  + ADDRESS + VRC/LRC  +                     03000013
*        +  FLAGS  +  NUMBER + RESPONSE+ RESPONSE +                     03100013
*        +----------------------------------------+                     03200013
*        +         +         +                    +                     03300013
*    28  +  TP-OP  +  ERROR  +     CSW STATUS     +                     03400013
*        +   CODE  +  STATUS +                    +                     03500013
*        +----------------------------------------+                     03600013
*        +         +                              +                     03700013
*    32  +RESERVED +      ADDRESS OF CURRENT      +                     03800013
*        +         +       ADDRESSING ENTRY       +                     03900013
*        +----------------------------------------+                     04000013
*        +         +                              +                     04100013
*    36  +RESERVED +      ADDRESS OF CURRENT      +                     04200013
*        +         +        POLLING ENTRY         +                     04300013
*        ------------------------------------------                     04400013
         EJECT                                                          04500013
DECSDECB DS    1F   STATUS FLAG + ADDRESS OF THE TCB                    04600013
         SPACE                                                          04700013
DECTYPE  DS    1H   OPERATION TYPE                                      04800013
         SPACE                                                          04900013
DECLNGTH DS    1H   AREA LENGTH                                         05000013
         SPACE                                                          05100013
DECONLTT DS    0CL1 RESERVED FOR ON-LINE TERMINAL TEST                  05200013
DECDCBAD DS    1F   ADDRESS OF DCB                                      05300013
         SPACE                                                          05400013
DECAREA  DS    1F   ADDRESS OF AREA                                     05500013
         SPACE                                                          05600013
DECSENS0 DS    1C   1ST SENSE BYTE                                      05700013
         SPACE                                                          05800013
DECSENS1 DS    1C   2ND SENSE BYTE                                      05900013
         SPACE                                                          06000013
DECCOUNT DS    1H   RESIDUAL COUNT                                      06100013
         SPACE                                                          06200013
DECCMCOD DS    0CL1 COMMAND CODE                                        06300013
DECENTRY DS    1F   ADDRESS OF TERMINAL LIST                            06400013
         SPACE                                                          06500013
         SPACE                                                          06600013
DECFLAGS DS    1C   STATUS FLAGS                                        06700013
         SPACE                                                          06800013
DECRLN   DS    1C   RELATIVE LINE NUMBER                                06900013
         SPACE                                                          07000013
DECRESPN DS    1H   RESPONSE FIELDS                                     07100013
         SPACE                                                          07200013
DECTPCOD DS    1C   TP-OP CODE                                          07300013
         SPACE                                                          07400013
DECERRST DS    1C   ERROR STATUS                                        07500013
         SPACE                                                          07600013
DECCSWST DS    1H   CSW STATUS                                          07700013
         SPACE                                                          07800013
DECADRPT DS    1F   ADDRESS OF CURRENT ADDRESSING ENTRY                 07900013
         SPACE                                                          08000013
DECPOLPT DS    1F   ADDRESS OF CURRENT POLLING ENTRY                    08100013
         SPACE                                                          08200013
         MEND                                                           08300013
         TITLE 'IGG019NZ -BTAM READ/WRITE ROUTINE'                      08400013
IGG019NZ CSECT                                                          08500013
* STATUS       CHANGE LEVEL= 19    JANUARY 1971                       * 08600021
         SPACE 2                                                        08700013
* FUNCTION -        GENERATE TELECOMMUNICATION CHANNEL PROGRAMS         08800013
         SPACE 2                                                        08900013
* ENTRY POINT -     ENTRY IS TO 1ST EXECUTABLE INSTRUCTION FROM USER    09000013
*                   PROGRAM READ/WRITE MACRO OR QTAM OR ERP             09100013
         SPACE 2                                                        09200013
* INPUT -           REGISTER  1 - ADDRESS OF DECB                       09300013
*                   REGISTER  2 - ADDRESS OF IOB                        09400013
*                   REGISTER  4 - ADDRESS OF DCB                        09500013
*                   REGISTER 14 - RETURN ADDRESS                        09600013
         SPACE 2                                                        09700013
* OUTPUT            1.  UPDATED IOB POINTERS                            09800013
*                   2.  GENERATED CHANNEL PROGRAM                       09900013
         SPACE 2                                                        11000013
* EXTERNAL ROUTINES-1.  REQUEST/RELEASE BUFFER ROUTINE (IGG019MS)       11100013
*                   2.  DEVICE I/O MODULE FOR SPECIFIED DEVICE          11200013
*                   3.  IOS SVC 0 ROUTINE (EXECUTE CHANNEL PROGRAM)     11300013
         SPACE 2                                                        11400013
* EXIT -            RETURN TO CALLING PROGRAM ADDRESS IN REGISTER 14    11500013
         SPACE 2                                                        11600013
* IN LINE ROUTINES -THE READ/WRITE ROUTINE FINDS THE IOB, FINDS THE     11700013
*                   DEVICE I/O MODULE, OBTAINS THE AREA ADDRESS AND     11800013
*                   LENGTH, LOOPS ON THE CCW COUNT UNTIL ALL CCWS       11900013
*                   HAVE BEEN MOVED AND COMPLETED IN THE CHANNEL        12000013
*                   PROGRAM AREA OF THE IOB, AND ISSUES EXCP.           12100013
         SPACE                                                          12200013
*                   THE CCW'S IN THE DEVICE I/O MODULE ARE COMPLETE     12300013
*                   EXCEPT FOR AREA ADDRESS AND COUNT.  AN INDEX IN     12400013
*                   THE 2ND AND 7TH BYTES OF THE CCW DETERMINES WHICH   12500013
*                   SUBROUTINE IS BRANCHED TO TO COMPLETE THE AREA      12600013
*                   ADDRESS AND COUNT RESPECTIVELY.  WHERE OFFSETS      12700013
*                   TO THE NORMAL ADRS OR COUNT OCCUR THEY ALREADY      12800013
*                   EXIST IN THE CCW. THE SUB-ROUTINES ARE-             12900013
         SPACE                                                          13000013
*                        A.  DATAREA - COMPLETES THE AREA ADDRESS FOR   13100013
*                                      A READ/WRITE DATA OR READ RESP.  13200013
*                                      INTO AREA COMMAND.               13300013
         SPACE                                                          13400013
*                        B.  RESPAREA - PROVIDES THE RESPONSE ADDRESS   13500013
*                                       IN THE DECB.                    13600013
         SPACE                                                          13700013
*                        C.  SPECCHAR - PROVIDES THE CONTROL CHARACTER  13800013
*                                       ADDRESS.  THE CONTROL CHARAC-   13900013
*                                       TERS ARE DEFINED AS CONSTANTS   14000013
*                                       AT THE END OF THE DEVICE I/O    14100013
*                                       MODULE.                         14200013
         SPACE                                                          14300013
*                        D.  LIST - PROVIDES THE ADDRESS OF THE DIAL    14400013
*                                   DIGITS AND THEIR COUNT              14500013
         SPACE                                                          14600013
*                        E.  PA1050D - SEE PALIST                       14700013
         SPACE                                                          14800013
*                        F.  PALIST - FINDS THE 1ST NONSKIP POLLING     14900013
*                                     OR ADDRESSING ENTRY AND PLACES    15000013
*                                     ITS ADDRESS IN THE CCW.           15100013
         SPACE                                                          15200013
*                        G.  TWXIDENT - PROVIDES THE ADDRESS AND COUNT  15300013
*                                       OF THE TWX IDENTIFICATION       15400013
*                                       CHARACTERS.                     15500013
         SPACE                                                          15600013
*                        H.  DISABLE - DETERMINES TYPE OF DIALING       15700013
*                                       LIST AND INSERTS ENABLE COMMAND 15800013
*                                       IF IT IS AN ANSWER LIST.        15900013
         SPACE                                                          16000013
*                        I.  DATALNG -  FOR READ/WRITE DATA IT OBTAINS  16100013
*                                       THE AREA LENGTH FROM THE DECB.  16200013
         SPACE                                                          16300013
*                        J.  SENSE - PROVIDES THE ADDRESS OF THE  TP  * 16310021
*                                    OP CODE BYTE FOR READ AREA.      * 16320021
*                                                                     * 16330021
*                        K.  WTTATIC - FOR WTTA TERMINALS, IF IAM=YES * 16340021
*                                      WAS SPECIFIED IN THE DCB AND   * 16350021
*                                      WRU MACRO IN THE SENDHDR, THE  * 16360021
*                                      ADDRESS OF THE NEXT CCW IS USED* 16370021
*                                      FOR THE WRITE AREA. OTHERWISE, * 16380021
*                                      THE ADDRESS OF THE WRITE DATA  * 16390021
*                                      CCW IS USED.                   * 16400021
*                                                                     * 16410021
*                        L.  WTTARDID - FOR WTTA TERMINALS, IF WRU=YES* 16420021
*                                       IS SPECIFIED IN DCB, THE C.D. * 16430021
*                                       FLAG AND COUNT IS SET IN THE  * 16440021
*                                       CCW. THE COMPUTER ID ADDRESS  * 16450021
*                                       IS USED FOR THE READ AREA.    * 16460021
*                                                                     * 16470021
*                        N.  WTTAPAD - FOR WTTA TERMINALS, THE NUMBER * 16480021
*                                      OF PADS FROM THE DCB IS STORED * 16490021
*                                      IN THE COUNT FIELD OF THE CCW. * 16500021
*                                                                     * 16510021
*                        O.  AUTOPOLL - THE FIRST AND SECOND POLL CCWS* 16520021
*                            ARE SET UP IN THE CCW AREA. THE CHANNEL  * 16530021
*                            PROGRAM IS CONSTRUCTED IN A POLL, TIC,   * 16540021
*                            TIC, POLL, TIC SEQUENCE.                 * 16550021
*                                       IF A PERMANENT NON-TEXT ERROR * 16560021
*                            HAS OCCURED, THE POLL POINTER IS CHANGED * 16570021
*                            TO THE NEXT SET OF POLLING CHARACTERS.   * 16580021
*                                       IF THE NEXT SCHEDULER IS THE  * 16590021
*                            RECEIVE SCHEDULER, THE TIC AFTER THE     * 16600021
*                            FIRST AND SECOND POLL CCW ARE NOP'ED. IF * 16610021
*                            THE SEND SCHEDULER IS NEXT, THE TIC AFTER* 16620021
*                            THE SECOND POLL CCW IS NOP'ED.           * 16630021
*                                       IF THE LINE IS IN CONVERSE    * 16640021
*                            MODE, THE CONVERSE MODE FLAG IN LCBSTATE * 16650021
*                            IS TURNED OFF AND THE POLL CCW IS NOP'ED * 16660021
*                            AND THE CHAINING FLAG IN THE FIRST CCW IS* 16670021
*                            TURNED OFF.                              * 16680021
*                                                                     * 16690021
*                        P.  CPAREA - FOR 2740 MODEL 2 TERMINALS, THE * 16700021
*                                     CHANNEL PROGRAM IS RIGHT. FOR   * 16710021
*                                     OTHER 2740 TERMINALS, THE       * 16720021
*                                     CHAINING FLAG IS SET IN THE CCW * 16730021
*                                     WITH A COUNT OF ONE.            * 16740021
         SPACE 2                                                        16900013
* ATTRIBUTES -      THIS ROUTINE IS REENTRANT                           17000013
*1170211000-245000                                                 2936 17030016
*117030550,367400-367600                                           6646 17060016
*90351464200-464600,491500                                         000D 17065017
*2719200000,264090-265500,305600-305800                            000C 17070017
*2719367610-367830,494500,500100-500500,507000                     000C 17080017
*1202305950,340070-340910,352000,359000,464050-464150              000D 17090018
* 367693-367696                                                  A29208 17095019
*A086000,163100-167400                                           S21016 17097021
*A270230                                                         A43629 17098021
         EJECT                                                          17100013
CCWTBLRG EQU   0                        ADDRESS OF TBL OF ALL CCW'S     17200013
DECBREG  EQU   1                        PTR TO DEC                      17300013
IOBREG   EQU   2                        PTR TO IOB                      17400013
AREAREG  EQU   3                        ADDRESS OF READ-WRITE AREA      17500013
DCBREG   EQU   4                        PTR TO DCB                      17600013
CCWREG   EQU   5                        PTR TO CHANNEL COMMAND WORDS    17700013
CHPRGREG EQU   6                        ADDRESS OF MODEL CHNL PROGRAM   17800013
ZEROREG  EQU   7                        COUNT OF CCW'S COMPLETED.       17900013
ICSREG   EQU   8                        WORK REGISTER                   18000013
ICREG    EQU   9                        1 CHARACTER WORK REGISTER       18100013
ONEREG   EQU   10                       CONTAINS 1 FOR COUNT            18200013
TOTREG   EQU   11                       CONTAINS NO OF CCW'S IN CHNL PG 18300013
BASEREG  EQU   12                       BASE REGISTER                   18400013
SAVEREG  EQU   13                       SAVE REGISTER                   18500013
RETREG   EQU   14                       RETURN REGISTER                 18600013
BRREG    EQU   15                                                       18700013
DEBNMEXT EQU   16                                                       18800013
         EJECT                                                          18900013
         SR    BRREG,BRREG                                              19000013
         STM   RETREG,BASEREG,12(SAVEREG) SAVE REGISTERS                19100013
         BALR  BASEREG,0                                                19200013
         USING *,BASEREG                                                19300013
         USING IECTDECB,DECBREG                                         19400013
         USING IECTIOB,IOBREG                                           19500013
         USING IHADCB,DCBREG                                            19600013
         B     LOADCBAD                                                 19700013
         SPACE 3                                                        19800013
IOD      DS    0F                                                       19900013
         DC    22F'0'             ADDRESSES OF DEVICE I/O MODULES  000C 20000017
         SPACE 3                                                        20100013
*                                       MAIN ROUTINE                    20200013
         SPACE 2                                                        20300013
LOADCBAD L     DCBREG,DECDCBAD          LOAD DCB ADDRESS                20400013
         SR    IOBREG,IOBREG            CALCULATE PTR TO IOB            20500013
         IC    IOBREG,DCBEIOBX          SIZE                            20600013
         LR    ONEREG,IOBREG           SAVE FOR LINR ERROR REC.         20700013
         NI    DECFLAGS,X'00'           RESET FLAGS                     20800013
         MH    IOBREG,DECRLN-1          LINE NUMBER                     20900013
         A     IOBREG,DCBIOBAD          PTR TO 1ST IOB                  21000013
NOSTAT   L     AREAREG,DCBDEBAD         LOAD ADDRESS OF DEB             24600013
         NI    IOBCSW+4,X'F0'           TURN OFF CHNL END, DEVICE END,  24700013
         SR    ICSREG,ICSREG            RESET REG                       24800013
         STH   ICSREG,IOBCPA+6     ZERO BREAKOFF COUNTER                24900013
         IC    ICSREG,DCBDEVTP          LOAD DEVICE TYPE                25000013
         SLA   ICSREG,2                 MULTIPLY BY 4                   25100013
         L     CHPRGREG,IOD(ICSREG)     ADD TO DIRECTORY BASE AND LOAD  25200013
         LA    CCWREG,0(CHPRGREG)       SAVE ADRS OF START OF MODULE    25300013
         IC    ICSREG,DECTYPE+1         LOAD TYPE I/O OPERATION         25400013
         N     ICSREG,OFFMSK            AND OFF RST & INIBIT BITS (3F)  25500013
         IC    ICSREG,0(CHPRGREG,ICSREG) LOAD CHNL PROG OFFSET          25600013
         AR    CHPRGREG,ICSREG          ADD OFFSET; REG ADRS=CHAL PROG  25700013
         ST    DECBREG,IOBECBPT         ST DECB PTR IN IOB              25800013
         ST    IOBREG,DECIOBPT                                          25900013
LNGOK    MVC   DECRESPN(2),FULL4        RESET RESPONSE FIELD TO ZERO    26000013
         SR    CCWTBLRG,CCWTBLRG                                        26100013
         IC    CCWTBLRG,15(CCWREG)      LOAD OFFSET TO CCW'S            26200013
         AR    CCWTBLRG,CCWREG          ADD MODULE START ADRS           26300013
         LA    CCWREG,LCBCPA(IOBREG)    LOAD ADRS OF CHANNEL PRO& AREA  26400013
         TM    DCBCPOLL(DCBREG),X'68'  IS IT A WTTA LINE GROUP     000C 26409017
         BNO   CCWIOB                  BRANCH IF NO                000C 26418017
         CLI   DECTYPE+1,X'02'         IS IT A WRITE INITIAL       000C 26427017
         BE    CCWIOB                  YES                         000C 26436017
         TM    IOBINCAM,WRUFLG         READ CONTINUE AFTER WRU     000C 26445017
         BNO   *+12                    NO,MODIFIE IOBSTART         000C 26454017
         NI    IOBINCAM,255-WRUFLG     RESET WRU FLAG              000C 26463017
         B     CCWIOB                                              000C 26472017
         LA    CCWREG,24(CCWREG)      POINT TO PREPARE OR READ CCW 000C 26481017
         NI    41(IOBREG),255-DATAFLG  RESET DATA FLAG FOR WTTA    000C 26490017
CCWIOB   ST    CCWREG,IOBSTART         INITIALIZE IOBSTART         000C 26520017
         LA    CCWREG,LCBCPA(IOBREG)   POINT AT CCW AREA BEGIN     000C 26550017
         SR    TOTREG,TOTREG                                            26600013
         SR    ICREG,ICREG                                              26700013
         LA    ONEREG,1                 LOAD CONSTANT 1                 26800013
         BAL   RETREG,RSTENTRY                                          26900013
ENDCCW   LR    DECBREG,IOBREG                                           27000013
         LR    ICSREG,IOBREG           IOB ADDRESS TO WORK REG    M3173 27010018
         SH    ICSREG,H48              BACK UP TO LCB             M3173 27020018
         CLI   LCBCECB(ICSREG),X'0A'  WRITE NEG-ACK C.P.         A43629 27023021
         BNE   CKREAD             BRANCH IF NO                   A43629 27026021
         MVI   LCBCPA+16(IOBREG),8  MOVE IN TIC SO ERP CAN       A43629 27029021
*                                   SAVE THE FAILING CCW         A43629 27032021
CKREAD   CLI   LCBCECB(ICSREG),1  IS THIS A READ INITIAL         A43629 27035021
         BNE   EXCP                    NO, DO EXCP                M3173 27040018
         CLI   IOBINCAM,2              IS LINE CONNECTED          M3173 27050018
         BNE   EXCP                    NO, DO EXCP                M3173 27060018
         LA    ICSREG,LCBCPA+16(IOBREG) ELSE SET IOBSTART         M3173 27070018
         ST    ICSREG,IOBSTART     PAST ENABLE/DISABLE COMMANDS   M3173 27080018
EXCP     EQU   *                                                  M3173 27090018
         EXCP  (1)                      EXECUTE CHANNEL PROGRAM         27100013
RESTREG  LM    RETREG,BASEREG,12(SAVEREG) RESTORE REGISTERS             27200013
         BR    RETREG                   RETURN TO USER                  27300013
         EJECT                                                          27400013
RSTENTRY LR    ZEROREG,ONEREG           RESET REGISTERS                 27500013
         IC    TOTREG,0(CHPRGREG)       LOAD COUNT OF CCW'S IN CHNL PRG 27600013
         N     TOTREG,OFFMSK            AND OF RESET BIT IF PRESENT     27700013
MOVECCW  SR    ICSREG,ICSREG                                            27800013
         IC    ICSREG,0(ZEROREG,CHPRGREG) LOAD OFFSET TO CCW WANTED     27900013
         SLA   ICSREG,3                 MULTIPLY BY SIZE OF CCW'S       28000013
         AR    ICSREG,CCWTBLRG          ADD TABLE STARTING ADDRESS      28100013
         MVC   0(8,CCWREG),0(ICSREG)    MOVE CCW TO CHNL PROS AREA      28200013
         IC    ICREG,1(CCWREG)          LOAD AREA INDEX                 28300013
         MVI   1(CCWREG),X'00'          ZERO INDEX IN CCW               28400013
         L     AREAREG,DECENTRY                                         28500013
         LA    AREAREG,0(AREAREG)                                       28600013
         B     BTBL1(ICREG)             GO TO AREA ROUTINE              28700013
TESTLNG  IC    ICREG,6(CCWREG)          LOAD LNGTH INDEX                28800013
         B     BTBL2(ICREG)             GO TO LENGTH ROUTINE            28900013
TESTLAST BXH   ZEROREG,ONEREG,0(RETREG) IS CHANNEL PROGRAM COMPLETE     29000013
         LA    CCWREG,8(CCWREG)         INCREMENT CCW ADDRESS           29100013
         B     MOVECCW                  GO TO MOVE IN NEXT CCW          29200013
         EJECT                                                          29300013
*                                       BRANCHING TABLE                 29400013
         SPACE 2                                                        29500013
BTBL1    B     TESTLNG               00 NO AREA, PRESET ADDRESS         29600013
         B     DATAREA               04 I/0 TO/FM DATA AREA + INCREMENT 29700013
         B     RESPAREA              08 READ INTO FIRST DATA AREA BYTE  29800013
         B     SPECCHAR              0C WRITE SPECIAL CHARACTER(S)      29900013
         B     LIST                  10 WRITE DIAL LIST                 30000013
         B     PALIST                14 WRITE POLLING CHARACTERS        30100013
         B     TWXIDENT              18 WRITE TWX IDENT                 30200013
         B     PA1050D               1C WRITE 1050 DIAL ADRS CHARACTERS 30300013
         B     DISABLE               20 DISABLE LINE                    30400013
         B     AUTOPOLL                                                 30500013
         B     SENSE               28 SET UP SENSE ADDRESS         6646 30550016
         B     WTTATIC              2C WTTA TIC                    000C 30560017
         B     WTTARDID             30 WTTA TERMINAL-IDENT         000C 30570017
         B     WTTAWTID             34 WTTA CPU-IDENT              000C 30580017
         B     WTTAPAD             38 WTTA WRITE PAD               000C 30590017
         B     CPAREA              3C   READ INTO TIC CCW IN CPA   000D 30595018
         SPACE 3                                                        30600013
BTBL2    B     TESTLAST              00 NO ADDITIONAL COUNT NEEDED      30700013
         B     DATALNG               04 GET LENGTH FROM DECB            30800013
         EJECT                                                          30900013
*                                       AREA ROUTINES                   31000013
         SPACE 2                                                        31100013
DATAREA  L     AREAREG,0(CCWREG)        LOAD PRESET AREA MODIFICATION   31200013
         A     AREAREG,DECAREA          ADD AREA ADDRESS                31300013
         ST    AREAREG,0(CCWREG)        STORE IN CCW                    31400013
QCCWST   LR    ICSREG,CCWREG           ADDRESS OF FIRST DATA CCW        31500013
         LA    AREAREG,LCBCPA(IOBREG)  START OF CHANNEL PROGRAM AREA    31600013
         SR    ICSREG,AREAREG          OFFSET TO FIRST DATA CCW         31700013
         STC   ICSREG,43(IOBREG)       STORE IN LCBERCCW+3              31800013
         B     TESTLNG                                                  31900013
         SPACE 3                                                        32000013
RESPAREA LA    AREAREG,DECRESPN         LOAD RESPONSE AREA ADDRESS      32100013
         A     AREAREG,0(CCWREG)        ADD CCW COMMAND                 32200013
STRESP   ST    AREAREG,0(CCWREG)        STORE IN CCW                    32300013
         LTR   BRREG,BRREG              IS WREG EMPTY                   32400013
         BZ    TESTLNG                  YES, POLL/ADRS DOES NOT PRECEDE 32500013
         TM    0(BRREG),X'80'           NO, IS POLL/ADRS TERM LAST      32600013
         BZ    RSTBRREG                 NO                              32700013
         OI    4(CCWREG),X'40'          YES, SET ON CC FLAG IN THE CCW  32800013
RSTBRREG SR    BRREG,BRREG              RESET REGISTER                  32900013
         B     TESTLNG                                                  33000013
         SPACE 3                                                        33100013
SPECCHAR LR    AREAREG,CCWTBLRG         LOAD BASE ADDRESS OF CONSTANTS  33200013
         A     AREAREG,0(CCWREG)        ADD OFFSET TO SPECIAL CHARACTER 33300013
         ST    AREAREG,0(CCWREG)        STORE IN CCW                    33400013
         B     TESTLAST                                                 33500013
         SPACE 3                                                        33600013
LIST     MVC   7(1,CCWREG),0(AREAREG)   MOVE DIAL COUNT TO COUNT FIELD  33700013
         A     AREAREG,0(CCWREG)        ADD COMMAND AND ADRS OFFSET     33800013
         ST    AREAREG,0(CCWREG)                                        33900013
         B     TESTLNG                                                  34000013
         SPACE 3                                                        34007018
CPAREA   LR    AREAREG,TOTREG      GET TOTAL NUMBER OF CCW'S       000D 34014018
         SLL   AREAREG,3           MULTIPLY BY 8(LENGTH OF ONE CCW)000D 34021018
         LA    AREAREG,LCBCPA+6(IOBREG,AREAREG)  POINT TO END      000D 34028018
*                                    OF TIC CCW IN CHANNEL PROGRAM 000D 34035018
         XC    0(2,AREAREG),0(AREAREG)  ZERO RESPONSE AREA         000D 34042018
         L     ICSREG,52(SAVEREG)  RELOAD TERMTABLE ENTRY ADDRESS  000D 34049018
         TM    8(ICSREG),X'10'     DOES THIS TERMINAL HAVE TWO-    000D 34056018
*                                    CHARACTER RESPONSE            000D 34063018
         BO    SPECCHAR+2          YES, CHANNEL PROGRAM IS OK      000D 34070018
         MVI   4(CCWREG),X'40'     SET CHAINING FLAG               000D 34077018
         MVI   7(CCWREG),1         SET COUNT TO ONE                000D 34084018
         B     SPECCHAR+2          STORE ADDRESS IN CCW            000D 34091018
         EJECT                                                          34100013
PA1050D  IC    ICREG,0(AREAREG)         INSERT COUNT OF DIAL CHARACTERS 34200013
         LA    AREAREG,1(ICREG,AREAREG) ADD TO ADRS FOR POLL/ADRS CHAR  34300013
         SPACE 3                                                        34400013
PALIST   IC    ICREG,7(CCWREG)          LOAD COUNT OF P-A CHARACTERS    34500013
         AR    AREAREG,ICREG            ADD TO ADDRESS                  34600013
PAOK     IC    ICREG,2(CCWREG)          LOAD POLL-ADRS OFFSET           34700013
         MVI   2(CCWREG),X'00'          ZERO OFFSET                     34800013
         LR    BRREG,AREAREG            SAVE ADRS OF CONTROL BYTE       34900013
         SH    AREAREG,6(CCWREG)        SUBTRACT TO GET ADRS OF P/A CHR 35000013
         B     SPECCHAR+2          STORE ADDRESS IN CCW            000D 35200018
         EJECT                                                          35400013
TWXIDENT IC    ICREG,0(AREAREG)         INSERT COUNT OF DIAL CHARACTERS 35500013
         LA    AREAREG,1(ICREG,AREAREG) ADD TO LIST ADRS                35600013
         MVC   7(1,CCWREG),0(AREAREG)   MOVE COUNT OF IDENT TO CCW      35700013
         B     SPECCHAR+2          STORE ADDRESS IN CCW            000D 35900018
         SPACE 3                                                        36100013
DISABLE  CLI   0(AREAREG),X'00'         IS LIST AN ANSWER LIST          36200013
         BNE   TESTLAST                 NO,O.K. TO SET UP DIAL CCW      36300013
         BXH   ZEROREG,ONEREG,0(RETREG) YES, STEP CNTR OMITTING DIAL    36400013
         LA    CCWREG,8(CCWREG)         STEP CCW REGISTER               36500013
         MVC   0(8,CCWREG),ENABLCCW     USE ENABLE CCWVS. DIAL          36600013
         B     TESTLAST                                                 36700013
         SPACE 2                                                        36720016
SENSE    LA    AREAREG,5(CCWREG)  ADDRESS OF TP OP CODE BYTE       6646 36740016
         B     SPECCHAR+2         USE COMMON CODE                  6646 36760016
         SPACE 3                                                   000C 36761017
WTTATIC  LA    AREAREG,8(CCWREG)       POINT TO THE NEXT CCW       000C 36762017
         TM    DCBBQFLG,IAM+SNDHDR     IAM=YES AND WRU IN SENDHDR  000C 36763017
         BO    SPECCHAR+2              YES                         000C 36764017
         LA    AREAREG,24(AREAREG)     POINT TO WRITE DATA CCW     000C 36765017
         B     SPECCHAR+2                                          000C 36766017
         SPACE 3                                                   000C 36767017
WTTARDID L     AREAREG,DECADRPT        GET TERM ID FIELD           000C 36768017
         IC    ICREG,1(AREAREG)        PICK UP SIZE OF TERM ID     000C 36769017
         LTR   ICREG,ICREG        IS TERM ID SPECIFIED           A29208 36769319
         BZ    *+6                BRANCH IF NO                   A29208 36769619
         BCTR  ICREG,0                 REDUCE COUNT BY OME         000C 36770017
*                        (THIS TO AVOID A TIME-OUT ON READ IDENT)  000C 36771017
         STC   ICREG,7(CCWREG)         SET COUNT IN CCW            000C 36772017
         LA    AREAREG,3(ICREG,AREAREG) GET TERM ID ADDRESS        000C 36773017
         B     SPECCHAR+2                                          000C 36774017
         SPACE 3                                                   000C 36775017
WTTAWTID TM    DCBBQFLG,WRU            IS WRU=YES                  000C 36776017
         BNO   *+8                     NO                          000C 36777017
         OI    4(CCWREG),X'80'         YES ,SET CD FLAG            000C 36778017
         L     AREAREG,DECPOLPT        GET POLLING ADDRESS         000C 36779017
         MVC   7(1,CCWREG),3(AREAREG)  SET COUNT IN CCW            000C 36780017
         LA    AREAREG,4(AREAREG)      GET COMPUTER ID ADDRESS     000C 36781017
         B     SPECCHAR+2                                          000C 36782017
         SPACE 2                                                        36783017
WTTAPAD  IC    ICREG,DCBWTPAD          PICK-UP PADDING COUNT       000C 36784017
         LA    ICREG,1(ICREG)          ADD ONE                     000C 36785017
         STC   ICREG,7(CCWREG)         AND STORE IN CCW COUNT      000C 36786017
         B     SPECCHAR                                                 36787017
         EJECT                                                          36788017
         SPACE 3                                                        36800013
*                                       LENGTH ROUTINES                 36900013
         SPACE 2                                                        37000013
DATALNG NI     6(CCWREG),X'00'          ZERO SUB-ROUTINE INDEX          37100013
         LH    AREAREG,DECLNGTH         LOAD LENGTH FROM DECB           37200013
         SH    AREAREG,6(CCWREG)        SUBTRACT OFFSET                 37300013
         STH   AREAREG,6(CCWREG)        STORE IN CCW                    37400013
         B     TESTLAST                                                 37500013
         EJECT                                                          37600013
*********************************************************************** 37700013
*                                                                     * 37800013
* THIS ROUTINE BUILDS A MAJOR PORTION OF THE AUTOPOLL CHANNEL PROGRAM * 37900013
* IN PARTICULAR IT COMPLETS THE 1ST POLL CCW (WHICH WAS PICKED UP     * 38000013
* FROM THE DEVICE I/O MODULE) AND CONSTRUCTS THE POLL, TIC,TIC, POLL, * 38100013
* TIC CCW SEQUENCE                                                    * 38200013
*                                                                     * 38300013
*********************************************************************** 38400013
*                                                                       38500013
* THIS CODE BUILDS THE FIRST TIC                                        38600013
*                                                                       38700013
AUTOPOLL MVC   8(8,CCWREG),APTIC   MOVE MODEL TIC BEHIND 1ST POLL CCW   38800013
         LA    ICSREG,24(CCWREG)   LOAD ADDRESS OF 2ND POLL CCW         38900013
         O     ICSREG,8(CCWREG)    GET TIC COMMAND CODE                 39000013
         ST    ICSREG,8(CCWREG)    COMPLETE THE TIC CCW                 39100013
*                                                                       39200013
* OBTAIN MODEL FOR 2ND POLL CCW AND THE COMPLETE 3RD TIC CCW            39300013
*                                                                       39400013
         MVC   24(16,CCWREG),0(CCWREG)                                  39500013
*                                                                       39600013
* THIS CODE BUILDS THE 2ND TIC CCW                                      39700013
*                                                                       39800013
         MVC   16(8,CCWREG),APTIC  MOVE MODEL TIC BEHIND 1ST TIC CCW    39900013
         LA    ICSREG,40(CCWREG)   LOAD ADDRESS OF READ INDEX CCW       40000013
         O     ICSREG,16(CCWREG)   GET TIC COMMAND CODE                 40100013
         ST    ICSREG,16(CCWREG)   COMPLETE THE 2ND TIC CCW             40200013
*                                                                       40300013
* COMPLETE DATA ADDRESS OF 1ST POLL CCW                                 40400013
*                                                                       40500013
         L     ICSREG,IOBPOLPT     LOAD DATA ADDRESS                    40600013
         ST    ICSREG,0(CCWREG)    STORE DATA ADDRESS                   40700013
         MVI   0(CCWREG),X'09'     RESTORE POLL COMMAND CODE            40800013
*                                                                       40900013
* OBTAIN COUNT FOR 1ST POLL CCW                                         41000013
*                                                                       41100013
         LA    ICSREG,0(ICSREG)    CLEAR HI ORDER BYTE                  41200013
         LR    ICREG,ICSREG        SAVE DATA ADDRESS                    41300013
APLOOP   AR    ICREG,ONEREG        ADD ONE TO DATA ADDRESS              41400013
         CLI   0(ICREG),X'FE'      IS THIS THE SCAN STOP BYTE           41500013
         BNE   APLOOP              IF NO LOOP                           41600013
         LR    AREAREG,ICREG       IF YES SAVE STOP BYTE ADDRESS        41700013
         SR    ICREG,ICSREG        COMPUTE COUNT FOR 1ST POLL CCW       41800013
         STH   ICREG,6(CCWREG)     STORE COUNT IN CCW                   41900013
*                                                                       42000013
* COMPUTE COUNT AND DATA ADDRESS FOR 2ND POLL CCW                       42100013
*                                                                       42200013
         MVC   22(2,CCWREG),1(AREAREG) MOVE OFFSET TO BEGINNING OF      42300013
*                                  POLLING LIST TO A HALF WORD WRKAREA  42400013
         SH    AREAREG,22(CCWREG)  FIND START OF POLLING LIST MINUS ONE 42500013
         SR    ICREG,ICREG                                              42600013
         SR    ICSREG,ICSREG                                            42700013
         IC    ICREG,5(AREAREG)    GET BYTE CONTAINING WIDTH            42800013
         SRL   ICREG,5             SHIFT WIDTH TO LOW ORDER POSITIONS   42900013
         IC    ICSREG,4(AREAREG)   GET NUMBER OF ENTRIES IN POLING LIST 43000013
         STH   ICREG,22(CCWREG)    STORE WIDTH IN HALF WORD WORK AREA   43100013
         MH    ICSREG,22(CCWREG)   COMPUTE COUNT                        43200013
         STH   ICSREG,30(CCWREG)   STORE COUNT IN 2ND CCW               43300013
         LA    AREAREG,6(AREAREG)  GET ADDRESS OF FIRST POLLING CHAR    43400013
         ST    AREAREG,24(CCWREG)  STORE DATA ADDRESS                   43500013
         MVI   24(CCWREG),X'09'    RESTORE POLL COMMAND CODE            43600013
*                                                                       43700013
* IF A PERMANENT NON-TEXT ERROR HAS OCCURRED THUS CODE ADJUSTS THE POLL 43800013
* POINTER TO THE 'NEXT' SET OF POLLING CHARACTERS                       43900013
*                                                                       44000013
         CLI   IOBERRCT,X'03'      IS THERE A PERMANENT NON-TEXT ERROR  44100013
         BNE   APOUT               BRANCH IF NO                         44200013
*                                                                       44300013
* THIS CODE ADJUSTS THE LCB POLL POINTER TO THE 'NEXT' TERMINAL THEN    44400013
* RE-EXECUTES THE MAIN AUTOPOLL ROUTINE                                 44500013
*                                                                       44600013
         L     ICSREG,IOBPOLPT     GET CURRENT POLL POINTER             44700013
         LA    ICSREG,0(ICSREG,ICREG) INCREMENT TO NEXT TERMINAL        44800013
*                                    AND ZERO POLL COUNTER              44900013
         CLI   0(ICSREG),X'FE'     TEST FOR END OF POLLING LIST         45000013
         BNE   APSTORE             BRANCH IF NOT END                    45100013
         LR    ICSREG,AREAREG      LOAD ADDRESS OF POLLING CHARACTERS   45200013
*                                  FOR THE 1ST TERMINAL IN LIST         45300013
APSTORE  ST    ICSREG,IOBPOLPT     STORE NEW POLL COUNT AND POINTER     45400013
         MVI   IOBERRCT,X'00'      INDICATE ERROR HANDLED               45500013
         B     AUTOPOLL                                                 45600013
*                                                                       45700013
* THE PREVIOUS CODE BUILT A WRAP CHANNEL PROGRAM. IF THE LCB LINK       45800013
* FIELD DOES NOT POINT TO THE QDISPATCH STCB THEN THERE IS A STCB       45900013
* ON THE CHAIN WHICH REQUIRES AN OPEN CHANNEL PROGRAM.  THIS CODE TESTS 46000013
* FOR SUCH A CONDITION AND ADJUSTS THE CHANNEL PROGRAM IF NECESSARY     46100013
*                                                                       46200013
APOUT    LR    ICSREG,IOBREG       LOAD IOB ADDRESS INTO WORK REGISTER  46300013
         SH    ICSREG,H48          BACK UP TO LCB                       46400013
         L     ICREG,LCBSCHAD(ICSREG)    GET ADDRESS OF FIRST STCB000D  46405018
         CLI   0(ICREG),X'12'     IS THIS THE RECEIVE SCHEDULER   000D  46410018
         BNE   *+16                                               000D  46415018
         L     ICREG,LCBSCHLK(ICSREG) GET ADDRESS OF NEXT STCB          46500013
         CLI   TPRI(ICREG),X'FF'   IS THIS QDISPATCH STCB               46600013
         BE    *+12                BRANCH IF YES                        46700013
         MVI   8(CCWREG),X'03'     NOP THE TIC AFTER 1ST POLL CCW       46800013
         MVI   32(CCWREG),X'03'    NOP THE TIC AFTER 2ND POLL CCW       46900013
*                                                                       47000013
*                                                                       47100013
* IF THE LINE IS IN CONVERSE MODE PREPARE THE CHANNEL PROGRAM TO        47200013
* CAUSE AN IMMEDIATE INTERRUPT                                          47300013
*                                                                       47400013
         TM    LCBSTATE(ICSREG),X'20' IS THE LINE IN CONVERSE MODE      47500013
         BZ    *+16                BRANCH IF NO                         47600013
         XI    LCBSTATE(ICSREG),X'20' TURN OFF CONVERSE MODE FLAG       47700013
         MVI   0(CCWREG),X'03'     NOP THE 1ST POLL CCW                 47800013
         MVI   4(CCWREG),X'20'     TURN OFF CHAINING FLAGS IN 1ST POLL  47900013
*                                                                       48000013
* THIS CODE PREPARES FOR BUILDING NEXT CCW AND LEAVES AUTOPOLL ROUTINE  48100013
*                                                                       48200013
         LA    CCWREG,32(CCWREG)   SET FOR BUILDING READ INDEX CCW      48300013
         SR    ICREG,ICREG         LEAVE REGISTER CLEARED               48400013
         B     TESTLAST                                                 48500013
*                                                                       48600013
APTIC    DC    X'08000000200900FF'                                      48700013
H48      DC    H'48'                                                    48800013
LCBSTATE EQU   0                                                        48900013
TPRI     EQU   4                                                        49000013
LCBSCHLK EQU   12                                                       49100013
LCBSCHAD  EQU  8                                                        49150017
LCBCECB  EQU   4                                                  M3173 49170018
         EJECT                                                          49200013
         SPACE 2                                                        49300013
DCBKSTAT EQU   52                                                       49400013
DCBCPOLL EQU   56                                                  000C 49450017
FULL4    DC    F'4'                                                     49500013
OFFMSK   DC    X'0000003F'                                              49600013
ENABLCCW DC    X'2700000020010001'   14 ENABLE          SLI, L=1        49700013
H64      DC    AL2(64)                                                  49800013
         CNOP  0,8                                                      49900013
LCBCPA   EQU   48                                                       50000013
WRU      EQU   X'40'                   WRU=YES CODED IN DCB        000C 50010017
IAM      EQU   X'20'                   IAM=YES CODED IN DCB        000C 50020017
SNDHDR   EQU   X'10'                   WRU MACRO IN SENDHDR        000C 50030017
DATAFLG  EQU   X'20'                   DATA FLAG                   000C 50040017
WRUFLG   EQU   X'40'                   WTTA IDENT REQUIRED         000C 50050017
         EJECT                                                          50100013
         IECTDECB                                                       50200013
         EJECT                                                          50300013
         IECKQIOB                                                       50400013
DECIOBPT EQU   DECSENS0                                                 50500013
         EJECT                                                          50600013
         DCBD  DSORG=BX,DEVD=WT                                    000C 50700017
         END                                                            50800013
